1 #
2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
27 # Converts autoconf style CPU name to OpenJDK style, into
28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
30 [
31 # First argument is the cpu name from the trip/quad
32 case "$1" in
33 x86_64)
34 VAR_CPU=x86_64
35 VAR_CPU_ARCH=x86
36 VAR_CPU_BITS=64
37 VAR_CPU_ENDIAN=little
38 ;;
39 i?86)
40 VAR_CPU=x86
41 VAR_CPU_ARCH=x86
42 VAR_CPU_BITS=32
43 VAR_CPU_ENDIAN=little
44 ;;
45 arm*)
46 VAR_CPU=arm
47 VAR_CPU_ARCH=arm
48 VAR_CPU_BITS=32
49 VAR_CPU_ENDIAN=little
50 ;;
51 powerpc)
52 VAR_CPU=ppc
53 VAR_CPU_ARCH=ppc
54 VAR_CPU_BITS=32
55 VAR_CPU_ENDIAN=big
56 ;;
57 powerpc64)
58 VAR_CPU=ppc64
59 VAR_CPU_ARCH=ppc
60 VAR_CPU_BITS=64
61 VAR_CPU_ENDIAN=big
62 ;;
63 sparc)
64 VAR_CPU=sparc
65 VAR_CPU_ARCH=sparc
66 VAR_CPU_BITS=32
67 VAR_CPU_ENDIAN=big
68 ;;
69 sparcv9)
70 VAR_CPU=sparcv9
71 VAR_CPU_ARCH=sparc
72 VAR_CPU_BITS=64
73 VAR_CPU_ENDIAN=big
74 ;;
75 *)
76 AC_MSG_ERROR([unsupported cpu $1])
77 ;;
78 esac
79 ])
80
81 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
82 # Converts autoconf style OS name to OpenJDK style, into
83 # VAR_OS and VAR_OS_API.
84 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
85 [
86 case "$1" in
87 *linux*)
88 VAR_OS=linux
89 VAR_OS_API=posix
90 VAR_OS_ENV=linux
91 ;;
92 *solaris*)
93 VAR_OS=solaris
94 VAR_OS_API=posix
95 VAR_OS_ENV=solaris
96 ;;
97 *darwin*)
98 VAR_OS=macosx
99 VAR_OS_API=posix
100 VAR_OS_ENV=macosx
101 ;;
102 *bsd*)
103 VAR_OS=bsd
104 VAR_OS_API=posix
105 VAR_OS_ENV=bsd
106 ;;
107 *cygwin*)
108 VAR_OS=windows
109 VAR_OS_API=winapi
110 VAR_OS_ENV=windows.cygwin
111 ;;
112 *mingw*)
113 VAR_OS=windows
114 VAR_OS_API=winapi
115 VAR_OS_ENV=windows.msys
116 ;;
117 *)
118 AC_MSG_ERROR([unsupported operating system $1])
119 ;;
120 esac
121 ])
122
123 # Expects $host_os $host_cpu $build_os and $build_cpu
124 # and $with_target_bits to have been setup!
125 #
126 # Translate the standard triplet(quadruplet) definition
127 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
128 # OPENJDK_BUILD_OS, etc.
129 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
130 [
131 # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
132 # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
133 # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
134 # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
135 OPENJDK_TARGET_AUTOCONF_NAME="$host"
136 OPENJDK_BUILD_AUTOCONF_NAME="$build"
137 AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
138 AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
139
140 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
141 PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
142 PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
143 # ..and setup our own variables. (Do this explicitely to facilitate searching)
144 OPENJDK_BUILD_OS="$VAR_OS"
145 OPENJDK_BUILD_OS_API="$VAR_OS_API"
146 OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
147 OPENJDK_BUILD_CPU="$VAR_CPU"
148 OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
149 OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
150 OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
151 AC_SUBST(OPENJDK_BUILD_OS)
152 AC_SUBST(OPENJDK_BUILD_OS_API)
153 AC_SUBST(OPENJDK_BUILD_CPU)
154 AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
155 AC_SUBST(OPENJDK_BUILD_CPU_BITS)
156 AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
157
158 AC_MSG_CHECKING([openjdk-build os-cpu])
159 AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
160
161 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
162 PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
163 PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
164 # ... and setup our own variables. (Do this explicitely to facilitate searching)
165 OPENJDK_TARGET_OS="$VAR_OS"
166 OPENJDK_TARGET_OS_API="$VAR_OS_API"
167 OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
168 OPENJDK_TARGET_CPU="$VAR_CPU"
169 OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
170 OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
171 OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
172 AC_SUBST(OPENJDK_TARGET_OS)
173 AC_SUBST(OPENJDK_TARGET_OS_API)
174 AC_SUBST(OPENJDK_TARGET_CPU)
175 AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
176 AC_SUBST(OPENJDK_TARGET_CPU_BITS)
177 AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
178
179 AC_MSG_CHECKING([openjdk-target os-cpu])
180 AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
181 ])
182
183 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
184 # accordingly. Must be done after setting up build and target system, but before
185 # doing anything else with these values.
186 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
187 [
188 AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
189 [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
190
191 # We have three types of compiles:
192 # native == normal compilation, target system == build system
193 # cross == traditional cross compilation, target system != build system; special toolchain needed
194 # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
195 #
196 if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
197 # We're doing a proper cross-compilation
198 COMPILE_TYPE="cross"
199 else
200 COMPILE_TYPE="native"
201 fi
202
203 if test "x$with_target_bits" != x; then
204 if test "x$COMPILE_TYPE" = "xcross"; then
205 AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
206 fi
207
208 if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
209 # A reduced build is requested
210 COMPILE_TYPE="reduced"
211 OPENJDK_TARGET_CPU_BITS=32
212 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
213 OPENJDK_TARGET_CPU=x86
214 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
215 OPENJDK_TARGET_CPU=sparc
216 else
217 AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
218 fi
219 elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
220 AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
221 elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
222 AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
223 else
224 AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
225 fi
226 fi
227 AC_SUBST(COMPILE_TYPE)
228
229 AC_MSG_CHECKING([compilation type])
230 AC_MSG_RESULT([$COMPILE_TYPE])
231 ])
232
233 # Setup the legacy variables, for controlling the old makefiles.
234 #
235 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
236 [
237 # Also store the legacy naming of the cpu.
238 # Ie i586 and amd64 instead of x86 and x86_64
239 OPENJDK_TARGET_CPU_LEGACY="$OPENJDK_TARGET_CPU"
240 if test "x$OPENJDK_TARGET_CPU" = xx86; then
241 OPENJDK_TARGET_CPU_LEGACY="i586"
242 elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
243 # On all platforms except MacOSX replace x86_64 with amd64.
244 OPENJDK_TARGET_CPU_LEGACY="amd64"
245 fi
246 AC_SUBST(OPENJDK_TARGET_CPU_LEGACY)
247
248 # And the second legacy naming of the cpu.
249 # Ie i386 and amd64 instead of x86 and x86_64.
250 OPENJDK_TARGET_CPU_LEGACY_LIB="$OPENJDK_TARGET_CPU"
251 if test "x$OPENJDK_TARGET_CPU" = xx86; then
252 OPENJDK_TARGET_CPU_LEGACY_LIB="i386"
253 elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then
254 OPENJDK_TARGET_CPU_LEGACY_LIB="amd64"
255 fi
256 AC_SUBST(OPENJDK_TARGET_CPU_LEGACY_LIB)
257
258 # This is the name of the cpu (but using i386 and amd64 instead of
259 # x86 and x86_64, respectively), preceeded by a /, to be used when
260 # locating libraries. On macosx, it's empty, though.
261 OPENJDK_TARGET_CPU_LIBDIR="/$OPENJDK_TARGET_CPU_LEGACY_LIB"
262 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
263 OPENJDK_TARGET_CPU_LIBDIR=""
264 fi
265 AC_SUBST(OPENJDK_TARGET_CPU_LIBDIR)
266
267 # OPENJDK_TARGET_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
268 # /amd64 or /sparcv9. This string is appended to some library paths, like this:
269 # /usr/lib${OPENJDK_TARGET_CPU_ISADIR}/libexample.so
270 OPENJDK_TARGET_CPU_ISADIR=""
271 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
272 if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
273 OPENJDK_TARGET_CPU_ISADIR="/amd64"
274 elif test "x$OPENJDK_TARGET_CPU" = xsparcv9; then
275 OPENJDK_TARGET_CPU_ISADIR="/sparcv9"
276 fi
277 fi
278 AC_SUBST(OPENJDK_TARGET_CPU_ISADIR)
279
280 # Setup OPENJDK_TARGET_CPU_OSARCH, which is used to set the os.arch Java system property
281 OPENJDK_TARGET_CPU_OSARCH="$OPENJDK_TARGET_CPU"
282 if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$OPENJDK_TARGET_CPU" = xx86; then
283 # On linux only, we replace x86 with i386.
284 OPENJDK_TARGET_CPU_OSARCH="i386"
285 elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
286 # On all platforms except macosx, we replace x86_64 with amd64.
287 OPENJDK_TARGET_CPU_OSARCH="amd64"
288 fi
289 AC_SUBST(OPENJDK_TARGET_CPU_OSARCH)
290
291 OPENJDK_TARGET_CPU_JLI="$OPENJDK_TARGET_CPU"
292 if test "x$OPENJDK_TARGET_CPU" = xx86; then
293 OPENJDK_TARGET_CPU_JLI="i386"
294 elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
295 # On all platforms except macosx, we replace x86_64 with amd64.
296 OPENJDK_TARGET_CPU_JLI="amd64"
297 fi
298 # Now setup the -D flags for building libjli.
299 OPENJDK_TARGET_CPU_JLI_CFLAGS="-DLIBARCHNAME='\"$OPENJDK_TARGET_CPU_JLI\"'"
300 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
301 if test "x$OPENJDK_TARGET_CPU_ARCH" = xsparc; then
302 OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"sparc\"' -DLIBARCH64NAME='\"sparcv9\"'"
303 elif test "x$OPENJDK_TARGET_CPU_ARCH" = xx86; then
304 OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"i386\"' -DLIBARCH64NAME='\"amd64\"'"
305 fi
306 fi
307 AC_SUBST(OPENJDK_TARGET_CPU_JLI_CFLAGS)
308
309 # Setup OPENJDK_TARGET_OS_API_DIR, used in source paths.
310 if test "x$OPENJDK_TARGET_OS_API" = xposix; then
311 OPENJDK_TARGET_OS_API_DIR="solaris"
312 fi
313 if test "x$OPENJDK_TARGET_OS_API" = xwinapi; then
314 OPENJDK_TARGET_OS_API_DIR="windows"
315 fi
316 AC_SUBST(OPENJDK_TARGET_OS_API_DIR)
317
318 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
319 A_LP64="LP64:="
320 # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
321 # unpack200.exe
322 if test "x$OPENJDK_TARGET_OS" = xlinux || test "x$OPENJDK_TARGET_OS" = xmacosx; then
323 ADD_LP64="-D_LP64=1"
324 fi
325 fi
326 AC_SUBST(LP64,$A_LP64)
327
328 if test "x$COMPILE_TYPE" = "xcross"; then
329 # FIXME: ... or should this include reduced builds..?
330 DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_TARGET_CPU_LEGACY"
331 else
332 DEFINE_CROSS_COMPILE_ARCH=""
333 fi
334 AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
335
336 # Some Zero and Shark settings.
337 # ZERO_ARCHFLAG tells the compiler which mode to build for
338 case "${OPENJDK_TARGET_CPU}" in
339 s390)
340 ZERO_ARCHFLAG="-m31"
341 ;;
342 *)
343 ZERO_ARCHFLAG="-m${OPENJDK_TARGET_CPU_BITS}"
344 esac
345 AC_SUBST(ZERO_ARCHFLAG)
346
347 # ZERO_ARCHDEF is used to enable architecture-specific code
348 case "${OPENJDK_TARGET_CPU}" in
349 ppc*) ZERO_ARCHDEF=PPC ;;
350 s390*) ZERO_ARCHDEF=S390 ;;
351 sparc*) ZERO_ARCHDEF=SPARC ;;
352 x86_64*) ZERO_ARCHDEF=AMD64 ;;
353 x86) ZERO_ARCHDEF=IA32 ;;
354 *) ZERO_ARCHDEF=$(echo "${OPENJDK_TARGET_CPU_LEGACY_LIB}" | tr a-z A-Z)
355 esac
356 AC_SUBST(ZERO_ARCHDEF)
357
358 ])
359
360 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
361 [
362 if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
363 REQUIRED_OS_NAME=SunOS
364 REQUIRED_OS_VERSION=5.10
365 fi
366 if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
367 REQUIRED_OS_NAME=Linux
368 REQUIRED_OS_VERSION=2.6
369 fi
370 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
371 REQUIRED_OS_NAME=Windows
372 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
373 REQUIRED_OS_VERSION=5.2
374 else
375 REQUIRED_OS_VERSION=5.1
376 fi
377 fi
378 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
379 REQUIRED_OS_NAME=Darwin
380 REQUIRED_OS_VERSION=11.2
381 fi
382
383 AC_SUBST(REQUIRED_OS_NAME)
384 AC_SUBST(REQUIRED_OS_VERSION)
385 ])
386
387 #%%% Build and target systems %%%
388 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
389 [
390 # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
391 # is confusing; it assumes you are cross-compiling a cross-compiler (!) and "target" is thus the target of the
392 # product you're building. The target of this build is called "host". Since this is confusing to most people, we
393 # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
394 # to use the configure naming style.
395 AC_CANONICAL_BUILD
396 AC_CANONICAL_HOST
397 AC_CANONICAL_TARGET
398
399 PLATFORM_EXTRACT_TARGET_AND_BUILD
400 PLATFORM_SETUP_TARGET_CPU_BITS
401 PLATFORM_SET_RELEASE_FILE_OS_VALUES
402 PLATFORM_SETUP_LEGACY_VARS
403 ])
404
405 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
406 [
407 ###############################################################################
408
409 # Note that this is the build platform OS version!
410
411 OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
412 OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
413 OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
414 OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
415 AC_SUBST(OS_VERSION_MAJOR)
416 AC_SUBST(OS_VERSION_MINOR)
417 AC_SUBST(OS_VERSION_MICRO)
418 ])
419
420 # Support macro for PLATFORM_SETUP_OPENJDK_TARGET_BITS.
421 # Add -mX to various FLAGS variables.
422 AC_DEFUN([PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS],
423 [
424 # keep track of c/cxx flags that we added outselves...
425 # to prevent emitting warning...
426 ADDED_CFLAGS=" -m${OPENJDK_TARGET_CPU_BITS}"
427 ADDED_CXXFLAGS=" -m${OPENJDK_TARGET_CPU_BITS}"
428 ADDED_LDFLAGS=" -m${OPENJDK_TARGET_CPU_BITS}"
429
430 CFLAGS="${CFLAGS}${ADDED_CFLAGS}"
431 CXXFLAGS="${CXXFLAGS}${ADDED_CXXFLAGS}"
432 LDFLAGS="${LDFLAGS}${ADDED_LDFLAGS}"
433
434 CFLAGS_JDK="${CFLAGS_JDK}${ADDED_CFLAGS}"
435 CXXFLAGS_JDK="${CXXFLAGS_JDK}${ADDED_CXXFLAGS}"
436 LDFLAGS_JDK="${LDFLAGS_JDK}${ADDED_LDFLAGS}"
437 ])
438
439 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
440 [
441 ###############################################################################
442 #
443 # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
444 # (The JVM can use 32 or 64 bit Java pointers but that decision
445 # is made at runtime.)
446 #
447 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
448 # Always specify -m flags on Solaris
449 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
450 elif test "x$COMPILE_TYPE" = xreduced; then
451 if test "x$OPENJDK_TARGET_OS" != xwindows; then
452 # Specify -m if running reduced on other Posix platforms
453 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
454 fi
455 fi
456
457 # Make compilation sanity check
458 AC_CHECK_HEADERS([stdio.h], , [
459 AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
460 if test "x$COMPILE_TYPE" = xreduced; then
461 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed.])
462 elif test "x$COMPILE_TYPE" = xcross; then
463 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
464 fi
465 AC_MSG_ERROR([Cannot continue.])
466 ])
467
468 AC_CHECK_SIZEOF([int *], [1111])
469
470 if test "x$SIZEOF_INT_P" != "x$ac_cv_sizeof_int_p"; then
471 # Workaround autoconf bug, see http://lists.gnu.org/archive/html/autoconf/2010-07/msg00004.html
472 SIZEOF_INT_P="$ac_cv_sizeof_int_p"
473 fi
474
475 if test "x$SIZEOF_INT_P" = x; then
476 # The test failed, lets stick to the assumed value.
477 AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
478 else
479 TESTED_TARGET_CPU_BITS=`expr 8 \* $SIZEOF_INT_P`
480
481 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
482 AC_MSG_ERROR([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
483 fi
484 fi
485
486 AC_MSG_CHECKING([for target address size])
487 AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
488 ])
489
490 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
491 [
492 ###############################################################################
493 #
494 # Is the target little of big endian?
495 #
496 AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
497
498 if test "x$ENDIAN" = xuniversal_endianness; then
499 AC_MSG_ERROR([Building with both big and little endianness is not supported])
500 fi
501 if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
502 AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
503 fi
504 ])