1 #
2 # Copyright (c) 2011, 2014, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 AC_DEFUN_ONCE([LIB_SETUP_INIT],
27 [
28
29 ###############################################################################
30 #
31 # OS specific settings that we never will need to probe.
32 #
33 if test "x$OPENJDK_TARGET_OS" = xlinux; then
34 AC_MSG_CHECKING([what is not needed on Linux?])
35 PULSE_NOT_NEEDED=yes
36 AC_MSG_RESULT([pulse])
37 fi
38
39 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
40 AC_MSG_CHECKING([what is not needed on Solaris?])
41 ALSA_NOT_NEEDED=yes
42 PULSE_NOT_NEEDED=yes
43 AC_MSG_RESULT([alsa pulse])
44 fi
45
46 if test "x$OPENJDK_TARGET_OS" = xaix; then
47 AC_MSG_CHECKING([what is not needed on AIX?])
48 ALSA_NOT_NEEDED=yes
49 PULSE_NOT_NEEDED=yes
50 AC_MSG_RESULT([alsa pulse])
51 fi
52
53
54 if test "x$OPENJDK_TARGET_OS" = xwindows; then
55 AC_MSG_CHECKING([what is not needed on Windows?])
56 CUPS_NOT_NEEDED=yes
57 ALSA_NOT_NEEDED=yes
58 PULSE_NOT_NEEDED=yes
59 X11_NOT_NEEDED=yes
60 AC_MSG_RESULT([alsa cups pulse x11])
61 fi
62
63 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
64 AC_MSG_CHECKING([what is not needed on MacOSX?])
65 ALSA_NOT_NEEDED=yes
66 PULSE_NOT_NEEDED=yes
67 X11_NOT_NEEDED=yes
68 # If the java runtime framework is disabled, then we need X11.
69 # This will be adjusted below.
70 AC_MSG_RESULT([alsa pulse x11])
71 fi
72
73 if test "x$OPENJDK_TARGET_OS" = xbsd; then
74 AC_MSG_CHECKING([what is not needed on bsd?])
75 ALSA_NOT_NEEDED=yes
76 AC_MSG_RESULT([alsa])
77 fi
78
79 if test "x$OPENJDK" = "xfalse"; then
80 FREETYPE_NOT_NEEDED=yes
81 fi
82
83 if test "x$SUPPORT_HEADFUL" = xno; then
84 X11_NOT_NEEDED=yes
85 fi
86
87 ###############################################################################
88 #
89 # Check for MacOSX support for OpenJDK.
90 #
91
92 BASIC_DEPRECATED_ARG_ENABLE(macosx-runtime-support, macosx_runtime_support)
93
94 AC_MSG_CHECKING([for Mac OS X Java Framework])
95 if test -f /System/Library/Frameworks/JavaVM.framework/Frameworks/JavaRuntimeSupport.framework/Headers/JavaRuntimeSupport.h; then
96 AC_MSG_RESULT([/System/Library/Frameworks/JavaVM.framework])
97 else
98 AC_MSG_RESULT([no])
99 fi
100 ])
101
102 AC_DEFUN_ONCE([LIB_SETUP_X11],
103 [
104
105 ###############################################################################
106 #
107 # Check for X Windows
108 #
109
110 # Check if the user has specified sysroot, but not --x-includes or --x-libraries.
111 # Make a simple check for the libraries at the sysroot, and setup --x-includes and
112 # --x-libraries for the sysroot, if that seems to be correct.
113 if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
114 if test "x$SYSROOT" != "x"; then
115 if test "x$x_includes" = xNONE; then
116 if test -f "$SYSROOT/usr/X11R6/include/X11/Xlib.h"; then
117 x_includes="$SYSROOT/usr/X11R6/include"
118 elif test -f "$SYSROOT/usr/include/X11/Xlib.h"; then
119 x_includes="$SYSROOT/usr/include"
120 fi
121 fi
122 if test "x$x_libraries" = xNONE; then
123 if test -f "$SYSROOT/usr/X11R6/lib/libX11.so"; then
124 x_libraries="$SYSROOT/usr/X11R6/lib"
125 elif test "$SYSROOT/usr/lib64/libX11.so" && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
126 x_libraries="$SYSROOT/usr/lib64"
127 elif test -f "$SYSROOT/usr/lib/libX11.so"; then
128 x_libraries="$SYSROOT/usr/lib"
129 fi
130 fi
131 fi
132 fi
133
134 # Now let autoconf do it's magic
135 AC_PATH_X
136 AC_PATH_XTRA
137
138 # AC_PATH_XTRA creates X_LIBS and sometimes adds -R flags. When cross compiling
139 # this doesn't make sense so we remove it.
140 if test "x$COMPILE_TYPE" = xcross; then
141 X_LIBS=`$ECHO $X_LIBS | $SED 's/-R \{0,1\}[[^ ]]*//g'`
142 fi
143
144 if test "x$no_x" = xyes && test "x$X11_NOT_NEEDED" != xyes; then
145 HELP_MSG_MISSING_DEPENDENCY([x11])
146 AC_MSG_ERROR([Could not find X11 libraries. $HELP_MSG])
147 fi
148
149 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
150 OPENWIN_HOME="/usr/openwin"
151 X_CFLAGS="-I$SYSROOT$OPENWIN_HOME/include -I$SYSROOT$OPENWIN_HOME/include/X11/extensions"
152 X_LIBS="-L$SYSROOT$OPENWIN_HOME/sfw/lib$OPENJDK_TARGET_CPU_ISADIR \
153 -L$SYSROOT$OPENWIN_HOME/lib$OPENJDK_TARGET_CPU_ISADIR \
154 -R$OPENWIN_HOME/sfw/lib$OPENJDK_TARGET_CPU_ISADIR \
155 -R$OPENWIN_HOME/lib$OPENJDK_TARGET_CPU_ISADIR"
156 fi
157
158 #
159 # Weird Sol10 something check...TODO change to try compile
160 #
161 if test "x${OPENJDK_TARGET_OS}" = xsolaris; then
162 if test "`uname -r`" = "5.10"; then
163 if test "`${EGREP} -c XLinearGradient ${OPENWIN_HOME}/share/include/X11/extensions/Xrender.h`" = "0"; then
164 X_CFLAGS="${X_CFLAGS} -DSOLARIS10_NO_XRENDER_STRUCTS"
165 fi
166 fi
167 fi
168
169 AC_LANG_PUSH(C)
170 OLD_CFLAGS="$CFLAGS"
171 CFLAGS="$CFLAGS $X_CFLAGS"
172
173 # Need to include Xlib.h and Xutil.h to avoid "present but cannot be compiled" warnings on Solaris 10
174 AC_CHECK_HEADERS([X11/extensions/shape.h X11/extensions/Xrender.h X11/extensions/XTest.h X11/Intrinsic.h],
175 [X11_A_OK=yes],
176 [X11_A_OK=no; break],
177 [
178 # include <X11/Xlib.h>
179 # include <X11/Xutil.h>
180 ]
181 )
182
183 CFLAGS="$OLD_CFLAGS"
184 AC_LANG_POP(C)
185
186 if test "x$X11_A_OK" = xno && test "x$X11_NOT_NEEDED" != xyes; then
187 HELP_MSG_MISSING_DEPENDENCY([x11])
188 AC_MSG_ERROR([Could not find all X11 headers (shape.h Xrender.h XTest.h Intrinsic.h). $HELP_MSG])
189 fi
190
191 AC_SUBST(X_CFLAGS)
192 AC_SUBST(X_LIBS)
193 ])
194
195 AC_DEFUN_ONCE([LIB_SETUP_CUPS],
196 [
197
198 ###############################################################################
199 #
200 # The common unix printing system cups is used to print from java.
201 #
202 AC_ARG_WITH(cups, [AS_HELP_STRING([--with-cups],
203 [specify prefix directory for the cups package
204 (expecting the headers under PATH/include)])])
205 AC_ARG_WITH(cups-include, [AS_HELP_STRING([--with-cups-include],
206 [specify directory for the cups include files])])
207
208 if test "x$CUPS_NOT_NEEDED" = xyes; then
209 if test "x${with_cups}" != x || test "x${with_cups_include}" != x; then
210 AC_MSG_WARN([cups not used, so --with-cups is ignored])
211 fi
212 CUPS_CFLAGS=
213 else
214 CUPS_FOUND=no
215
216 if test "x${with_cups}" = xno || test "x${with_cups_include}" = xno; then
217 AC_MSG_ERROR([It is not possible to disable the use of cups. Remove the --without-cups option.])
218 fi
219
220 if test "x${with_cups}" != x; then
221 CUPS_CFLAGS="-I${with_cups}/include"
222 CUPS_FOUND=yes
223 fi
224 if test "x${with_cups_include}" != x; then
225 CUPS_CFLAGS="-I${with_cups_include}"
226 CUPS_FOUND=yes
227 fi
228 if test "x$CUPS_FOUND" = xno; then
229 BDEPS_CHECK_MODULE(CUPS, cups, xxx, [CUPS_FOUND=yes])
230 fi
231 if test "x$CUPS_FOUND" = xno; then
232 # Are the cups headers installed in the default /usr/include location?
233 AC_CHECK_HEADERS([cups/cups.h cups/ppd.h],
234 [
235 CUPS_FOUND=yes
236 CUPS_CFLAGS=
237 DEFAULT_CUPS=yes
238 ]
239 )
240 fi
241 if test "x$CUPS_FOUND" = xno; then
242 # Getting nervous now? Lets poke around for standard Solaris third-party
243 # package installation locations.
244 AC_MSG_CHECKING([for cups headers])
245 if test -s $SYSROOT/opt/sfw/cups/include/cups/cups.h; then
246 # An SFW package seems to be installed!
247 CUPS_FOUND=yes
248 CUPS_CFLAGS="-I$SYSROOT/opt/sfw/cups/include"
249 elif test -s $SYSROOT/opt/csw/include/cups/cups.h; then
250 # A CSW package seems to be installed!
251 CUPS_FOUND=yes
252 CUPS_CFLAGS="-I$SYSROOT/opt/csw/include"
253 fi
254 AC_MSG_RESULT([$CUPS_FOUND])
255 fi
256 if test "x$CUPS_FOUND" = xno; then
257 HELP_MSG_MISSING_DEPENDENCY([cups])
258 AC_MSG_ERROR([Could not find cups! $HELP_MSG ])
259 fi
260 fi
261
262 AC_SUBST(CUPS_CFLAGS)
263
264 ])
265
266 AC_DEFUN([LIB_CHECK_POTENTIAL_FREETYPE],
267 [
268 POTENTIAL_FREETYPE_INCLUDE_PATH="$1"
269 POTENTIAL_FREETYPE_LIB_PATH="$2"
270 METHOD="$3"
271
272 # First check if the files exists.
273 if test -s "$POTENTIAL_FREETYPE_INCLUDE_PATH/ft2build.h"; then
274 # We found an arbitrary include file. That's a good sign.
275 AC_MSG_NOTICE([Found freetype include files at $POTENTIAL_FREETYPE_INCLUDE_PATH using $METHOD])
276 FOUND_FREETYPE=yes
277
278 FREETYPE_LIB_NAME="${LIBRARY_PREFIX}freetype${SHARED_LIBRARY_SUFFIX}"
279 if ! test -s "$POTENTIAL_FREETYPE_LIB_PATH/$FREETYPE_LIB_NAME"; then
280 AC_MSG_NOTICE([Could not find $POTENTIAL_FREETYPE_LIB_PATH/$FREETYPE_LIB_NAME. Ignoring location.])
281 FOUND_FREETYPE=no
282 else
283 if test "x$OPENJDK_TARGET_OS" = xwindows; then
284 # On Windows, we will need both .lib and .dll file.
285 if ! test -s "$POTENTIAL_FREETYPE_LIB_PATH/freetype.lib"; then
286 AC_MSG_NOTICE([Could not find $POTENTIAL_FREETYPE_LIB_PATH/freetype.lib. Ignoring location.])
287 FOUND_FREETYPE=no
288 fi
289 elif test "x$OPENJDK_TARGET_OS" = xsolaris \
290 && test -s "$POTENTIAL_FREETYPE_LIB_PATH$OPENJDK_TARGET_CPU_ISADIR/$FREETYPE_LIB_NAME"; then
291 # Found lib in isa dir, use that instead.
292 POTENTIAL_FREETYPE_LIB_PATH="$POTENTIAL_FREETYPE_LIB_PATH$OPENJDK_TARGET_CPU_ISADIR"
293 fi
294 fi
295 fi
296
297 if test "x$FOUND_FREETYPE" = xyes; then
298 BASIC_FIXUP_PATH(POTENTIAL_FREETYPE_INCLUDE_PATH)
299 BASIC_FIXUP_PATH(POTENTIAL_FREETYPE_LIB_PATH)
300
301 FREETYPE_INCLUDE_PATH="$POTENTIAL_FREETYPE_INCLUDE_PATH"
302 AC_MSG_CHECKING([for freetype includes])
303 AC_MSG_RESULT([$FREETYPE_INCLUDE_PATH])
304 FREETYPE_LIB_PATH="$POTENTIAL_FREETYPE_LIB_PATH"
305 AC_MSG_CHECKING([for freetype libraries])
306 AC_MSG_RESULT([$FREETYPE_LIB_PATH])
307 fi
308 ])
309
310 AC_DEFUN_ONCE([LIB_SETUP_FREETYPE],
311 [
312
313 ###############################################################################
314 #
315 # The ubiquitous freetype library is used to render fonts.
316 #
317 AC_ARG_WITH(freetype, [AS_HELP_STRING([--with-freetype],
318 [specify prefix directory for the freetype package
319 (expecting the libraries under PATH/lib and the headers under PATH/include)])])
320 AC_ARG_WITH(freetype-include, [AS_HELP_STRING([--with-freetype-include],
321 [specify directory for the freetype include files])])
322 AC_ARG_WITH(freetype-lib, [AS_HELP_STRING([--with-freetype-lib],
323 [specify directory for the freetype library])])
324 AC_ARG_ENABLE(freetype-bundling, [AS_HELP_STRING([--disable-freetype-bundling],
325 [disable bundling of the freetype library with the build result @<:@enabled on Windows or when using --with-freetype, disabled otherwise@:>@])])
326
327 FREETYPE_CFLAGS=
328 FREETYPE_LIBS=
329 FREETYPE_BUNDLE_LIB_PATH=
330
331 if test "x$FREETYPE_NOT_NEEDED" = xyes; then
332 if test "x$with_freetype" != x || test "x$with_freetype_include" != x || test "x$with_freetype_lib" != x; then
333 AC_MSG_WARN([freetype not used, so --with-freetype is ignored])
334 fi
335 if test "x$enable_freetype_bundling" != x; then
336 AC_MSG_WARN([freetype not used, so --enable-freetype-bundling is ignored])
337 fi
338 else
339 # freetype is needed to build; go get it!
340
341 BUNDLE_FREETYPE="$enable_freetype_bundling"
342
343 if test "x$with_freetype" != x || test "x$with_freetype_include" != x || test "x$with_freetype_lib" != x; then
344 # User has specified settings
345
346 if test "x$BUNDLE_FREETYPE" = x; then
347 # If not specified, default is to bundle freetype
348 BUNDLE_FREETYPE=yes
349 fi
350
351 if test "x$with_freetype" != x; then
352 POTENTIAL_FREETYPE_INCLUDE_PATH="$with_freetype/include"
353 POTENTIAL_FREETYPE_LIB_PATH="$with_freetype/lib"
354 fi
355
356 # Allow --with-freetype-lib and --with-freetype-include to override
357 if test "x$with_freetype_include" != x; then
358 POTENTIAL_FREETYPE_INCLUDE_PATH="$with_freetype_include"
359 fi
360 if test "x$with_freetype_lib" != x; then
361 POTENTIAL_FREETYPE_LIB_PATH="$with_freetype_lib"
362 fi
363
364 if test "x$POTENTIAL_FREETYPE_INCLUDE_PATH" != x && test "x$POTENTIAL_FREETYPE_LIB_PATH" != x; then
365 # Okay, we got it. Check that it works.
366 LIB_CHECK_POTENTIAL_FREETYPE($POTENTIAL_FREETYPE_INCLUDE_PATH, $POTENTIAL_FREETYPE_LIB_PATH, [--with-freetype])
367 if test "x$FOUND_FREETYPE" != xyes; then
368 AC_MSG_ERROR([Can not find or use freetype at location given by --with-freetype])
369 fi
370 else
371 # User specified only one of lib or include. This is an error.
372 if test "x$POTENTIAL_FREETYPE_INCLUDE_PATH" = x ; then
373 AC_MSG_NOTICE([User specified --with-freetype-lib but not --with-freetype-include])
374 AC_MSG_ERROR([Need both freetype lib and include paths. Consider using --with-freetype instead.])
375 else
376 AC_MSG_NOTICE([User specified --with-freetype-include but not --with-freetype-lib])
377 AC_MSG_ERROR([Need both freetype lib and include paths. Consider using --with-freetype instead.])
378 fi
379 fi
380 else
381 # User did not specify settings, but we need freetype. Try to locate it.
382
383 if test "x$BUNDLE_FREETYPE" = x; then
384 # If not specified, default is to bundle freetype only on windows
385 if test "x$OPENJDK_TARGET_OS" = xwindows; then
386 BUNDLE_FREETYPE=yes
387 else
388 BUNDLE_FREETYPE=no
389 fi
390 fi
391
392 if test "x$FOUND_FREETYPE" != xyes; then
393 # Check builddeps
394 BDEPS_CHECK_MODULE(FREETYPE, freetype2, xxx, [FOUND_FREETYPE=yes], [FOUND_FREETYPE=no])
395 # BDEPS_CHECK_MODULE will set FREETYPE_CFLAGS and _LIBS, but we don't get a lib path for bundling.
396 if test "x$FOUND_FREETYPE" = xyes; then
397 if test "x$BUNDLE_FREETYPE" = xyes; then
398 AC_MSG_NOTICE([Found freetype using builddeps, but ignoring since we can not bundle that])
399 FOUND_FREETYPE=no
400 else
401 AC_MSG_CHECKING([for freetype])
402 AC_MSG_RESULT([yes (using builddeps)])
403 fi
404 fi
405 fi
406
407 # If we have a sysroot, assume that's where we are supposed to look and skip pkg-config.
408 if test "x$SYSROOT" = x; then
409 if test "x$FOUND_FREETYPE" != xyes; then
410 # Check modules using pkg-config, but only if we have it (ugly output results otherwise)
411 if test "x$PKG_CONFIG" != x; then
412 PKG_CHECK_MODULES(FREETYPE, freetype2, [FOUND_FREETYPE=yes], [FOUND_FREETYPE=no])
413 if test "x$FOUND_FREETYPE" = xyes; then
414 # On solaris, pkg_check adds -lz to freetype libs, which isn't necessary for us.
415 FREETYPE_LIBS=`$ECHO $FREETYPE_LIBS | $SED 's/-lz//g'`
416 # 64-bit libs for Solaris x86 are installed in the amd64 subdirectory, change lib to lib/amd64
417 if test "x$OPENJDK_TARGET_OS" = xsolaris && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
418 FREETYPE_LIBS=`$ECHO $FREETYPE_LIBS | $SED 's?/lib?/lib/amd64?g'`
419 fi
420 # BDEPS_CHECK_MODULE will set FREETYPE_CFLAGS and _LIBS, but we don't get a lib path for bundling.
421 if test "x$BUNDLE_FREETYPE" = xyes; then
422 AC_MSG_NOTICE([Found freetype using pkg-config, but ignoring since we can not bundle that])
423 FOUND_FREETYPE=no
424 else
425 AC_MSG_CHECKING([for freetype])
426 AC_MSG_RESULT([yes (using pkg-config)])
427 fi
428 fi
429 fi
430 fi
431 fi
432
433 if test "x$FOUND_FREETYPE" != xyes; then
434 # Check in well-known locations
435 if test "x$OPENJDK_TARGET_OS" = xwindows; then
436 FREETYPE_BASE_DIR="$PROGRAMFILES/GnuWin32"
437 BASIC_WINDOWS_REWRITE_AS_UNIX_PATH(FREETYPE_BASE_DIR)
438 LIB_CHECK_POTENTIAL_FREETYPE([$FREETYPE_BASE_DIR/include], [$FREETYPE_BASE_DIR/lib], [well-known location])
439 if test "x$FOUND_FREETYPE" != xyes; then
440 FREETYPE_BASE_DIR="$ProgramW6432/GnuWin32"
441 BASIC_WINDOWS_REWRITE_AS_UNIX_PATH(FREETYPE_BASE_DIR)
442 LIB_CHECK_POTENTIAL_FREETYPE([$FREETYPE_BASE_DIR/include], [$FREETYPE_BASE_DIR/lib], [well-known location])
443 fi
444 else
445 FREETYPE_BASE_DIR="$SYSROOT/usr"
446 LIB_CHECK_POTENTIAL_FREETYPE([$FREETYPE_BASE_DIR/include], [$FREETYPE_BASE_DIR/lib], [well-known location])
447
448 if test "x$FOUND_FREETYPE" != xyes; then
449 FREETYPE_BASE_DIR="$SYSROOT/usr/X11"
450 LIB_CHECK_POTENTIAL_FREETYPE([$FREETYPE_BASE_DIR/include], [$FREETYPE_BASE_DIR/lib], [well-known location])
451 fi
452
453 if test "x$FOUND_FREETYPE" != xyes; then
454 FREETYPE_BASE_DIR="$SYSROOT/usr/sfw"
455 LIB_CHECK_POTENTIAL_FREETYPE([$FREETYPE_BASE_DIR/include], [$FREETYPE_BASE_DIR/lib], [well-known location])
456 fi
457
458 if test "x$FOUND_FREETYPE" != xyes; then
459 FREETYPE_BASE_DIR="$SYSROOT/usr"
460 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
461 LIB_CHECK_POTENTIAL_FREETYPE([$FREETYPE_BASE_DIR/include], [$FREETYPE_BASE_DIR/lib/x86_64-linux-gnu], [well-known location])
462 else
463 LIB_CHECK_POTENTIAL_FREETYPE([$FREETYPE_BASE_DIR/include], [$FREETYPE_BASE_DIR/lib/i386-linux-gnu], [well-known location])
464 if test "x$FOUND_FREETYPE" != xyes; then
465 LIB_CHECK_POTENTIAL_FREETYPE([$FREETYPE_BASE_DIR/include], [$FREETYPE_BASE_DIR/lib32], [well-known location])
466 fi
467 fi
468 fi
469 fi
470 fi # end check in well-known locations
471
472 if test "x$FOUND_FREETYPE" != xyes; then
473 HELP_MSG_MISSING_DEPENDENCY([freetype])
474 AC_MSG_ERROR([Could not find freetype! $HELP_MSG ])
475 fi
476 fi # end user specified settings
477
478 # Set FREETYPE_CFLAGS, _LIBS and _LIB_PATH from include and lib dir.
479 if test "x$FREETYPE_CFLAGS" = x; then
480 BASIC_FIXUP_PATH(FREETYPE_INCLUDE_PATH)
481 if test -d $FREETYPE_INCLUDE_PATH/freetype2/freetype; then
482 FREETYPE_CFLAGS="-I$FREETYPE_INCLUDE_PATH/freetype2 -I$FREETYPE_INCLUDE_PATH"
483 else
484 FREETYPE_CFLAGS="-I$FREETYPE_INCLUDE_PATH"
485 fi
486 fi
487
488 if test "x$FREETYPE_LIBS" = x; then
489 BASIC_FIXUP_PATH(FREETYPE_LIB_PATH)
490 if test "x$OPENJDK_TARGET_OS" = xwindows; then
491 FREETYPE_LIBS="$FREETYPE_LIB_PATH/freetype.lib"
492 else
493 FREETYPE_LIBS="-L$FREETYPE_LIB_PATH -lfreetype"
494 fi
495 fi
496
497 # Try to compile it
498 AC_MSG_CHECKING([if we can compile and link with freetype])
499 AC_LANG_PUSH(C++)
500 PREV_CXXCFLAGS="$CXXFLAGS"
501 PREV_LIBS="$LIBS"
502 PREV_CXX="$CXX"
503 CXXFLAGS="$CXXFLAGS $FREETYPE_CFLAGS"
504 LIBS="$LIBS $FREETYPE_LIBS"
505 CXX="$FIXPATH $CXX"
506 AC_LINK_IFELSE([AC_LANG_SOURCE([[
507 #include<ft2build.h>
508 #include FT_FREETYPE_H
509 int main () {
510 FT_Init_FreeType(NULL);
511 return 0;
512 }
513 ]])],
514 [
515 AC_MSG_RESULT([yes])
516 ],
517 [
518 AC_MSG_RESULT([no])
519 AC_MSG_NOTICE([Could not compile and link with freetype. This might be a 32/64-bit mismatch.])
520 AC_MSG_NOTICE([Using FREETYPE_CFLAGS=$FREETYPE_CFLAGS and FREETYPE_LIBS=$FREETYPE_LIBS])
521
522 HELP_MSG_MISSING_DEPENDENCY([freetype])
523
524 AC_MSG_ERROR([Can not continue without freetype. $HELP_MSG])
525 ]
526 )
527 CXXCFLAGS="$PREV_CXXFLAGS"
528 LIBS="$PREV_LIBS"
529 CXX="$PREV_CXX"
530 AC_LANG_POP(C++)
531
532 AC_MSG_CHECKING([if we should bundle freetype])
533 if test "x$BUNDLE_FREETYPE" = xyes; then
534 FREETYPE_BUNDLE_LIB_PATH="$FREETYPE_LIB_PATH"
535 fi
536 AC_MSG_RESULT([$BUNDLE_FREETYPE])
537
538 fi # end freetype needed
539
540 AC_SUBST(FREETYPE_BUNDLE_LIB_PATH)
541 AC_SUBST(FREETYPE_CFLAGS)
542 AC_SUBST(FREETYPE_LIBS)
543 ])
544
545 AC_DEFUN_ONCE([LIB_SETUP_ALSA],
546 [
547
548 ###############################################################################
549 #
550 # Check for alsa headers and libraries. Used on Linux/GNU systems.
551 #
552 AC_ARG_WITH(alsa, [AS_HELP_STRING([--with-alsa],
553 [specify prefix directory for the alsa package
554 (expecting the libraries under PATH/lib and the headers under PATH/include)])])
555 AC_ARG_WITH(alsa-include, [AS_HELP_STRING([--with-alsa-include],
556 [specify directory for the alsa include files])])
557 AC_ARG_WITH(alsa-lib, [AS_HELP_STRING([--with-alsa-lib],
558 [specify directory for the alsa library])])
559
560 if test "x$ALSA_NOT_NEEDED" = xyes; then
561 if test "x${with_alsa}" != x || test "x${with_alsa_include}" != x || test "x${with_alsa_lib}" != x; then
562 AC_MSG_WARN([alsa not used, so --with-alsa is ignored])
563 fi
564 ALSA_CFLAGS=
565 ALSA_LIBS=
566 else
567 ALSA_FOUND=no
568
569 if test "x${with_alsa}" = xno || test "x${with_alsa_include}" = xno || test "x${with_alsa_lib}" = xno; then
570 AC_MSG_ERROR([It is not possible to disable the use of alsa. Remove the --without-alsa option.])
571 fi
572
573 if test "x${with_alsa}" != x; then
574 ALSA_LIBS="-L${with_alsa}/lib -lasound"
575 ALSA_CFLAGS="-I${with_alsa}/include"
576 ALSA_FOUND=yes
577 fi
578 if test "x${with_alsa_include}" != x; then
579 ALSA_CFLAGS="-I${with_alsa_include}"
580 ALSA_FOUND=yes
581 fi
582 if test "x${with_alsa_lib}" != x; then
583 ALSA_LIBS="-L${with_alsa_lib} -lasound"
584 ALSA_FOUND=yes
585 fi
586 if test "x$ALSA_FOUND" = xno; then
587 BDEPS_CHECK_MODULE(ALSA, alsa, xxx, [ALSA_FOUND=yes], [ALSA_FOUND=no])
588 fi
589 # Do not try pkg-config if we have a sysroot set.
590 if test "x$SYSROOT" = x; then
591 if test "x$ALSA_FOUND" = xno; then
592 PKG_CHECK_MODULES(ALSA, alsa, [ALSA_FOUND=yes], [ALSA_FOUND=no])
593 fi
594 fi
595 if test "x$ALSA_FOUND" = xno; then
596 AC_CHECK_HEADERS([alsa/asoundlib.h],
597 [
598 ALSA_FOUND=yes
599 ALSA_CFLAGS=-Iignoreme
600 ALSA_LIBS=-lasound
601 DEFAULT_ALSA=yes
602 ],
603 [ALSA_FOUND=no])
604 fi
605 if test "x$ALSA_FOUND" = xno; then
606 HELP_MSG_MISSING_DEPENDENCY([alsa])
607 AC_MSG_ERROR([Could not find alsa! $HELP_MSG ])
608 fi
609 fi
610
611 AC_SUBST(ALSA_CFLAGS)
612 AC_SUBST(ALSA_LIBS)
613 ])
614
615 AC_DEFUN_ONCE([LIB_SETUP_MISC_LIBS],
616 [
617
618 ###############################################################################
619 #
620 # Check for the jpeg library
621 #
622
623 USE_EXTERNAL_LIBJPEG=true
624 AC_CHECK_LIB(jpeg, main, [],
625 [ USE_EXTERNAL_LIBJPEG=false
626 AC_MSG_NOTICE([Will use jpeg decoder bundled with the OpenJDK source])
627 ])
628 AC_SUBST(USE_EXTERNAL_LIBJPEG)
629
630 ###############################################################################
631 #
632 # Check for the gif library
633 #
634
635 AC_ARG_WITH(giflib, [AS_HELP_STRING([--with-giflib],
636 [use giflib from build system or OpenJDK source (system, bundled) @<:@bundled@:>@])])
637
638
639 AC_MSG_CHECKING([for which giflib to use])
640
641 # default is bundled
642 DEFAULT_GIFLIB=bundled
643
644 #
645 # if user didn't specify, use DEFAULT_GIFLIB
646 #
647 if test "x${with_giflib}" = "x"; then
648 with_giflib=${DEFAULT_GIFLIB}
649 fi
650
651 AC_MSG_RESULT(${with_giflib})
652
653 if test "x${with_giflib}" = "xbundled"; then
654 USE_EXTERNAL_LIBGIF=false
655 elif test "x${with_giflib}" = "xsystem"; then
656 AC_CHECK_HEADER(gif_lib.h, [],
657 [ AC_MSG_ERROR([--with-giflib=system specified, but gif_lib.h not found!])])
658 AC_CHECK_LIB(gif, DGifGetCode, [],
659 [ AC_MSG_ERROR([--with-giflib=system specified, but no giflib found!])])
660
661 USE_EXTERNAL_LIBGIF=true
662 else
663 AC_MSG_ERROR([Invalid value of --with-giflib: ${with_giflib}, use 'system' or 'bundled'])
664 fi
665 AC_SUBST(USE_EXTERNAL_LIBGIF)
666
667 ###############################################################################
668 #
669 # Check for the lcms2 library
670 #
671
672 AC_ARG_WITH(lcms, [AS_HELP_STRING([--with-lcms],
673 [use lcms2 from build system or OpenJDK source (system, bundled) @<:@bundled@:>@])])
674
675 AC_MSG_CHECKING([for which lcms to use])
676
677 DEFAULT_LCMS=bundled
678
679 #
680 # If user didn't specify, use DEFAULT_LCMS
681 #
682 if test "x${with_lcms}" = "x"; then
683 with_lcms=${DEFAULT_LCMS}
684 fi
685
686 if test "x${with_lcms}" = "xbundled"; then
687 USE_EXTERNAL_LCMS=false
688 AC_MSG_RESULT([bundled])
689 elif test "x${with_lcms}" = "xsystem"; then
690 AC_MSG_RESULT([system])
691 PKG_CHECK_MODULES([LCMS], [lcms2], [LCMS_FOUND=yes], [LCMS_FOUND=no])
692 if test "x${LCMS_FOUND}" = "xyes"; then
693 USE_EXTERNAL_LCMS=true
694 else
695 AC_MSG_ERROR([--with-lcms=system specified, but no lcms found!])
696 fi
697 else
698 AC_MSG_ERROR([Invalid value for --with-lcms: ${with_lcms}, use 'system' or 'bundled'])
699 fi
700
701 AC_SUBST(USE_EXTERNAL_LCMS)
702
703 ###############################################################################
704 #
705 # Check for the png library
706 #
707
708 AC_ARG_WITH(libpng, [AS_HELP_STRING([--with-libpng],
709 [use libpng from build system or OpenJDK source (system, bundled) @<:@bundled@:>@])])
710
711
712 AC_MSG_CHECKING([for which libpng to use])
713
714 # default is bundled
715 DEFAULT_LIBPNG=bundled
716
717 #
718 # if user didn't specify, use DEFAULT_LIBPNG
719 #
720 if test "x${with_libpng}" = "x"; then
721 with_libpng=${DEFAULT_LIBPNG}
722 fi
723
724 if test "x${with_libpng}" = "xbundled"; then
725 USE_EXTERNAL_LIBPNG=false
726 AC_MSG_RESULT([bundled])
727 elif test "x${with_libpng}" = "xsystem"; then
728 PKG_CHECK_MODULES(PNG, libpng,
729 [ LIBPNG_FOUND=yes ],
730 [ LIBPNG_FOUND=no ])
731 if test "x${LIBPNG_FOUND}" = "xyes"; then
732 USE_EXTERNAL_LIBPNG=true
733 AC_MSG_RESULT([system])
734 else
735 AC_MSG_RESULT([system not found])
736 AC_MSG_ERROR([--with-libpng=system specified, but no libpng found!])
737 fi
738 else
739 AC_MSG_ERROR([Invalid value of --with-libpng: ${with_libpng}, use 'system' or 'bundled'])
740 fi
741 AC_SUBST(USE_EXTERNAL_LIBPNG)
742
743 ###############################################################################
744 #
745 # Check for the zlib library
746 #
747
748 AC_ARG_WITH(zlib, [AS_HELP_STRING([--with-zlib],
749 [use zlib from build system or OpenJDK source (system, bundled) @<:@bundled@:>@])])
750
751 AC_CHECK_LIB(z, compress,
752 [ ZLIB_FOUND=yes ],
753 [ ZLIB_FOUND=no ])
754
755 AC_MSG_CHECKING([for which zlib to use])
756
757 DEFAULT_ZLIB=bundled
758 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
759 #
760 # On macosx default is system...on others default is
761 #
762 DEFAULT_ZLIB=system
763 fi
764
765 if test "x${ZLIB_FOUND}" != "xyes"; then
766 #
767 # If we don't find any system...set default to bundled
768 #
769 DEFAULT_ZLIB=bundled
770 fi
771
772 #
773 # If user didn't specify, use DEFAULT_ZLIB
774 #
775 if test "x${with_zlib}" = "x"; then
776 with_zlib=${DEFAULT_ZLIB}
777 fi
778
779 if test "x${with_zlib}" = "xbundled"; then
780 USE_EXTERNAL_LIBZ=false
781 AC_MSG_RESULT([bundled])
782 elif test "x${with_zlib}" = "xsystem"; then
783 if test "x${ZLIB_FOUND}" = "xyes"; then
784 USE_EXTERNAL_LIBZ=true
785 AC_MSG_RESULT([system])
786 else
787 AC_MSG_RESULT([system not found])
788 AC_MSG_ERROR([--with-zlib=system specified, but no zlib found!])
789 fi
790 else
791 AC_MSG_ERROR([Invalid value for --with-zlib: ${with_zlib}, use 'system' or 'bundled'])
792 fi
793
794 AC_SUBST(USE_EXTERNAL_LIBZ)
795
796 ###############################################################################
797 LIBZIP_CAN_USE_MMAP=true
798
799 AC_SUBST(LIBZIP_CAN_USE_MMAP)
800
801 ###############################################################################
802 #
803 # Check if altzone exists in time.h
804 #
805
806 AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <time.h>], [return (int)altzone;])],
807 [has_altzone=yes],
808 [has_altzone=no])
809 if test "x$has_altzone" = xyes; then
810 AC_DEFINE([HAVE_ALTZONE], 1, [Define if you have the external 'altzone' variable in time.h])
811 fi
812
813 ###############################################################################
814 #
815 # Check the maths library
816 #
817
818 AC_CHECK_LIB(m, cos, [],
819 [
820 AC_MSG_NOTICE([Maths library was not found])
821 ]
822 )
823 AC_SUBST(LIBM)
824
825 ###############################################################################
826 #
827 # Check for libdl.so
828
829 save_LIBS="$LIBS"
830 LIBS=""
831 AC_CHECK_LIB(dl,dlopen)
832 LIBDL="$LIBS"
833 AC_SUBST(LIBDL)
834 LIBS="$save_LIBS"
835 ])
836
837 AC_DEFUN_ONCE([LIB_SETUP_STATIC_LINK_LIBSTDCPP],
838 [
839 ###############################################################################
840 #
841 # statically link libstdc++ before C++ ABI is stablized on Linux unless
842 # dynamic build is configured on command line.
843 #
844 AC_ARG_WITH([stdc++lib], [AS_HELP_STRING([--with-stdc++lib=<static>,<dynamic>,<default>],
845 [force linking of the C++ runtime on Linux to either static or dynamic, default is static with dynamic as fallback])],
846 [
847 if test "x$with_stdc__lib" != xdynamic && test "x$with_stdc__lib" != xstatic \
848 && test "x$with_stdc__lib" != xdefault; then
849 AC_MSG_ERROR([Bad parameter value --with-stdc++lib=$with_stdc__lib!])
850 fi
851 ],
852 [with_stdc__lib=default]
853 )
854
855 if test "x$OPENJDK_TARGET_OS" = xlinux; then
856 # Test if -lstdc++ works.
857 AC_MSG_CHECKING([if dynamic link of stdc++ is possible])
858 AC_LANG_PUSH(C++)
859 OLD_CXXFLAGS="$CXXFLAGS"
860 CXXFLAGS="$CXXFLAGS -lstdc++"
861 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
862 [has_dynamic_libstdcxx=yes],
863 [has_dynamic_libstdcxx=no])
864 CXXFLAGS="$OLD_CXXFLAGS"
865 AC_LANG_POP(C++)
866 AC_MSG_RESULT([$has_dynamic_libstdcxx])
867
868 # Test if stdc++ can be linked statically.
869 AC_MSG_CHECKING([if static link of stdc++ is possible])
870 STATIC_STDCXX_FLAGS="-Wl,-Bstatic -lstdc++ -lgcc -Wl,-Bdynamic"
871 AC_LANG_PUSH(C++)
872 OLD_LIBS="$LIBS"
873 OLD_CXX="$CXX"
874 LIBS="$STATIC_STDCXX_FLAGS"
875 CXX="$CC"
876 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
877 [has_static_libstdcxx=yes],
878 [has_static_libstdcxx=no])
879 LIBS="$OLD_LIBS"
880 CXX="$OLD_CXX"
881 AC_LANG_POP(C++)
882 AC_MSG_RESULT([$has_static_libstdcxx])
883
884 if test "x$has_static_libstdcxx" = xno && test "x$has_dynamic_libstdcxx" = xno; then
885 AC_MSG_ERROR([Cannot link to stdc++, neither dynamically nor statically!])
886 fi
887
888 if test "x$with_stdc__lib" = xstatic && test "x$has_static_libstdcxx" = xno; then
889 AC_MSG_ERROR([Static linking of libstdc++ was not possible!])
890 fi
891
892 if test "x$with_stdc__lib" = xdynamic && test "x$has_dynamic_libstdcxx" = xno; then
893 AC_MSG_ERROR([Dynamic linking of libstdc++ was not possible!])
894 fi
895
896 AC_MSG_CHECKING([how to link with libstdc++])
897 # If dynamic was requested, it's available since it would fail above otherwise.
898 # If dynamic wasn't requested, go with static unless it isn't available.
899 if test "x$with_stdc__lib" = xdynamic || test "x$has_static_libstdcxx" = xno || test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
900 LIBCXX="$LIBCXX -lstdc++"
901 LDCXX="$CXX"
902 STATIC_CXX_SETTING="STATIC_CXX=false"
903 AC_MSG_RESULT([dynamic])
904 else
905 LIBCXX="$LIBCXX $STATIC_STDCXX_FLAGS"
906 LDCXX="$CC"
907 STATIC_CXX_SETTING="STATIC_CXX=true"
908 AC_MSG_RESULT([static])
909 fi
910 fi
911 AC_SUBST(STATIC_CXX_SETTING)
912
913 if test "x$JVM_VARIANT_ZERO" = xtrue || test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
914 # Figure out LIBFFI_CFLAGS and LIBFFI_LIBS
915 PKG_CHECK_MODULES([LIBFFI], [libffi])
916
917 fi
918
919 if test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
920 AC_CHECK_PROG([LLVM_CONFIG], [llvm-config], [llvm-config])
921
922 if test "x$LLVM_CONFIG" != xllvm-config; then
923 AC_MSG_ERROR([llvm-config not found in $PATH.])
924 fi
925
926 llvm_components="jit mcjit engine nativecodegen native"
927 unset LLVM_CFLAGS
928 for flag in $("$LLVM_CONFIG" --cxxflags); do
929 if echo "${flag}" | grep -q '^-@<:@ID@:>@'; then
930 if test "${flag}" != "-D_DEBUG" ; then
931 if test "${LLVM_CFLAGS}" != "" ; then
932 LLVM_CFLAGS="${LLVM_CFLAGS} "
933 fi
934 LLVM_CFLAGS="${LLVM_CFLAGS}${flag}"
935 fi
936 fi
937 done
938 llvm_version=$("${LLVM_CONFIG}" --version | sed 's/\.//; s/svn.*//')
939 LLVM_CFLAGS="${LLVM_CFLAGS} -DSHARK_LLVM_VERSION=${llvm_version}"
940
941 unset LLVM_LDFLAGS
942 for flag in $("${LLVM_CONFIG}" --ldflags); do
943 if echo "${flag}" | grep -q '^-L'; then
944 if test "${LLVM_LDFLAGS}" != ""; then
945 LLVM_LDFLAGS="${LLVM_LDFLAGS} "
946 fi
947 LLVM_LDFLAGS="${LLVM_LDFLAGS}${flag}"
948 fi
949 done
950
951 unset LLVM_LIBS
952 for flag in $("${LLVM_CONFIG}" --libs ${llvm_components}); do
953 if echo "${flag}" | grep -q '^-l'; then
954 if test "${LLVM_LIBS}" != ""; then
955 LLVM_LIBS="${LLVM_LIBS} "
956 fi
957 LLVM_LIBS="${LLVM_LIBS}${flag}"
958 fi
959 done
960
961 AC_SUBST(LLVM_CFLAGS)
962 AC_SUBST(LLVM_LDFLAGS)
963 AC_SUBST(LLVM_LIBS)
964 fi
965
966 # libCrun is the c++ runtime-library with SunStudio (roughly the equivalent of gcc's libstdc++.so)
967 if test "x$TOOLCHAIN_TYPE" = xsolstudio && test "x$LIBCXX" = x; then
968 LIBCXX="${SYSROOT}/usr/lib${OPENJDK_TARGET_CPU_ISADIR}/libCrun.so.1"
969 fi
970
971 # TODO better (platform agnostic) test
972 if test "x$OPENJDK_TARGET_OS" = xmacosx && test "x$LIBCXX" = x && test "x$TOOLCHAIN_TYPE" = xgcc; then
973 LIBCXX="-lstdc++"
974 fi
975
976 AC_SUBST(LIBCXX)
977 ])
978
979 AC_DEFUN_ONCE([LIB_SETUP_ON_WINDOWS],
980 [
981 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
982 TOOLCHAIN_SETUP_MSVCR_DLL
983 BASIC_DEPRECATED_ARG_WITH([dxsdk])
984 BASIC_DEPRECATED_ARG_WITH([dxsdk-lib])
985 BASIC_DEPRECATED_ARG_WITH([dxsdk-include])
986 fi
987 AC_SUBST(MSVCR_DLL)
988 ])