1 #
2 # Copyright (c) 2011, 2014, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VARIANT],
27 [
28 ###############################################################################
29 #
30 # Check which variant of the JDK that we want to build.
31 # Currently we have:
32 # normal: standard edition
33 # but the custom make system may add other variants
34 #
35 # Effectively the JDK variant gives a name to a specific set of
36 # modules to compile into the JDK. In the future, these modules
37 # might even be Jigsaw modules.
38 #
39 AC_MSG_CHECKING([which variant of the JDK to build])
40 AC_ARG_WITH([jdk-variant], [AS_HELP_STRING([--with-jdk-variant],
41 [JDK variant to build (normal) @<:@normal@:>@])])
42
43 if test "x$with_jdk_variant" = xnormal || test "x$with_jdk_variant" = x; then
44 JDK_VARIANT="normal"
45 else
46 AC_MSG_ERROR([The available JDK variants are: normal])
47 fi
48
49 AC_SUBST(JDK_VARIANT)
50
51 AC_MSG_RESULT([$JDK_VARIANT])
52 ])
53
54 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_INTERPRETER],
55 [
56 ###############################################################################
57 #
58 # Check which interpreter of the JVM we want to build.
59 # Currently we have:
60 # template: Template interpreter (the default)
61 # cpp : C++ interpreter
62 AC_MSG_CHECKING([which interpreter of the JVM to build])
63 AC_ARG_WITH([jvm-interpreter], [AS_HELP_STRING([--with-jvm-interpreter],
64 [JVM interpreter to build (template, cpp) @<:@template@:>@])])
65
66 if test "x$with_jvm_interpreter" = x; then
67 with_jvm_interpreter="template"
68 fi
69
70 JVM_INTERPRETER="$with_jvm_interpreter"
71
72 if test "x$JVM_INTERPRETER" != xtemplate && test "x$JVM_INTERPRETER" != xcpp; then
73 AC_MSG_ERROR([The available JVM interpreters are: template, cpp])
74 fi
75
76 AC_SUBST(JVM_INTERPRETER)
77
78 AC_MSG_RESULT([$with_jvm_interpreter])
79 ])
80
81 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_VARIANTS],
82 [
83
84 ###############################################################################
85 #
86 # Check which variants of the JVM that we want to build.
87 # Currently we have:
88 # server: normal interpreter and a tiered C1/C2 compiler
89 # client: normal interpreter and C1 (no C2 compiler) (only 32-bit platforms)
90 # minimal1: reduced form of client with optional VM services and features stripped out
91 # kernel: kernel footprint JVM that passes the TCK without major performance problems,
92 # ie normal interpreter and C1, only the serial GC, kernel jvmti etc
93 # zero: no machine code interpreter, no compiler
94 # zeroshark: zero interpreter and shark/llvm compiler backend
95 # core: interpreter only, no compiler (only works on some platforms)
96 AC_MSG_CHECKING([which variants of the JVM to build])
97 AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
98 [JVM variants (separated by commas) to build (server, client, minimal1, kernel, zero, zeroshark, core) @<:@server@:>@])])
99
100 if test "x$with_jvm_variants" = x; then
101 with_jvm_variants="server"
102 fi
103
104 JVM_VARIANTS=",$with_jvm_variants,"
105 TEST_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,//' -e 's/client,//' -e 's/minimal1,//' -e 's/kernel,//' -e 's/zero,//' -e 's/zeroshark,//' -e 's/core,//'`
106
107 if test "x$TEST_VARIANTS" != "x,"; then
108 AC_MSG_ERROR([The available JVM variants are: server, client, minimal1, kernel, zero, zeroshark, core])
109 fi
110 AC_MSG_RESULT([$with_jvm_variants])
111
112 JVM_VARIANT_SERVER=`$ECHO "$JVM_VARIANTS" | $SED -e '/,server,/!s/.*/false/g' -e '/,server,/s/.*/true/g'`
113 JVM_VARIANT_CLIENT=`$ECHO "$JVM_VARIANTS" | $SED -e '/,client,/!s/.*/false/g' -e '/,client,/s/.*/true/g'`
114 JVM_VARIANT_MINIMAL1=`$ECHO "$JVM_VARIANTS" | $SED -e '/,minimal1,/!s/.*/false/g' -e '/,minimal1,/s/.*/true/g'`
115 JVM_VARIANT_KERNEL=`$ECHO "$JVM_VARIANTS" | $SED -e '/,kernel,/!s/.*/false/g' -e '/,kernel,/s/.*/true/g'`
116 JVM_VARIANT_ZERO=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zero,/!s/.*/false/g' -e '/,zero,/s/.*/true/g'`
117 JVM_VARIANT_ZEROSHARK=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zeroshark,/!s/.*/false/g' -e '/,zeroshark,/s/.*/true/g'`
118 JVM_VARIANT_CORE=`$ECHO "$JVM_VARIANTS" | $SED -e '/,core,/!s/.*/false/g' -e '/,core,/s/.*/true/g'`
119
120 if test "x$JVM_VARIANT_CLIENT" = xtrue; then
121 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
122 AC_MSG_ERROR([You cannot build a client JVM for a 64-bit machine.])
123 fi
124 fi
125 if test "x$JVM_VARIANT_KERNEL" = xtrue; then
126 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
127 AC_MSG_ERROR([You cannot build a kernel JVM for a 64-bit machine.])
128 fi
129 fi
130 if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
131 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
132 AC_MSG_ERROR([You cannot build a minimal JVM for a 64-bit machine.])
133 fi
134 fi
135
136 # Replace the commas with AND for use in the build directory name.
137 ANDED_JVM_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/^,//' -e 's/,$//' -e 's/,/AND/g'`
138 COUNT_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,/1/' -e 's/client,/1/' -e 's/minimal1,/1/' -e 's/kernel,/1/' -e 's/zero,/1/' -e 's/zeroshark,/1/' -e 's/core,/1/'`
139 if test "x$COUNT_VARIANTS" != "x,1"; then
140 BUILDING_MULTIPLE_JVM_VARIANTS=yes
141 else
142 BUILDING_MULTIPLE_JVM_VARIANTS=no
143 fi
144
145 AC_SUBST(JVM_VARIANTS)
146 AC_SUBST(JVM_VARIANT_SERVER)
147 AC_SUBST(JVM_VARIANT_CLIENT)
148 AC_SUBST(JVM_VARIANT_MINIMAL1)
149 AC_SUBST(JVM_VARIANT_KERNEL)
150 AC_SUBST(JVM_VARIANT_ZERO)
151 AC_SUBST(JVM_VARIANT_ZEROSHARK)
152 AC_SUBST(JVM_VARIANT_CORE)
153
154 INCLUDE_SA=true
155 if test "x$JVM_VARIANT_ZERO" = xtrue ; then
156 INCLUDE_SA=false
157 fi
158 if test "x$JVM_VARIANT_ZEROSHARK" = xtrue ; then
159 INCLUDE_SA=false
160 fi
161 if test "x$VAR_CPU" = xppc64 ; then
162 INCLUDE_SA=false
163 fi
164 AC_SUBST(INCLUDE_SA)
165
166 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
167 MACOSX_UNIVERSAL="true"
168 fi
169
170 AC_SUBST(MACOSX_UNIVERSAL)
171 ])
172
173 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_LEVEL],
174 [
175 ###############################################################################
176 #
177 # Set the debug level
178 # release: no debug information, all optimizations, no asserts.
179 # optimized: no debug information, all optimizations, no asserts, not product.
180 # fastdebug: debug information (-g), all optimizations, all asserts
181 # slowdebug: debug information (-g), no optimizations, all asserts
182 #
183 DEBUG_LEVEL="release"
184 AC_MSG_CHECKING([which debug level to use])
185 AC_ARG_ENABLE([debug], [AS_HELP_STRING([--enable-debug],
186 [set the debug level to fastdebug (shorthand for --with-debug-level=fastdebug) @<:@disabled@:>@])],
187 [
188 ENABLE_DEBUG="${enableval}"
189 DEBUG_LEVEL="fastdebug"
190 ], [ENABLE_DEBUG="no"])
191
192 AC_ARG_WITH([debug-level], [AS_HELP_STRING([--with-debug-level],
193 [set the debug level (release, fastdebug, slowdebug, optimized (i.e. not-product)) @<:@release@:>@])],
194 [
195 DEBUG_LEVEL="${withval}"
196 if test "x$ENABLE_DEBUG" = xyes; then
197 AC_MSG_ERROR([You cannot use both --enable-debug and --with-debug-level at the same time.])
198 fi
199 ])
200 AC_MSG_RESULT([$DEBUG_LEVEL])
201
202 if test "x$DEBUG_LEVEL" != xrelease && \
203 test "x$DEBUG_LEVEL" != xoptimized && \
204 test "x$DEBUG_LEVEL" != xfastdebug && \
205 test "x$DEBUG_LEVEL" != xslowdebug; then
206 AC_MSG_ERROR([Allowed debug levels are: release, fastdebug and slowdebug])
207 fi
208
209
210 ###############################################################################
211 #
212 # Setup legacy vars/targets and new vars to deal with different debug levels.
213 #
214
215 case $DEBUG_LEVEL in
216 release )
217 VARIANT="OPT"
218 FASTDEBUG="false"
219 DEBUG_CLASSFILES="false"
220 BUILD_VARIANT_RELEASE=""
221 HOTSPOT_DEBUG_LEVEL="product"
222 HOTSPOT_EXPORT="product"
223 ;;
224 fastdebug )
225 VARIANT="DBG"
226 FASTDEBUG="true"
227 DEBUG_CLASSFILES="true"
228 BUILD_VARIANT_RELEASE="-fastdebug"
229 HOTSPOT_DEBUG_LEVEL="fastdebug"
230 HOTSPOT_EXPORT="fastdebug"
231 ;;
232 slowdebug )
233 VARIANT="DBG"
234 FASTDEBUG="false"
235 DEBUG_CLASSFILES="true"
236 BUILD_VARIANT_RELEASE="-debug"
237 HOTSPOT_DEBUG_LEVEL="jvmg"
238 HOTSPOT_EXPORT="debug"
239 ;;
240 optimized )
241 VARIANT="OPT"
242 FASTDEBUG="false"
243 DEBUG_CLASSFILES="false"
244 BUILD_VARIANT_RELEASE="-optimized"
245 HOTSPOT_DEBUG_LEVEL="optimized"
246 HOTSPOT_EXPORT="optimized"
247 ;;
248 esac
249
250 #####
251 # Generate the legacy makefile targets for hotspot.
252 # The hotspot api for selecting the build artifacts, really, needs to be improved.
253 # JDK-7195896 will fix this on the hotspot side by using the JVM_VARIANT_* variables to
254 # determine what needs to be built. All we will need to set here is all_product, all_fastdebug etc
255 # But until then ...
256 HOTSPOT_TARGET=""
257
258 if test "x$JVM_VARIANT_SERVER" = xtrue; then
259 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL} "
260 fi
261
262 if test "x$JVM_VARIANT_CLIENT" = xtrue; then
263 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}1 "
264 fi
265
266 if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
267 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}minimal1 "
268 fi
269
270 if test "x$JVM_VARIANT_KERNEL" = xtrue; then
271 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}kernel "
272 fi
273
274 if test "x$JVM_VARIANT_ZERO" = xtrue; then
275 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}zero "
276 fi
277
278 if test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
279 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}shark "
280 fi
281
282 if test "x$JVM_VARIANT_CORE" = xtrue; then
283 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}core "
284 fi
285
286 HOTSPOT_TARGET="$HOTSPOT_TARGET docs export_$HOTSPOT_EXPORT"
287
288 # On Macosx universal binaries are produced, but they only contain
289 # 64 bit intel. This invalidates control of which jvms are built
290 # from configure, but only server is valid anyway. Fix this
291 # when hotspot makefiles are rewritten.
292 if test "x$MACOSX_UNIVERSAL" = xtrue; then
293 HOTSPOT_TARGET=universal_${HOTSPOT_EXPORT}
294 fi
295
296 #####
297
298 AC_SUBST(DEBUG_LEVEL)
299 AC_SUBST(VARIANT)
300 AC_SUBST(FASTDEBUG)
301 AC_SUBST(DEBUG_CLASSFILES)
302 AC_SUBST(BUILD_VARIANT_RELEASE)
303 ])
304
305
306 ###############################################################################
307 #
308 # Should we build only OpenJDK even if closed sources are present?
309 #
310 AC_DEFUN_ONCE([JDKOPT_SETUP_OPEN_OR_CUSTOM],
311 [
312 AC_ARG_ENABLE([openjdk-only], [AS_HELP_STRING([--enable-openjdk-only],
313 [suppress building custom source even if present @<:@disabled@:>@])],,[enable_openjdk_only="no"])
314
315 AC_MSG_CHECKING([for presence of closed sources])
316 if test -d "$SRC_ROOT/jdk/src/closed"; then
317 CLOSED_SOURCE_PRESENT=yes
318 else
319 CLOSED_SOURCE_PRESENT=no
320 fi
321 AC_MSG_RESULT([$CLOSED_SOURCE_PRESENT])
322
323 AC_MSG_CHECKING([if closed source is suppressed (openjdk-only)])
324 SUPPRESS_CLOSED_SOURCE="$enable_openjdk_only"
325 AC_MSG_RESULT([$SUPPRESS_CLOSED_SOURCE])
326
327 if test "x$CLOSED_SOURCE_PRESENT" = xno; then
328 OPENJDK=true
329 if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
330 AC_MSG_WARN([No closed source present, --enable-openjdk-only makes no sense])
331 fi
332 else
333 if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
334 OPENJDK=true
335 else
336 OPENJDK=false
337 fi
338 fi
339
340 if test "x$OPENJDK" = "xtrue"; then
341 SET_OPENJDK="OPENJDK=true"
342 fi
343
344 AC_SUBST(SET_OPENJDK)
345
346 # custom-make-dir is deprecated. Please use your custom-hook.m4 to override
347 # the IncludeCustomExtension macro.
348 BASIC_DEPRECATED_ARG_WITH(custom-make-dir)
349 ])
350
351 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_OPTIONS],
352 [
353
354 ###############################################################################
355 #
356 # Should we build a JDK/JVM with headful support (ie a graphical ui)?
357 # We always build headless support.
358 #
359 AC_MSG_CHECKING([headful support])
360 AC_ARG_ENABLE([headful], [AS_HELP_STRING([--disable-headful],
361 [disable building headful support (graphical UI support) @<:@enabled@:>@])],
362 [SUPPORT_HEADFUL=${enable_headful}], [SUPPORT_HEADFUL=yes])
363
364 SUPPORT_HEADLESS=yes
365 BUILD_HEADLESS="BUILD_HEADLESS:=true"
366
367 if test "x$SUPPORT_HEADFUL" = xyes; then
368 # We are building both headful and headless.
369 headful_msg="include support for both headful and headless"
370 fi
371
372 if test "x$SUPPORT_HEADFUL" = xno; then
373 # Thus we are building headless only.
374 BUILD_HEADLESS="BUILD_HEADLESS:=true"
375 headful_msg="headless only"
376 fi
377
378 AC_MSG_RESULT([$headful_msg])
379
380 AC_SUBST(SUPPORT_HEADLESS)
381 AC_SUBST(SUPPORT_HEADFUL)
382 AC_SUBST(BUILD_HEADLESS)
383
384 # Control wether Hotspot runs Queens test after build.
385 AC_ARG_ENABLE([hotspot-test-in-build], [AS_HELP_STRING([--enable-hotspot-test-in-build],
386 [run the Queens test after Hotspot build @<:@disabled@:>@])],,
387 [enable_hotspot_test_in_build=no])
388 if test "x$enable_hotspot_test_in_build" = "xyes"; then
389 TEST_IN_BUILD=true
390 else
391 TEST_IN_BUILD=false
392 fi
393 AC_SUBST(TEST_IN_BUILD)
394
395 ###############################################################################
396 #
397 # Choose cacerts source file
398 #
399 AC_ARG_WITH(cacerts-file, [AS_HELP_STRING([--with-cacerts-file],
400 [specify alternative cacerts file])])
401 if test "x$with_cacerts_file" != x; then
402 CACERTS_FILE=$with_cacerts_file
403 else
404 CACERTS_FILE=${SRC_ROOT}/jdk/src/share/lib/security/cacerts
405 fi
406 AC_SUBST(CACERTS_FILE)
407
408 ###############################################################################
409 #
410 # Enable or disable unlimited crypto
411 #
412 AC_ARG_ENABLE(unlimited-crypto, [AS_HELP_STRING([--enable-unlimited-crypto],
413 [Enable unlimited crypto policy @<:@disabled@:>@])],,
414 [enable_unlimited_crypto=no])
415 if test "x$enable_unlimited_crypto" = "xyes"; then
416 UNLIMITED_CRYPTO=true
417 else
418 UNLIMITED_CRYPTO=false
419 fi
420 AC_SUBST(UNLIMITED_CRYPTO)
421
422 ###############################################################################
423 #
424 # Enable or disable the elliptic curve crypto implementation
425 #
426 AC_DEFUN_ONCE([JDKOPT_DETECT_INTREE_EC],
427 [
428 AC_MSG_CHECKING([if elliptic curve crypto implementation is present])
429
430 if test -d "${SRC_ROOT}/jdk/src/share/native/sun/security/ec/impl"; then
431 ENABLE_INTREE_EC=yes
432 AC_MSG_RESULT([yes])
433 else
434 ENABLE_INTREE_EC=no
435 AC_MSG_RESULT([no])
436 fi
437
438 AC_SUBST(ENABLE_INTREE_EC)
439 ])
440
441 ###############################################################################
442 #
443 # --enable-rmiconnector-iiop
444 #
445 AC_ARG_ENABLE(rmiconnector-iiop, [AS_HELP_STRING([--enable-rmiconnector-iiop],
446 [enable the JMX RMIConnector iiop transport @<:@disabled@:>@])])
447 if test "x$enable_rmiconnector_iiop" = "xyes"; then
448 RMICONNECTOR_IIOP=true
449 else
450 RMICONNECTOR_IIOP=false
451 fi
452 AC_SUBST(RMICONNECTOR_IIOP)
453
454 ###############################################################################
455 #
456 # Compress jars
457 #
458 COMPRESS_JARS=false
459
460 AC_SUBST(COMPRESS_JARS)
461 ])
462
463 ###############################################################################
464 #
465 # Setup version numbers
466 #
467 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VERSION_NUMBERS],
468 [
469 # Source the version numbers
470 . $AUTOCONF_DIR/version-numbers
471
472 # Get the settings from parameters
473 AC_ARG_WITH(milestone, [AS_HELP_STRING([--with-milestone],
474 [Set milestone value for build @<:@internal@:>@])])
475 if test "x$with_milestone" = xyes; then
476 AC_MSG_ERROR([Milestone must have a value])
477 elif test "x$with_milestone" != x; then
478 MILESTONE="$with_milestone"
479 fi
480 if test "x$MILESTONE" = x; then
481 MILESTONE=internal
482 fi
483
484 AC_ARG_WITH(update-version, [AS_HELP_STRING([--with-update-version],
485 [Set update version value for build @<:@b00@:>@])])
486 if test "x$with_update_version" = xyes; then
487 AC_MSG_ERROR([Update version must have a value])
488 elif test "x$with_update_version" != x; then
489 JDK_UPDATE_VERSION="$with_update_version"
490 # On macosx 10.7, it's not possible to set --with-update-version=0X due
491 # to a bug in expr (which reduces it to just X). To work around this, we
492 # always add a 0 to one digit update versions.
493 if test "${#JDK_UPDATE_VERSION}" = "1"; then
494 JDK_UPDATE_VERSION="0${JDK_UPDATE_VERSION}"
495 fi
496 fi
497
498 AC_ARG_WITH(user-release-suffix, [AS_HELP_STRING([--with-user-release-suffix],
499 [Add a custom string to the version string if build number is not set.@<:@username_builddateb00@:>@])])
500 if test "x$with_user_release_suffix" = xyes; then
501 AC_MSG_ERROR([Release suffix must have a value])
502 elif test "x$with_user_release_suffix" != x; then
503 USER_RELEASE_SUFFIX="$with_user_release_suffix"
504 fi
505
506 AC_ARG_WITH(build-number, [AS_HELP_STRING([--with-build-number],
507 [Set build number value for build @<:@b00@:>@])])
508 if test "x$with_build_number" = xyes; then
509 AC_MSG_ERROR([Build number must have a value])
510 elif test "x$with_build_number" != x; then
511 JDK_BUILD_NUMBER="$with_build_number"
512 fi
513 # Define default USER_RELEASE_SUFFIX if BUILD_NUMBER and USER_RELEASE_SUFFIX are not set
514 if test "x$JDK_BUILD_NUMBER" = x; then
515 JDK_BUILD_NUMBER=b00
516 if test "x$USER_RELEASE_SUFFIX" = x; then
517 BUILD_DATE=`date '+%Y_%m_%d_%H_%M'`
518 # Avoid [:alnum:] since it depends on the locale.
519 CLEAN_USERNAME=`echo "$USER" | $TR -d -c 'abcdefghijklmnopqrstuvqxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789'`
520 USER_RELEASE_SUFFIX=`echo "${CLEAN_USERNAME}_${BUILD_DATE}" | $TR 'ABCDEFGHIJKLMNOPQRSTUVWXYZ' 'abcdefghijklmnopqrstuvwxyz'`
521 fi
522 fi
523
524 # Now set the JDK version, milestone, build number etc.
525 AC_SUBST(USER_RELEASE_SUFFIX)
526 AC_SUBST(JDK_MAJOR_VERSION)
527 AC_SUBST(JDK_MINOR_VERSION)
528 AC_SUBST(JDK_MICRO_VERSION)
529 AC_SUBST(JDK_UPDATE_VERSION)
530 AC_SUBST(JDK_BUILD_NUMBER)
531 AC_SUBST(MILESTONE)
532 AC_SUBST(LAUNCHER_NAME)
533 AC_SUBST(PRODUCT_NAME)
534 AC_SUBST(PRODUCT_SUFFIX)
535 AC_SUBST(JDK_RC_PLATFORM_NAME)
536 AC_SUBST(COMPANY_NAME)
537 AC_SUBST(MACOSX_BUNDLE_NAME_BASE)
538 AC_SUBST(MACOSX_BUNDLE_ID_BASE)
539
540 COPYRIGHT_YEAR=`date +'%Y'`
541 AC_SUBST(COPYRIGHT_YEAR)
542
543 if test "x$JDK_UPDATE_VERSION" != x; then
544 JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}_${JDK_UPDATE_VERSION}"
545 else
546 JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}"
547 fi
548 AC_SUBST(JDK_VERSION)
549
550 COOKED_BUILD_NUMBER=`$ECHO $JDK_BUILD_NUMBER | $SED -e 's/^b//' -e 's/^0//'`
551 AC_SUBST(COOKED_BUILD_NUMBER)
552 ])
553
554 AC_DEFUN_ONCE([JDKOPT_SETUP_BUILD_TWEAKS],
555 [
556 HOTSPOT_MAKE_ARGS="$HOTSPOT_TARGET"
557 AC_SUBST(HOTSPOT_MAKE_ARGS)
558
559 # The name of the Service Agent jar.
560 SALIB_NAME="${LIBRARY_PREFIX}saproc${SHARED_LIBRARY_SUFFIX}"
561 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
562 SALIB_NAME="${LIBRARY_PREFIX}sawindbg${SHARED_LIBRARY_SUFFIX}"
563 fi
564 AC_SUBST(SALIB_NAME)
565 ])
566
567 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_SYMBOLS],
568 [
569 #
570 # ENABLE_DEBUG_SYMBOLS
571 # This must be done after the toolchain is setup, since we're looking at objcopy.
572 #
573 AC_ARG_ENABLE([debug-symbols],
574 [AS_HELP_STRING([--disable-debug-symbols],[disable generation of debug symbols @<:@enabled@:>@])])
575
576 AC_MSG_CHECKING([if we should generate debug symbols])
577
578 if test "x$enable_debug_symbols" = "xyes" && test "x$OBJCOPY" = x; then
579 # explicit enabling of enable-debug-symbols and can't find objcopy
580 # this is an error
581 AC_MSG_ERROR([Unable to find objcopy, cannot enable debug-symbols])
582 fi
583
584 if test "x$enable_debug_symbols" = "xyes"; then
585 ENABLE_DEBUG_SYMBOLS=true
586 elif test "x$enable_debug_symbols" = "xno"; then
587 ENABLE_DEBUG_SYMBOLS=false
588 else
589 # Default is on if objcopy is found
590 if test "x$OBJCOPY" != x; then
591 ENABLE_DEBUG_SYMBOLS=true
592 # MacOS X and Windows don't use objcopy but default is on for those OSes
593 elif test "x$OPENJDK_TARGET_OS" = xmacosx || test "x$OPENJDK_TARGET_OS" = xwindows; then
594 ENABLE_DEBUG_SYMBOLS=true
595 else
596 ENABLE_DEBUG_SYMBOLS=false
597 fi
598 fi
599
600 AC_MSG_RESULT([$ENABLE_DEBUG_SYMBOLS])
601
602 #
603 # ZIP_DEBUGINFO_FILES
604 #
605 AC_MSG_CHECKING([if we should zip debug-info files])
606 AC_ARG_ENABLE([zip-debug-info],
607 [AS_HELP_STRING([--disable-zip-debug-info],[disable zipping of debug-info files @<:@enabled@:>@])],
608 [enable_zip_debug_info="${enableval}"], [enable_zip_debug_info="yes"])
609 AC_MSG_RESULT([${enable_zip_debug_info}])
610
611 if test "x${enable_zip_debug_info}" = "xno"; then
612 ZIP_DEBUGINFO_FILES=false
613 else
614 ZIP_DEBUGINFO_FILES=true
615 fi
616
617 AC_SUBST(ENABLE_DEBUG_SYMBOLS)
618 AC_SUBST(ZIP_DEBUGINFO_FILES)
619 ])