1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 # All valid JVM features, regardless of platform
  27 VALID_JVM_FEATURES="compiler1 compiler2 zero minimal dtrace jvmti jvmci \
  28     graal vm-structs jni-check services management cmsgc g1gc parallelgc serialgc epsilongc nmt cds \
  29     static-build link-time-opt aot jfr"
  30 
  31 # All valid JVM variants
  32 VALID_JVM_VARIANTS="server client minimal core zero custom"
  33 
  34 ###############################################################################
  35 # Check if the specified JVM variant should be built. To be used in shell if
  36 # constructs, like this:
  37 # if HOTSPOT_CHECK_JVM_VARIANT(server); then
  38 #
  39 # Only valid to use after HOTSPOT_SETUP_JVM_VARIANTS has setup variants.
  40 
  41 # Definition kept in one line to allow inlining in if statements.
  42 # Additional [] needed to keep m4 from mangling shell constructs.
  43 AC_DEFUN([HOTSPOT_CHECK_JVM_VARIANT],
  44 [ [ [[ " $JVM_VARIANTS " =~ " $1 " ]] ] ])
  45 
  46 ###############################################################################
  47 # Check if the specified JVM features are explicitly enabled. To be used in
  48 # shell if constructs, like this:
  49 # if HOTSPOT_CHECK_JVM_FEATURE(jvmti); then
  50 #
  51 # Only valid to use after HOTSPOT_SETUP_JVM_FEATURES has setup features.
  52 
  53 # Definition kept in one line to allow inlining in if statements.
  54 # Additional [] needed to keep m4 from mangling shell constructs.
  55 AC_DEFUN([HOTSPOT_CHECK_JVM_FEATURE],
  56 [ [ [[ " $JVM_FEATURES " =~ " $1 " ]] ] ])
  57 
  58 ###############################################################################
  59 # Check which variants of the JVM that we want to build. Available variants are:
  60 #   server: normal interpreter, and a tiered C1/C2 compiler
  61 #   client: normal interpreter, and C1 (no C2 compiler)
  62 #   minimal: reduced form of client with optional features stripped out
  63 #   core: normal interpreter only, no compiler
  64 #   zero: C++ based interpreter only, no compiler
  65 #   custom: baseline JVM with no default features
  66 #
  67 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_VARIANTS],
  68 [
  69   AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
  70       [JVM variants (separated by commas) to build (server,client,minimal,core,zero,custom) @<:@server@:>@])])
  71 
  72   SETUP_HOTSPOT_TARGET_CPU_PORT
  73 
  74   if test "x$with_jvm_variants" = x; then
  75     with_jvm_variants="server"
  76   fi
  77   JVM_VARIANTS_OPT="$with_jvm_variants"
  78 
  79   # Has the user listed more than one variant?
  80   # Additional [] needed to keep m4 from mangling shell constructs.
  81   if [ [[ "$JVM_VARIANTS_OPT" =~ "," ]] ]; then
  82     BUILDING_MULTIPLE_JVM_VARIANTS=true
  83   else
  84     BUILDING_MULTIPLE_JVM_VARIANTS=false
  85   fi
  86   # Replace the commas with AND for use in the build directory name.
  87   JVM_VARIANTS_WITH_AND=`$ECHO "$JVM_VARIANTS_OPT" | $SED -e 's/,/AND/g'`
  88 
  89   AC_MSG_CHECKING([which variants of the JVM to build])
  90   # JVM_VARIANTS is a space-separated list.
  91   # Also use minimal, not minimal1 (which is kept for backwards compatibility).
  92   JVM_VARIANTS=`$ECHO $JVM_VARIANTS_OPT | $SED -e 's/,/ /g' -e 's/minimal1/minimal/'`
  93   AC_MSG_RESULT([$JVM_VARIANTS])
  94 
  95   # Check that the selected variants are valid
  96   BASIC_GET_NON_MATCHING_VALUES(INVALID_VARIANTS, $JVM_VARIANTS, $VALID_JVM_VARIANTS)
  97   if test "x$INVALID_VARIANTS" != x; then
  98     AC_MSG_NOTICE([Unknown variant(s) specified: "$INVALID_VARIANTS"])
  99     AC_MSG_NOTICE([The available JVM variants are: "$VALID_JVM_VARIANTS"])
 100     AC_MSG_ERROR([Cannot continue])
 101   fi
 102 
 103   # All "special" variants share the same output directory ("server")
 104   VALID_MULTIPLE_JVM_VARIANTS="server client minimal"
 105   BASIC_GET_NON_MATCHING_VALUES(INVALID_MULTIPLE_VARIANTS, $JVM_VARIANTS, $VALID_MULTIPLE_JVM_VARIANTS)
 106   if  test "x$INVALID_MULTIPLE_VARIANTS" != x && test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = xtrue; then
 107     AC_MSG_ERROR([You cannot build multiple variants with anything else than $VALID_MULTIPLE_JVM_VARIANTS.])
 108   fi
 109 
 110   # The "main" variant is the one used by other libs to link against during the
 111   # build.
 112   if test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = "xtrue"; then
 113     MAIN_VARIANT_PRIO_ORDER="server client minimal"
 114     for variant in $MAIN_VARIANT_PRIO_ORDER; do
 115       if HOTSPOT_CHECK_JVM_VARIANT($variant); then
 116         JVM_VARIANT_MAIN="$variant"
 117         break
 118       fi
 119     done
 120   else
 121     JVM_VARIANT_MAIN="$JVM_VARIANTS"
 122   fi
 123 
 124   AC_SUBST(JVM_VARIANTS)
 125   AC_SUBST(VALID_JVM_VARIANTS)
 126   AC_SUBST(JVM_VARIANT_MAIN)
 127 
 128   if HOTSPOT_CHECK_JVM_VARIANT(zero); then
 129     # zero behaves as a platform and rewrites these values. This is really weird. :(
 130     # We are guaranteed that we do not build any other variants when building zero.
 131     HOTSPOT_TARGET_CPU=zero
 132     HOTSPOT_TARGET_CPU_ARCH=zero
 133   fi
 134 ])
 135 
 136 ###############################################################################
 137 # Check if dtrace should be enabled and has all prerequisites present.
 138 #
 139 AC_DEFUN_ONCE([HOTSPOT_SETUP_DTRACE],
 140 [
 141   # Test for dtrace dependencies
 142   AC_ARG_ENABLE([dtrace], [AS_HELP_STRING([--enable-dtrace@<:@=yes/no/auto@:>@],
 143       [enable dtrace. Default is auto, where dtrace is enabled if all dependencies
 144       are present.])])
 145 
 146   DTRACE_DEP_MISSING=false
 147 
 148   AC_MSG_CHECKING([for dtrace tool])
 149   if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
 150     AC_MSG_RESULT([$DTRACE])
 151   else
 152     AC_MSG_RESULT([not found, cannot build dtrace])
 153     DTRACE_DEP_MISSING=true
 154   fi
 155 
 156   AC_CHECK_HEADERS([sys/sdt.h], [DTRACE_HEADERS_OK=yes],[DTRACE_HEADERS_OK=no])
 157   if test "x$DTRACE_HEADERS_OK" != "xyes"; then
 158     DTRACE_DEP_MISSING=true
 159   fi
 160 
 161   AC_MSG_CHECKING([if dtrace should be built])
 162   if test "x$enable_dtrace" = "xyes"; then
 163     if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
 164       AC_MSG_RESULT([no, missing dependencies])
 165       HELP_MSG_MISSING_DEPENDENCY([dtrace])
 166       AC_MSG_ERROR([Cannot enable dtrace with missing dependencies. See above. $HELP_MSG])
 167     else
 168       INCLUDE_DTRACE=true
 169       AC_MSG_RESULT([yes, forced])
 170     fi
 171   elif test "x$enable_dtrace" = "xno"; then
 172     INCLUDE_DTRACE=false
 173     AC_MSG_RESULT([no, forced])
 174   elif test "x$enable_dtrace" = "xauto" || test "x$enable_dtrace" = "x"; then
 175     if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
 176       INCLUDE_DTRACE=false
 177       AC_MSG_RESULT([no, missing dependencies])
 178     else
 179       INCLUDE_DTRACE=true
 180       AC_MSG_RESULT([yes, dependencies present])
 181     fi
 182   else
 183     AC_MSG_ERROR([Invalid value for --enable-dtrace: $enable_dtrace])
 184   fi
 185 ])
 186 
 187 ################################################################################
 188 # Check if AOT should be enabled
 189 #
 190 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_AOT],
 191 [
 192   AC_ARG_ENABLE([aot], [AS_HELP_STRING([--enable-aot@<:@=yes/no/auto@:>@],
 193       [enable ahead of time compilation feature. Default is auto, where aot is enabled if all dependencies are present.])])
 194 
 195   if test "x$enable_aot" = "x" || test "x$enable_aot" = "xauto"; then
 196     ENABLE_AOT="true"
 197   elif test "x$enable_aot" = "xyes"; then
 198     ENABLE_AOT="true"
 199   elif test "x$enable_aot" = "xno"; then
 200     ENABLE_AOT="false"
 201     AC_MSG_CHECKING([if aot should be enabled])
 202     AC_MSG_RESULT([no, forced])
 203   else
 204     AC_MSG_ERROR([Invalid value for --enable-aot: $enable_aot])
 205   fi
 206 
 207   if test "x$ENABLE_AOT" = "xtrue"; then
 208     # Only enable AOT on X64 platforms.
 209     if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
 210       if test -e "${TOPDIR}/src/jdk.aot"; then
 211         if test -e "${TOPDIR}/src/jdk.internal.vm.compiler"; then
 212           ENABLE_AOT="true"
 213         else
 214           ENABLE_AOT="false"
 215           if test "x$enable_aot" = "xyes"; then
 216             AC_MSG_ERROR([Cannot build AOT without src/jdk.internal.vm.compiler sources. Remove --enable-aot.])
 217           fi
 218         fi
 219       else
 220         ENABLE_AOT="false"
 221         if test "x$enable_aot" = "xyes"; then
 222           AC_MSG_ERROR([Cannot build AOT without src/jdk.aot sources. Remove --enable-aot.])
 223         fi
 224       fi
 225     else
 226       ENABLE_AOT="false"
 227       if test "x$enable_aot" = "xyes"; then
 228         AC_MSG_ERROR([AOT is currently only supported on x86_64. Remove --enable-aot.])
 229       fi
 230     fi
 231   fi
 232 
 233   AC_SUBST(ENABLE_AOT)
 234 ])
 235 
 236 ################################################################################
 237 # Allow to disable CDS
 238 #
 239 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_CDS],
 240 [
 241   AC_ARG_ENABLE([cds], [AS_HELP_STRING([--enable-cds@<:@=yes/no@:>@],
 242       [enable class data sharing feature in non-minimal VM. Default is yes.])])
 243 
 244   if test "x$enable_cds" = "x" || test "x$enable_cds" = "xyes"; then
 245     ENABLE_CDS="true"
 246   elif test "x$enable_cds" = "xno"; then
 247     ENABLE_CDS="false"
 248   else
 249     AC_MSG_ERROR([Invalid value for --enable-cds: $enable_cds])
 250   fi
 251 
 252   AC_SUBST(ENABLE_CDS)
 253 ])
 254 
 255 ###############################################################################
 256 # Set up all JVM features for each JVM variant.
 257 #
 258 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_FEATURES],
 259 [
 260   # Prettify the VALID_JVM_FEATURES string
 261   BASIC_SORT_LIST(VALID_JVM_FEATURES, $VALID_JVM_FEATURES)
 262 
 263   # The user can in some cases supply additional jvm features. For the custom
 264   # variant, this defines the entire variant.
 265   AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
 266       [JVM features to enable (foo) or disable (-foo), separated by comma. Use '--help' to show possible values @<:@none@:>@])])
 267   if test "x$with_jvm_features" != x; then
 268     AC_MSG_CHECKING([user specified JVM feature list])
 269     USER_JVM_FEATURE_LIST=`$ECHO $with_jvm_features | $SED -e 's/,/ /g'`
 270     AC_MSG_RESULT([$user_jvm_feature_list])
 271     # These features will be added to all variant defaults
 272     JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (!match($i, /^-.*/)) print $i }'`
 273     # These features will be removed from all variant defaults
 274     DISABLED_JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (match($i, /^-.*/)) print substr($i, 2) }'`
 275 
 276     # Verify that the user has provided valid features
 277     BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES $DISABLED_JVM_FEATURES, $VALID_JVM_FEATURES)
 278     if test "x$INVALID_FEATURES" != x; then
 279       AC_MSG_NOTICE([Unknown JVM features specified: "$INVALID_FEATURES"])
 280       AC_MSG_NOTICE([The available JVM features are: "$VALID_JVM_FEATURES"])
 281       AC_MSG_ERROR([Cannot continue])
 282     fi
 283 
 284   fi
 285 
 286   # Override hotspot cpu definitions for ARM platforms
 287   if test "x$OPENJDK_TARGET_CPU" = xarm; then
 288     HOTSPOT_TARGET_CPU=arm_32
 289     HOTSPOT_TARGET_CPU_DEFINE="ARM32"
 290   elif test "x$OPENJDK_TARGET_CPU" = xaarch64 && test "x$HOTSPOT_TARGET_CPU_PORT" = xarm64; then
 291     HOTSPOT_TARGET_CPU=arm_64
 292     HOTSPOT_TARGET_CPU_ARCH=arm
 293   fi
 294 
 295   # Verify that dependencies are met for explicitly set features.
 296   if HOTSPOT_CHECK_JVM_FEATURE(jvmti) && ! HOTSPOT_CHECK_JVM_FEATURE(services); then
 297     AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services'])
 298   fi
 299 
 300   if HOTSPOT_CHECK_JVM_FEATURE(management) && ! HOTSPOT_CHECK_JVM_FEATURE(nmt); then
 301     AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt'])
 302   fi
 303 
 304   if HOTSPOT_CHECK_JVM_FEATURE(jvmci) && ! (HOTSPOT_CHECK_JVM_FEATURE(compiler1) || HOTSPOT_CHECK_JVM_FEATURE(compiler2)); then
 305     AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2' or 'compiler1'])
 306   fi
 307 
 308   if HOTSPOT_CHECK_JVM_FEATURE(cmsgc) && ! HOTSPOT_CHECK_JVM_FEATURE(serialgc); then
 309     AC_MSG_ERROR([Specified JVM feature 'cmsgc' requires feature 'serialgc'])
 310   fi
 311 
 312   # Enable JFR by default, except on linux-sparcv9 and on minimal.
 313   if test "x$OPENJDK_TARGET_OS" != xlinux || test "x$OPENJDK_TARGET_CPU" != xsparcv9; then
 314     NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES jfr"
 315   fi
 316 
 317   # Turn on additional features based on other parts of configure
 318   if test "x$INCLUDE_DTRACE" = "xtrue"; then
 319     JVM_FEATURES="$JVM_FEATURES dtrace"
 320   else
 321     if HOTSPOT_CHECK_JVM_FEATURE(dtrace); then
 322       AC_MSG_ERROR([To enable dtrace, you must use --enable-dtrace])
 323     fi
 324   fi
 325 
 326   if test "x$STATIC_BUILD" = "xtrue"; then
 327     JVM_FEATURES="$JVM_FEATURES static-build"
 328   else
 329     if HOTSPOT_CHECK_JVM_FEATURE(static-build); then
 330       AC_MSG_ERROR([To enable static-build, you must use --enable-static-build])
 331     fi
 332   fi
 333 
 334   if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
 335     if HOTSPOT_CHECK_JVM_FEATURE(zero); then
 336       AC_MSG_ERROR([To enable zero, you must use --with-jvm-variants=zero])
 337     fi
 338   fi
 339 
 340   # Only enable jvmci on x86_64, sparcv9 and aarch64.
 341   if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
 342      test "x$OPENJDK_TARGET_CPU" = "xsparcv9" || \
 343      test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
 344     JVM_FEATURES_jvmci="jvmci"
 345   else
 346     JVM_FEATURES_jvmci=""
 347   fi
 348 
 349   AC_MSG_CHECKING([if jdk.internal.vm.compiler should be built])
 350   if HOTSPOT_CHECK_JVM_FEATURE(graal); then
 351     AC_MSG_RESULT([yes, forced])
 352     if test "x$JVM_FEATURES_jvmci" != "xjvmci" ; then
 353       AC_MSG_ERROR([Specified JVM feature 'graal' requires feature 'jvmci'])
 354     fi
 355     INCLUDE_GRAAL="true"
 356   else
 357     # By default enable graal build on x64 or where AOT is available.
 358     # graal build requires jvmci.
 359     if test "x$JVM_FEATURES_jvmci" = "xjvmci" && \
 360         (test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
 361          test "x$ENABLE_AOT" = "xtrue") ; then
 362       AC_MSG_RESULT([yes])
 363       JVM_FEATURES_graal="graal"
 364       INCLUDE_GRAAL="true"
 365     else
 366       AC_MSG_RESULT([no])
 367       JVM_FEATURES_graal=""
 368       INCLUDE_GRAAL="false"
 369     fi
 370   fi
 371 
 372   AC_SUBST(INCLUDE_GRAAL)
 373 
 374   AC_MSG_CHECKING([if aot should be enabled])
 375   if test "x$ENABLE_AOT" = "xtrue"; then
 376     if test "x$enable_aot" = "xyes"; then
 377       AC_MSG_RESULT([yes, forced])
 378     else
 379       AC_MSG_RESULT([yes])
 380     fi
 381     JVM_FEATURES_aot="aot"
 382   else
 383     if test "x$enable_aot" = "xno"; then
 384       AC_MSG_RESULT([no, forced])
 385     else
 386       AC_MSG_RESULT([no])
 387     fi
 388     JVM_FEATURES_aot=""
 389   fi
 390 
 391   if test "x$OPENJDK_TARGET_CPU" = xarm ; then
 392     # Default to use link time optimizations on minimal on arm
 393     JVM_FEATURES_link_time_opt="link-time-opt"
 394   else
 395     JVM_FEATURES_link_time_opt=""
 396   fi
 397 
 398   # All variants but minimal (and custom) get these features
 399   NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cmsgc g1gc parallelgc serialgc epsilongc jni-check jvmti management nmt services vm-structs"
 400   if test "x$ENABLE_CDS" = "xtrue"; then
 401     NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cds"
 402   fi
 403 
 404   # Enable features depending on variant.
 405   JVM_FEATURES_server="compiler1 compiler2 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci $JVM_FEATURES_aot $JVM_FEATURES_graal"
 406   JVM_FEATURES_client="compiler1 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci"
 407   JVM_FEATURES_core="$NON_MINIMAL_FEATURES $JVM_FEATURES"
 408   JVM_FEATURES_minimal="compiler1 minimal serialgc $JVM_FEATURES $JVM_FEATURES_link_time_opt"
 409   JVM_FEATURES_zero="zero $NON_MINIMAL_FEATURES $JVM_FEATURES"
 410   JVM_FEATURES_custom="$JVM_FEATURES"
 411 
 412   AC_SUBST(JVM_FEATURES_server)
 413   AC_SUBST(JVM_FEATURES_client)
 414   AC_SUBST(JVM_FEATURES_core)
 415   AC_SUBST(JVM_FEATURES_minimal)
 416   AC_SUBST(JVM_FEATURES_zero)
 417   AC_SUBST(JVM_FEATURES_custom)
 418 
 419   # Used for verification of Makefiles by check-jvm-feature
 420   AC_SUBST(VALID_JVM_FEATURES)
 421 
 422   # We don't support --with-jvm-interpreter anymore, use zero instead.
 423   BASIC_DEPRECATED_ARG_WITH(jvm-interpreter)
 424 ])
 425 
 426 ###############################################################################
 427 # Finalize JVM features once all setup is complete, including custom setup.
 428 #
 429 AC_DEFUN_ONCE([HOTSPOT_FINALIZE_JVM_FEATURES],
 430 [
 431   for variant in $JVM_VARIANTS; do
 432     AC_MSG_CHECKING([JVM features for JVM variant '$variant'])
 433     features_var_name=JVM_FEATURES_$variant
 434     JVM_FEATURES_FOR_VARIANT=${!features_var_name}
 435 
 436     # Filter out user-requested disabled features
 437     BASIC_GET_NON_MATCHING_VALUES(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT, $DISABLED_JVM_FEATURES)
 438 
 439     # Keep feature lists sorted and free of duplicates
 440     BASIC_SORT_LIST(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT)
 441 
 442     # Update real feature set variable
 443     eval $features_var_name='"'$JVM_FEATURES_FOR_VARIANT'"'
 444     AC_MSG_RESULT(["$JVM_FEATURES_FOR_VARIANT"])
 445 
 446     # Verify that we have at least one gc selected
 447     GC_FEATURES=`$ECHO $JVM_FEATURES_FOR_VARIANT | $GREP gc`
 448     if test "x$GC_FEATURES" = x; then
 449       AC_MSG_WARN([Invalid JVM features: No gc selected for variant $variant.])
 450     fi
 451 
 452     # Validate features (for configure script errors, not user errors)
 453     BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES_FOR_VARIANT, $VALID_JVM_FEATURES)
 454     if test "x$INVALID_FEATURES" != x; then
 455       AC_MSG_ERROR([Internal configure script error. Invalid JVM feature(s): $INVALID_FEATURES])
 456     fi
 457   done
 458 ])
 459 
 460 ################################################################################
 461 #
 462 # Specify which sources will be used to build the 64-bit ARM port
 463 #
 464 # --with-cpu-port=arm64   will use hotspot/src/cpu/arm
 465 # --with-cpu-port=aarch64 will use hotspot/src/cpu/aarch64
 466 #
 467 AC_DEFUN([SETUP_HOTSPOT_TARGET_CPU_PORT],
 468 [
 469   AC_ARG_WITH(cpu-port, [AS_HELP_STRING([--with-cpu-port],
 470       [specify sources to use for Hotspot 64-bit ARM port (arm64,aarch64) @<:@aarch64@:>@ ])])
 471 
 472   if test "x$with_cpu_port" != x; then
 473     if test "x$OPENJDK_TARGET_CPU" != xaarch64; then
 474       AC_MSG_ERROR([--with-cpu-port only available on aarch64])
 475     fi
 476     if test "x$with_cpu_port" != xarm64 && \
 477         test "x$with_cpu_port" != xaarch64; then
 478       AC_MSG_ERROR([--with-cpu-port must specify arm64 or aarch64])
 479     fi
 480     HOTSPOT_TARGET_CPU_PORT="$with_cpu_port"
 481   fi
 482 ])
 483 
 484 
 485 ################################################################################
 486 # Check if gtest should be built
 487 #
 488 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_GTEST],
 489 [
 490   AC_ARG_ENABLE([hotspot-gtest], [AS_HELP_STRING([--disable-hotspot-gtest],
 491       [Disables building of the Hotspot unit tests @<:@enabled@:>@])])
 492 
 493   if test -e "${TOPDIR}/test/hotspot/gtest"; then
 494     GTEST_DIR_EXISTS="true"
 495   else
 496     GTEST_DIR_EXISTS="false"
 497   fi
 498 
 499   AC_MSG_CHECKING([if Hotspot gtest unit tests should be built])
 500   if test "x$enable_hotspot_gtest" = "xyes"; then
 501     if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
 502       AC_MSG_RESULT([yes, forced])
 503       BUILD_GTEST="true"
 504     else
 505       AC_MSG_ERROR([Cannot build gtest without the test source])
 506     fi
 507   elif test "x$enable_hotspot_gtest" = "xno"; then
 508     AC_MSG_RESULT([no, forced])
 509     BUILD_GTEST="false"
 510   elif test "x$enable_hotspot_gtest" = "x"; then
 511     if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
 512       AC_MSG_RESULT([yes])
 513       BUILD_GTEST="true"
 514     else
 515       AC_MSG_RESULT([no])
 516       BUILD_GTEST="false"
 517     fi
 518   else
 519     AC_MSG_ERROR([--enable-gtest must be either yes or no])
 520   fi
 521 
 522   AC_SUBST(BUILD_GTEST)
 523 ])