1 #
   2 # Copyright (c) 2011, 2019, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 ################################################################################
  27 #
  28 # Setup flags for C/C++ compiler
  29 #
  30 
  31 ###############################################################################
  32 #
  33 # How to compile shared libraries.
  34 #
  35 AC_DEFUN([FLAGS_SETUP_SHARED_LIBS],
  36 [
  37   if test "x$TOOLCHAIN_TYPE" = xgcc; then
  38     C_FLAG_REORDER=''
  39 
  40     # Default works for linux, might work on other platforms as well.
  41     SHARED_LIBRARY_FLAGS='-shared'
  42     SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
  43     SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
  44     SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
  45     SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
  46 
  47   elif test "x$TOOLCHAIN_TYPE" = xclang; then
  48     C_FLAG_REORDER=''
  49 
  50     if test "x$OPENJDK_TARGET_OS" = xmacosx; then
  51       # Linking is different on MacOSX
  52       SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0"
  53       SET_EXECUTABLE_ORIGIN='-Wl,-rpath,@loader_path$(or [$]1,/.)'
  54       SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
  55       SET_SHARED_LIBRARY_NAME='-Wl,-install_name,@rpath/[$]1'
  56       SET_SHARED_LIBRARY_MAPFILE='-Wl,-exported_symbols_list,[$]1'
  57 
  58     else
  59       # Default works for linux, might work on other platforms as well.
  60       SHARED_LIBRARY_FLAGS='-shared'
  61       SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
  62       SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
  63       SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
  64 
  65       # arm specific settings
  66       if test "x$OPENJDK_TARGET_CPU" = "xarm"; then
  67         # '-Wl,-z,origin' isn't used on arm.
  68         SET_SHARED_LIBRARY_ORIGIN='-Wl,-rpath,\$$$$ORIGIN[$]1'
  69       else
  70         SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
  71       fi
  72     fi
  73 
  74   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
  75     C_FLAG_REORDER='-xF'
  76     SHARED_LIBRARY_FLAGS="-G"
  77     SET_EXECUTABLE_ORIGIN='-R\$$ORIGIN[$]1'
  78     SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
  79     SET_SHARED_LIBRARY_NAME='-h [$]1'
  80     SET_SHARED_LIBRARY_MAPFILE='-M[$]1'
  81 
  82   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
  83     C_FLAG_REORDER=''
  84     SHARED_LIBRARY_FLAGS="-qmkshrobj -bM:SRE -bnoentry"
  85     SET_EXECUTABLE_ORIGIN=""
  86     SET_SHARED_LIBRARY_ORIGIN=''
  87     SET_SHARED_LIBRARY_NAME=''
  88     SET_SHARED_LIBRARY_MAPFILE=''
  89 
  90   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
  91     C_FLAG_REORDER=''
  92     SHARED_LIBRARY_FLAGS="-dll"
  93     SET_EXECUTABLE_ORIGIN=''
  94     SET_SHARED_LIBRARY_ORIGIN=''
  95     SET_SHARED_LIBRARY_NAME=''
  96     SET_SHARED_LIBRARY_MAPFILE='-def:[$]1'
  97   fi
  98 
  99   AC_SUBST(C_FLAG_REORDER)
 100   AC_SUBST(SET_EXECUTABLE_ORIGIN)
 101   AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
 102   AC_SUBST(SET_SHARED_LIBRARY_NAME)
 103   AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
 104   AC_SUBST(SHARED_LIBRARY_FLAGS)
 105 ])
 106 
 107 AC_DEFUN([FLAGS_SETUP_DEBUG_SYMBOLS],
 108 [
 109   # By default don't set any specific assembler debug
 110   # info flags for toolchains unless we know they work.
 111   # See JDK-8207057.
 112   ASFLAGS_DEBUG_SYMBOLS=""
 113   # Debug symbols
 114   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 115     CFLAGS_DEBUG_SYMBOLS="-g"
 116     ASFLAGS_DEBUG_SYMBOLS="-g"
 117   elif test "x$TOOLCHAIN_TYPE" = xclang; then
 118     CFLAGS_DEBUG_SYMBOLS="-g"
 119     ASFLAGS_DEBUG_SYMBOLS="-g"
 120   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 121     # -g0 enables debug symbols without disabling inlining.
 122     CFLAGS_DEBUG_SYMBOLS="-g0 -xs"
 123   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 124     CFLAGS_DEBUG_SYMBOLS="-g"
 125   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 126     CFLAGS_DEBUG_SYMBOLS="-Z7 -d2Zi+"
 127   fi
 128 
 129   AC_SUBST(CFLAGS_DEBUG_SYMBOLS)
 130   AC_SUBST(ASFLAGS_DEBUG_SYMBOLS)
 131 ])
 132 
 133 AC_DEFUN([FLAGS_SETUP_WARNINGS],
 134 [
 135   AC_ARG_ENABLE([warnings-as-errors], [AS_HELP_STRING([--disable-warnings-as-errors],
 136       [do not consider native warnings to be an error @<:@enabled@:>@])])
 137 
 138   # Set default value.
 139   if test "x$TOOLCHAIN_TYPE" = xxlc; then
 140     WARNINGS_AS_ERRORS=false
 141   else
 142     WARNINGS_AS_ERRORS=true
 143   fi
 144 
 145   AC_MSG_CHECKING([if native warnings are errors])
 146   if test "x$enable_warnings_as_errors" = "xyes"; then
 147     AC_MSG_RESULT([yes (explicitly set)])
 148     WARNINGS_AS_ERRORS=true
 149   elif test "x$enable_warnings_as_errors" = "xno"; then
 150     AC_MSG_RESULT([no (explicitly set)])
 151     WARNINGS_AS_ERRORS=false
 152   elif test "x$enable_warnings_as_errors" = "x"; then
 153     AC_MSG_RESULT([${WARNINGS_AS_ERRORS} (default)])
 154   else
 155     AC_MSG_ERROR([--enable-warnings-as-errors accepts no argument])
 156   fi
 157 
 158   AC_SUBST(WARNINGS_AS_ERRORS)
 159 
 160   case "${TOOLCHAIN_TYPE}" in
 161     microsoft)
 162       DISABLE_WARNING_PREFIX="-wd"
 163       CFLAGS_WARNINGS_ARE_ERRORS="-WX"
 164       ;;
 165     solstudio)
 166       DISABLE_WARNING_PREFIX="-erroff="
 167       CFLAGS_WARNINGS_ARE_ERRORS="-errtags -errwarn=%all"
 168       ;;
 169     gcc)
 170       DISABLE_WARNING_PREFIX="-Wno-"
 171       CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
 172       # Repeate the check for the BUILD_CC and BUILD_CXX. Need to also reset
 173       # CFLAGS since any target specific flags will likely not work with the
 174       # build compiler
 175       CC_OLD="$CC"
 176       CXX_OLD="$CXX"
 177       CC="$BUILD_CC"
 178       CXX="$BUILD_CXX"
 179       CFLAGS_OLD="$CFLAGS"
 180       CFLAGS=""
 181       BUILD_CC_DISABLE_WARNING_PREFIX="-Wno-"
 182       CC="$CC_OLD"
 183       CXX="$CXX_OLD"
 184       CFLAGS="$CFLAGS_OLD"
 185       ;;
 186     clang)
 187       DISABLE_WARNING_PREFIX="-Wno-"
 188       CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
 189       ;;
 190     xlc)
 191       DISABLE_WARNING_PREFIX="-qsuppress="
 192       CFLAGS_WARNINGS_ARE_ERRORS="-qhalt=w"
 193       ;;
 194   esac
 195   AC_SUBST(DISABLE_WARNING_PREFIX)
 196   AC_SUBST(BUILD_CC_DISABLE_WARNING_PREFIX)
 197   AC_SUBST(CFLAGS_WARNINGS_ARE_ERRORS)
 198 ])
 199 
 200 AC_DEFUN([FLAGS_SETUP_QUALITY_CHECKS],
 201 [
 202   # bounds, memory and behavior checking options
 203   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 204     case $DEBUG_LEVEL in
 205     release )
 206       # no adjustment
 207       ;;
 208     fastdebug )
 209       # no adjustment
 210       ;;
 211     slowdebug )
 212       # FIXME: By adding this to C(XX)FLAGS_DEBUG_OPTIONS/JVM_CFLAGS_SYMBOLS it
 213       # get's added conditionally on whether we produce debug symbols or not.
 214       # This is most likely not really correct.
 215 
 216       # Add runtime stack smashing and undefined behavior checks.
 217       CFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
 218       CXXFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
 219 
 220       JVM_CFLAGS_SYMBOLS="$JVM_CFLAGS_SYMBOLS -fstack-protector-all --param ssp-buffer-size=1"
 221       ;;
 222     esac
 223   fi
 224 ])
 225 
 226 AC_DEFUN([FLAGS_SETUP_OPTIMIZATION],
 227 [
 228   if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 229     CC_HIGHEST="-fns -fsimple -fsingle -xbuiltin=%all -xdepend -xrestrict -xlibmil"
 230 
 231     C_O_FLAG_HIGHEST_JVM="-xO4"
 232     C_O_FLAG_DEBUG_JVM=""
 233     C_O_FLAG_SIZE=""
 234     C_O_FLAG_DEBUG=""
 235     C_O_FLAG_NONE=""
 236     if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
 237       C_O_FLAG_HIGHEST="-xO4 -Wu,-O4~yz $CC_HIGHEST"
 238       C_O_FLAG_HI="-xO4 -Wu,-O4~yz"
 239       C_O_FLAG_NORM="-xO2 -Wu,-O2~yz"
 240     elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
 241       C_O_FLAG_HIGHEST="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0 \
 242           -xprefetch=auto,explicit $CC_HIGHEST"
 243       C_O_FLAG_HI="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0"
 244       C_O_FLAG_NORM="-xO2 -Wc,-Qrm-s -Wc,-Qiselect-T0"
 245     fi
 246   elif test "x$TOOLCHAIN_TYPE" = xgcc; then
 247     C_O_FLAG_HIGHEST_JVM="-O3"
 248     C_O_FLAG_HIGHEST="-O3"
 249     C_O_FLAG_HI="-O3"
 250     C_O_FLAG_NORM="-O2"
 251     C_O_FLAG_SIZE="-Os"
 252     C_O_FLAG_DEBUG="-O0"
 253     C_O_FLAG_DEBUG_JVM="-O0"
 254     C_O_FLAG_NONE="-O0"
 255   elif test "x$TOOLCHAIN_TYPE" = xclang; then
 256     if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 257       # On MacOSX we optimize for size, something
 258       # we should do for all platforms?
 259       C_O_FLAG_HIGHEST_JVM="-Os"
 260       C_O_FLAG_HIGHEST="-Os"
 261       C_O_FLAG_HI="-Os"
 262       C_O_FLAG_NORM="-Os"
 263       C_O_FLAG_DEBUG_JVM=""
 264     else
 265       C_O_FLAG_HIGHEST_JVM="-O3"
 266       C_O_FLAG_HIGHEST="-O3"
 267       C_O_FLAG_HI="-O3"
 268       C_O_FLAG_NORM="-O2"
 269       C_O_FLAG_DEBUG_JVM="-O0"
 270     fi
 271     C_O_FLAG_SIZE="-Os"
 272     C_O_FLAG_DEBUG="-O0"
 273     C_O_FLAG_NONE="-O0"
 274   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 275     C_O_FLAG_HIGHEST_JVM="-O3 -qhot=level=1 -qinline -qinlglue"
 276     C_O_FLAG_HIGHEST="-O3 -qhot=level=1 -qinline -qinlglue"
 277     C_O_FLAG_HI="-O3 -qinline -qinlglue"
 278     C_O_FLAG_NORM="-O2"
 279     C_O_FLAG_DEBUG="-qnoopt"
 280     # FIXME: Value below not verified.
 281     C_O_FLAG_DEBUG_JVM=""
 282     C_O_FLAG_NONE="-qnoopt"
 283   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 284     C_O_FLAG_HIGHEST_JVM="-O2 -Oy-"
 285     C_O_FLAG_HIGHEST="-O2"
 286     C_O_FLAG_HI="-O1"
 287     C_O_FLAG_NORM="-O1"
 288     C_O_FLAG_DEBUG="-Od"
 289     C_O_FLAG_DEBUG_JVM=""
 290     C_O_FLAG_NONE="-Od"
 291     C_O_FLAG_SIZE="-Os"
 292   fi
 293 
 294   # Now copy to C++ flags
 295   CXX_O_FLAG_HIGHEST_JVM="$C_O_FLAG_HIGHEST_JVM"
 296   CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
 297   CXX_O_FLAG_HI="$C_O_FLAG_HI"
 298   CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
 299   CXX_O_FLAG_DEBUG="$C_O_FLAG_DEBUG"
 300   CXX_O_FLAG_DEBUG_JVM="$C_O_FLAG_DEBUG_JVM"
 301   CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
 302   CXX_O_FLAG_SIZE="$C_O_FLAG_SIZE"
 303 
 304   if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 305     # In solstudio, also add this to C (but not C++) flags...
 306     C_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST -xalias_level=basic"
 307   fi
 308 
 309   # Adjust optimization flags according to debug level.
 310   case $DEBUG_LEVEL in
 311     release )
 312       # no adjustment
 313       ;;
 314     fastdebug )
 315       # Not quite so much optimization
 316       C_O_FLAG_HI="$C_O_FLAG_NORM"
 317       CXX_O_FLAG_HI="$CXX_O_FLAG_NORM"
 318       ;;
 319     slowdebug )
 320       # Disable optimization
 321       C_O_FLAG_HIGHEST_JVM="$C_O_FLAG_DEBUG_JVM"
 322       C_O_FLAG_HIGHEST="$C_O_FLAG_DEBUG"
 323       C_O_FLAG_HI="$C_O_FLAG_DEBUG"
 324       C_O_FLAG_NORM="$C_O_FLAG_DEBUG"
 325       C_O_FLAG_SIZE="$C_O_FLAG_DEBUG"
 326       CXX_O_FLAG_HIGHEST_JVM="$CXX_O_FLAG_DEBUG_JVM"
 327       CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_DEBUG"
 328       CXX_O_FLAG_HI="$CXX_O_FLAG_DEBUG"
 329       CXX_O_FLAG_NORM="$CXX_O_FLAG_DEBUG"
 330       CXX_O_FLAG_SIZE="$CXX_O_FLAG_DEBUG"
 331       ;;
 332   esac
 333 
 334   AC_SUBST(C_O_FLAG_HIGHEST_JVM)
 335   AC_SUBST(C_O_FLAG_HIGHEST)
 336   AC_SUBST(C_O_FLAG_HI)
 337   AC_SUBST(C_O_FLAG_NORM)
 338   AC_SUBST(C_O_FLAG_NONE)
 339   AC_SUBST(C_O_FLAG_SIZE)
 340   AC_SUBST(CXX_O_FLAG_HIGHEST_JVM)
 341   AC_SUBST(CXX_O_FLAG_HIGHEST)
 342   AC_SUBST(CXX_O_FLAG_HI)
 343   AC_SUBST(CXX_O_FLAG_NORM)
 344   AC_SUBST(CXX_O_FLAG_NONE)
 345   AC_SUBST(CXX_O_FLAG_SIZE)
 346 ])
 347 
 348 AC_DEFUN([FLAGS_SETUP_CFLAGS],
 349 [
 350   ### CFLAGS
 351 
 352   FLAGS_SETUP_CFLAGS_HELPER
 353 
 354   FLAGS_OS=$OPENJDK_TARGET_OS
 355   FLAGS_OS_TYPE=$OPENJDK_TARGET_OS_TYPE
 356   FLAGS_CPU=$OPENJDK_TARGET_CPU
 357   FLAGS_CPU_ARCH=$OPENJDK_TARGET_CPU_ARCH
 358   FLAGS_CPU_BITS=$OPENJDK_TARGET_CPU_BITS
 359   FLAGS_CPU_ENDIAN=$OPENJDK_TARGET_CPU_ENDIAN
 360   FLAGS_CPU_LEGACY=$OPENJDK_TARGET_CPU_LEGACY
 361   FLAGS_CPU_LEGACY_LIB=$OPENJDK_TARGET_CPU_LEGACY_LIB
 362 
 363   FLAGS_SETUP_CFLAGS_CPU_DEP([TARGET])
 364 
 365   FLAGS_OS=$OPENJDK_BUILD_OS
 366   FLAGS_OS_TYPE=$OPENJDK_BUILD_OS_TYPE
 367   FLAGS_CPU=$OPENJDK_BUILD_CPU
 368   FLAGS_CPU_ARCH=$OPENJDK_BUILD_CPU_ARCH
 369   FLAGS_CPU_BITS=$OPENJDK_BUILD_CPU_BITS
 370   FLAGS_CPU_ENDIAN=$OPENJDK_BUILD_CPU_ENDIAN
 371   FLAGS_CPU_LEGACY=$OPENJDK_BUILD_CPU_LEGACY
 372   FLAGS_CPU_LEGACY_LIB=$OPENJDK_BUILD_CPU_LEGACY_LIB
 373 
 374   FLAGS_SETUP_CFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_], [BUILD_])
 375 
 376   # Tests are only ever compiled for TARGET
 377   CFLAGS_TESTLIB="$CFLAGS_JDKLIB"
 378   CXXFLAGS_TESTLIB="$CXXFLAGS_JDKLIB"
 379   CFLAGS_TESTEXE="$CFLAGS_JDKEXE"
 380   CXXFLAGS_TESTEXE="$CXXFLAGS_JDKEXE"
 381 
 382   AC_SUBST(CFLAGS_TESTLIB)
 383   AC_SUBST(CFLAGS_TESTEXE)
 384   AC_SUBST(CXXFLAGS_TESTLIB)
 385   AC_SUBST(CXXFLAGS_TESTEXE)
 386 ])
 387 
 388 ################################################################################
 389 # platform independent
 390 AC_DEFUN([FLAGS_SETUP_CFLAGS_HELPER],
 391 [
 392   #### OS DEFINES, these should be independent on toolchain
 393   if test "x$OPENJDK_TARGET_OS" = xlinux; then
 394     CFLAGS_OS_DEF_JVM="-DLINUX"
 395     CFLAGS_OS_DEF_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
 396   elif test "x$OPENJDK_TARGET_OS" = xsolaris; then
 397     CFLAGS_OS_DEF_JVM="-DSOLARIS"
 398     CFLAGS_OS_DEF_JDK="-D__solaris__"
 399   elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
 400     CFLAGS_OS_DEF_JVM="-D_ALLBSD_SOURCE -D_DARWIN_C_SOURCE -D_XOPEN_SOURCE"
 401     CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE -D_DARWIN_UNLIMITED_SELECT"
 402   elif test "x$OPENJDK_TARGET_OS" = xaix; then
 403     CFLAGS_OS_DEF_JVM="-DAIX"
 404   elif test "x$OPENJDK_TARGET_OS" = xbsd; then
 405     CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE"
 406   elif test "x$OPENJDK_TARGET_OS" = xwindows; then
 407     CFLAGS_OS_DEF_JVM="-D_WINDOWS -DWIN32 -D_JNI_IMPLEMENTATION_"
 408   fi
 409 
 410   CFLAGS_OS_DEF_JDK="$CFLAGS_OS_DEF_JDK -D$OPENJDK_TARGET_OS_UPPERCASE"
 411 
 412   #### GLOBAL DEFINES
 413   # Set some common defines. These works for all compilers, but assume
 414   # -D is universally accepted.
 415 
 416   # Always enable optional macros for VM.
 417   ALWAYS_CFLAGS_JVM="-D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 418 
 419   # Setup some hard coded includes
 420   ALWAYS_CFLAGS_JDK=" \
 421       -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base \
 422       -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base/\$(OPENJDK_TARGET_OS_INCLUDE_SUBDIR) \
 423       -I${TOPDIR}/src/java.base/share/native/libjava \
 424       -I${TOPDIR}/src/java.base/$OPENJDK_TARGET_OS_TYPE/native/libjava \
 425       -I${TOPDIR}/src/hotspot/share/include \
 426       -I${TOPDIR}/src/hotspot/os/${HOTSPOT_TARGET_OS_TYPE}/include"
 427 
 428   ###############################################################################
 429 
 430   # Adjust flags according to debug level.
 431   # Setup debug/release defines
 432   if test "x$DEBUG_LEVEL" = xrelease; then
 433     DEBUG_CFLAGS_JDK="-DNDEBUG"
 434     if test "x$OPENJDK_TARGET_OS" = xsolaris; then
 435       DEBUG_CFLAGS_JDK="$DEBUG_CFLAGS_JDK -DTRIMMED"
 436     fi
 437   else
 438     DEBUG_CFLAGS_JDK="-DDEBUG"
 439 
 440     if test "x$TOOLCHAIN_TYPE" = xxlc; then
 441       # We need '-qminimaltoc' or '-qpic=large -bbigtoc' if the TOC overflows.
 442       # Hotspot now overflows its 64K TOC (currently only for debug),
 443       # so for debug we build with '-qpic=large -bbigtoc'.
 444       DEBUG_CFLAGS_JVM="-qpic=large"
 445     fi
 446   fi
 447 
 448   if test "x$DEBUG_LEVEL" != xrelease; then
 449     DEBUG_OPTIONS_FLAGS_JDK="$CFLAGS_DEBUG_OPTIONS"
 450     DEBUG_SYMBOLS_CFLAGS_JDK="$CFLAGS_DEBUG_SYMBOLS"
 451   fi
 452 
 453   #### TOOLCHAIN DEFINES
 454 
 455   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 456     ALWAYS_DEFINES_JVM="-D_GNU_SOURCE -D_REENTRANT"
 457   elif test "x$TOOLCHAIN_TYPE" = xclang; then
 458     ALWAYS_DEFINES_JVM="-D_GNU_SOURCE"
 459   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 460     ALWAYS_DEFINES_JVM="-DSPARC_WORKS -D_Crun_inline_placement"
 461     ALWAYS_DEFINES_JDK="-DTRACING -DMACRO_MEMSYS_OPS -DBREAKPTS"
 462     ALWAYS_DEFINES_JDK_CXXONLY="-DCC_NOEX"
 463   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 464     ALWAYS_DEFINES_JVM="-D_REENTRANT"
 465     ALWAYS_DEFINES_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
 466   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 467     ALWAYS_DEFINES_JDK="-DWIN32_LEAN_AND_MEAN -D_CRT_SECURE_NO_DEPRECATE \
 468         -D_CRT_NONSTDC_NO_DEPRECATE -DWIN32 -DIAL"
 469     ALWAYS_DEFINES_JVM="-DNOMINMAX -DWIN32_LEAN_AND_MEAN"
 470   fi
 471 
 472   ###############################################################################
 473   #
 474   #
 475   # CFLAGS BASIC
 476   if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
 477     # COMMON to gcc and clang
 478     TOOLCHAIN_CFLAGS_JVM="-pipe -fno-rtti -fno-exceptions \
 479         -fvisibility=hidden -fno-strict-aliasing -fno-omit-frame-pointer"
 480   fi
 481 
 482   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 483     TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -fcheck-new -fstack-protector"
 484     TOOLCHAIN_CFLAGS_JDK="-pipe -fstack-protector"
 485     # reduce lib size on s390x in link step, this needs also special compile flags
 486     if test "x$OPENJDK_TARGET_CPU" = xs390x; then
 487       TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -ffunction-sections -fdata-sections"
 488       TOOLCHAIN_CFLAGS_JDK="$TOOLCHAIN_CFLAGS_JDK -ffunction-sections -fdata-sections"
 489     fi
 490     # technically NOT for CXX (but since this gives *worse* performance, use
 491     # no-strict-aliasing everywhere!)
 492     TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing"
 493 
 494   elif test "x$TOOLCHAIN_TYPE" = xclang; then
 495     # Restrict the debug information created by Clang to avoid
 496     # too big object files and speed the build up a little bit
 497     # (see http://llvm.org/bugs/show_bug.cgi?id=7554)
 498     TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -flimit-debug-info"
 499 
 500     # In principle the stack alignment below is cpu- and ABI-dependent and
 501     # should agree with values of StackAlignmentInBytes in various
 502     # src/hotspot/cpu/*/globalDefinitions_*.hpp files, but this value currently
 503     # works for all platforms.
 504     TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -mno-omit-leaf-frame-pointer -mstack-alignment=16"
 505 
 506     if test "x$OPENJDK_TARGET_OS" = xlinux; then
 507       TOOLCHAIN_CFLAGS_JDK="-pipe"
 508       TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing" # technically NOT for CXX
 509     fi
 510   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 511     TOOLCHAIN_CFLAGS_JDK="-mt"
 512     TOOLCHAIN_CFLAGS_JDK_CONLY="-xCC -Xa -v -W0,-noglobal" # C only
 513     TOOLCHAIN_CFLAGS_JDK_CXXONLY="-features=no%except -norunpath -xnolib" # CXX only
 514     TOOLCHAIN_CFLAGS_JVM="-template=no%extdef -features=no%split_init \
 515         -library=stlport4 -mt -features=no%except"
 516     if test "x$DEBUG_LEVEL" = xslowdebug; then
 517       # Previously -g was used instead of -g0 for slowdebug; this is equivalent
 518       # to setting +d.
 519       TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM +d"
 520     fi
 521 
 522   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 523     TOOLCHAIN_CFLAGS_JDK="-qchars=signed -qfullpath -qsaveopt"  # add on both CFLAGS
 524     TOOLCHAIN_CFLAGS_JVM="-qtune=balanced \
 525         -qalias=noansi -qstrict -qtls=default -qlanglvl=c99vla \
 526         -qlanglvl=noredefmac -qnortti -qnoeh -qignerrno"
 527   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 528     TOOLCHAIN_CFLAGS_JVM="-nologo -MD -MP"
 529     TOOLCHAIN_CFLAGS_JDK="-nologo -MD -Zc:wchar_t-"
 530   fi
 531 
 532   # CFLAGS WARNINGS STUFF
 533   # Set JVM_CFLAGS warning handling
 534   if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
 535     # COMMON to gcc and clang
 536     WARNING_CFLAGS_JVM="-Wpointer-arith -Wsign-compare -Wunused-function"
 537     if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
 538       # Non-zero builds have stricter warnings
 539       WARNING_CFLAGS_JVM="$WARNING_CFLAGS_JVM -Wundef -Wformat=2"
 540     fi
 541 
 542   fi
 543   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 544     WARNING_CFLAGS_JDK="-Wall -Wextra -Wno-unused -Wno-unused-parameter -Wformat=2"
 545     WARNING_CFLAGS_JVM="$WARNING_CFLAGS_JVM -Wunused-value -Woverloaded-virtual"
 546 
 547     if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
 548       # Non-zero builds have stricter warnings
 549       WARNING_CFLAGS_JVM="$WARNING_CFLAGS_JVM -Wreturn-type"
 550     fi
 551   elif test "x$TOOLCHAIN_TYPE" = xclang; then
 552     WARNING_CFLAGS_JVM="$WARNING_CFLAGS_JVM -Wno-deprecated"
 553     if test "x$OPENJDK_TARGET_OS" = xlinux; then
 554       WARNING_CFLAGS_JVM="$WARNING_CFLAGS_JVM -Wno-sometimes-uninitialized"
 555       WARNING_CFLAGS_JDK="-Wall -Wextra -Wno-unused -Wno-unused-parameter -Wformat=2"
 556     fi
 557   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 558     WARNING_CFLAGS_JDK_CONLY="-errshort=tags"
 559     WARNING_CFLAGS_JDK_CXXONLY="+w"
 560     WARNING_CFLAGS_JDK="-errtags=yes -errfmt"
 561   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 562     WARNING_CFLAGS="-W3"
 563     WARNING_CFLAGS_JDK="-wd4800"
 564     WARNING_CFLAGS_JVM="-wd4800"
 565   fi
 566 
 567   # Set some additional per-OS defines.
 568 
 569   # Additional macosx handling
 570   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 571     OS_CFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=$MACOSX_VERSION_MIN_NODOTS \
 572         -mmacosx-version-min=$MACOSX_VERSION_MIN"
 573 
 574     if test -n "$MACOSX_VERSION_MAX"; then
 575         OS_CFLAGS="$OS_CFLAGS \
 576             -DMAC_OS_X_VERSION_MAX_ALLOWED=$MACOSX_VERSION_MAX_NODOTS"
 577     fi
 578   fi
 579 
 580   # Where does this really belong??
 581   if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
 582     PICFLAG="-fPIC"
 583     PIEFLAG="-fPIE"
 584   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 585     PICFLAG="-KPIC"
 586   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 587     # '-qpic' defaults to 'qpic=small'. This means that the compiler generates only
 588     # one instruction for accessing the TOC. If the TOC grows larger than 64K, the linker
 589     # will have to patch this single instruction with a call to some out-of-order code which
 590     # does the load from the TOC. This is of course slower, and we also would have
 591     # to use '-bbigtoc' for linking anyway so we could also change the PICFLAG to 'qpic=large'.
 592     # With 'qpic=large' the compiler will by default generate a two-instruction sequence which
 593     # can be patched directly by the linker and does not require a jump to out-of-order code.
 594     #
 595     # Since large TOC causes perf. overhead, only pay it where we must. Currently this is
 596     # for all libjvm variants (both gtest and normal) but no other binaries. So, build
 597     # libjvm with -qpic=large and link with -bbigtoc.
 598     JVM_PICFLAG="-qpic=large"
 599     JDK_PICFLAG="-qpic"
 600   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 601     PICFLAG=""
 602   fi
 603 
 604   if test "x$TOOLCHAIN_TYPE" != xxlc; then
 605     JVM_PICFLAG="$PICFLAG"
 606     JDK_PICFLAG="$PICFLAG"
 607   fi
 608 
 609   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 610     # Linking is different on MacOSX
 611     JDK_PICFLAG=''
 612     if test "x$STATIC_BUILD" = xtrue; then
 613       JVM_PICFLAG=""
 614     fi
 615   fi
 616 
 617   # Optional POSIX functionality needed by the JVM
 618   #
 619   # Check if clock_gettime is available and in which library. This indicates
 620   # availability of CLOCK_MONOTONIC for hotspot. But we don't need to link, so
 621   # don't let it update LIBS.
 622   save_LIBS="$LIBS"
 623   AC_SEARCH_LIBS(clock_gettime, rt, [HAS_CLOCK_GETTIME=true], [])
 624   if test "x$LIBS" = "x-lrt "; then
 625     CLOCK_GETTIME_IN_LIBRT=true
 626   fi
 627   LIBS="$save_LIBS"
 628 
 629   if test "x$HAS_CLOCK_GETTIME" = "xtrue"; then
 630     OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DSUPPORTS_CLOCK_MONOTONIC"
 631     if test "x$CLOCK_GETTIME_IN_LIBRT" = "xtrue"; then
 632       OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DNEEDS_LIBRT"
 633     fi
 634   fi
 635 ])
 636 
 637 ################################################################################
 638 # $1 - Either BUILD or TARGET to pick the correct OS/CPU variables to check
 639 #      conditionals against.
 640 # $2 - Optional prefix for each variable defined.
 641 # $3 - Optional prefix for compiler variables (either BUILD_ or nothing).
 642 AC_DEFUN([FLAGS_SETUP_CFLAGS_CPU_DEP],
 643 [
 644   #### CPU DEFINES, these should (in theory) be independent on toolchain
 645 
 646   # Setup target CPU
 647   # Setup endianness
 648   if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
 649     $1_DEFINES_CPU_JVM="-DVM_LITTLE_ENDIAN"
 650   fi
 651   if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 652     # The macro _LITTLE_ENDIAN needs to be defined the same to avoid the
 653     #   Sun C compiler warning message: warning: macro redefined: _LITTLE_ENDIAN
 654     if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
 655       $1_DEFINES_CPU_JDK="-D_LITTLE_ENDIAN="
 656     else
 657       $1_DEFINES_CPU_JDK="-D_BIG_ENDIAN="
 658     fi
 659   else
 660     if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
 661       $1_DEFINES_CPU_JDK="-D_LITTLE_ENDIAN"
 662     else
 663       $1_DEFINES_CPU_JDK="-D_BIG_ENDIAN"
 664     fi
 665   fi
 666 
 667   # setup CPU bit size
 668   $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -DARCH='\"$FLAGS_CPU_LEGACY\"' \
 669       -D$FLAGS_CPU_LEGACY"
 670 
 671   if test "x$FLAGS_CPU_BITS" = x64; then
 672     # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
 673     # unpack200.exe.
 674     if test "x$FLAGS_OS" = xlinux || test "x$FLAGS_OS" = xmacosx; then
 675       $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_LP64=1"
 676     fi
 677     if test "x$FLAGS_OS" != xsolaris && test "x$FLAGS_OS" != xaix; then
 678       # Solaris does not have _LP64=1 in the old build.
 679       # xlc on AIX defines _LP64=1 by default and issues a warning if we redefine it.
 680       $1_DEFINES_CPU_JVM="${$1_DEFINES_CPU_JVM} -D_LP64=1"
 681     fi
 682   fi
 683 
 684   # toolchain dependend, per-cpu
 685   if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 686     if test "x$FLAGS_CPU_ARCH" = xx86; then
 687       $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -DcpuIntel -Di586 -D$FLAGS_CPU_LEGACY_LIB"
 688     fi
 689   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 690     if test "x$FLAGS_CPU" = xx86_64; then
 691       $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_AMD64_ -Damd64"
 692     else
 693       $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_X86_ -Dx86"
 694     fi
 695   fi
 696 
 697   # CFLAGS PER CPU
 698   if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
 699     # COMMON to gcc and clang
 700     if test "x$FLAGS_CPU" = xx86; then
 701       # Force compatibility with i586 on 32 bit intel platforms.
 702       $1_CFLAGS_CPU="-march=i586"
 703     fi
 704   fi
 705 
 706   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 707     if test "x$FLAGS_CPU" = xarm; then
 708       # -Wno-psabi to get rid of annoying "note: the mangling of 'va_list' has changed in GCC 4.4"
 709       $1_CFLAGS_CPU="-fsigned-char -Wno-psabi $ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS -DJDK_ARCH_ABI_PROP_NAME='\"\$(JDK_ARCH_ABI_PROP_NAME)\"'"
 710       $1_CFLAGS_CPU_JVM="-DARM"
 711     elif test "x$FLAGS_CPU" = xaarch64; then
 712       if test "x$HOTSPOT_TARGET_CPU_PORT" = xarm64; then
 713         $1_CFLAGS_CPU_JVM="-fsigned-char -DARM"
 714       fi
 715     elif test "x$FLAGS_CPU_ARCH" = xppc; then
 716       $1_CFLAGS_CPU_JVM="-minsert-sched-nops=regroup_exact -mno-multiple -mno-string"
 717       if test "x$FLAGS_CPU" = xppc64; then
 718         # -mminimal-toc fixes `relocation truncated to fit' error for gcc 4.1.
 719         # Use ppc64 instructions, but schedule for power5
 720         $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -mminimal-toc -mcpu=powerpc64 -mtune=power5"
 721       elif test "x$FLAGS_CPU" = xppc64le; then
 722         # Little endian machine uses ELFv2 ABI.
 723         # Use Power8, this is the first CPU to support PPC64 LE with ELFv2 ABI.
 724         $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -DABI_ELFv2 -mcpu=power8 -mtune=power8"
 725       fi
 726     elif test "x$FLAGS_CPU" = xs390x; then
 727       $1_CFLAGS_CPU="-mbackchain -march=z10"
 728     fi
 729 
 730     if test "x$FLAGS_CPU_ARCH" != xarm &&  test "x$FLAGS_CPU_ARCH" != xppc; then
 731       # for all archs except arm and ppc, prevent gcc to omit frame pointer
 732       $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
 733     fi
 734 
 735     $1_CXXSTD_CXXFLAG="-std=gnu++98"
 736     FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${$1_CXXSTD_CXXFLAG} -Werror],
 737         PREFIX: $3, IF_FALSE: [$1_CXXSTD_CXXFLAG=""])
 738     $1_TOOLCHAIN_CFLAGS_JDK_CXXONLY="${$1_CXXSTD_CXXFLAG}"
 739     $1_TOOLCHAIN_CFLAGS_JVM="${$1_TOOLCHAIN_CFLAGS_JVM} ${$1_CXXSTD_CXXFLAG}"
 740     $2ADLC_CXXFLAG="${$1_CXXSTD_CXXFLAG}"
 741 
 742   elif test "x$TOOLCHAIN_TYPE" = xclang; then
 743     if test "x$FLAGS_OS" = xlinux; then
 744       # ppc test not really needed for clang
 745       if test "x$FLAGS_CPU_ARCH" != xarm &&  test "x$FLAGS_CPU_ARCH" != xppc; then
 746         # for all archs except arm and ppc, prevent gcc to omit frame pointer
 747         $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
 748       fi
 749     fi
 750 
 751   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 752     if test "x$FLAGS_CPU" = xx86_64; then
 753       # NOTE: -xregs=no%frameptr is supposed to be default on x64
 754       $1_CFLAGS_CPU_JDK="-xregs=no%frameptr"
 755     elif test "x$FLAGS_CPU" = xsparcv9; then
 756       $1_CFLAGS_CPU_JVM="-xarch=sparc"
 757       $1_CFLAGS_CPU_JDK_LIBONLY="-xregs=no%appl"
 758     fi
 759 
 760   elif test "x$TOOLCHAIN_TYPE" = xxlc; then
 761     if test "x$FLAGS_CPU" = xppc64; then
 762       $1_CFLAGS_CPU_JVM="-qarch=ppc64"
 763     fi
 764 
 765   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 766     if test "x$FLAGS_CPU" = xx86; then
 767       $1_CFLAGS_CPU_JVM="-arch:IA32"
 768     elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then
 769       if test "x$DEBUG_LEVEL" != xrelease; then
 770         # NOTE: This is probably redundant; -homeparams is default on
 771         # non-release builds.
 772         $1_CFLAGS_CPU_JVM="-homeparams"
 773       fi
 774     fi
 775   fi
 776 
 777   if test "x$TOOLCHAIN_TYPE" = xgcc; then
 778     FLAGS_SETUP_GCC6_COMPILER_FLAGS($1, $3)
 779     $1_TOOLCHAIN_CFLAGS="${$1_GCC6_CFLAGS}"
 780 
 781     $1_WARNING_CFLAGS_JVM="-Wno-format-zero-length -Wtype-limits -Wuninitialized"
 782   fi
 783 
 784   # Prevent the __FILE__ macro from generating absolute paths into the built
 785   # binaries. Depending on toolchain, different mitigations are possible.
 786   # * GCC and Clang of new enough versions have -fmacro-prefix-map.
 787   # * For most other toolchains, supplying all source files and -I flags as
 788   #   relative paths fixes the issue.
 789   FILE_MACRO_CFLAGS=
 790   if test "x$ALLOW_ABSOLUTE_PATHS_IN_OUTPUT" = "xfalse"; then
 791     if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
 792       # Check if compiler supports -fmacro-prefix-map. If so, use that to make
 793       # the __FILE__ macro resolve to paths relative to the workspace root.
 794       workspace_root_trailing_slash="${WORKSPACE_ROOT%/}/"
 795       FILE_MACRO_CFLAGS="-fmacro-prefix-map=${workspace_root_trailing_slash}="
 796       FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${FILE_MACRO_CFLAGS}],
 797           PREFIX: $3,
 798           IF_FALSE: [
 799               FILE_MACRO_CFLAGS=
 800           ]
 801       )
 802     fi
 803   fi
 804   AC_SUBST(FILE_MACRO_CFLAGS)
 805 
 806   # EXPORT to API
 807   CFLAGS_JVM_COMMON="$ALWAYS_CFLAGS_JVM $ALWAYS_DEFINES_JVM \
 808       $TOOLCHAIN_CFLAGS_JVM ${$1_TOOLCHAIN_CFLAGS_JVM} \
 809       $OS_CFLAGS $OS_CFLAGS_JVM $CFLAGS_OS_DEF_JVM $DEBUG_CFLAGS_JVM \
 810       $WARNING_CFLAGS $WARNING_CFLAGS_JVM $JVM_PICFLAG $FILE_MACRO_CFLAGS"
 811 
 812   CFLAGS_JDK_COMMON="$ALWAYS_CFLAGS_JDK $ALWAYS_DEFINES_JDK $TOOLCHAIN_CFLAGS_JDK \
 813       $OS_CFLAGS $CFLAGS_OS_DEF_JDK $DEBUG_CFLAGS_JDK $DEBUG_OPTIONS_FLAGS_JDK \
 814       $WARNING_CFLAGS $WARNING_CFLAGS_JDK $DEBUG_SYMBOLS_CFLAGS_JDK \
 815       $FILE_MACRO_CFLAGS"
 816 
 817   # Use ${$2EXTRA_CFLAGS} to block EXTRA_CFLAGS to be added to build flags.
 818   # (Currently we don't have any OPENJDK_BUILD_EXTRA_CFLAGS, but that might
 819   # change in the future.)
 820 
 821   CFLAGS_JDK_COMMON_CONLY="$TOOLCHAIN_CFLAGS_JDK_CONLY  \
 822       $WARNING_CFLAGS_JDK_CONLY ${$2EXTRA_CFLAGS}"
 823   CFLAGS_JDK_COMMON_CXXONLY="$ALWAYS_DEFINES_JDK_CXXONLY \
 824       $TOOLCHAIN_CFLAGS_JDK_CXXONLY \
 825       ${$1_TOOLCHAIN_CFLAGS_JDK_CXXONLY} \
 826       $WARNING_CFLAGS_JDK_CXXONLY ${$2EXTRA_CXXFLAGS}"
 827 
 828   $1_CFLAGS_JVM="${$1_DEFINES_CPU_JVM} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JVM} ${$1_TOOLCHAIN_CFLAGS} ${$1_WARNING_CFLAGS_JVM}"
 829   $1_CFLAGS_JDK="${$1_DEFINES_CPU_JDK} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JDK} ${$1_TOOLCHAIN_CFLAGS}"
 830 
 831   $2JVM_CFLAGS="$CFLAGS_JVM_COMMON ${$1_CFLAGS_JVM} ${$2EXTRA_CXXFLAGS}"
 832 
 833   $2CFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CONLY ${$1_CFLAGS_JDK} $PIEFLAG"
 834   $2CXXFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CXXONLY ${$1_CFLAGS_JDK} $PIEFLAG"
 835   $2CFLAGS_JDKLIB="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CONLY ${$1_CFLAGS_JDK} \
 836       $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
 837   $2CXXFLAGS_JDKLIB="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CXXONLY ${$1_CFLAGS_JDK} \
 838       $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
 839 
 840   AC_SUBST($2JVM_CFLAGS)
 841   AC_SUBST($2CFLAGS_JDKLIB)
 842   AC_SUBST($2CFLAGS_JDKEXE)
 843   AC_SUBST($2CXXFLAGS_JDKLIB)
 844   AC_SUBST($2CXXFLAGS_JDKEXE)
 845   AC_SUBST($2ADLC_CXXFLAG)
 846 
 847   COMPILER_FP_CONTRACT_OFF_FLAG="-ffp-contract=off"
 848   # Check that the compiler supports -ffp-contract=off flag
 849   # Set FDLIBM_CFLAGS to -ffp-contract=off if it does. Empty
 850   # otherwise.
 851   # These flags are required for GCC-based builds of
 852   # fdlibm with optimization without losing precision.
 853   # Notably, -ffp-contract=off needs to be added for GCC >= 4.6.
 854   if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
 855     FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${COMPILER_FP_CONTRACT_OFF_FLAG}],
 856         PREFIX: $3,
 857         IF_TRUE: [$2FDLIBM_CFLAGS=${COMPILER_FP_CONTRACT_OFF_FLAG}],
 858         IF_FALSE: [$2FDLIBM_CFLAGS=""])
 859   fi
 860   AC_SUBST($2FDLIBM_CFLAGS)
 861 ])
 862 
 863 # FLAGS_SETUP_GCC6_COMPILER_FLAGS([PREFIX])
 864 # Arguments:
 865 # $1 - Prefix for each variable defined.
 866 # $2 - Prefix for compiler variables (either BUILD_ or nothing).
 867 AC_DEFUN([FLAGS_SETUP_GCC6_COMPILER_FLAGS],
 868 [
 869   # These flags are required for GCC 6 builds as undefined behaviour in OpenJDK code
 870   # runs afoul of the more aggressive versions of these optimisations.
 871   # Notably, value range propagation now assumes that the this pointer of C++
 872   # member functions is non-null.
 873   NO_DELETE_NULL_POINTER_CHECKS_CFLAG="-fno-delete-null-pointer-checks"
 874   FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_DELETE_NULL_POINTER_CHECKS_CFLAG -Werror],
 875       PREFIX: $2, IF_FALSE: [NO_DELETE_NULL_POINTER_CHECKS_CFLAG=""])
 876   NO_LIFETIME_DSE_CFLAG="-fno-lifetime-dse"
 877   FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_LIFETIME_DSE_CFLAG -Werror],
 878       PREFIX: $2, IF_FALSE: [NO_LIFETIME_DSE_CFLAG=""])
 879   $1_GCC6_CFLAGS="${NO_DELETE_NULL_POINTER_CHECKS_CFLAG} ${NO_LIFETIME_DSE_CFLAG}"
 880 ])
 881 
 882 # Documentation on common flags used for solstudio in HIGHEST.
 883 #
 884 # WARNING: Use of OPTIMIZATION_LEVEL=HIGHEST in your Makefile needs to be
 885 #          done with care, there are some assumptions below that need to
 886 #          be understood about the use of pointers, and IEEE behavior.
 887 #
 888 # -fns: Use non-standard floating point mode (not IEEE 754)
 889 # -fsimple: Do some simplification of floating point arithmetic (not IEEE 754)
 890 # -fsingle: Use single precision floating point with 'float'
 891 # -xalias_level=basic: Assume memory references via basic pointer types do not alias
 892 #   (Source with excessing pointer casting and data access with mixed
 893 #    pointer types are not recommended)
 894 # -xbuiltin=%all: Use intrinsic or inline versions for math/std functions
 895 #   (If you expect perfect errno behavior, do not use this)
 896 # -xdepend: Loop data dependency optimizations (need -xO3 or higher)
 897 # -xrestrict: Pointer parameters to functions do not overlap
 898 #   (Similar to -xalias_level=basic usage, but less obvious sometimes.
 899 #    If you pass in multiple pointers to the same data, do not use this)
 900 # -xlibmil: Inline some library routines
 901 #   (If you expect perfect errno behavior, do not use this)
 902 # -xlibmopt: Use optimized math routines (CURRENTLY DISABLED)
 903 #   (If you expect perfect errno behavior, do not use this)
 904 #  Can cause undefined external on Solaris 8 X86 on __sincos, removing for now