1 #
2 # Copyright (c) 2011, 2013, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VARIANT],
27 [
28 ###############################################################################
29 #
30 # Check which variant of the JDK that we want to build.
31 # Currently we have:
32 # normal: standard edition
33 # but the custom make system may add other variants
34 #
35 # Effectively the JDK variant gives a name to a specific set of
36 # modules to compile into the JDK. In the future, these modules
37 # might even be Jigsaw modules.
38 #
39 AC_MSG_CHECKING([which variant of the JDK to build])
40 AC_ARG_WITH([jdk-variant], [AS_HELP_STRING([--with-jdk-variant],
41 [JDK variant to build (normal) @<:@normal@:>@])])
42
43 if test "x$with_jdk_variant" = xnormal || test "x$with_jdk_variant" = x; then
44 JDK_VARIANT="normal"
45 else
46 AC_MSG_ERROR([The available JDK variants are: normal])
47 fi
48
49 AC_SUBST(JDK_VARIANT)
50
51 AC_MSG_RESULT([$JDK_VARIANT])
52 ])
53
54 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_VARIANTS],
55 [
56
57 ###############################################################################
58 #
59 # Check which variants of the JVM that we want to build.
60 # Currently we have:
61 # server: normal interpreter and a tiered C1/C2 compiler
62 # client: normal interpreter and C1 (no C2 compiler) (only 32-bit platforms)
63 # minimal1: reduced form of client with optional VM services and features stripped out
64 # kernel: kernel footprint JVM that passes the TCK without major performance problems,
65 # ie normal interpreter and C1, only the serial GC, kernel jvmti etc
66 # zero: no machine code interpreter, no compiler
67 # zeroshark: zero interpreter and shark/llvm compiler backend
68 AC_MSG_CHECKING([which variants of the JVM to build])
69 AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
70 [JVM variants (separated by commas) to build (server, client, minimal1, kernel, zero, zeroshark) @<:@server@:>@])])
71
72 if test "x$with_jvm_variants" = x; then
73 with_jvm_variants="server"
74 fi
75
76 JVM_VARIANTS=",$with_jvm_variants,"
77 TEST_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,//' -e 's/client,//' -e 's/minimal1,//' -e 's/kernel,//' -e 's/zero,//' -e 's/zeroshark,//'`
78
79 if test "x$TEST_VARIANTS" != "x,"; then
80 AC_MSG_ERROR([The available JVM variants are: server, client, minimal1, kernel, zero, zeroshark])
81 fi
82 AC_MSG_RESULT([$with_jvm_variants])
83
84 JVM_VARIANT_SERVER=`$ECHO "$JVM_VARIANTS" | $SED -e '/,server,/!s/.*/false/g' -e '/,server,/s/.*/true/g'`
85 JVM_VARIANT_CLIENT=`$ECHO "$JVM_VARIANTS" | $SED -e '/,client,/!s/.*/false/g' -e '/,client,/s/.*/true/g'`
86 JVM_VARIANT_MINIMAL1=`$ECHO "$JVM_VARIANTS" | $SED -e '/,minimal1,/!s/.*/false/g' -e '/,minimal1,/s/.*/true/g'`
87 JVM_VARIANT_KERNEL=`$ECHO "$JVM_VARIANTS" | $SED -e '/,kernel,/!s/.*/false/g' -e '/,kernel,/s/.*/true/g'`
88 JVM_VARIANT_ZERO=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zero,/!s/.*/false/g' -e '/,zero,/s/.*/true/g'`
89 JVM_VARIANT_ZEROSHARK=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zeroshark,/!s/.*/false/g' -e '/,zeroshark,/s/.*/true/g'`
90
91 if test "x$JVM_VARIANT_CLIENT" = xtrue; then
92 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
93 AC_MSG_ERROR([You cannot build a client JVM for a 64-bit machine.])
94 fi
95 fi
96 if test "x$JVM_VARIANT_KERNEL" = xtrue; then
97 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
98 AC_MSG_ERROR([You cannot build a kernel JVM for a 64-bit machine.])
99 fi
100 fi
101 if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
102 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
103 AC_MSG_ERROR([You cannot build a minimal JVM for a 64-bit machine.])
104 fi
105 fi
106
107 # Replace the commas with AND for use in the build directory name.
108 ANDED_JVM_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/^,//' -e 's/,$//' -e 's/,/AND/'`
109 COUNT_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,/1/' -e 's/client,/1/' -e 's/minimal1,/1/' -e 's/kernel,/1/' -e 's/zero,/1/' -e 's/zeroshark,/1/'`
110 if test "x$COUNT_VARIANTS" != "x,1"; then
111 BUILDING_MULTIPLE_JVM_VARIANTS=yes
112 else
113 BUILDING_MULTIPLE_JVM_VARIANTS=no
114 fi
115
116 AC_SUBST(JVM_VARIANTS)
117 AC_SUBST(JVM_VARIANT_SERVER)
118 AC_SUBST(JVM_VARIANT_CLIENT)
119 AC_SUBST(JVM_VARIANT_MINIMAL1)
120 AC_SUBST(JVM_VARIANT_KERNEL)
121 AC_SUBST(JVM_VARIANT_ZERO)
122 AC_SUBST(JVM_VARIANT_ZEROSHARK)
123
124 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
125 MACOSX_UNIVERSAL="true"
126 fi
127
128 AC_SUBST(MACOSX_UNIVERSAL)
129
130 ])
131
132 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_LEVEL],
133 [
134 ###############################################################################
135 #
136 # Set the debug level
137 # release: no debug information, all optimizations, no asserts.
138 # fastdebug: debug information (-g), all optimizations, all asserts
139 # slowdebug: debug information (-g), no optimizations, all asserts
140 #
141 DEBUG_LEVEL="release"
142 AC_MSG_CHECKING([which debug level to use])
143 AC_ARG_ENABLE([debug], [AS_HELP_STRING([--enable-debug],
144 [set the debug level to fastdebug (shorthand for --with-debug-level=fastdebug) @<:@disabled@:>@])],
145 [
146 ENABLE_DEBUG="${enableval}"
147 DEBUG_LEVEL="fastdebug"
148 ], [ENABLE_DEBUG="no"])
149
150 AC_ARG_WITH([debug-level], [AS_HELP_STRING([--with-debug-level],
151 [set the debug level (release, fastdebug, slowdebug) @<:@release@:>@])],
152 [
153 DEBUG_LEVEL="${withval}"
154 if test "x$ENABLE_DEBUG" = xyes; then
155 AC_MSG_ERROR([You cannot use both --enable-debug and --with-debug-level at the same time.])
156 fi
157 ])
158 AC_MSG_RESULT([$DEBUG_LEVEL])
159
160 if test "x$DEBUG_LEVEL" != xrelease && \
161 test "x$DEBUG_LEVEL" != xfastdebug && \
162 test "x$DEBUG_LEVEL" != xslowdebug; then
163 AC_MSG_ERROR([Allowed debug levels are: release, fastdebug and slowdebug])
164 fi
165
166
167 ###############################################################################
168 #
169 # Setup legacy vars/targets and new vars to deal with different debug levels.
170 #
171
172 case $DEBUG_LEVEL in
173 release )
174 VARIANT="OPT"
175 FASTDEBUG="false"
176 DEBUG_CLASSFILES="false"
177 BUILD_VARIANT_RELEASE=""
178 HOTSPOT_DEBUG_LEVEL="product"
179 HOTSPOT_EXPORT="product"
180 ;;
181 fastdebug )
182 VARIANT="DBG"
183 FASTDEBUG="true"
184 DEBUG_CLASSFILES="true"
185 BUILD_VARIANT_RELEASE="-fastdebug"
186 HOTSPOT_DEBUG_LEVEL="fastdebug"
187 HOTSPOT_EXPORT="fastdebug"
188 ;;
189 slowdebug )
190 VARIANT="DBG"
191 FASTDEBUG="false"
192 DEBUG_CLASSFILES="true"
193 BUILD_VARIANT_RELEASE="-debug"
194 HOTSPOT_DEBUG_LEVEL="jvmg"
195 HOTSPOT_EXPORT="debug"
196 ;;
197 esac
198
199 #####
200 # Generate the legacy makefile targets for hotspot.
201 # The hotspot api for selecting the build artifacts, really, needs to be improved.
202 # JDK-7195896 will fix this on the hotspot side by using the JVM_VARIANT_* variables to
203 # determine what needs to be built. All we will need to set here is all_product, all_fastdebug etc
204 # But until then ...
205 HOTSPOT_TARGET=""
206
207 if test "x$JVM_VARIANT_SERVER" = xtrue; then
208 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL} "
209 fi
210
211 if test "x$JVM_VARIANT_CLIENT" = xtrue; then
212 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}1 "
213 fi
214
215 if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
216 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}minimal1 "
217 fi
218
219 if test "x$JVM_VARIANT_KERNEL" = xtrue; then
220 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}kernel "
221 fi
222
223 if test "x$JVM_VARIANT_ZERO" = xtrue; then
224 PKG_CHECK_MODULES([LIBFFI], [libffi])
225 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}zero "
226 case "${OPENJDK_TARGET_CPU_LEGACY_LIB}" in
227 i386) ZERO_ARCHDEF=IA32 ;;
228 ppc*) ZERO_ARCHDEF=PPC ;;
229 s390*) ZERO_ARCHDEF=S390 ;;
230 sparc*) ZERO_ARCHDEF=SPARC ;;
231 *) ZERO_ARCHDEF=$(echo "${OPENJDK_TARGET_CPU_LEGACY_LIB}" | tr a-z A-Z)
232 esac
233 fi
234
235 if test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
236 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}shark "
237 fi
238
239 HOTSPOT_TARGET="$HOTSPOT_TARGET docs export_$HOTSPOT_EXPORT"
240
241 # On Macosx universal binaries are produced, but they only contain
242 # 64 bit intel. This invalidates control of which jvms are built
243 # from configure, but only server is valid anyway. Fix this
244 # when hotspot makefiles are rewritten.
245 if test "x$MACOSX_UNIVERSAL" = xtrue; then
246 HOTSPOT_TARGET=universal_${HOTSPOT_EXPORT}
247 fi
248
249 #####
250
251 AC_SUBST(DEBUG_LEVEL)
252 AC_SUBST(VARIANT)
253 AC_SUBST(FASTDEBUG)
254 AC_SUBST(DEBUG_CLASSFILES)
255 AC_SUBST(BUILD_VARIANT_RELEASE)
256 AC_SUBST(ZERO_ARCHDEF)
257 ])
258
259
260 ###############################################################################
261 #
262 # Should we build only OpenJDK even if closed sources are present?
263 #
264 AC_DEFUN_ONCE([JDKOPT_SETUP_OPEN_OR_CUSTOM],
265 [
266 AC_ARG_ENABLE([openjdk-only], [AS_HELP_STRING([--enable-openjdk-only],
267 [suppress building custom source even if present @<:@disabled@:>@])],,[enable_openjdk_only="no"])
268
269 AC_MSG_CHECKING([for presence of closed sources])
270 if test -d "$SRC_ROOT/jdk/src/closed"; then
271 CLOSED_SOURCE_PRESENT=yes
272 else
273 CLOSED_SOURCE_PRESENT=no
274 fi
275 AC_MSG_RESULT([$CLOSED_SOURCE_PRESENT])
276
277 AC_MSG_CHECKING([if closed source is suppressed (openjdk-only)])
278 SUPPRESS_CLOSED_SOURCE="$enable_openjdk_only"
279 AC_MSG_RESULT([$SUPPRESS_CLOSED_SOURCE])
280
281 if test "x$CLOSED_SOURCE_PRESENT" = xno; then
282 OPENJDK=true
283 if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
284 AC_MSG_WARN([No closed source present, --enable-openjdk-only makes no sense])
285 fi
286 else
287 if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
288 OPENJDK=true
289 else
290 OPENJDK=false
291 fi
292 fi
293
294 if test "x$OPENJDK" = "xtrue"; then
295 SET_OPENJDK="OPENJDK=true"
296 fi
297
298 AC_SUBST(SET_OPENJDK)
299 ])
300
301 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_OPTIONS],
302 [
303
304 ###############################################################################
305 #
306 # Should we build a JDK/JVM with headful support (ie a graphical ui)?
307 # We always build headless support.
308 #
309 AC_MSG_CHECKING([headful support])
310 AC_ARG_ENABLE([headful], [AS_HELP_STRING([--disable-headful],
311 [disable building headful support (graphical UI support) @<:@enabled@:>@])],
312 [SUPPORT_HEADFUL=${enable_headful}], [SUPPORT_HEADFUL=yes])
313
314 SUPPORT_HEADLESS=yes
315 BUILD_HEADLESS="BUILD_HEADLESS:=true"
316
317 if test "x$SUPPORT_HEADFUL" = xyes; then
318 # We are building both headful and headless.
319 headful_msg="inlude support for both headful and headless"
320 fi
321
322 if test "x$SUPPORT_HEADFUL" = xno; then
323 # Thus we are building headless only.
324 BUILD_HEADLESS="BUILD_HEADLESS:=true"
325 headful_msg="headless only"
326 fi
327
328 AC_MSG_RESULT([$headful_msg])
329
330 AC_SUBST(SUPPORT_HEADLESS)
331 AC_SUBST(SUPPORT_HEADFUL)
332 AC_SUBST(BUILD_HEADLESS)
333
334 # Control wether Hotspot runs Queens test after build.
335 AC_ARG_ENABLE([hotspot-test-in-build], [AS_HELP_STRING([--enable-hotspot-test-in-build],
336 [run the Queens test after Hotspot build @<:@disabled@:>@])],,
337 [enable_hotspot_test_in_build=no])
338 if test "x$enable_hotspot_test_in_build" = "xyes"; then
339 TEST_IN_BUILD=true
340 else
341 TEST_IN_BUILD=false
342 fi
343 AC_SUBST(TEST_IN_BUILD)
344
345 ###############################################################################
346 #
347 # Choose cacerts source file
348 #
349 AC_ARG_WITH(cacerts-file, [AS_HELP_STRING([--with-cacerts-file],
350 [specify alternative cacerts file])])
351 if test "x$with_cacerts_file" != x; then
352 CACERTS_FILE=$with_cacerts_file
353 else
354 if test "x$OPENJDK" = "xtrue"; then
355 CACERTS_FILE=${SRC_ROOT}/jdk/src/share/lib/security/cacerts
356 else
357 CACERTS_FILE=${SRC_ROOT}/jdk/src/closed/share/lib/security/cacerts.internal
358 fi
359 fi
360 AC_SUBST(CACERTS_FILE)
361
362 ###############################################################################
363 #
364 # Enable or disable unlimited crypto
365 #
366 AC_ARG_ENABLE(unlimited-crypto, [AS_HELP_STRING([--enable-unlimited-crypto],
367 [Enable unlimited crypto policy @<:@disabled@:>@])],,
368 [enable_unlimited_crypto=no])
369 if test "x$enable_unlimited_crypto" = "xyes"; then
370 UNLIMITED_CRYPTO=true
371 else
372 UNLIMITED_CRYPTO=false
373 fi
374 AC_SUBST(UNLIMITED_CRYPTO)
375
376 ###############################################################################
377 #
378 # Enable or disable the elliptic curve crypto implementation
379 #
380 AC_DEFUN_ONCE([JDKOPT_DETECT_INTREE_EC],
381 [
382 AC_MSG_CHECKING([if elliptic curve crypto implementation is present])
383
384 if test -d "${SRC_ROOT}/jdk/src/share/native/sun/security/ec/impl"; then
385 ENABLE_INTREE_EC=yes
386 AC_MSG_RESULT([yes])
387 else
388 ENABLE_INTREE_EC=no
389 AC_MSG_RESULT([no])
390 fi
391
392 AC_SUBST(ENABLE_INTREE_EC)
393 ])
394
395 ###############################################################################
396 #
397 # Compress jars
398 #
399 COMPRESS_JARS=false
400
401 AC_SUBST(COMPRESS_JARS)
402 ])
403
404 ###############################################################################
405 #
406 # Setup version numbers
407 #
408 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VERSION_NUMBERS],
409 [
410 # Source the version numbers
411 . $AUTOCONF_DIR/version-numbers
412
413 # Get the settings from parameters
414 AC_ARG_WITH(milestone, [AS_HELP_STRING([--with-milestone],
415 [Set milestone value for build @<:@internal@:>@])])
416 if test "x$with_milestone" = xyes; then
417 AC_MSG_ERROR([Milestone must have a value])
418 elif test "x$with_milestone" != x; then
419 MILESTONE="$with_milestone"
420 fi
421 if test "x$MILESTONE" = x; then
422 MILESTONE=internal
423 fi
424
425 AC_ARG_WITH(build-number, [AS_HELP_STRING([--with-build-number],
426 [Set build number value for build @<:@b00@:>@])])
427 if test "x$with_build_number" = xyes; then
428 AC_MSG_ERROR([Build number must have a value])
429 elif test "x$with_build_number" != x; then
430 JDK_BUILD_NUMBER="$with_build_number"
431 fi
432 if test "x$JDK_BUILD_NUMBER" = x; then
433 JDK_BUILD_NUMBER=b00
434 fi
435
436 AC_ARG_WITH(user-release-suffix, [AS_HELP_STRING([--with-user-release-suffix],
437 [Add a custom string to the version string if build number isn't set.@<:@username_builddateb00@:>@])])
438 if test "x$with_user_release_suffix" = xyes; then
439 AC_MSG_ERROR([Release suffix must have a value])
440 elif test "x$with_user_release_suffix" != x; then
441 USER_RELEASE_SUFFIX="$with_user_release_suffix"
442 else
443 BUILD_DATE=`date '+%Y_%m_%d_%H_%M'`
444 # Avoid [:alnum:] since it depends on the locale.
445 CLEAN_USERNAME=`echo "$USER" | $TR -d -c 'abcdefghijklmnopqrstuvqxyz0123456789'`
446 USER_RELEASE_SUFFIX=`echo "${CLEAN_USERNAME}_${BUILD_DATE}" | $TR 'ABCDEFGHIJKLMNOPQRSTUVWXYZ' 'abcdefghijklmnopqrstuvwxyz'`
447 fi
448 AC_SUBST(USER_RELEASE_SUFFIX)
449
450 # Now set the JDK version, milestone, build number etc.
451 AC_SUBST(JDK_MAJOR_VERSION)
452 AC_SUBST(JDK_MINOR_VERSION)
453 AC_SUBST(JDK_MICRO_VERSION)
454 AC_SUBST(JDK_UPDATE_VERSION)
455 AC_SUBST(JDK_BUILD_NUMBER)
456 AC_SUBST(MILESTONE)
457 AC_SUBST(LAUNCHER_NAME)
458 AC_SUBST(PRODUCT_NAME)
459 AC_SUBST(PRODUCT_SUFFIX)
460 AC_SUBST(JDK_RC_PLATFORM_NAME)
461 AC_SUBST(COMPANY_NAME)
462 AC_SUBST(MACOSX_BUNDLE_NAME_BASE)
463 AC_SUBST(MACOSX_BUNDLE_ID_BASE)
464
465 COPYRIGHT_YEAR=`date +'%Y'`
466 AC_SUBST(COPYRIGHT_YEAR)
467
468 if test "x$JDK_UPDATE_VERSION" != x; then
469 JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}_${JDK_UPDATE_VERSION}"
470 else
471 JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}"
472 fi
473 AC_SUBST(JDK_VERSION)
474
475 COOKED_BUILD_NUMBER=`$ECHO $JDK_BUILD_NUMBER | $SED -e 's/^b//' -e 's/^0//'`
476 AC_SUBST(COOKED_BUILD_NUMBER)
477 ])
478
479 AC_DEFUN_ONCE([JDKOPT_SETUP_BUILD_TWEAKS],
480 [
481 HOTSPOT_MAKE_ARGS="$HOTSPOT_TARGET"
482 AC_SUBST(HOTSPOT_MAKE_ARGS)
483
484 # The name of the Service Agent jar.
485 SALIB_NAME="${LIBRARY_PREFIX}saproc${SHARED_LIBRARY_SUFFIX}"
486 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
487 SALIB_NAME="${LIBRARY_PREFIX}sawindbg${SHARED_LIBRARY_SUFFIX}"
488 fi
489 AC_SUBST(SALIB_NAME)
490
491 ])
492
493 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_SYMBOLS],
494 [
495 #
496 # ENABLE_DEBUG_SYMBOLS
497 # This must be done after the toolchain is setup, since we're looking at objcopy.
498 #
499 AC_ARG_ENABLE([debug-symbols],
500 [AS_HELP_STRING([--disable-debug-symbols],[disable generation of debug symbols @<:@enabled@:>@])])
501
502 AC_MSG_CHECKING([if we should generate debug symbols])
503
504 if test "x$enable_debug_symbols" = "xyes" && test "x$OBJCOPY" = x; then
505 # explicit enabling of enable-debug-symbols and can't find objcopy
506 # this is an error
507 AC_MSG_ERROR([Unable to find objcopy, cannot enable debug-symbols])
508 fi
509
510 if test "x$enable_debug_symbols" = "xyes"; then
511 ENABLE_DEBUG_SYMBOLS=true
512 elif test "x$enable_debug_symbols" = "xno"; then
513 ENABLE_DEBUG_SYMBOLS=false
514 else
515 # default on macosx is false
516 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
517 ENABLE_DEBUG_SYMBOLS=false
518 # Default is on if objcopy is found, otherwise off
519 elif test "x$OBJCOPY" != x || test "x$OPENJDK_TARGET_OS" = xwindows; then
520 ENABLE_DEBUG_SYMBOLS=true
521 else
522 ENABLE_DEBUG_SYMBOLS=false
523 fi
524 fi
525
526 AC_MSG_RESULT([$ENABLE_DEBUG_SYMBOLS])
527
528 #
529 # ZIP_DEBUGINFO_FILES
530 #
531 AC_ARG_ENABLE([zip-debug-info],
532 [AS_HELP_STRING([--disable-zip-debug-info],[disable zipping of debug-info files @<:@enabled@:>@])])
533
534 AC_MSG_CHECKING([if we should zip debug-info files])
535 AC_MSG_RESULT([${enable_zip_debug_info}])
536
537 if test "x${enable_zip_debug_info}" = "xno"; then
538 ZIP_DEBUGINFO_FILES=false
539 else
540 ZIP_DEBUGINFO_FILES=true
541 fi
542
543 AC_SUBST(ENABLE_DEBUG_SYMBOLS)
544 AC_SUBST(ZIP_DEBUGINFO_FILES)
545 AC_SUBST(CFLAGS_DEBUG_SYMBOLS)
546 AC_SUBST(CXXFLAGS_DEBUG_SYMBOLS)
547 ])
548
549 # Support for customization of the build process. Some build files
550 # will include counterparts from this location, if they exist. This allows
551 # for a degree of customization of the build targets and the rules/recipes
552 # to create them
553 AC_ARG_WITH([custom-make-dir], [AS_HELP_STRING([--with-custom-make-dir],
554 [use this directory for custom build/make files])], [CUSTOM_MAKE_DIR=$with_custom_make_dir])
555 AC_SUBST(CUSTOM_MAKE_DIR)