1 #
2 # Copyright (c) 2011, 2017, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # All valid JVM features, regardless of platform
27 VALID_JVM_FEATURES="compiler1 compiler2 zero shark minimal dtrace jvmti jvmci \
28 graal vm-structs jni-check services management all-gcs nmt cds \
29 static-build link-time-opt aot"
30
31 # All valid JVM variants
32 VALID_JVM_VARIANTS="server client minimal core zero zeroshark custom"
33
34 ###############################################################################
35 # Check if the specified JVM variant should be built. To be used in shell if
36 # constructs, like this:
37 # if HOTSPOT_CHECK_JVM_VARIANT(server); then
38 #
39 # Only valid to use after HOTSPOT_SETUP_JVM_VARIANTS has setup variants.
40
41 # Definition kept in one line to allow inlining in if statements.
42 # Additional [] needed to keep m4 from mangling shell constructs.
43 AC_DEFUN([HOTSPOT_CHECK_JVM_VARIANT],
44 [ [ [[ " $JVM_VARIANTS " =~ " $1 " ]] ] ])
45
46 ###############################################################################
47 # Check if the specified JVM features are explicitly enabled. To be used in
48 # shell if constructs, like this:
49 # if HOTSPOT_CHECK_JVM_FEATURE(jvmti); then
50 #
51 # Only valid to use after HOTSPOT_SETUP_JVM_FEATURES has setup features.
52
53 # Definition kept in one line to allow inlining in if statements.
54 # Additional [] needed to keep m4 from mangling shell constructs.
55 AC_DEFUN([HOTSPOT_CHECK_JVM_FEATURE],
56 [ [ [[ " $JVM_FEATURES " =~ " $1 " ]] ] ])
57
58 ###############################################################################
59 # Check which variants of the JVM that we want to build. Available variants are:
60 # server: normal interpreter, and a tiered C1/C2 compiler
61 # client: normal interpreter, and C1 (no C2 compiler)
62 # minimal: reduced form of client with optional features stripped out
63 # core: normal interpreter only, no compiler
64 # zero: C++ based interpreter only, no compiler
65 # zeroshark: C++ based interpreter, and a llvm-based compiler
66 # custom: baseline JVM with no default features
67 #
68 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_VARIANTS],
69 [
70 AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
71 [JVM variants (separated by commas) to build (server,client,minimal,core,zero,zeroshark,custom) @<:@server@:>@])])
72
73 SETUP_HOTSPOT_TARGET_CPU_PORT
74
75 if test "x$with_jvm_variants" = x; then
76 with_jvm_variants="server"
77 fi
78 JVM_VARIANTS_OPT="$with_jvm_variants"
79
80 # Has the user listed more than one variant?
81 # Additional [] needed to keep m4 from mangling shell constructs.
82 if [ [[ "$JVM_VARIANTS_OPT" =~ "," ]] ]; then
83 BUILDING_MULTIPLE_JVM_VARIANTS=true
84 else
85 BUILDING_MULTIPLE_JVM_VARIANTS=false
86 fi
87 # Replace the commas with AND for use in the build directory name.
88 JVM_VARIANTS_WITH_AND=`$ECHO "$JVM_VARIANTS_OPT" | $SED -e 's/,/AND/g'`
89
90 AC_MSG_CHECKING([which variants of the JVM to build])
91 # JVM_VARIANTS is a space-separated list.
92 # Also use minimal, not minimal1 (which is kept for backwards compatibility).
93 JVM_VARIANTS=`$ECHO $JVM_VARIANTS_OPT | $SED -e 's/,/ /g' -e 's/minimal1/minimal/'`
94 AC_MSG_RESULT([$JVM_VARIANTS])
95
96 # Check that the selected variants are valid
97
98 # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
99 # Notice that the original variant failes on SLES 10 and 11
100 NEEDLE=${VALID_JVM_VARIANTS// /$'\n'}
101 STACK=${JVM_VARIANTS// /$'\n'}
102 INVALID_VARIANTS=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
103 if test "x$INVALID_VARIANTS" != x; then
104 AC_MSG_NOTICE([Unknown variant(s) specified: $INVALID_VARIANTS])
105 AC_MSG_ERROR([The available JVM variants are: $VALID_JVM_VARIANTS])
106 fi
107
108 # All "special" variants share the same output directory ("server")
109 VALID_MULTIPLE_JVM_VARIANTS="server client minimal"
110 NEEDLE=${VALID_MULTIPLE_JVM_VARIANTS// /$'\n'}
111 STACK=${JVM_VARIANTS// /$'\n'}
112 INVALID_MULTIPLE_VARIANTS=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
113 if test "x$INVALID_MULTIPLE_VARIANTS" != x && test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = xtrue; then
114 AC_MSG_ERROR([You cannot build multiple variants with anything else than $VALID_MULTIPLE_JVM_VARIANTS.])
115 fi
116
117 # The "main" variant is the one used by other libs to link against during the
118 # build.
119 if test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = "xtrue"; then
120 MAIN_VARIANT_PRIO_ORDER="server client minimal"
121 for variant in $MAIN_VARIANT_PRIO_ORDER; do
122 if HOTSPOT_CHECK_JVM_VARIANT($variant); then
123 JVM_VARIANT_MAIN="$variant"
124 break
125 fi
126 done
127 else
128 JVM_VARIANT_MAIN="$JVM_VARIANTS"
129 fi
130
131 AC_SUBST(JVM_VARIANTS)
132 AC_SUBST(VALID_JVM_VARIANTS)
133 AC_SUBST(JVM_VARIANT_MAIN)
134
135 if HOTSPOT_CHECK_JVM_VARIANT(zero) || HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
136 # zero behaves as a platform and rewrites these values. This is really weird. :(
137 # We are guaranteed that we do not build any other variants when building zero.
138 HOTSPOT_TARGET_CPU=zero
139 HOTSPOT_TARGET_CPU_ARCH=zero
140 fi
141 ])
142
143 ###############################################################################
144 # Check if dtrace should be enabled and has all prerequisites present.
145 #
146 AC_DEFUN_ONCE([HOTSPOT_SETUP_DTRACE],
147 [
148 # Test for dtrace dependencies
149 AC_ARG_ENABLE([dtrace], [AS_HELP_STRING([--enable-dtrace@<:@=yes/no/auto@:>@],
150 [enable dtrace. Default is auto, where dtrace is enabled if all dependencies
151 are present.])])
152
153 DTRACE_DEP_MISSING=false
154
155 AC_MSG_CHECKING([for dtrace tool])
156 if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
157 AC_MSG_RESULT([$DTRACE])
158 else
159 AC_MSG_RESULT([not found, cannot build dtrace])
160 DTRACE_DEP_MISSING=true
161 fi
162
163 AC_CHECK_HEADERS([sys/sdt.h], [DTRACE_HEADERS_OK=yes],[DTRACE_HEADERS_OK=no])
164 if test "x$DTRACE_HEADERS_OK" != "xyes"; then
165 DTRACE_DEP_MISSING=true
166 fi
167
168 AC_MSG_CHECKING([if dtrace should be built])
169 if test "x$enable_dtrace" = "xyes"; then
170 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
171 AC_MSG_RESULT([no, missing dependencies])
172 HELP_MSG_MISSING_DEPENDENCY([dtrace])
173 AC_MSG_ERROR([Cannot enable dtrace with missing dependencies. See above. $HELP_MSG])
174 else
175 INCLUDE_DTRACE=true
176 AC_MSG_RESULT([yes, forced])
177 fi
178 elif test "x$enable_dtrace" = "xno"; then
179 INCLUDE_DTRACE=false
180 AC_MSG_RESULT([no, forced])
181 elif test "x$enable_dtrace" = "xauto" || test "x$enable_dtrace" = "x"; then
182 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
183 INCLUDE_DTRACE=false
184 AC_MSG_RESULT([no, missing dependencies])
185 else
186 INCLUDE_DTRACE=true
187 AC_MSG_RESULT([yes, dependencies present])
188 fi
189 else
190 AC_MSG_ERROR([Invalid value for --enable-dtrace: $enable_dtrace])
191 fi
192 ])
193
194 ################################################################################
195 # Check if AOT should be enabled
196 #
197 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_AOT],
198 [
199 AC_ARG_ENABLE([aot], [AS_HELP_STRING([--enable-aot@<:@=yes/no/auto@:>@],
200 [enable ahead of time compilation feature. Default is auto, where aot is enabled if all dependencies are present.])])
201
202 if test "x$enable_aot" = "x" || test "x$enable_aot" = "xauto"; then
203 ENABLE_AOT="true"
204 elif test "x$enable_aot" = "xyes"; then
205 ENABLE_AOT="true"
206 elif test "x$enable_aot" = "xno"; then
207 ENABLE_AOT="false"
208 AC_MSG_CHECKING([if aot should be enabled])
209 AC_MSG_RESULT([no, forced])
210 else
211 AC_MSG_ERROR([Invalid value for --enable-aot: $enable_aot])
212 fi
213
214 if test "x$ENABLE_AOT" = "xtrue"; then
215 # Only enable AOT on X64 platforms.
216 if test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
217 if test -e "${TOPDIR}/src/jdk.aot"; then
218 if test -e "${TOPDIR}/src/jdk.internal.vm.compiler"; then
219 ENABLE_AOT="true"
220 else
221 ENABLE_AOT="false"
222 if test "x$enable_aot" = "xyes"; then
223 AC_MSG_ERROR([Cannot build AOT without src/jdk.internal.vm.compiler sources. Remove --enable-aot.])
224 fi
225 fi
226 else
227 ENABLE_AOT="false"
228 if test "x$enable_aot" = "xyes"; then
229 AC_MSG_ERROR([Cannot build AOT without src/jdk.aot sources. Remove --enable-aot.])
230 fi
231 fi
232 else
233 ENABLE_AOT="false"
234 if test "x$enable_aot" = "xyes"; then
235 AC_MSG_ERROR([AOT is currently only supported on x86_64. Remove --enable-aot.])
236 fi
237 fi
238 fi
239
240 AC_SUBST(ENABLE_AOT)
241 ])
242
243 ################################################################################
244 # Allow to disable CDS
245 #
246 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_CDS],
247 [
248 AC_ARG_ENABLE([cds], [AS_HELP_STRING([--enable-cds@<:@=yes/no@:>@],
249 [enable class data sharing feature in non-minimal VM. Default is yes.])])
250
251 if test "x$enable_cds" = "x" || test "x$enable_cds" = "xyes"; then
252 ENABLE_CDS="true"
253 elif test "x$enable_cds" = "xno"; then
254 ENABLE_CDS="false"
255 else
256 AC_MSG_ERROR([Invalid value for --enable-cds: $enable_cds])
257 fi
258
259 AC_SUBST(ENABLE_CDS)
260 ])
261
262 ###############################################################################
263 # Set up all JVM features for each JVM variant.
264 #
265 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_FEATURES],
266 [
267 # The user can in some cases supply additional jvm features. For the custom
268 # variant, this defines the entire variant.
269 AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
270 [additional JVM features to enable (separated by comma), use '--help' to show possible values @<:@none@:>@])])
271 if test "x$with_jvm_features" != x; then
272 AC_MSG_CHECKING([additional JVM features])
273 JVM_FEATURES=`$ECHO $with_jvm_features | $SED -e 's/,/ /g'`
274 AC_MSG_RESULT([$JVM_FEATURES])
275 fi
276
277 # Override hotspot cpu definitions for ARM platforms
278 if test "x$OPENJDK_TARGET_CPU" = xarm; then
279 HOTSPOT_TARGET_CPU=arm_32
280 HOTSPOT_TARGET_CPU_DEFINE="ARM32"
281 JVM_LDFLAGS="$JVM_LDFLAGS -fsigned-char"
282 JVM_CFLAGS="$JVM_CFLAGS -DARM -fsigned-char"
283 elif test "x$OPENJDK_TARGET_CPU" = xaarch64 && test "x$HOTSPOT_TARGET_CPU_PORT" = xarm64; then
284 HOTSPOT_TARGET_CPU=arm_64
285 HOTSPOT_TARGET_CPU_ARCH=arm
286 JVM_LDFLAGS="$JVM_LDFLAGS -fsigned-char"
287 JVM_CFLAGS="$JVM_CFLAGS -DARM -fsigned-char"
288 fi
289
290 # Verify that dependencies are met for explicitly set features.
291 if HOTSPOT_CHECK_JVM_FEATURE(jvmti) && ! HOTSPOT_CHECK_JVM_FEATURE(services); then
292 AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services'])
293 fi
294
295 if HOTSPOT_CHECK_JVM_FEATURE(management) && ! HOTSPOT_CHECK_JVM_FEATURE(nmt); then
296 AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt'])
297 fi
298
299 if HOTSPOT_CHECK_JVM_FEATURE(jvmci) && ! (HOTSPOT_CHECK_JVM_FEATURE(compiler1) || HOTSPOT_CHECK_JVM_FEATURE(compiler2)); then
300 AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2' or 'compiler1'])
301 fi
302
303 if HOTSPOT_CHECK_JVM_FEATURE(compiler2) && ! HOTSPOT_CHECK_JVM_FEATURE(all-gcs); then
304 AC_MSG_ERROR([Specified JVM feature 'compiler2' requires feature 'all-gcs'])
305 fi
306
307 if HOTSPOT_CHECK_JVM_FEATURE(vm-structs) && ! HOTSPOT_CHECK_JVM_FEATURE(all-gcs); then
308 AC_MSG_ERROR([Specified JVM feature 'vm-structs' requires feature 'all-gcs'])
309 fi
310
311 # Turn on additional features based on other parts of configure
312 if test "x$INCLUDE_DTRACE" = "xtrue"; then
313 JVM_FEATURES="$JVM_FEATURES dtrace"
314 else
315 if HOTSPOT_CHECK_JVM_FEATURE(dtrace); then
316 AC_MSG_ERROR([To enable dtrace, you must use --enable-dtrace])
317 fi
318 fi
319
320 if test "x$STATIC_BUILD" = "xtrue"; then
321 JVM_FEATURES="$JVM_FEATURES static-build"
322 else
323 if HOTSPOT_CHECK_JVM_FEATURE(static-build); then
324 AC_MSG_ERROR([To enable static-build, you must use --enable-static-build])
325 fi
326 fi
327
328 if ! HOTSPOT_CHECK_JVM_VARIANT(zero) && ! HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
329 if HOTSPOT_CHECK_JVM_FEATURE(zero); then
330 AC_MSG_ERROR([To enable zero/zeroshark, you must use --with-jvm-variants=zero/zeroshark])
331 fi
332 fi
333
334 if ! HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
335 if HOTSPOT_CHECK_JVM_FEATURE(shark); then
336 AC_MSG_ERROR([To enable shark, you must use --with-jvm-variants=zeroshark])
337 fi
338 fi
339
340 # Only enable jvmci on x86_64, sparcv9 and aarch64.
341 if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
342 test "x$OPENJDK_TARGET_CPU" = "xsparcv9" || \
343 test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
344 JVM_FEATURES_jvmci="jvmci"
345 else
346 JVM_FEATURES_jvmci=""
347 fi
348
349 AC_MSG_CHECKING([if jdk.internal.vm.compiler should be built])
350 if HOTSPOT_CHECK_JVM_FEATURE(graal); then
351 AC_MSG_RESULT([yes, forced])
352 if test "x$JVM_FEATURES_jvmci" != "xjvmci" ; then
353 AC_MSG_ERROR([Specified JVM feature 'graal' requires feature 'jvmci'])
354 fi
355 INCLUDE_GRAAL="true"
356 else
357 # By default enable graal build on linux-x64 or where AOT is available.
358 # graal build requires jvmci.
359 if test "x$JVM_FEATURES_jvmci" = "xjvmci" && \
360 (test "x$OPENJDK_TARGET_CPU" = "xx86_64" && \
361 test "x$OPENJDK_TARGET_OS" = "xlinux" || \
362 test "x$ENABLE_AOT" = "xtrue") ; then
363 AC_MSG_RESULT([yes])
364 JVM_FEATURES_graal="graal"
365 INCLUDE_GRAAL="true"
366 else
367 AC_MSG_RESULT([no])
368 JVM_FEATURES_graal=""
369 INCLUDE_GRAAL="false"
370 fi
371 fi
372
373 AC_SUBST(INCLUDE_GRAAL)
374
375 AC_MSG_CHECKING([if aot should be enabled])
376 if test "x$ENABLE_AOT" = "xtrue"; then
377 if test "x$enable_aot" = "xyes"; then
378 AC_MSG_RESULT([yes, forced])
379 else
380 AC_MSG_RESULT([yes])
381 fi
382 JVM_FEATURES_aot="aot"
383 else
384 if test "x$enable_aot" = "xno"; then
385 AC_MSG_RESULT([no, forced])
386 else
387 AC_MSG_RESULT([no])
388 fi
389 JVM_FEATURES_aot=""
390 fi
391
392 if test "x$OPENJDK_TARGET_CPU" = xarm ; then
393 # Default to use link time optimizations on minimal on arm
394 JVM_FEATURES_link_time_opt="link-time-opt"
395 else
396 JVM_FEATURES_link_time_opt=""
397 fi
398
399 # All variants but minimal (and custom) get these features
400 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES jvmti vm-structs jni-check services management all-gcs nmt"
401 if test "x$ENABLE_CDS" = "xtrue"; then
402 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cds"
403 fi
404
405 # Enable features depending on variant.
406 JVM_FEATURES_server="compiler1 compiler2 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci $JVM_FEATURES_aot $JVM_FEATURES_graal"
407 JVM_FEATURES_client="compiler1 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci"
408 JVM_FEATURES_core="$NON_MINIMAL_FEATURES $JVM_FEATURES"
409 JVM_FEATURES_minimal="compiler1 minimal $JVM_FEATURES $JVM_FEATURES_link_time_opt"
410 JVM_FEATURES_zero="zero $NON_MINIMAL_FEATURES $JVM_FEATURES"
411 JVM_FEATURES_zeroshark="zero shark $NON_MINIMAL_FEATURES $JVM_FEATURES"
412 JVM_FEATURES_custom="$JVM_FEATURES"
413
414 AC_SUBST(JVM_FEATURES_server)
415 AC_SUBST(JVM_FEATURES_client)
416 AC_SUBST(JVM_FEATURES_core)
417 AC_SUBST(JVM_FEATURES_minimal)
418 AC_SUBST(JVM_FEATURES_zero)
419 AC_SUBST(JVM_FEATURES_zeroshark)
420 AC_SUBST(JVM_FEATURES_custom)
421
422 # Used for verification of Makefiles by check-jvm-feature
423 AC_SUBST(VALID_JVM_FEATURES)
424
425 # We don't support --with-jvm-interpreter anymore, use zero instead.
426 BASIC_DEPRECATED_ARG_WITH(jvm-interpreter)
427 ])
428
429 ###############################################################################
430 # Validate JVM features once all setup is complete, including custom setup.
431 #
432 AC_DEFUN_ONCE([HOTSPOT_VALIDATE_JVM_FEATURES],
433 [
434 # Keep feature lists sorted and free of duplicates
435 JVM_FEATURES_server="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_server | $SORT -u))"
436 JVM_FEATURES_client="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_client | $SORT -u))"
437 JVM_FEATURES_core="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_core | $SORT -u))"
438 JVM_FEATURES_minimal="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_minimal | $SORT -u))"
439 JVM_FEATURES_zero="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_zero | $SORT -u))"
440 JVM_FEATURES_zeroshark="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_zeroshark | $SORT -u))"
441 JVM_FEATURES_custom="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_custom | $SORT -u))"
442
443 # Validate features
444 for variant in $JVM_VARIANTS; do
445 AC_MSG_CHECKING([JVM features for JVM variant '$variant'])
446 features_var_name=JVM_FEATURES_$variant
447 JVM_FEATURES_TO_TEST=${!features_var_name}
448 AC_MSG_RESULT([$JVM_FEATURES_TO_TEST])
449 NEEDLE=${VALID_JVM_FEATURES// /$'\n'}
450 STACK=${JVM_FEATURES_TO_TEST// /$'\n'}
451 INVALID_FEATURES=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
452 if test "x$INVALID_FEATURES" != x; then
453 AC_MSG_ERROR([Invalid JVM feature(s): $INVALID_FEATURES])
454 fi
455 done
456 ])
457
458 ################################################################################
459 #
460 # Specify which sources will be used to build the 64-bit ARM port
461 #
462 # --with-cpu-port=arm64 will use hotspot/src/cpu/arm
463 # --with-cpu-port=aarch64 will use hotspot/src/cpu/aarch64
464 #
465 AC_DEFUN([SETUP_HOTSPOT_TARGET_CPU_PORT],
466 [
467 AC_ARG_WITH(cpu-port, [AS_HELP_STRING([--with-cpu-port],
468 [specify sources to use for Hotspot 64-bit ARM port (arm64,aarch64) @<:@aarch64@:>@ ])])
469
470 if test "x$with_cpu_port" != x; then
471 if test "x$OPENJDK_TARGET_CPU" != xaarch64; then
472 AC_MSG_ERROR([--with-cpu-port only available on aarch64])
473 fi
474 if test "x$with_cpu_port" != xarm64 && \
475 test "x$with_cpu_port" != xaarch64; then
476 AC_MSG_ERROR([--with-cpu-port must specify arm64 or aarch64])
477 fi
478 HOTSPOT_TARGET_CPU_PORT="$with_cpu_port"
479 fi
480 ])
481
482
483 ################################################################################
484 # Check if gtest should be built
485 #
486 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_GTEST],
487 [
488 AC_ARG_ENABLE([hotspot-gtest], [AS_HELP_STRING([--disable-hotspot-gtest],
489 [Disables building of the Hotspot unit tests])])
490
491 if test -e "${TOPDIR}/test/hotspot/gtest"; then
492 GTEST_DIR_EXISTS="true"
493 else
494 GTEST_DIR_EXISTS="false"
495 fi
496
497 AC_MSG_CHECKING([if Hotspot gtest unit tests should be built])
498 if test "x$enable_hotspot_gtest" = "xyes"; then
499 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
500 AC_MSG_RESULT([yes, forced])
501 BUILD_GTEST="true"
502 else
503 AC_MSG_ERROR([Cannot build gtest without the test source])
504 fi
505 elif test "x$enable_hotspot_gtest" = "xno"; then
506 AC_MSG_RESULT([no, forced])
507 BUILD_GTEST="false"
508 elif test "x$enable_hotspot_gtest" = "x"; then
509 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
510 AC_MSG_RESULT([yes])
511 BUILD_GTEST="true"
512 else
513 AC_MSG_RESULT([no])
514 BUILD_GTEST="false"
515 fi
516 else
517 AC_MSG_ERROR([--enable-gtest must be either yes or no])
518 fi
519
520 AC_SUBST(BUILD_GTEST)
521 ])