1 #
2 # Copyright (c) 2011, 2016, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 AC_DEFUN([BPERF_CHECK_CORES],
27 [
28 AC_MSG_CHECKING([for number of cores])
29 NUM_CORES=1
30 FOUND_CORES=no
31
32 if test -f /proc/cpuinfo; then
33 # Looks like a Linux (or cygwin) system
34 NUM_CORES=`cat /proc/cpuinfo | grep -c processor`
35 FOUND_CORES=yes
36 elif test -x /usr/sbin/psrinfo; then
37 # Looks like a Solaris system
38 NUM_CORES=`LC_MESSAGES=C /usr/sbin/psrinfo -v | grep -c on-line`
39 FOUND_CORES=yes
40 elif test -x /usr/sbin/sysctl; then
41 # Looks like a MacOSX system
42 NUM_CORES=`/usr/sbin/sysctl -n hw.ncpu`
43 FOUND_CORES=yes
44 elif test "x$OPENJDK_BUILD_OS" = xaix ; then
45 NUM_CORES=`/usr/sbin/prtconf | grep "^Number Of Processors" | awk '{ print [$]4 }'`
46 FOUND_CORES=yes
47 elif test -n "$NUMBER_OF_PROCESSORS"; then
48 # On windows, look in the env
49 NUM_CORES=$NUMBER_OF_PROCESSORS
50 FOUND_CORES=yes
51 fi
52
53 if test "x$FOUND_CORES" = xyes; then
54 AC_MSG_RESULT([$NUM_CORES])
55 else
56 AC_MSG_RESULT([could not detect number of cores, defaulting to 1])
57 AC_MSG_WARN([This will disable all parallelism from build!])
58 fi
59 ])
60
61 AC_DEFUN([BPERF_CHECK_MEMORY_SIZE],
62 [
63 AC_MSG_CHECKING([for memory size])
64 # Default to 1024 MB
65 MEMORY_SIZE=1024
66 FOUND_MEM=no
67
68 if test -f /proc/meminfo; then
69 # Looks like a Linux (or cygwin) system
70 MEMORY_SIZE=`cat /proc/meminfo | grep MemTotal | awk '{print [$]2}'`
71 MEMORY_SIZE=`expr $MEMORY_SIZE / 1024`
72 FOUND_MEM=yes
73 elif test -x /usr/sbin/prtconf; then
74 # Looks like a Solaris or AIX system
75 MEMORY_SIZE=`/usr/sbin/prtconf 2> /dev/null | grep "^Memory [[Ss]]ize" | awk '{ print [$]3 }'`
76 FOUND_MEM=yes
77 elif test -x /usr/sbin/sysctl; then
78 # Looks like a MacOSX system
79 MEMORY_SIZE=`/usr/sbin/sysctl -n hw.memsize`
80 MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`
81 FOUND_MEM=yes
82 elif test "x$OPENJDK_BUILD_OS" = xwindows; then
83 # Windows, but without cygwin
84 MEMORY_SIZE=`wmic computersystem get totalphysicalmemory -value | grep = | cut -d "=" -f 2-`
85 MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`
86 FOUND_MEM=yes
87 fi
88
89 if test "x$FOUND_MEM" = xyes; then
90 AC_MSG_RESULT([$MEMORY_SIZE MB])
91 else
92 AC_MSG_RESULT([could not detect memory size, defaulting to $MEMORY_SIZE MB])
93 AC_MSG_WARN([This might seriously impact build performance!])
94 fi
95 ])
96
97 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_CORES],
98 [
99 # How many cores do we have on this build system?
100 AC_ARG_WITH(num-cores, [AS_HELP_STRING([--with-num-cores],
101 [number of cores in the build system, e.g. --with-num-cores=8 @<:@probed@:>@])])
102 if test "x$with_num_cores" = x; then
103 # The number of cores were not specified, try to probe them.
104 BPERF_CHECK_CORES
105 else
106 NUM_CORES=$with_num_cores
107 fi
108 AC_SUBST(NUM_CORES)
109 ])
110
111 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_MEMORY],
112 [
113 # How much memory do we have on this build system?
114 AC_ARG_WITH(memory-size, [AS_HELP_STRING([--with-memory-size],
115 [memory (in MB) available in the build system, e.g. --with-memory-size=1024 @<:@probed@:>@])])
116 if test "x$with_memory_size" = x; then
117 # The memory size was not specified, try to probe it.
118 BPERF_CHECK_MEMORY_SIZE
119 else
120 MEMORY_SIZE=$with_memory_size
121 fi
122 AC_SUBST(MEMORY_SIZE)
123 ])
124
125 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_JOBS],
126 [
127 # Provide a decent default number of parallel jobs for make depending on
128 # number of cores, amount of memory and machine architecture.
129 AC_ARG_WITH(jobs, [AS_HELP_STRING([--with-jobs],
130 [number of parallel jobs to let make run @<:@calculated based on cores and memory@:>@])])
131 if test "x$with_jobs" = x; then
132 # Number of jobs was not specified, calculate.
133 AC_MSG_CHECKING([for appropriate number of jobs to run in parallel])
134 # Approximate memory in GB.
135 memory_gb=`expr $MEMORY_SIZE / 1024`
136 # Pick the lowest of memory in gb and number of cores.
137 if test "$memory_gb" -lt "$NUM_CORES"; then
138 JOBS="$memory_gb"
139 else
140 JOBS="$NUM_CORES"
141 fi
142 if test "$JOBS" -eq "0"; then
143 JOBS=1
144 fi
145 AC_MSG_RESULT([$JOBS])
146 else
147 JOBS=$with_jobs
148 fi
149 AC_SUBST(JOBS)
150 ])
151
152 AC_DEFUN_ONCE([BPERF_SETUP_TEST_JOBS],
153 [
154 # The number of test jobs will be chosen automatically if TEST_JOBS is 0
155 AC_ARG_WITH(test-jobs, [AS_HELP_STRING([--with-test-jobs],
156 [number of parallel tests jobs to run @<:@based on build jobs@:>@])])
157 if test "x$with_test_jobs" = x; then
158 TEST_JOBS=0
159 else
160 TEST_JOBS=$with_test_jobs
161 fi
162 AC_SUBST(TEST_JOBS)
163 ])
164
165 AC_DEFUN([BPERF_SETUP_CCACHE],
166 [
167 AC_ARG_ENABLE([ccache],
168 [AS_HELP_STRING([--enable-ccache],
169 [enable using ccache to speed up recompilations @<:@disabled@:>@])])
170
171 CCACHE=
172 CCACHE_STATUS=
173 AC_MSG_CHECKING([is ccache enabled])
174 if test "x$enable_ccache" = xyes; then
175 if test "x$TOOLCHAIN_TYPE" = "xgcc" -o "x$TOOLCHAIN_TYPE" = "xclang"; then
176 AC_MSG_RESULT([yes])
177 OLD_PATH="$PATH"
178 if test "x$TOOLCHAIN_PATH" != x; then
179 PATH=$TOOLCHAIN_PATH:$PATH
180 fi
181 BASIC_REQUIRE_PROGS(CCACHE, ccache)
182 PATH="$OLD_PATH"
183 CCACHE_VERSION=[`$CCACHE --version | head -n1 | $SED 's/[A-Za-z ]*//'`]
184 CCACHE_STATUS="Active ($CCACHE_VERSION)"
185 else
186 AC_MSG_RESULT([no])
187 AC_MSG_WARN([ccache is not supported with toolchain type $TOOLCHAIN_TYPE])
188 fi
189 elif test "x$enable_ccache" = xno; then
190 AC_MSG_RESULT([no, explicitly disabled])
191 CCACHE_STATUS="Disabled"
192 elif test "x$enable_ccache" = x; then
193 AC_MSG_RESULT([no])
194 else
195 AC_MSG_RESULT([unknown])
196 AC_MSG_ERROR([--enable-ccache does not accept any parameters])
197 fi
198 AC_SUBST(CCACHE)
199
200 AC_ARG_WITH([ccache-dir],
201 [AS_HELP_STRING([--with-ccache-dir],
202 [where to store ccache files @<:@~/.ccache@:>@])])
203
204 if test "x$with_ccache_dir" != x; then
205 # When using a non home ccache directory, assume the use is to share ccache files
206 # with other users. Thus change the umask.
207 SET_CCACHE_DIR="CCACHE_DIR=$with_ccache_dir CCACHE_UMASK=002"
208 if test "x$CCACHE" = x; then
209 AC_MSG_WARN([--with-ccache-dir has no meaning when ccache is not enabled])
210 fi
211 fi
212
213 if test "x$CCACHE" != x; then
214 BPERF_SETUP_CCACHE_USAGE
215 fi
216 ])
217
218 AC_DEFUN([BPERF_SETUP_CCACHE_USAGE],
219 [
220 if test "x$CCACHE" != x; then
221 if test "x$USE_PRECOMPILED_HEADER" = "x1"; then
222 HAS_BAD_CCACHE=[`$ECHO $CCACHE_VERSION | \
223 $GREP -e '^1.*' -e '^2.*' -e '^3\.0.*' -e '^3\.1\.[0123]$'`]
224 if test "x$HAS_BAD_CCACHE" != "x"; then
225 AC_MSG_ERROR([Precompiled headers requires ccache 3.1.4 or later, found $CCACHE_VERSION])
226 fi
227 AC_MSG_CHECKING([if C-compiler supports ccache precompiled headers])
228 CCACHE_PRECOMP_FLAG="-fpch-preprocess"
229 PUSHED_FLAGS="$CXXFLAGS"
230 CXXFLAGS="$CCACHE_PRECOMP_FLAG $CXXFLAGS"
231 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [CC_KNOWS_CCACHE_TRICK=yes], [CC_KNOWS_CCACHE_TRICK=no])
232 CXXFLAGS="$PUSHED_FLAGS"
233 if test "x$CC_KNOWS_CCACHE_TRICK" = xyes; then
234 AC_MSG_RESULT([yes])
235 CFLAGS_CCACHE="$CCACHE_PRECOMP_FLAG"
236 AC_SUBST(CFLAGS_CCACHE)
237 CCACHE_SLOPPINESS=pch_defines,time_macros
238 else
239 AC_MSG_RESULT([no])
240 AC_MSG_ERROR([Cannot use ccache with precompiled headers without compiler support for $CCACHE_PRECOMP_FLAG])
241 fi
242 fi
243
244 CCACHE="CCACHE_COMPRESS=1 $SET_CCACHE_DIR \
245 CCACHE_SLOPPINESS=$CCACHE_SLOPPINESS CCACHE_BASEDIR=$TOPDIR $CCACHE"
246
247 if test "x$SET_CCACHE_DIR" != x; then
248 mkdir -p $CCACHE_DIR > /dev/null 2>&1
249 chmod a+rwxs $CCACHE_DIR > /dev/null 2>&1
250 fi
251 fi
252 ])
253
254 ################################################################################
255 #
256 # Runs icecc-create-env once and prints the error if it fails
257 #
258 # $1: arguments to icecc-create-env
259 # $2: log file
260 #
261 AC_DEFUN([BPERF_RUN_ICECC_CREATE_ENV],
262 [
263 ( cd ${CONFIGURESUPPORT_OUTPUTDIR}/icecc \
264 && ${ICECC_CREATE_ENV} $1 > $2 2>&1 )
265 if test "$?" != "0"; then
266 AC_MSG_NOTICE([icecc-create-env output:])
267 cat $2
268 AC_MSG_ERROR([Failed to create icecc compiler environment])
269 fi
270 ])
271
272 ################################################################################
273 #
274 # Optionally enable distributed compilation of native code using icecc/icecream
275 #
276 AC_DEFUN([BPERF_SETUP_ICECC],
277 [
278 AC_ARG_ENABLE([icecc], [AS_HELP_STRING([--enable-icecc],
279 [enable distribted compilation of native code using icecc/icecream @<:@disabled@:>@])])
280
281 if test "x${enable_icecc}" = "xyes"; then
282 BASIC_REQUIRE_PROGS(ICECC_CMD, icecc)
283 old_path="$PATH"
284
285 # Look for icecc-create-env in some known places
286 PATH="$PATH:/usr/lib/icecc:/usr/lib64/icecc"
287 BASIC_REQUIRE_PROGS(ICECC_CREATE_ENV, icecc-create-env)
288 # Use icecc-create-env to create a minimal compilation environment that can
289 # be sent to the other hosts in the icecream cluster.
290 icecc_create_env_log="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/icecc_create_env.log"
291 ${MKDIR} -p ${CONFIGURESUPPORT_OUTPUTDIR}/icecc
292 # Older versions of icecc does not have the --gcc parameter
293 if ${ICECC_CREATE_ENV} | $GREP -q -e --gcc; then
294 icecc_gcc_arg="--gcc"
295 fi
296 if test "x${TOOLCHAIN_TYPE}" = "xgcc"; then
297 BPERF_RUN_ICECC_CREATE_ENV([${icecc_gcc_arg} ${CC} ${CXX}], \
298 ${icecc_create_env_log})
299 elif test "x$TOOLCHAIN_TYPE" = "xclang"; then
300 # For clang, the icecc compilerwrapper is needed. It usually resides next
301 # to icecc-create-env.
302 BASIC_REQUIRE_PROGS(ICECC_WRAPPER, compilerwrapper)
303 BPERF_RUN_ICECC_CREATE_ENV([--clang ${CC} ${ICECC_WRAPPER}], ${icecc_create_env_log})
304 else
305 AC_MSG_ERROR([Can only create icecc compiler packages for toolchain types gcc and clang])
306 fi
307 PATH="$old_path"
308 # The bundle with the compiler gets a name based on checksums. Parse log file
309 # to find it.
310 ICECC_ENV_BUNDLE_BASENAME="`${SED} -n '/^creating/s/creating //p' ${icecc_create_env_log}`"
311 ICECC_ENV_BUNDLE="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/${ICECC_ENV_BUNDLE_BASENAME}"
312 if test ! -f ${ICECC_ENV_BUNDLE}; then
313 AC_MSG_ERROR([icecc-create-env did not produce an environment ${ICECC_ENV_BUNDLE}])
314 fi
315 AC_MSG_CHECKING([for icecc build environment for target compiler])
316 AC_MSG_RESULT([${ICECC_ENV_BUNDLE}])
317 ICECC="ICECC_VERSION=${ICECC_ENV_BUNDLE} ICECC_CC=${CC} ICECC_CXX=${CXX} ${ICECC_CMD}"
318
319 if test "x${COMPILE_TYPE}" = "xcross"; then
320 # If cross compiling, create a separate env package for the build compiler
321 # Assume "gcc" or "cc" is gcc and "clang" is clang. Otherwise bail.
322 icecc_create_env_log_build="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/icecc_create_env_build.log"
323 if test "x${BUILD_CC##*/}" = "xgcc" || test "x${BUILD_CC##*/}" = "xcc"; then
324 BPERF_RUN_ICECC_CREATE_ENV([${icecc_gcc_arg} ${BUILD_CC} ${BUILD_CXX}], \
325 ${icecc_create_env_log_build})
326 elif test "x${BUILD_CC##*/}" = "xclang"; then
327 BPERF_RUN_ICECC_CREATE_ENV([--clang ${BUILD_CC} ${ICECC_WRAPPER}], ${icecc_create_env_log_build})
328 else
329 AC_MSG_ERROR([Cannot create icecc compiler package for ${BUILD_CC}])
330 fi
331 ICECC_ENV_BUNDLE_BASENAME="`${SED} -n '/^creating/s/creating //p' ${icecc_create_env_log_build}`"
332 ICECC_ENV_BUNDLE="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/${ICECC_ENV_BUNDLE_BASENAME}"
333 if test ! -f ${ICECC_ENV_BUNDLE}; then
334 AC_MSG_ERROR([icecc-create-env did not produce an environment ${ICECC_ENV_BUNDLE}])
335 fi
336 AC_MSG_CHECKING([for icecc build environment for build compiler])
337 AC_MSG_RESULT([${ICECC_ENV_BUNDLE}])
338 BUILD_ICECC="ICECC_VERSION=${ICECC_ENV_BUNDLE} ICECC_CC=${BUILD_CC} \
339 ICECC_CXX=${BUILD_CXX} ${ICECC_CMD}"
340 else
341 BUILD_ICECC="${ICECC}"
342 fi
343 AC_SUBST(ICECC)
344 AC_SUBST(BUILD_ICECC)
345 fi
346 ])
347
348 AC_DEFUN_ONCE([BPERF_SETUP_PRECOMPILED_HEADERS],
349 [
350
351 ###############################################################################
352 #
353 # Can the C/C++ compiler use precompiled headers?
354 #
355 AC_ARG_ENABLE([precompiled-headers], [AS_HELP_STRING([--disable-precompiled-headers],
356 [disable using precompiled headers when compiling C++ @<:@enabled@:>@])],
357 [ENABLE_PRECOMPH=${enable_precompiled_headers}], [ENABLE_PRECOMPH=yes])
358
359 USE_PRECOMPILED_HEADER=1
360 AC_MSG_CHECKING([If precompiled header is enabled])
361 if test "x$ENABLE_PRECOMPH" = xno; then
362 AC_MSG_RESULT([no, forced])
363 USE_PRECOMPILED_HEADER=0
364 elif test "x$ICECC" != "x"; then
365 AC_MSG_RESULT([no, does not work effectively with icecc])
366 USE_PRECOMPILED_HEADER=0
367 else
368 AC_MSG_RESULT([yes])
369 fi
370
371 if test "x$ENABLE_PRECOMPH" = xyes; then
372 # Check that the compiler actually supports precomp headers.
373 if test "x$TOOLCHAIN_TYPE" = xgcc; then
374 AC_MSG_CHECKING([that precompiled headers work])
375 echo "int alfa();" > conftest.h
376 $CXX -x c++-header conftest.h -o conftest.hpp.gch 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
377 if test ! -f conftest.hpp.gch; then
378 USE_PRECOMPILED_HEADER=0
379 AC_MSG_RESULT([no])
380 else
381 AC_MSG_RESULT([yes])
382 fi
383 rm -f conftest.h conftest.hpp.gch
384 fi
385 fi
386
387 AC_SUBST(USE_PRECOMPILED_HEADER)
388 ])
389
390
391 AC_DEFUN_ONCE([BPERF_SETUP_SMART_JAVAC],
392 [
393 AC_ARG_WITH(sjavac-server-java, [AS_HELP_STRING([--with-sjavac-server-java],
394 [use this java binary for running the sjavac background server @<:@Boot JDK java@:>@])])
395
396 if test "x$with_sjavac_server_java" != x; then
397 SJAVAC_SERVER_JAVA="$with_sjavac_server_java"
398 FOUND_VERSION=`$SJAVAC_SERVER_JAVA -version 2>&1 | grep " version \""`
399 if test "x$FOUND_VERSION" = x; then
400 AC_MSG_ERROR([Could not execute server java: $SJAVAC_SERVER_JAVA])
401 fi
402 else
403 SJAVAC_SERVER_JAVA="$JAVA"
404 fi
405 AC_SUBST(SJAVAC_SERVER_JAVA)
406
407 if test "$MEMORY_SIZE" -gt "3000"; then
408 ADD_JVM_ARG_IF_OK([-d64],SJAVAC_SERVER_JAVA_FLAGS,[$SJAVAC_SERVER_JAVA])
409 if test "$JVM_ARG_OK" = true; then
410 JVM_64BIT=true
411 JVM_ARG_OK=false
412 fi
413 fi
414
415 MX_VALUE=`expr $MEMORY_SIZE / 2`
416 if test "$JVM_64BIT" = true; then
417 # Set ms lower than mx since more than one instance of the server might
418 # get launched at the same time before they figure out which instance won.
419 MS_VALUE=512
420 if test "$MX_VALUE" -gt "2048"; then
421 MX_VALUE=2048
422 fi
423 else
424 MS_VALUE=256
425 if test "$MX_VALUE" -gt "1500"; then
426 MX_VALUE=1500
427 fi
428 fi
429 if test "$MX_VALUE" -lt "512"; then
430 MX_VALUE=512
431 fi
432 ADD_JVM_ARG_IF_OK([-Xms${MS_VALUE}M -Xmx${MX_VALUE}M],SJAVAC_SERVER_JAVA_FLAGS,[$SJAVAC_SERVER_JAVA])
433 AC_SUBST(SJAVAC_SERVER_JAVA_FLAGS)
434
435 AC_ARG_ENABLE([sjavac], [AS_HELP_STRING([--enable-sjavac],
436 [use sjavac to do fast incremental compiles @<:@disabled@:>@])],
437 [ENABLE_SJAVAC="${enableval}"], [ENABLE_SJAVAC="no"])
438 if test "x$JVM_ARG_OK" = "xfalse"; then
439 AC_MSG_WARN([Could not set -Xms${MS_VALUE}M -Xmx${MX_VALUE}M, disabling sjavac])
440 ENABLE_SJAVAC="no"
441 fi
442 AC_MSG_CHECKING([whether to use sjavac])
443 AC_MSG_RESULT([$ENABLE_SJAVAC])
444 AC_SUBST(ENABLE_SJAVAC)
445
446 AC_ARG_ENABLE([javac-server], [AS_HELP_STRING([--disable-javac-server],
447 [disable javac server @<:@enabled@:>@])],
448 [ENABLE_JAVAC_SERVER="${enableval}"], [ENABLE_JAVAC_SERVER="yes"])
449 if test "x$JVM_ARG_OK" = "xfalse"; then
450 AC_MSG_WARN([Could not set -Xms${MS_VALUE}M -Xmx${MX_VALUE}M, disabling javac server])
451 ENABLE_JAVAC_SERVER="no"
452 fi
453 AC_MSG_CHECKING([whether to use javac server])
454 AC_MSG_RESULT([$ENABLE_JAVAC_SERVER])
455 AC_SUBST(ENABLE_JAVAC_SERVER)
456
457 if test "x$ENABLE_JAVAC_SERVER" = "xyes" || "x$ENABLE_SJAVAC" = "xyes"; then
458 # When using a server javac, the small client instances do not need much
459 # resources.
460 JAVA_FLAGS_JAVAC="$JAVA_FLAGS_SMALL"
461 fi
462 ])