1 #
2 # Copyright (c) 2011, 2017, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
27 # Converts autoconf style CPU name to OpenJDK style, into
28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
30 [
31 # First argument is the cpu name from the trip/quad
32 case "$1" in
33 x86_64)
34 VAR_CPU=x86_64
35 VAR_CPU_ARCH=x86
36 VAR_CPU_BITS=64
37 VAR_CPU_ENDIAN=little
38 ;;
39 i?86)
40 VAR_CPU=x86
41 VAR_CPU_ARCH=x86
42 VAR_CPU_BITS=32
43 VAR_CPU_ENDIAN=little
44 ;;
45 alpha*)
46 VAR_CPU=alpha
47 VAR_CPU_ARCH=alpha
48 VAR_CPU_BITS=64
49 VAR_CPU_ENDIAN=little
50 ;;
51 arm*)
52 VAR_CPU=arm
53 VAR_CPU_ARCH=arm
54 VAR_CPU_BITS=32
55 VAR_CPU_ENDIAN=little
56 ;;
57 aarch64)
58 VAR_CPU=aarch64
59 VAR_CPU_ARCH=aarch64
60 VAR_CPU_BITS=64
61 VAR_CPU_ENDIAN=little
62 ;;
63 m68k)
64 VAR_CPU=m68k
65 VAR_CPU_ARCH=m68k
66 VAR_CPU_BITS=32
67 VAR_CPU_ENDIAN=big
68 ;;
69 mips)
70 VAR_CPU=mips
71 VAR_CPU_ARCH=mips
72 VAR_CPU_BITS=32
73 VAR_CPU_ENDIAN=big
74 ;;
75 mipsel)
76 VAR_CPU=mipsel
77 VAR_CPU_ARCH=mipsel
78 VAR_CPU_BITS=32
79 VAR_CPU_ENDIAN=little
80 ;;
81 mips64)
82 VAR_CPU=mips64
83 VAR_CPU_ARCH=mips64
84 VAR_CPU_BITS=64
85 VAR_CPU_ENDIAN=big
86 ;;
87 mips64el)
88 VAR_CPU=mips64el
89 VAR_CPU_ARCH=mips64el
90 VAR_CPU_BITS=64
91 VAR_CPU_ENDIAN=little
92 ;;
93 powerpc)
94 VAR_CPU=ppc
95 VAR_CPU_ARCH=ppc
96 VAR_CPU_BITS=32
97 VAR_CPU_ENDIAN=big
98 ;;
99 powerpc64)
100 VAR_CPU=ppc64
101 VAR_CPU_ARCH=ppc
102 VAR_CPU_BITS=64
103 VAR_CPU_ENDIAN=big
104 ;;
105 powerpc64le)
106 VAR_CPU=ppc64le
107 VAR_CPU_ARCH=ppc
108 VAR_CPU_BITS=64
109 VAR_CPU_ENDIAN=little
110 ;;
111 s390)
112 VAR_CPU=s390
113 VAR_CPU_ARCH=s390
114 VAR_CPU_BITS=32
115 VAR_CPU_ENDIAN=big
116 ;;
117 s390x)
118 VAR_CPU=s390x
119 VAR_CPU_ARCH=s390
120 VAR_CPU_BITS=64
121 VAR_CPU_ENDIAN=big
122 ;;
123 sh*eb)
124 VAR_CPU=sh
125 VAR_CPU_ARCH=sh
126 VAR_CPU_BITS=32
127 VAR_CPU_ENDIAN=big
128 ;;
129 sh*)
130 VAR_CPU=sh
131 VAR_CPU_ARCH=sh
132 VAR_CPU_BITS=32
133 VAR_CPU_ENDIAN=little
134 ;;
135 sparc)
136 VAR_CPU=sparc
137 VAR_CPU_ARCH=sparc
138 VAR_CPU_BITS=32
139 VAR_CPU_ENDIAN=big
140 ;;
141 sparcv9|sparc64)
142 VAR_CPU=sparcv9
143 VAR_CPU_ARCH=sparc
144 VAR_CPU_BITS=64
145 VAR_CPU_ENDIAN=big
146 ;;
147 *)
148 AC_MSG_ERROR([unsupported cpu $1])
149 ;;
150 esac
151 ])
152
153 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
154 # Converts autoconf style OS name to OpenJDK style, into
155 # VAR_OS, VAR_OS_TYPE and VAR_OS_ENV.
156 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
157 [
158 case "$1" in
159 *linux*)
160 VAR_OS=linux
161 VAR_OS_TYPE=unix
162 ;;
163 *solaris*)
164 VAR_OS=solaris
165 VAR_OS_TYPE=unix
166 ;;
167 *darwin*)
168 VAR_OS=macosx
169 VAR_OS_TYPE=unix
170 ;;
171 *bsd*)
172 VAR_OS=bsd
173 VAR_OS_TYPE=unix
174 ;;
175 *cygwin*)
176 VAR_OS=windows
177 VAR_OS_ENV=windows.cygwin
178 ;;
179 *mingw*)
180 VAR_OS=windows
181 VAR_OS_ENV=windows.msys
182 ;;
183 *aix*)
184 VAR_OS=aix
185 VAR_OS_TYPE=unix
186 ;;
187 *)
188 AC_MSG_ERROR([unsupported operating system $1])
189 ;;
190 esac
191 ])
192
193 # Expects $host_os $host_cpu $build_os and $build_cpu
194 # and $with_target_bits to have been setup!
195 #
196 # Translate the standard triplet(quadruplet) definition
197 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
198 # OPENJDK_BUILD_OS, etc.
199 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
200 [
201 # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
202 # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
203 # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
204 # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
205 OPENJDK_TARGET_AUTOCONF_NAME="$host"
206 OPENJDK_BUILD_AUTOCONF_NAME="$build"
207 AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
208 AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
209
210 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
211 PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
212 PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
213 # ..and setup our own variables. (Do this explicitly to facilitate searching)
214 OPENJDK_BUILD_OS="$VAR_OS"
215 if test "x$VAR_OS_TYPE" != x; then
216 OPENJDK_BUILD_OS_TYPE="$VAR_OS_TYPE"
217 else
218 OPENJDK_BUILD_OS_TYPE="$VAR_OS"
219 fi
220 if test "x$VAR_OS_ENV" != x; then
221 OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
222 else
223 OPENJDK_BUILD_OS_ENV="$VAR_OS"
224 fi
225 OPENJDK_BUILD_CPU="$VAR_CPU"
226 OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
227 OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
228 OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
229 AC_SUBST(OPENJDK_BUILD_OS)
230 AC_SUBST(OPENJDK_BUILD_OS_TYPE)
231 AC_SUBST(OPENJDK_BUILD_OS_ENV)
232 AC_SUBST(OPENJDK_BUILD_CPU)
233 AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
234 AC_SUBST(OPENJDK_BUILD_CPU_BITS)
235 AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
236
237 AC_MSG_CHECKING([openjdk-build os-cpu])
238 AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
239
240 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
241 PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
242 PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
243 # ... and setup our own variables. (Do this explicitly to facilitate searching)
244 OPENJDK_TARGET_OS="$VAR_OS"
245 if test "x$VAR_OS_TYPE" != x; then
246 OPENJDK_TARGET_OS_TYPE="$VAR_OS_TYPE"
247 else
248 OPENJDK_TARGET_OS_TYPE="$VAR_OS"
249 fi
250 if test "x$VAR_OS_ENV" != x; then
251 OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
252 else
253 OPENJDK_TARGET_OS_ENV="$VAR_OS"
254 fi
255 OPENJDK_TARGET_CPU="$VAR_CPU"
256 OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
257 OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
258 OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
259 AC_SUBST(OPENJDK_TARGET_OS)
260 AC_SUBST(OPENJDK_TARGET_OS_TYPE)
261 AC_SUBST(OPENJDK_TARGET_OS_ENV)
262 AC_SUBST(OPENJDK_TARGET_CPU)
263 AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
264 AC_SUBST(OPENJDK_TARGET_CPU_BITS)
265 AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
266
267 AC_MSG_CHECKING([openjdk-target os-cpu])
268 AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
269 ])
270
271 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
272 # accordingly. Must be done after setting up build and target system, but before
273 # doing anything else with these values.
274 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
275 [
276 AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
277 [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
278
279 # We have three types of compiles:
280 # native == normal compilation, target system == build system
281 # cross == traditional cross compilation, target system != build system; special toolchain needed
282 # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
283 #
284 if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
285 # We're doing a proper cross-compilation
286 COMPILE_TYPE="cross"
287 else
288 COMPILE_TYPE="native"
289 fi
290
291 if test "x$with_target_bits" != x; then
292 if test "x$COMPILE_TYPE" = "xcross"; then
293 AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
294 fi
295
296 if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
297 # A reduced build is requested
298 COMPILE_TYPE="reduced"
299 OPENJDK_TARGET_CPU_BITS=32
300 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
301 OPENJDK_TARGET_CPU=x86
302 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
303 OPENJDK_TARGET_CPU=sparc
304 else
305 AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
306 fi
307 elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
308 AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
309 elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
310 AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
311 else
312 AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
313 fi
314 fi
315 AC_SUBST(COMPILE_TYPE)
316
317 AC_MSG_CHECKING([compilation type])
318 AC_MSG_RESULT([$COMPILE_TYPE])
319 ])
320
321 # Setup the legacy variables, for controlling the old makefiles.
322 #
323 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
324 [
325 PLATFORM_SETUP_LEGACY_VARS_HELPER([TARGET])
326 PLATFORM_SETUP_LEGACY_VARS_HELPER([BUILD])
327 ])
328
329 # $1 - Either TARGET or BUILD to setup the variables for.
330 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS_HELPER],
331 [
332 # Also store the legacy naming of the cpu.
333 # Ie i586 and amd64 instead of x86 and x86_64
334 OPENJDK_$1_CPU_LEGACY="$OPENJDK_$1_CPU"
335 if test "x$OPENJDK_$1_CPU" = xx86; then
336 OPENJDK_$1_CPU_LEGACY="i586"
337 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
338 # On all platforms except MacOSX replace x86_64 with amd64.
339 OPENJDK_$1_CPU_LEGACY="amd64"
340 elif test "x$OPENJDK_$1_CPU" = xalpha; then
341 # Avoid name collisions with variables named alpha
342 OPENJDK_$1_CPU_LEGACY="_alpha_"
343 elif test "x$OPENJDK_$1_CPU" = xsh; then
344 # Avoid name collisions with variables named sh
345 OPENJDK_$1_CPU_LEGACY="_sh_"
346 fi
347 AC_SUBST(OPENJDK_$1_CPU_LEGACY)
348
349 # And the second legacy naming of the cpu.
350 # Ie i386 and amd64 instead of x86 and x86_64.
351 OPENJDK_$1_CPU_LEGACY_LIB="$OPENJDK_$1_CPU"
352 if test "x$OPENJDK_$1_CPU" = xx86; then
353 OPENJDK_$1_CPU_LEGACY_LIB="i386"
354 elif test "x$OPENJDK_$1_CPU" = xx86_64; then
355 OPENJDK_$1_CPU_LEGACY_LIB="amd64"
356 fi
357 AC_SUBST(OPENJDK_$1_CPU_LEGACY_LIB)
358
359 # OPENJDK_$1_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
360 # /amd64 or /sparcv9. This string is appended to some library paths, like this:
361 # /usr/lib${OPENJDK_$1_CPU_ISADIR}/libexample.so
362 OPENJDK_$1_CPU_ISADIR=""
363 if test "x$OPENJDK_$1_OS" = xsolaris; then
364 if test "x$OPENJDK_$1_CPU" = xx86_64; then
365 OPENJDK_$1_CPU_ISADIR="/amd64"
366 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
367 OPENJDK_$1_CPU_ISADIR="/sparcv9"
368 fi
369 fi
370 AC_SUBST(OPENJDK_$1_CPU_ISADIR)
371
372 # Setup OPENJDK_$1_CPU_OSARCH, which is used to set the os.arch Java system property
373 OPENJDK_$1_CPU_OSARCH="$OPENJDK_$1_CPU"
374 if test "x$OPENJDK_$1_OS" = xlinux && test "x$OPENJDK_$1_CPU" = xx86; then
375 # On linux only, we replace x86 with i386.
376 OPENJDK_$1_CPU_OSARCH="i386"
377 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
378 # On all platforms except macosx, we replace x86_64 with amd64.
379 OPENJDK_$1_CPU_OSARCH="amd64"
380 fi
381 AC_SUBST(OPENJDK_$1_CPU_OSARCH)
382
383 OPENJDK_$1_CPU_JLI="$OPENJDK_$1_CPU"
384 if test "x$OPENJDK_$1_CPU" = xx86; then
385 OPENJDK_$1_CPU_JLI="i386"
386 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
387 # On all platforms except macosx, we replace x86_64 with amd64.
388 OPENJDK_$1_CPU_JLI="amd64"
389 fi
390
391 # The new version string in JDK 9 also defined new naming of OS and ARCH for bundles
392 # Macosx is osx and x86_64 is x64
393 if test "x$OPENJDK_$1_OS" = xmacosx; then
394 OPENJDK_$1_OS_BUNDLE="osx"
395 else
396 OPENJDK_$1_OS_BUNDLE="$OPENJDK_TARGET_OS"
397 fi
398 if test "x$OPENJDK_$1_CPU" = xx86_64; then
399 OPENJDK_$1_CPU_BUNDLE="x64"
400 else
401 OPENJDK_$1_CPU_BUNDLE="$OPENJDK_$1_CPU"
402 fi
403 OPENJDK_$1_BUNDLE_PLATFORM="${OPENJDK_$1_OS_BUNDLE}-${OPENJDK_$1_CPU_BUNDLE}"
404 AC_SUBST(OPENJDK_$1_BUNDLE_PLATFORM)
405
406 if test "x$OPENJDK_$1_CPU_BITS" = x64; then
407 # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
408 # unpack200.exe. This variable is used in
409 # FLAGS_SETUP_COMPILER_FLAGS_FOR_JDK_HELPER.
410 if test "x$OPENJDK_$1_OS" = xlinux || test "x$OPENJDK_$1_OS" = xmacosx; then
411 OPENJDK_$1_ADD_LP64="-D_LP64=1"
412 fi
413 fi
414
415 if test "x$COMPILE_TYPE" = "xcross"; then
416 # FIXME: ... or should this include reduced builds..?
417 DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_$1_CPU_LEGACY"
418 else
419 DEFINE_CROSS_COMPILE_ARCH=""
420 fi
421 AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
422
423 # Convert openjdk platform names to hotspot names
424
425 HOTSPOT_$1_OS=${OPENJDK_$1_OS}
426 if test "x$OPENJDK_$1_OS" = xmacosx; then
427 HOTSPOT_$1_OS=bsd
428 fi
429 AC_SUBST(HOTSPOT_$1_OS)
430
431 HOTSPOT_$1_OS_TYPE=${OPENJDK_$1_OS_TYPE}
432 if test "x$OPENJDK_$1_OS_TYPE" = xunix; then
433 HOTSPOT_$1_OS_TYPE=posix
434 fi
435 AC_SUBST(HOTSPOT_$1_OS_TYPE)
436
437 HOTSPOT_$1_CPU=${OPENJDK_$1_CPU}
438 if test "x$OPENJDK_$1_CPU" = xx86; then
439 HOTSPOT_$1_CPU=x86_32
440 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
441 HOTSPOT_$1_CPU=sparc
442 elif test "x$OPENJDK_$1_CPU" = xppc64; then
443 HOTSPOT_$1_CPU=ppc_64
444 elif test "x$OPENJDK_$1_CPU" = xppc64le; then
445 HOTSPOT_$1_CPU=ppc_64
446 fi
447 AC_SUBST(HOTSPOT_$1_CPU)
448
449 # This is identical with OPENJDK_*, but define anyway for consistency.
450 HOTSPOT_$1_CPU_ARCH=${OPENJDK_$1_CPU_ARCH}
451 AC_SUBST(HOTSPOT_$1_CPU_ARCH)
452
453 # Setup HOTSPOT_$1_CPU_DEFINE
454 if test "x$OPENJDK_$1_CPU" = xx86; then
455 HOTSPOT_$1_CPU_DEFINE=IA32
456 elif test "x$OPENJDK_$1_CPU" = xx86_64; then
457 HOTSPOT_$1_CPU_DEFINE=AMD64
458 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
459 HOTSPOT_$1_CPU_DEFINE=SPARC
460 elif test "x$OPENJDK_$1_CPU" = xaarch64; then
461 HOTSPOT_$1_CPU_DEFINE=AARCH64
462 elif test "x$OPENJDK_$1_CPU" = xppc64; then
463 HOTSPOT_$1_CPU_DEFINE=PPC64
464 elif test "x$OPENJDK_$1_CPU" = xppc64le; then
465 HOTSPOT_$1_CPU_DEFINE=PPC64
466
467 # The cpu defines below are for zero, we don't support them directly.
468 elif test "x$OPENJDK_$1_CPU" = xsparc; then
469 HOTSPOT_$1_CPU_DEFINE=SPARC
470 elif test "x$OPENJDK_$1_CPU" = xppc; then
471 HOTSPOT_$1_CPU_DEFINE=PPC32
472 elif test "x$OPENJDK_$1_CPU" = xs390; then
473 HOTSPOT_$1_CPU_DEFINE=S390
474 elif test "x$OPENJDK_$1_CPU" = xs390x; then
475 HOTSPOT_$1_CPU_DEFINE=S390
476 elif test "x$OPENJDK_$1_CPU" != x; then
477 HOTSPOT_$1_CPU_DEFINE=$(echo $OPENJDK_$1_CPU | tr a-z A-Z)
478 fi
479 AC_SUBST(HOTSPOT_$1_CPU_DEFINE)
480
481 # For historical reasons, the OS include directories have odd names.
482 OPENJDK_$1_OS_INCLUDE_SUBDIR="$OPENJDK_TARGET_OS"
483 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
484 OPENJDK_$1_OS_INCLUDE_SUBDIR="win32"
485 elif test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
486 OPENJDK_$1_OS_INCLUDE_SUBDIR="darwin"
487 fi
488 AC_SUBST(OPENJDK_$1_OS_INCLUDE_SUBDIR)
489 ])
490
491 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
492 [
493 if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
494 RELEASE_FILE_OS_NAME=SunOS
495 fi
496 if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
497 RELEASE_FILE_OS_NAME=Linux
498 fi
499 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
500 RELEASE_FILE_OS_NAME=Windows
501 fi
502 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
503 RELEASE_FILE_OS_NAME="Darwin"
504 fi
505 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
506 RELEASE_FILE_OS_NAME="AIX"
507 fi
508 RELEASE_FILE_OS_ARCH=${OPENJDK_TARGET_CPU}
509
510 AC_SUBST(RELEASE_FILE_OS_NAME)
511 AC_SUBST(RELEASE_FILE_OS_ARCH)
512 ])
513
514 AC_DEFUN([PLATFORM_SET_MODULE_TARGET_OS_VALUES],
515 [
516 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
517 OPENJDK_MODULE_TARGET_OS_NAME="macos"
518 else
519 OPENJDK_MODULE_TARGET_OS_NAME="$OPENJDK_TARGET_OS"
520 fi
521
522 if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
523 OPENJDK_MODULE_TARGET_OS_ARCH="amd64"
524 else
525 OPENJDK_MODULE_TARGET_OS_ARCH="$OPENJDK_TARGET_CPU"
526 fi
527
528 OPENJDK_MODULE_TARGET_PLATFORM="${OPENJDK_MODULE_TARGET_OS_NAME}-${OPENJDK_MODULE_TARGET_OS_ARCH}"
529 AC_SUBST(OPENJDK_MODULE_TARGET_PLATFORM)
530 ])
531
532 #%%% Build and target systems %%%
533 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
534 [
535 # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
536 # is confusing; it assumes you are cross-compiling a cross-compiler (!) and "target" is thus the target of the
537 # product you're building. The target of this build is called "host". Since this is confusing to most people, we
538 # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
539 # to use the configure naming style.
540 AC_CANONICAL_BUILD
541 AC_CANONICAL_HOST
542 AC_CANONICAL_TARGET
543
544 PLATFORM_EXTRACT_TARGET_AND_BUILD
545 PLATFORM_SETUP_TARGET_CPU_BITS
546 PLATFORM_SET_MODULE_TARGET_OS_VALUES
547 PLATFORM_SET_RELEASE_FILE_OS_VALUES
548 PLATFORM_SETUP_LEGACY_VARS
549 ])
550
551 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
552 [
553 ###############################################################################
554
555 # Note that this is the build platform OS version!
556
557 OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
558 OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
559 OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
560 OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
561 AC_SUBST(OS_VERSION_MAJOR)
562 AC_SUBST(OS_VERSION_MINOR)
563 AC_SUBST(OS_VERSION_MICRO)
564 ])
565
566 # Support macro for PLATFORM_SETUP_OPENJDK_TARGET_BITS.
567 # Add -mX to various FLAGS variables.
568 AC_DEFUN([PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS],
569 [
570 # When we add flags to the "official" CFLAGS etc, we need to
571 # keep track of these additions in ADDED_CFLAGS etc. These
572 # will later be checked to make sure only controlled additions
573 # have been made to CFLAGS etc.
574 ADDED_CFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
575 ADDED_CXXFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
576 ADDED_LDFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
577
578 CFLAGS="${CFLAGS}${ADDED_CFLAGS}"
579 CXXFLAGS="${CXXFLAGS}${ADDED_CXXFLAGS}"
580 LDFLAGS="${LDFLAGS}${ADDED_LDFLAGS}"
581
582 CFLAGS_JDK="${CFLAGS_JDK}${ADDED_CFLAGS}"
583 CXXFLAGS_JDK="${CXXFLAGS_JDK}${ADDED_CXXFLAGS}"
584 LDFLAGS_JDK="${LDFLAGS_JDK}${ADDED_LDFLAGS}"
585
586 JVM_CFLAGS="$JVM_CFLAGS $ADDED_CFLAGS"
587 JVM_LDFLAGS="$JVM_LDFLAGS $ADDED_LDFLAGS"
588 JVM_ASFLAGS="$JVM_ASFLAGS $ADDED_CFLAGS"
589 ])
590
591 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
592 [
593 ###############################################################################
594 #
595 # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
596 # (The JVM can use 32 or 64 bit Java pointers but that decision
597 # is made at runtime.)
598 #
599
600 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xaix; then
601 # Always specify -m flag on Solaris
602 # And -q on AIX because otherwise the compiler produces 32-bit objects by default
603 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
604 elif test "x$COMPILE_TYPE" = xreduced; then
605 if test "x$OPENJDK_TARGET_OS_TYPE" = xunix; then
606 # Specify -m if running reduced on unix platforms
607 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
608 fi
609 fi
610 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
611 JVM_CFLAGS="$JVM_CFLAGS ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
612 JVM_LDFLAGS="$JVM_LDFLAGS ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
613 JVM_ASFLAGS="$JVM_ASFLAGS ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
614 fi
615
616 # Make compilation sanity check
617 AC_CHECK_HEADERS([stdio.h], , [
618 AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
619 if test "x$COMPILE_TYPE" = xreduced; then
620 HELP_MSG_MISSING_DEPENDENCY([reduced])
621 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
622 elif test "x$COMPILE_TYPE" = xcross; then
623 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
624 fi
625 AC_MSG_ERROR([Cannot continue.])
626 ])
627
628 AC_CHECK_SIZEOF([int *], [1111])
629
630 # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
631 if test "x$ac_cv_sizeof_int_p" = x; then
632 # The test failed, lets stick to the assumed value.
633 AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
634 else
635 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
636
637 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
638 # This situation may happen on 64-bit platforms where the compiler by default only generates 32-bit objects
639 # Let's try to implicitely set the compilers target architecture and retry the test
640 AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS).])
641 AC_MSG_NOTICE([Retrying with platforms compiler target bits flag to ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}])
642 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
643
644 # We have to unset 'ac_cv_sizeof_int_p' first, otherwise AC_CHECK_SIZEOF will use the previously cached value!
645 unset ac_cv_sizeof_int_p
646 # And we have to undef the definition of SIZEOF_INT_P in confdefs.h by the previous invocation of AC_CHECK_SIZEOF
647 cat >>confdefs.h <<_ACEOF
648 #undef SIZEOF_INT_P
649 _ACEOF
650
651 AC_CHECK_SIZEOF([int *], [1111])
652
653 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
654
655 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
656 AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
657 if test "x$COMPILE_TYPE" = xreduced; then
658 HELP_MSG_MISSING_DEPENDENCY([reduced])
659 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
660 elif test "x$COMPILE_TYPE" = xcross; then
661 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
662 fi
663 AC_MSG_ERROR([Cannot continue.])
664 fi
665 fi
666 fi
667
668 AC_MSG_CHECKING([for target address size])
669 AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
670 ])
671
672 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
673 [
674 ###############################################################################
675 #
676 # Is the target little of big endian?
677 #
678 AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
679
680 if test "x$ENDIAN" = xuniversal_endianness; then
681 AC_MSG_ERROR([Building with both big and little endianness is not supported])
682 fi
683 if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
684 AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
685 fi
686 ])