1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # All valid JVM features, regardless of platform
27 VALID_JVM_FEATURES="compiler1 compiler2 zero minimal dtrace jvmti jvmci \
28 graal vm-structs jni-check services management cmsgc epsilongc g1gc parallelgc serialgc shenandoahgc zgc nmt cds \
29 static-build link-time-opt aot jfr"
30
31 # Deprecated JVM features (these are ignored, but with a warning)
32 DEPRECATED_JVM_FEATURES="trace"
33
34 # All valid JVM variants
35 VALID_JVM_VARIANTS="server client minimal core zero custom"
36
37 ###############################################################################
38 # Check if the specified JVM variant should be built. To be used in shell if
39 # constructs, like this:
40 # if HOTSPOT_CHECK_JVM_VARIANT(server); then
41 #
42 # Only valid to use after HOTSPOT_SETUP_JVM_VARIANTS has setup variants.
43
44 # Definition kept in one line to allow inlining in if statements.
45 # Additional [] needed to keep m4 from mangling shell constructs.
46 AC_DEFUN([HOTSPOT_CHECK_JVM_VARIANT],
47 [ [ [[ " $JVM_VARIANTS " =~ " $1 " ]] ] ])
48
49 ###############################################################################
50 # Check if the specified JVM features are explicitly enabled. To be used in
51 # shell if constructs, like this:
52 # if HOTSPOT_CHECK_JVM_FEATURE(jvmti); then
53 #
54 # Only valid to use after HOTSPOT_SETUP_JVM_FEATURES has setup features.
55
56 # Definition kept in one line to allow inlining in if statements.
57 # Additional [] needed to keep m4 from mangling shell constructs.
58 AC_DEFUN([HOTSPOT_CHECK_JVM_FEATURE],
59 [ [ [[ " $JVM_FEATURES " =~ " $1 " ]] ] ])
60
61 ###############################################################################
62 # Check which variants of the JVM that we want to build. Available variants are:
63 # server: normal interpreter, and a tiered C1/C2 compiler
64 # client: normal interpreter, and C1 (no C2 compiler)
65 # minimal: reduced form of client with optional features stripped out
66 # core: normal interpreter only, no compiler
67 # zero: C++ based interpreter only, no compiler
68 # custom: baseline JVM with no default features
69 #
70 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_VARIANTS],
71 [
72 AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
73 [JVM variants (separated by commas) to build (server,client,minimal,core,zero,custom) @<:@server@:>@])])
74
75 if test "x$with_jvm_variants" = x; then
76 with_jvm_variants="server"
77 fi
78 JVM_VARIANTS_OPT="$with_jvm_variants"
79
80 # Has the user listed more than one variant?
81 # Additional [] needed to keep m4 from mangling shell constructs.
82 if [ [[ "$JVM_VARIANTS_OPT" =~ "," ]] ]; then
83 BUILDING_MULTIPLE_JVM_VARIANTS=true
84 else
85 BUILDING_MULTIPLE_JVM_VARIANTS=false
86 fi
87 # Replace the commas with AND for use in the build directory name.
88 JVM_VARIANTS_WITH_AND=`$ECHO "$JVM_VARIANTS_OPT" | $SED -e 's/,/AND/g'`
89
90 AC_MSG_CHECKING([which variants of the JVM to build])
91 # JVM_VARIANTS is a space-separated list.
92 # Also use minimal, not minimal1 (which is kept for backwards compatibility).
93 JVM_VARIANTS=`$ECHO $JVM_VARIANTS_OPT | $SED -e 's/,/ /g' -e 's/minimal1/minimal/'`
94 AC_MSG_RESULT([$JVM_VARIANTS])
95
96 # Check that the selected variants are valid
97 BASIC_GET_NON_MATCHING_VALUES(INVALID_VARIANTS, $JVM_VARIANTS, $VALID_JVM_VARIANTS)
98 if test "x$INVALID_VARIANTS" != x; then
99 AC_MSG_NOTICE([Unknown variant(s) specified: "$INVALID_VARIANTS"])
100 AC_MSG_NOTICE([The available JVM variants are: "$VALID_JVM_VARIANTS"])
101 AC_MSG_ERROR([Cannot continue])
102 fi
103
104 # All "special" variants share the same output directory ("server")
105 VALID_MULTIPLE_JVM_VARIANTS="server client minimal"
106 BASIC_GET_NON_MATCHING_VALUES(INVALID_MULTIPLE_VARIANTS, $JVM_VARIANTS, $VALID_MULTIPLE_JVM_VARIANTS)
107 if test "x$INVALID_MULTIPLE_VARIANTS" != x && test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = xtrue; then
108 AC_MSG_ERROR([You cannot build multiple variants with anything else than $VALID_MULTIPLE_JVM_VARIANTS.])
109 fi
110
111 # The "main" variant is the one used by other libs to link against during the
112 # build.
113 if test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = "xtrue"; then
114 MAIN_VARIANT_PRIO_ORDER="server client minimal"
115 for variant in $MAIN_VARIANT_PRIO_ORDER; do
116 if HOTSPOT_CHECK_JVM_VARIANT($variant); then
117 JVM_VARIANT_MAIN="$variant"
118 break
119 fi
120 done
121 else
122 JVM_VARIANT_MAIN="$JVM_VARIANTS"
123 fi
124
125 AC_SUBST(JVM_VARIANTS)
126 AC_SUBST(VALID_JVM_VARIANTS)
127 AC_SUBST(JVM_VARIANT_MAIN)
128
129 if HOTSPOT_CHECK_JVM_VARIANT(zero); then
130 # zero behaves as a platform and rewrites these values. This is really weird. :(
131 # We are guaranteed that we do not build any other variants when building zero.
132 HOTSPOT_TARGET_CPU=zero
133 HOTSPOT_TARGET_CPU_ARCH=zero
134 fi
135 ])
136
137 ###############################################################################
138 # Check if dtrace should be enabled and has all prerequisites present.
139 #
140 AC_DEFUN_ONCE([HOTSPOT_SETUP_DTRACE],
141 [
142 # Test for dtrace dependencies
143 AC_ARG_ENABLE([dtrace], [AS_HELP_STRING([--enable-dtrace@<:@=yes/no/auto@:>@],
144 [enable dtrace. Default is auto, where dtrace is enabled if all dependencies
145 are present.])])
146
147 DTRACE_DEP_MISSING=false
148
149 AC_MSG_CHECKING([for dtrace tool])
150 if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
151 AC_MSG_RESULT([$DTRACE])
152 else
153 AC_MSG_RESULT([not found, cannot build dtrace])
154 DTRACE_DEP_MISSING=true
155 fi
156
157 AC_CHECK_HEADERS([sys/sdt.h], [DTRACE_HEADERS_OK=yes],[DTRACE_HEADERS_OK=no])
158 if test "x$DTRACE_HEADERS_OK" != "xyes"; then
159 DTRACE_DEP_MISSING=true
160 fi
161
162 AC_MSG_CHECKING([if dtrace should be built])
163 if test "x$enable_dtrace" = "xyes"; then
164 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
165 AC_MSG_RESULT([no, missing dependencies])
166 HELP_MSG_MISSING_DEPENDENCY([dtrace])
167 AC_MSG_ERROR([Cannot enable dtrace with missing dependencies. See above. $HELP_MSG])
168 else
169 INCLUDE_DTRACE=true
170 AC_MSG_RESULT([yes, forced])
171 fi
172 elif test "x$enable_dtrace" = "xno"; then
173 INCLUDE_DTRACE=false
174 AC_MSG_RESULT([no, forced])
175 elif test "x$enable_dtrace" = "xauto" || test "x$enable_dtrace" = "x"; then
176 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
177 INCLUDE_DTRACE=false
178 AC_MSG_RESULT([no, missing dependencies])
179 else
180 INCLUDE_DTRACE=true
181 AC_MSG_RESULT([yes, dependencies present])
182 fi
183 else
184 AC_MSG_ERROR([Invalid value for --enable-dtrace: $enable_dtrace])
185 fi
186 ])
187
188 ################################################################################
189 # Check if AOT should be enabled
190 #
191 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_AOT],
192 [
193 AC_ARG_ENABLE([aot], [AS_HELP_STRING([--enable-aot@<:@=yes/no/auto@:>@],
194 [enable ahead of time compilation feature. Default is auto, where aot is enabled if all dependencies are present.])])
195
196 if test "x$enable_aot" = "x" || test "x$enable_aot" = "xauto"; then
197 ENABLE_AOT="true"
198 elif test "x$enable_aot" = "xyes"; then
199 ENABLE_AOT="true"
200 elif test "x$enable_aot" = "xno"; then
201 ENABLE_AOT="false"
202 else
203 AC_MSG_ERROR([Invalid value for --enable-aot: $enable_aot])
204 fi
205
206 if test "x$ENABLE_AOT" = "xtrue"; then
207 # Only enable AOT on X64 platforms.
208 if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
209 if test -e "${TOPDIR}/src/jdk.aot"; then
210 if test -e "${TOPDIR}/src/jdk.internal.vm.compiler"; then
211 ENABLE_AOT="true"
212 else
213 ENABLE_AOT="false"
214 if test "x$enable_aot" = "xyes"; then
215 AC_MSG_ERROR([Cannot build AOT without src/jdk.internal.vm.compiler sources. Remove --enable-aot.])
216 fi
217 fi
218 else
219 ENABLE_AOT="false"
220 if test "x$enable_aot" = "xyes"; then
221 AC_MSG_ERROR([Cannot build AOT without src/jdk.aot sources. Remove --enable-aot.])
222 fi
223 fi
224 else
225 ENABLE_AOT="false"
226 if test "x$enable_aot" = "xyes"; then
227 AC_MSG_ERROR([AOT is currently only supported on x86_64 and aarch64. Remove --enable-aot.])
228 fi
229 fi
230 fi
231
232 AC_SUBST(ENABLE_AOT)
233 ])
234
235 ################################################################################
236 # Allow to disable CDS
237 #
238 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_CDS],
239 [
240 AC_ARG_ENABLE([cds], [AS_HELP_STRING([--enable-cds@<:@=yes/no/auto@:>@],
241 [enable class data sharing feature in non-minimal VM. Default is auto, where cds is enabled if supported on the platform.])])
242
243 if test "x$enable_cds" = "x" || test "x$enable_cds" = "xauto"; then
244 ENABLE_CDS="true"
245 elif test "x$enable_cds" = "xyes"; then
246 ENABLE_CDS="true"
247 elif test "x$enable_cds" = "xno"; then
248 ENABLE_CDS="false"
249 else
250 AC_MSG_ERROR([Invalid value for --enable-cds: $enable_cds])
251 fi
252
253 AC_SUBST(ENABLE_CDS)
254 ])
255
256 ###############################################################################
257 # Set up all JVM features for each JVM variant.
258 #
259 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_FEATURES],
260 [
261 # Prettify the VALID_JVM_FEATURES string
262 BASIC_SORT_LIST(VALID_JVM_FEATURES, $VALID_JVM_FEATURES)
263
264 # The user can in some cases supply additional jvm features. For the custom
265 # variant, this defines the entire variant.
266 AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
267 [JVM features to enable (foo) or disable (-foo), separated by comma. Use '--help' to show possible values @<:@none@:>@])])
268 if test "x$with_jvm_features" != x; then
269 AC_MSG_CHECKING([user specified JVM feature list])
270 USER_JVM_FEATURE_LIST=`$ECHO $with_jvm_features | $SED -e 's/,/ /g'`
271 AC_MSG_RESULT([$user_jvm_feature_list])
272 # These features will be added to all variant defaults
273 JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (!match($i, /^-.*/)) printf("%s ", $i) }'`
274 # These features will be removed from all variant defaults
275 DISABLED_JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (match($i, /^-.*/)) printf("%s ", substr($i, 2))}'`
276
277 # Verify that the user has provided valid features
278 BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES $DISABLED_JVM_FEATURES, $VALID_JVM_FEATURES $DEPRECATED_JVM_FEATURES)
279 if test "x$INVALID_FEATURES" != x; then
280 AC_MSG_NOTICE([Unknown JVM features specified: "$INVALID_FEATURES"])
281 AC_MSG_NOTICE([The available JVM features are: "$VALID_JVM_FEATURES"])
282 AC_MSG_ERROR([Cannot continue])
283 fi
284
285 # Check if the user has provided deprecated features
286 BASIC_GET_MATCHING_VALUES(DEPRECATED_FEATURES, $JVM_FEATURES $DISABLED_JVM_FEATURES, $DEPRECATED_JVM_FEATURES)
287 if test "x$DEPRECATED_FEATURES" != x; then
288 AC_MSG_WARN([Deprecated JVM features specified (will be ignored): "$DEPRECATED_FEATURES"])
289 # Filter out deprecated features
290 BASIC_GET_NON_MATCHING_VALUES(JVM_FEATURES, $JVM_FEATURES, $DEPRECATED_FEATURES)
291 BASIC_GET_NON_MATCHING_VALUES(DISABLED_JVM_FEATURES, $DISABLED_JVM_FEATURES, $DEPRECATED_FEATURES)
292 fi
293
294 fi
295
296 # Override hotspot cpu definitions for ARM platforms
297 if test "x$OPENJDK_TARGET_CPU" = xarm; then
298 HOTSPOT_TARGET_CPU=arm_32
299 HOTSPOT_TARGET_CPU_DEFINE="ARM32"
300 fi
301
302 # Verify that dependencies are met for explicitly set features.
303 if HOTSPOT_CHECK_JVM_FEATURE(jvmti) && ! HOTSPOT_CHECK_JVM_FEATURE(services); then
304 AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services'])
305 fi
306
307 if HOTSPOT_CHECK_JVM_FEATURE(management) && ! HOTSPOT_CHECK_JVM_FEATURE(nmt); then
308 AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt'])
309 fi
310
311 if HOTSPOT_CHECK_JVM_FEATURE(jvmci) && ! (HOTSPOT_CHECK_JVM_FEATURE(compiler1) || HOTSPOT_CHECK_JVM_FEATURE(compiler2)); then
312 AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2' or 'compiler1'])
313 fi
314
315 if HOTSPOT_CHECK_JVM_FEATURE(cmsgc) && ! HOTSPOT_CHECK_JVM_FEATURE(serialgc); then
316 AC_MSG_ERROR([Specified JVM feature 'cmsgc' requires feature 'serialgc'])
317 fi
318
319 # Enable JFR by default, except for Zero, linux-sparcv9 and on minimal.
320 if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
321 if test "x$OPENJDK_TARGET_OS" != xaix; then
322 if test "x$OPENJDK_TARGET_OS" != xlinux || test "x$OPENJDK_TARGET_CPU" != xsparcv9; then
323 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES jfr"
324 fi
325 fi
326 fi
327
328 # Only enable Shenandoah on supported arches
329 AC_MSG_CHECKING([if shenandoah can be built])
330 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86" || test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
331 AC_MSG_RESULT([yes])
332 else
333 DISABLED_JVM_FEATURES="$DISABLED_JVM_FEATURES shenandoahgc"
334 AC_MSG_RESULT([no, platform not supported])
335 fi
336
337 # Only enable ZGC on Linux x86_64
338 AC_MSG_CHECKING([if zgc should be built])
339 if HOTSPOT_CHECK_JVM_FEATURE(zgc); then
340 if test "x$OPENJDK_TARGET_OS" = "xlinux" && test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
341 AC_MSG_RESULT([yes])
342 else
343 DISABLED_JVM_FEATURES="$DISABLED_JVM_FEATURES zgc"
344 AC_MSG_RESULT([no, platform not supported])
345 fi
346 else
347 AC_MSG_RESULT([no])
348 fi
349
350 # Disable unsupported GCs for Zero
351 if HOTSPOT_CHECK_JVM_VARIANT(zero); then
352 DISABLED_JVM_FEATURES="$DISABLED_JVM_FEATURES epsilongc g1gc zgc shenandoahgc"
353 fi
354
355 # Turn on additional features based on other parts of configure
356 if test "x$INCLUDE_DTRACE" = "xtrue"; then
357 JVM_FEATURES="$JVM_FEATURES dtrace"
358 else
359 if HOTSPOT_CHECK_JVM_FEATURE(dtrace); then
360 AC_MSG_ERROR([To enable dtrace, you must use --enable-dtrace])
361 fi
362 fi
363
364 if test "x$STATIC_BUILD" = "xtrue"; then
365 JVM_FEATURES="$JVM_FEATURES static-build"
366 else
367 if HOTSPOT_CHECK_JVM_FEATURE(static-build); then
368 AC_MSG_ERROR([To enable static-build, you must use --enable-static-build])
369 fi
370 fi
371
372 if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
373 if HOTSPOT_CHECK_JVM_FEATURE(zero); then
374 AC_MSG_ERROR([To enable zero, you must use --with-jvm-variants=zero])
375 fi
376 fi
377
378 AC_MSG_CHECKING([if jvmci module jdk.internal.vm.ci should be built])
379 # Check if jvmci is diabled
380 DISABLE_JVMCI=`$ECHO $DISABLED_JVM_FEATURES | $GREP jvmci`
381 if test "x$DISABLE_JVMCI" = "xjvmci"; then
382 AC_MSG_RESULT([no, forced])
383 JVM_FEATURES_jvmci=""
384 INCLUDE_JVMCI="false"
385 else
386 # Only enable jvmci on x86_64, sparcv9 and aarch64
387 if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
388 test "x$OPENJDK_TARGET_CPU" = "xsparcv9" || \
389 test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
390 AC_MSG_RESULT([yes])
391 JVM_FEATURES_jvmci="jvmci"
392 INCLUDE_JVMCI="true"
393 else
394 AC_MSG_RESULT([no])
395 JVM_FEATURES_jvmci=""
396 INCLUDE_JVMCI="false"
397 if HOTSPOT_CHECK_JVM_FEATURE(jvmci); then
398 AC_MSG_ERROR([JVMCI is currently not supported on this platform.])
399 fi
400 fi
401 fi
402
403 AC_SUBST(INCLUDE_JVMCI)
404
405 AC_MSG_CHECKING([if graal module jdk.internal.vm.compiler should be built])
406 # Check if graal is diabled
407 DISABLE_GRAAL=`$ECHO $DISABLED_JVM_FEATURES | $GREP graal`
408 if test "x$DISABLE_GRAAL" = "xgraal"; then
409 AC_MSG_RESULT([no, forced])
410 JVM_FEATURES_graal=""
411 INCLUDE_GRAAL="false"
412 else
413 if HOTSPOT_CHECK_JVM_FEATURE(graal); then
414 AC_MSG_RESULT([yes, forced])
415 if test "x$JVM_FEATURES_jvmci" != "xjvmci" ; then
416 AC_MSG_ERROR([Specified JVM feature 'graal' requires feature 'jvmci'])
417 fi
418 JVM_FEATURES_graal="graal"
419 INCLUDE_GRAAL="true"
420 else
421 # By default enable graal build on x64 or where AOT is available.
422 # graal build requires jvmci.
423 if test "x$JVM_FEATURES_jvmci" = "xjvmci" && \
424 (test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
425 test "x$ENABLE_AOT" = "xtrue") ; then
426 AC_MSG_RESULT([yes])
427 JVM_FEATURES_graal="graal"
428 INCLUDE_GRAAL="true"
429 else
430 AC_MSG_RESULT([no])
431 JVM_FEATURES_graal=""
432 INCLUDE_GRAAL="false"
433 fi
434 fi
435 fi
436
437 AC_SUBST(INCLUDE_GRAAL)
438
439 # Disable aot with '--with-jvm-features=-aot'
440 DISABLE_AOT=`$ECHO $DISABLED_JVM_FEATURES | $GREP aot`
441 if test "x$DISABLE_AOT" = "xaot"; then
442 ENABLE_AOT="false"
443 fi
444
445 AC_MSG_CHECKING([if aot should be enabled])
446 if test "x$ENABLE_AOT" = "xtrue"; then
447 if test "x$JVM_FEATURES_graal" != "xgraal"; then
448 if test "x$enable_aot" = "xyes" || HOTSPOT_CHECK_JVM_FEATURE(aot); then
449 AC_MSG_RESULT([yes, forced])
450 AC_MSG_ERROR([Specified JVM feature 'aot' requires feature 'graal'])
451 else
452 AC_MSG_RESULT([no])
453 fi
454 JVM_FEATURES_aot=""
455 ENABLE_AOT="false"
456 else
457 if test "x$enable_aot" = "xyes" || HOTSPOT_CHECK_JVM_FEATURE(aot); then
458 AC_MSG_RESULT([yes, forced])
459 else
460 AC_MSG_RESULT([yes])
461 fi
462 JVM_FEATURES_aot="aot"
463 fi
464 else
465 if test "x$enable_aot" = "xno" || test "x$DISABLE_AOT" = "xaot"; then
466 AC_MSG_RESULT([no, forced])
467 else
468 AC_MSG_RESULT([no])
469 fi
470 JVM_FEATURES_aot=""
471 if HOTSPOT_CHECK_JVM_FEATURE(aot); then
472 AC_MSG_ERROR([To enable aot, you must use --enable-aot])
473 fi
474 fi
475
476 AC_SUBST(ENABLE_AOT)
477
478 if test "x$OPENJDK_TARGET_CPU" = xarm ; then
479 # Default to use link time optimizations on minimal on arm
480 JVM_FEATURES_link_time_opt="link-time-opt"
481 else
482 JVM_FEATURES_link_time_opt=""
483 fi
484
485 # All variants but minimal (and custom) get these features
486 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cmsgc g1gc parallelgc serialgc epsilongc shenandoahgc jni-check jvmti management nmt services vm-structs"
487
488 # Disable CDS on AIX.
489 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
490 ENABLE_CDS="false"
491 if test "x$enable_cds" = "xyes"; then
492 AC_MSG_ERROR([CDS is currently not supported on AIX. Remove --enable-cds.])
493 fi
494 fi
495
496 # Disable CDS if user requested it with --with-jvm-features=-cds.
497 DISABLE_CDS=`$ECHO $DISABLED_JVM_FEATURES | $GREP cds`
498 if test "x$DISABLE_CDS" = "xcds"; then
499 ENABLE_CDS="false"
500 if test "x$enable_cds" = "xyes"; then
501 AC_MSG_ERROR([CDS was disabled by --with-jvm-features=-cds. Remove --enable-cds.])
502 fi
503 fi
504
505 # Disable CDS for zero, minimal, core..
506 if HOTSPOT_CHECK_JVM_VARIANT(zero) || HOTSPOT_CHECK_JVM_VARIANT(minimal) || HOTSPOT_CHECK_JVM_VARIANT(core); then
507 # ..except when the user explicitely requested it with --enable-jvm-features
508 if ! HOTSPOT_CHECK_JVM_FEATURE(cds); then
509 ENABLE_CDS="false"
510 if test "x$enable_cds" = "xyes"; then
511 AC_MSG_ERROR([CDS not implemented for variants zero, minimal, core. Remove --enable-cds.])
512 fi
513 fi
514 fi
515
516 AC_MSG_CHECKING([if cds should be enabled])
517 if test "x$ENABLE_CDS" = "xtrue"; then
518 if test "x$enable_cds" = "xyes"; then
519 AC_MSG_RESULT([yes, forced])
520 else
521 AC_MSG_RESULT([yes])
522 fi
523 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cds"
524 else
525 if test "x$enable_cds" = "xno"; then
526 AC_MSG_RESULT([no, forced])
527 else
528 AC_MSG_RESULT([no])
529 fi
530 fi
531
532 # Enable features depending on variant.
533 JVM_FEATURES_server="compiler1 compiler2 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci $JVM_FEATURES_aot $JVM_FEATURES_graal"
534 JVM_FEATURES_client="compiler1 $NON_MINIMAL_FEATURES $JVM_FEATURES"
535 JVM_FEATURES_core="$NON_MINIMAL_FEATURES $JVM_FEATURES"
536 JVM_FEATURES_minimal="compiler1 minimal serialgc $JVM_FEATURES $JVM_FEATURES_link_time_opt"
537 JVM_FEATURES_zero="zero $NON_MINIMAL_FEATURES $JVM_FEATURES"
538 JVM_FEATURES_custom="$JVM_FEATURES"
539
540 AC_SUBST(JVM_FEATURES_server)
541 AC_SUBST(JVM_FEATURES_client)
542 AC_SUBST(JVM_FEATURES_core)
543 AC_SUBST(JVM_FEATURES_minimal)
544 AC_SUBST(JVM_FEATURES_zero)
545 AC_SUBST(JVM_FEATURES_custom)
546
547 # Used for verification of Makefiles by check-jvm-feature
548 AC_SUBST(VALID_JVM_FEATURES)
549
550 # --with-cpu-port is no longer supported
551 BASIC_DEPRECATED_ARG_WITH(with-cpu-port)
552 ])
553
554 ###############################################################################
555 # Finalize JVM features once all setup is complete, including custom setup.
556 #
557 AC_DEFUN_ONCE([HOTSPOT_FINALIZE_JVM_FEATURES],
558 [
559 for variant in $JVM_VARIANTS; do
560 AC_MSG_CHECKING([JVM features for JVM variant '$variant'])
561 features_var_name=JVM_FEATURES_$variant
562 JVM_FEATURES_FOR_VARIANT=${!features_var_name}
563
564 # Filter out user-requested disabled features
565 BASIC_GET_NON_MATCHING_VALUES(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT, $DISABLED_JVM_FEATURES)
566
567 # Keep feature lists sorted and free of duplicates
568 BASIC_SORT_LIST(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT)
569
570 # Update real feature set variable
571 eval $features_var_name='"'$JVM_FEATURES_FOR_VARIANT'"'
572 AC_MSG_RESULT(["$JVM_FEATURES_FOR_VARIANT"])
573
574 # Verify that we have at least one gc selected
575 GC_FEATURES=`$ECHO $JVM_FEATURES_FOR_VARIANT | $GREP gc`
576 if test "x$GC_FEATURES" = x; then
577 AC_MSG_WARN([Invalid JVM features: No gc selected for variant $variant.])
578 fi
579
580 # Validate features (for configure script errors, not user errors)
581 BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES_FOR_VARIANT, $VALID_JVM_FEATURES)
582 if test "x$INVALID_FEATURES" != x; then
583 AC_MSG_ERROR([Internal configure script error. Invalid JVM feature(s): $INVALID_FEATURES])
584 fi
585 done
586 ])
587
588 ################################################################################
589 # Check if gtest should be built
590 #
591 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_GTEST],
592 [
593 AC_ARG_ENABLE([hotspot-gtest], [AS_HELP_STRING([--disable-hotspot-gtest],
594 [Disables building of the Hotspot unit tests @<:@enabled@:>@])])
595
596 if test -e "${TOPDIR}/test/hotspot/gtest"; then
597 GTEST_DIR_EXISTS="true"
598 else
599 GTEST_DIR_EXISTS="false"
600 fi
601
602 AC_MSG_CHECKING([if Hotspot gtest unit tests should be built])
603 if test "x$enable_hotspot_gtest" = "xyes"; then
604 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
605 AC_MSG_RESULT([yes, forced])
606 BUILD_GTEST="true"
607 else
608 AC_MSG_ERROR([Cannot build gtest without the test source])
609 fi
610 elif test "x$enable_hotspot_gtest" = "xno"; then
611 AC_MSG_RESULT([no, forced])
612 BUILD_GTEST="false"
613 elif test "x$enable_hotspot_gtest" = "x"; then
614 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
615 AC_MSG_RESULT([yes])
616 BUILD_GTEST="true"
617 else
618 AC_MSG_RESULT([no])
619 BUILD_GTEST="false"
620 fi
621 else
622 AC_MSG_ERROR([--enable-gtest must be either yes or no])
623 fi
624
625 AC_SUBST(BUILD_GTEST)
626 ])