1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ################################################################################
27 #
28
29 AC_DEFUN([FLAGS_SETUP_LDFLAGS],
30 [
31 FLAGS_SETUP_LDFLAGS_HELPER
32
33 # Setup the target toolchain
34
35 # On some platforms (mac) the linker warns about non existing -L dirs.
36 # For any of the variants server, client or minimal, the dir matches the
37 # variant name. The "main" variant should be used for linking. For the
38 # rest, the dir is just server.
39 if HOTSPOT_CHECK_JVM_VARIANT(server) || HOTSPOT_CHECK_JVM_VARIANT(client) \
40 || HOTSPOT_CHECK_JVM_VARIANT(minimal); then
41 TARGET_JVM_VARIANT_PATH=$JVM_VARIANT_MAIN
42 else
43 TARGET_JVM_VARIANT_PATH=server
44 fi
45 FLAGS_SETUP_LDFLAGS_CPU_DEP([TARGET])
46
47 # Setup the build toolchain
48
49 # When building a buildjdk, it's always only the server variant
50 BUILD_JVM_VARIANT_PATH=server
51
52 FLAGS_SETUP_LDFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_])
53
54 LDFLAGS_TESTLIB="$LDFLAGS_JDKLIB"
55 LDFLAGS_TESTEXE="$LDFLAGS_JDKEXE ${TARGET_LDFLAGS_JDK_LIBPATH}"
56 AC_SUBST(LDFLAGS_TESTLIB)
57 AC_SUBST(LDFLAGS_TESTEXE)
58 ])
59
60 ################################################################################
61
62 # CPU independent LDFLAGS setup, used for both target and build toolchain.
63 AC_DEFUN([FLAGS_SETUP_LDFLAGS_HELPER],
64 [
65 # Setup basic LDFLAGS
66 if test "x$TOOLCHAIN_TYPE" = xgcc; then
67 # If this is a --hash-style=gnu system, use --hash-style=both, why?
68 # We have previously set HAS_GNU_HASH if this is the case
69 if test -n "$HAS_GNU_HASH"; then
70 BASIC_LDFLAGS="-Wl,--hash-style=both"
71 LIBJSIG_HASHSTYLE_LDFLAGS="-Wl,--hash-style=both"
72 fi
73
74 # Add -z defs, to forbid undefined symbols in object files.
75 # add relro (mark relocations read only) for all libs
76 BASIC_LDFLAGS="$BASIC_LDFLAGS -Wl,-z,defs -Wl,-z,relro"
77 # s390x : remove unused code+data in link step
78 if test "x$OPENJDK_TARGET_CPU" = xs390x; then
79 BASIC_LDFLAGS="$BASIC_LDFLAGS -Wl,--gc-sections -Wl,--print-gc-sections"
80 fi
81
82 BASIC_LDFLAGS_JVM_ONLY="-Wl,-O1"
83
84 elif test "x$TOOLCHAIN_TYPE" = xclang; then
85 BASIC_LDFLAGS_JVM_ONLY="-mno-omit-leaf-frame-pointer -mstack-alignment=16 \
86 -fPIC"
87
88 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
89 BASIC_LDFLAGS="-Wl,-z,defs"
90 BASIC_LDFLAGS_ONLYCXX="-norunpath"
91 BASIC_LDFLAGS_ONLYCXX_JDK_ONLY="-xnolib"
92
93 BASIC_LDFLAGS_JDK_ONLY="-ztext"
94 BASIC_LDFLAGS_JVM_ONLY="-library=%none -mt -z noversion"
95
96 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
97 BASIC_LDFLAGS="-b64 -brtl -bnolibpath -bexpall -bernotok -btextpsize:64K \
98 -bdatapsize:64K -bstackpsize:64K"
99 # libjvm.so has gotten too large for normal TOC size; compile with qpic=large and link with bigtoc
100 BASIC_LDFLAGS_JVM_ONLY="-Wl,-lC_r -bbigtoc"
101
102 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
103 BASIC_LDFLAGS="-nologo -opt:ref"
104 BASIC_LDFLAGS_JDK_ONLY="-incremental:no"
105 BASIC_LDFLAGS_JVM_ONLY="-opt:icf,8 -subsystem:windows"
106 fi
107
108 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
109 if test -n "$HAS_NOEXECSTACK"; then
110 BASIC_LDFLAGS="$BASIC_LDFLAGS -Wl,-z,noexecstack"
111 fi
112 fi
113
114 # Setup OS-dependent LDFLAGS
115 if test "x$TOOLCHAIN_TYPE" = xclang || test "x$TOOLCHAIN_TYPE" = xgcc; then
116 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
117 # Assume clang or gcc.
118 # FIXME: We should really generalize SET_SHARED_LIBRARY_ORIGIN instead.
119 OS_LDFLAGS_JVM_ONLY="-Wl,-rpath,@loader_path/. -Wl,-rpath,@loader_path/.."
120 OS_LDFLAGS_JDK_ONLY="-mmacosx-version-min=$MACOSX_VERSION_MIN"
121 fi
122 fi
123
124 # Setup debug level-dependent LDFLAGS
125 if test "x$TOOLCHAIN_TYPE" = xgcc; then
126 if test "x$OPENJDK_TARGET_OS" = xlinux; then
127 if test x$DEBUG_LEVEL = xrelease; then
128 DEBUGLEVEL_LDFLAGS_JDK_ONLY="$DEBUGLEVEL_LDFLAGS_JDK_ONLY -Wl,-O1"
129 fi
130 if test x$DEBUG_LEVEL = xslowdebug; then
131 # do relocations at load
132 DEBUGLEVEL_LDFLAGS="-Wl,-z,now"
133 fi
134 fi
135
136 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
137 # We need '-qminimaltoc' or '-qpic=large -bbigtoc' if the TOC overflows.
138 # Hotspot now overflows its 64K TOC (currently only for debug),
139 # so we build with '-qpic=large -bbigtoc'.
140 if test "x$DEBUG_LEVEL" != xrelease; then
141 DEBUGLEVEL_LDFLAGS_JVM_ONLY="$DEBUGLEVEL_LDFLAGS_JVM_ONLY -bbigtoc"
142 fi
143 fi
144
145 # Setup LDFLAGS for linking executables
146 if test "x$TOOLCHAIN_TYPE" = xgcc; then
147 EXECUTABLE_LDFLAGS="$EXECUTABLE_LDFLAGS -Wl,--allow-shlib-undefined"
148 # Enabling pie on 32 bit builds prevents the JVM from allocating a continuous
149 # java heap.
150 if test "x$OPENJDK_TARGET_CPU_BITS" != "x32"; then
151 EXECUTABLE_LDFLAGS="$EXECUTABLE_LDFLAGS -pie"
152 fi
153 fi
154
155 if test "x$ALLOW_ABSOLUTE_PATHS_IN_OUTPUT" = "xfalse"; then
156 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
157 BASIC_LDFLAGS="$BASIC_LDFLAGS -pdbaltpath:%_PDB%"
158 fi
159 fi
160
161 # Export some intermediate variables for compatibility
162 LDFLAGS_CXX_JDK="$BASIC_LDFLAGS_ONLYCXX $BASIC_LDFLAGS_ONLYCXX_JDK_ONLY $DEBUGLEVEL_LDFLAGS_JDK_ONLY"
163 AC_SUBST(LDFLAGS_CXX_JDK)
164 AC_SUBST(LIBJSIG_HASHSTYLE_LDFLAGS)
165 AC_SUBST(LIBJSIG_NOEXECSTACK_LDFLAGS)
166 ])
167
168 ################################################################################
169 # $1 - Either BUILD or TARGET to pick the correct OS/CPU variables to check
170 # conditionals against.
171 # $2 - Optional prefix for each variable defined.
172 AC_DEFUN([FLAGS_SETUP_LDFLAGS_CPU_DEP],
173 [
174 # Setup CPU-dependent basic LDFLAGS. These can differ between the target and
175 # build toolchain.
176 if test "x$TOOLCHAIN_TYPE" = xgcc; then
177 if test "x${OPENJDK_$1_CPU}" = xx86; then
178 $1_CPU_LDFLAGS_JVM_ONLY="-march=i586"
179 elif test "x$OPENJDK_$1_CPU" = xarm; then
180 $1_CPU_LDFLAGS_JVM_ONLY="${$1_CPU_LDFLAGS_JVM_ONLY} -fsigned-char"
181 $1_CPU_LDFLAGS="$ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS"
182 elif test "x$FLAGS_CPU" = xaarch64; then
183 if test "x$HOTSPOT_TARGET_CPU_PORT" = xarm64; then
184 $1_CPU_LDFLAGS_JVM_ONLY="${$1_CPU_LDFLAGS_JVM_ONLY} -fsigned-char"
185 fi
186 fi
187
188 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
189 if test "x${OPENJDK_$1_CPU}" = "xsparcv9"; then
190 $1_CPU_LDFLAGS_JVM_ONLY="-xarch=sparc"
191 fi
192
193 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
194 if test "x${OPENJDK_$1_CPU}" = "xx86"; then
195 $1_CPU_LDFLAGS="-safeseh"
196 # NOTE: Old build added -machine. Probably not needed.
197 $1_CPU_LDFLAGS_JVM_ONLY="-machine:I386"
198 $1_CPU_EXECUTABLE_LDFLAGS="-stack:327680"
199 else
200 $1_CPU_LDFLAGS_JVM_ONLY="-machine:AMD64"
201 $1_CPU_EXECUTABLE_LDFLAGS="-stack:1048576"
202 fi
203 fi
204
205 # JVM_VARIANT_PATH depends on if this is build or target...
206 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
207 $1_LDFLAGS_JDK_LIBPATH="-libpath:${OUTPUTDIR}/support/modules_libs/java.base"
208 else
209 $1_LDFLAGS_JDK_LIBPATH="-L\$(SUPPORT_OUTPUTDIR)/modules_libs/java.base \
210 -L\$(SUPPORT_OUTPUTDIR)/modules_libs/java.base/${$1_JVM_VARIANT_PATH}"
211 fi
212
213 # Export variables according to old definitions, prefix with $2 if present.
214 LDFLAGS_JDK_COMMON="$BASIC_LDFLAGS $BASIC_LDFLAGS_JDK_ONLY \
215 $OS_LDFLAGS_JDK_ONLY $DEBUGLEVEL_LDFLAGS_JDK_ONLY ${$2EXTRA_LDFLAGS}"
216 $2LDFLAGS_JDKLIB="$LDFLAGS_JDK_COMMON $BASIC_LDFLAGS_JDK_LIB_ONLY \
217 ${$1_LDFLAGS_JDK_LIBPATH} $SHARED_LIBRARY_FLAGS"
218 $2LDFLAGS_JDKEXE="$LDFLAGS_JDK_COMMON $EXECUTABLE_LDFLAGS \
219 ${$1_CPU_EXECUTABLE_LDFLAGS}"
220
221 $2JVM_LDFLAGS="$BASIC_LDFLAGS $BASIC_LDFLAGS_JVM_ONLY $OS_LDFLAGS_JVM_ONLY \
222 $DEBUGLEVEL_LDFLAGS $DEBUGLEVEL_LDFLAGS_JVM_ONLY $BASIC_LDFLAGS_ONLYCXX \
223 ${$1_CPU_LDFLAGS} ${$1_CPU_LDFLAGS_JVM_ONLY} ${$2EXTRA_LDFLAGS}"
224
225 AC_SUBST($2LDFLAGS_JDKLIB)
226 AC_SUBST($2LDFLAGS_JDKEXE)
227
228 AC_SUBST($2JVM_LDFLAGS)
229 ])