1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 m4_include([flags-cflags.m4])
27 m4_include([flags-ldflags.m4])
28 m4_include([flags-other.m4])
29
30 ################################################################################
31 #
32 # Setup ABI profile (for arm)
33 #
34 AC_DEFUN([FLAGS_SETUP_ABI_PROFILE],
35 [
36 AC_ARG_WITH(abi-profile, [AS_HELP_STRING([--with-abi-profile],
37 [specify ABI profile for ARM builds (arm-vfp-sflt,arm-vfp-hflt,arm-sflt, armv5-vfp-sflt,armv6-vfp-hflt,arm64,aarch64) @<:@toolchain dependent@:>@ ])])
38
39 if test "x$with_abi_profile" != x; then
40 if test "x$OPENJDK_TARGET_CPU" != xarm && \
41 test "x$OPENJDK_TARGET_CPU" != xaarch64 && \
42 test "x$OPENJDK_TARGET_CPU" != xaarch32 ; then
43 AC_MSG_ERROR([--with-abi-profile only available on arm/aarch64/aarch32])
44 fi
45
46 OPENJDK_TARGET_ABI_PROFILE=$with_abi_profile
47 AC_MSG_CHECKING([for ABI profle])
48 AC_MSG_RESULT([$OPENJDK_TARGET_ABI_PROFILE])
49
50 if test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm-vfp-sflt; then
51 ARM_FLOAT_TYPE=vfp-sflt
52 ARM_ARCH_TYPE_FLAGS='-march=armv7-a -mthumb'
53 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm-vfp-hflt; then
54 ARM_FLOAT_TYPE=vfp-hflt
55 ARM_ARCH_TYPE_FLAGS='-march=armv7-a -mthumb'
56 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm-sflt; then
57 ARM_FLOAT_TYPE=sflt
58 ARM_ARCH_TYPE_FLAGS='-march=armv5t -marm'
59 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarmv5-vfp-sflt; then
60 ARM_FLOAT_TYPE=vfp-sflt
61 ARM_ARCH_TYPE_FLAGS='-march=armv5t -marm'
62 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarmv6-vfp-hflt; then
63 ARM_FLOAT_TYPE=vfp-hflt
64 ARM_ARCH_TYPE_FLAGS='-march=armv6 -marm'
65 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm64; then
66 # No special flags, just need to trigger setting JDK_ARCH_ABI_PROP_NAME
67 ARM_FLOAT_TYPE=
68 ARM_ARCH_TYPE_FLAGS=
69 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xgnueabihf; then
70 # No special flags, just need to trigger setting JDK_ARCH_ABI_PROP_NAME
71 ARM_FLOAT_TYPE=
72 ARM_ARCH_TYPE_FLAGS=
73 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xgnueabi; then
74 # No special flags, just need to trigger setting JDK_ARCH_ABI_PROP_NAME
75 ARM_FLOAT_TYPE=
76 ARM_ARCH_TYPE_FLAGS=
77 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xaarch64; then
78 # No special flags, just need to trigger setting JDK_ARCH_ABI_PROP_NAME
79 ARM_FLOAT_TYPE=
80 ARM_ARCH_TYPE_FLAGS=
81 else
82 AC_MSG_ERROR([Invalid ABI profile: "$OPENJDK_TARGET_ABI_PROFILE"])
83 fi
84
85 if test "x$ARM_FLOAT_TYPE" = xvfp-sflt; then
86 ARM_FLOAT_TYPE_FLAGS='-mfloat-abi=softfp -mfpu=vfp -DFLOAT_ARCH=-vfp-sflt'
87 elif test "x$ARM_FLOAT_TYPE" = xvfp-hflt; then
88 ARM_FLOAT_TYPE_FLAGS='-mfloat-abi=hard -mfpu=vfp -DFLOAT_ARCH=-vfp-hflt'
89 elif test "x$ARM_FLOAT_TYPE" = xsflt; then
90 ARM_FLOAT_TYPE_FLAGS='-msoft-float -mfpu=vfp'
91 fi
92 AC_MSG_CHECKING([for $ARM_FLOAT_TYPE floating point flags])
93 AC_MSG_RESULT([$ARM_FLOAT_TYPE_FLAGS])
94
95 AC_MSG_CHECKING([for arch type flags])
96 AC_MSG_RESULT([$ARM_ARCH_TYPE_FLAGS])
97
98 # Now set JDK_ARCH_ABI_PROP_NAME. This is equivalent to the last part of the
99 # autoconf target triplet.
100 [ JDK_ARCH_ABI_PROP_NAME=`$ECHO $OPENJDK_TARGET_AUTOCONF_NAME | $SED -e 's/.*-\([^-]*\)$/\1/'` ]
101 # Sanity check that it is a known ABI.
102 if test "x$JDK_ARCH_ABI_PROP_NAME" != xgnu && \
103 test "x$JDK_ARCH_ABI_PROP_NAME" != xgnueabi && \
104 test "x$JDK_ARCH_ABI_PROP_NAME" != xgnueabihf; then
105 AC_MSG_WARN([Unknown autoconf target triplet ABI: "$JDK_ARCH_ABI_PROP_NAME"])
106 fi
107 AC_MSG_CHECKING([for ABI property name])
108 AC_MSG_RESULT([$JDK_ARCH_ABI_PROP_NAME])
109 AC_SUBST(JDK_ARCH_ABI_PROP_NAME)
110 fi
111
112 # When building with an abi profile, the name of that profile is appended on the
113 # bundle platform, which is used in bundle names.
114 if test "x$OPENJDK_TARGET_ABI_PROFILE" != x; then
115 OPENJDK_TARGET_BUNDLE_PLATFORM="$OPENJDK_TARGET_OS_BUNDLE-$OPENJDK_TARGET_ABI_PROFILE"
116 fi
117 ])
118
119 AC_DEFUN([FLAGS_SETUP_MACOSX_VERSION],
120 [
121 # Additional macosx handling
122 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
123 # MACOSX_VERSION_MIN specifies the lowest version of Macosx that the built
124 # binaries should be compatible with, even if compiled on a newer version
125 # of the OS. It currently has a hard coded value. Setting this also limits
126 # exposure to API changes in header files. Bumping this is likely to
127 # require code changes to build.
128 MACOSX_VERSION_MIN=10.9.0
129 MACOSX_VERSION_MIN_NODOTS=${MACOSX_VERSION_MIN//\./}
130
131 AC_SUBST(MACOSX_VERSION_MIN)
132
133 # Setting --with-macosx-version-max=<version> makes it an error to build or
134 # link to macosx APIs that are newer than the given OS version. The expected
135 # format for <version> is either nn.n.n or nn.nn.nn. See /usr/include/AvailabilityMacros.h.
136 AC_ARG_WITH([macosx-version-max], [AS_HELP_STRING([--with-macosx-version-max],
137 [error on use of newer functionality. @<:@macosx@:>@])],
138 [
139 if echo "$with_macosx_version_max" | $GREP -q "^[[0-9]][[0-9]]\.[[0-9]]\.[[0-9]]\$"; then
140 MACOSX_VERSION_MAX=$with_macosx_version_max
141 elif echo "$with_macosx_version_max" | $GREP -q "^[[0-9]][[0-9]]\.[[0-9]][[0-9]]\.[[0-9]][[0-9]]\$"; then
142 MACOSX_VERSION_MAX=$with_macosx_version_max
143 elif test "x$with_macosx_version_max" = "xno"; then
144 # Use build system default
145 MACOSX_VERSION_MAX=
146 else
147 AC_MSG_ERROR([osx version format must be nn.n.n or nn.nn.nn])
148 fi
149 ],
150 [MACOSX_VERSION_MAX=]
151 )
152 MACOSX_VERSION_MAX_NODOTS=${MACOSX_VERSION_MAX//\./}
153
154 AC_SUBST(MACOSX_VERSION_MAX)
155 fi
156 ])
157
158 # Reset the global CFLAGS/LDFLAGS variables and initialize them with the
159 # corresponding configure arguments instead
160 AC_DEFUN_ONCE([FLAGS_SETUP_USER_SUPPLIED_FLAGS],
161 [
162 if test "x$CFLAGS" != "x"; then
163 AC_MSG_WARN([Ignoring CFLAGS($CFLAGS) found in environment. Use --with-extra-cflags])
164 fi
165
166 if test "x$CXXFLAGS" != "x"; then
167 AC_MSG_WARN([Ignoring CXXFLAGS($CXXFLAGS) found in environment. Use --with-extra-cxxflags])
168 fi
169
170 if test "x$LDFLAGS" != "x"; then
171 AC_MSG_WARN([Ignoring LDFLAGS($LDFLAGS) found in environment. Use --with-extra-ldflags])
172 fi
173
174 AC_ARG_WITH(extra-cflags, [AS_HELP_STRING([--with-extra-cflags],
175 [extra flags to be used when compiling jdk c-files])])
176
177 AC_ARG_WITH(extra-cxxflags, [AS_HELP_STRING([--with-extra-cxxflags],
178 [extra flags to be used when compiling jdk c++-files])])
179
180 AC_ARG_WITH(extra-ldflags, [AS_HELP_STRING([--with-extra-ldflags],
181 [extra flags to be used when linking jdk])])
182
183 USER_CFLAGS="$with_extra_cflags"
184 USER_CXXFLAGS="$with_extra_cxxflags"
185 USER_LDFLAGS="$with_extra_ldflags"
186 ])
187
188 # Setup the sysroot flags and add them to global CFLAGS and LDFLAGS so
189 # that configure can use them while detecting compilers.
190 # TOOLCHAIN_TYPE is available here.
191 # Param 1 - Optional prefix to all variables. (e.g BUILD_)
192 AC_DEFUN([FLAGS_SETUP_SYSROOT_FLAGS],
193 [
194 if test "x[$]$1SYSROOT" != "x"; then
195 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
196 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
197 # Solaris Studio does not have a concept of sysroot. Instead we must
198 # make sure the default include and lib dirs are appended to each
199 # compile and link command line. Must also add -I-xbuiltin to enable
200 # inlining of system functions and intrinsics.
201 $1SYSROOT_CFLAGS="-I-xbuiltin -I[$]$1SYSROOT/usr/include"
202 $1SYSROOT_LDFLAGS="-L[$]$1SYSROOT/usr/lib$OPENJDK_TARGET_CPU_ISADIR \
203 -L[$]$1SYSROOT/lib$OPENJDK_TARGET_CPU_ISADIR"
204 # If the devkit contains the ld linker, make sure we use it.
205 AC_PATH_PROG(SOLARIS_LD, ld, , $DEVKIT_TOOLCHAIN_PATH:$DEVKIT_EXTRA_PATH)
206 # Make sure this ld is runnable.
207 if test -f "$SOLARIS_LD"; then
208 if "$SOLARIS_LD" -V > /dev/null 2> /dev/null; then
209 $1SYSROOT_LDFLAGS="[$]$1SYSROOT_LDFLAGS -Yl,$(dirname $SOLARIS_LD)"
210 else
211 AC_MSG_WARN([Could not run $SOLARIS_LD found in devkit, reverting to system ld])
212 fi
213 fi
214 fi
215 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
216 $1SYSROOT_CFLAGS="--sysroot=[$]$1SYSROOT"
217 $1SYSROOT_LDFLAGS="--sysroot=[$]$1SYSROOT"
218 elif test "x$TOOLCHAIN_TYPE" = xclang; then
219 $1SYSROOT_CFLAGS="-isysroot [$]$1SYSROOT"
220 $1SYSROOT_LDFLAGS="-isysroot [$]$1SYSROOT"
221 fi
222 fi
223
224 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
225 # We also need -iframework<path>/System/Library/Frameworks
226 $1SYSROOT_CFLAGS="[$]$1SYSROOT_CFLAGS -iframework [$]$1SYSROOT/System/Library/Frameworks"
227 $1SYSROOT_LDFLAGS="[$]$1SYSROOT_LDFLAGS -iframework [$]$1SYSROOT/System/Library/Frameworks"
228 # These always need to be set, or we can't find the frameworks embedded in JavaVM.framework
229 # set this here so it doesn't have to be peppered throughout the forest
230 $1SYSROOT_CFLAGS="[$]$1SYSROOT_CFLAGS -F [$]$1SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks"
231 $1SYSROOT_LDFLAGS="[$]$1SYSROOT_LDFLAGS -F [$]$1SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks"
232 fi
233
234 AC_SUBST($1SYSROOT_CFLAGS)
235 AC_SUBST($1SYSROOT_LDFLAGS)
236 ])
237
238 AC_DEFUN_ONCE([FLAGS_PRE_TOOLCHAIN],
239 [
240 # We should always include user supplied flags
241 FLAGS_SETUP_USER_SUPPLIED_FLAGS
242 # The sysroot flags are needed for configure to be able to run the compilers
243 FLAGS_SETUP_SYSROOT_FLAGS
244
245 # For solstudio and xlc, the word size flag is required for correct behavior.
246 # For clang/gcc, the flag is only strictly required for reduced builds, but
247 # set it always where possible (x86, sparc and ppc).
248 if test "x$TOOLCHAIN_TYPE" = xxlc; then
249 MACHINE_FLAG="-q${OPENJDK_TARGET_CPU_BITS}"
250 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
251 MACHINE_FLAG="-m${OPENJDK_TARGET_CPU_BITS}"
252 elif test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
253 if test "x$OPENJDK_TARGET_CPU_ARCH" = xx86 ||
254 test "x$OPENJDK_TARGET_CPU_ARCH" = xsparc ||
255 test "x$OPENJDK_TARGET_CPU_ARCH" = xppc; then
256 MACHINE_FLAG="-m${OPENJDK_TARGET_CPU_BITS}"
257 fi
258 fi
259
260 # FIXME: global flags are not used yet...
261 # The "global" flags will *always* be set. Without them, it is not possible to
262 # get a working compilation.
263 GLOBAL_CFLAGS="$MACHINE_FLAG $SYSROOT_CFLAGS $USER_CFLAGS"
264 GLOBAL_CXXFLAGS="$MACHINE_FLAG $SYSROOT_CFLAGS $USER_CXXFLAGS"
265 GLOBAL_LDFLAGS="$MACHINE_FLAG $SYSROOT_LDFLAGS $USER_LDFLAGS"
266 # FIXME: Don't really know how to do with this, but this was the old behavior
267 GLOBAL_CPPFLAGS="$SYSROOT_CFLAGS"
268 AC_SUBST(GLOBAL_CFLAGS)
269 AC_SUBST(GLOBAL_CXXFLAGS)
270 AC_SUBST(GLOBAL_LDFLAGS)
271 AC_SUBST(GLOBAL_CPPFLAGS)
272
273 # FIXME: For compatilibity, export this as EXTRA_CFLAGS for now.
274 EXTRA_CFLAGS="$MACHINE_FLAG $USER_CFLAGS"
275 EXTRA_CXXFLAGS="$MACHINE_FLAG $USER_CXXFLAGS"
276 EXTRA_LDFLAGS="$MACHINE_FLAG $USER_LDFLAGS"
277
278 AC_SUBST(EXTRA_CFLAGS)
279 AC_SUBST(EXTRA_CXXFLAGS)
280 AC_SUBST(EXTRA_LDFLAGS)
281
282 # For autoconf testing to work, the global flags must also be stored in the
283 # "unnamed" CFLAGS etc.
284 CFLAGS="$GLOBAL_CFLAGS"
285 CXXFLAGS="$GLOBAL_CXXFLAGS"
286 LDFLAGS="$GLOBAL_LDFLAGS"
287 CPPFLAGS="$GLOBAL_CPPFLAGS"
288 ])
289
290 AC_DEFUN([FLAGS_SETUP_TOOLCHAIN_CONTROL],
291 [
292 # COMPILER_TARGET_BITS_FLAG : option for selecting 32- or 64-bit output
293 # COMPILER_COMMAND_FILE_FLAG : option for passing a command file to the compiler
294 # COMPILER_BINDCMD_FILE_FLAG : option for specifying a file which saves the binder
295 # commands produced by the link step (currently AIX only)
296 if test "x$TOOLCHAIN_TYPE" = xxlc; then
297 COMPILER_TARGET_BITS_FLAG="-q"
298 COMPILER_COMMAND_FILE_FLAG="-f"
299 COMPILER_BINDCMD_FILE_FLAG="-bloadmap:"
300 else
301 COMPILER_TARGET_BITS_FLAG="-m"
302 COMPILER_COMMAND_FILE_FLAG="@"
303 COMPILER_BINDCMD_FILE_FLAG=""
304
305 # The solstudio linker does not support @-files.
306 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
307 COMPILER_COMMAND_FILE_FLAG=
308 fi
309
310 # Check if @file is supported by gcc
311 if test "x$TOOLCHAIN_TYPE" = xgcc; then
312 AC_MSG_CHECKING([if @file is supported by gcc])
313 # Extra emtpy "" to prevent ECHO from interpreting '--version' as argument
314 $ECHO "" "--version" > command.file
315 if $CXX @command.file 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD; then
316 AC_MSG_RESULT(yes)
317 COMPILER_COMMAND_FILE_FLAG="@"
318 else
319 AC_MSG_RESULT(no)
320 COMPILER_COMMAND_FILE_FLAG=
321 fi
322 $RM command.file
323 fi
324 fi
325
326 AC_SUBST(COMPILER_TARGET_BITS_FLAG)
327 AC_SUBST(COMPILER_COMMAND_FILE_FLAG)
328 AC_SUBST(COMPILER_BINDCMD_FILE_FLAG)
329
330 # Check that the compiler supports -mX (or -qX on AIX) flags
331 # Set COMPILER_SUPPORTS_TARGET_BITS_FLAG to 'true' if it does
332 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}],
333 IF_TRUE: [COMPILER_SUPPORTS_TARGET_BITS_FLAG=true],
334 IF_FALSE: [COMPILER_SUPPORTS_TARGET_BITS_FLAG=false])
335 AC_SUBST(COMPILER_SUPPORTS_TARGET_BITS_FLAG)
336
337 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
338 CC_OUT_OPTION=-Fo
339 LD_OUT_OPTION=-out:
340 AR_OUT_OPTION=-out:
341 else
342 # The option used to specify the target .o,.a or .so file.
343 # When compiling, how to specify the to be created object file.
344 CC_OUT_OPTION='-o$(SPACE)'
345 # When linking, how to specify the output
346 LD_OUT_OPTION='-o$(SPACE)'
347 # When archiving, how to specify the to be create static archive for object files.
348 AR_OUT_OPTION='rcs$(SPACE)'
349 fi
350 AC_SUBST(CC_OUT_OPTION)
351 AC_SUBST(LD_OUT_OPTION)
352 AC_SUBST(AR_OUT_OPTION)
353
354 # Generate make dependency files
355 if test "x$TOOLCHAIN_TYPE" = xgcc; then
356 C_FLAG_DEPS="-MMD -MF"
357 elif test "x$TOOLCHAIN_TYPE" = xclang; then
358 C_FLAG_DEPS="-MMD -MF"
359 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
360 C_FLAG_DEPS="-xMMD -xMF"
361 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
362 C_FLAG_DEPS="-qmakedep=gcc -MF"
363 fi
364 CXX_FLAG_DEPS="$C_FLAG_DEPS"
365 AC_SUBST(C_FLAG_DEPS)
366 AC_SUBST(CXX_FLAG_DEPS)
367 ])
368
369 AC_DEFUN_ONCE([FLAGS_POST_TOOLCHAIN],
370 [
371 FLAGS_SETUP_TOOLCHAIN_CONTROL
372
373 if test "x$BUILD_SYSROOT" != x; then
374 FLAGS_SETUP_SYSROOT_FLAGS([BUILD_])
375 else
376 if test "x$COMPILE_TYPE" != "xcross"; then
377 BUILD_SYSROOT_CFLAGS="$SYSROOT_CFLAGS"
378 BUILD_SYSROOT_LDFLAGS="$SYSROOT_LDFLAGS"
379 fi
380 fi
381 AC_SUBST(BUILD_SYSROOT_CFLAGS)
382 AC_SUBST(BUILD_SYSROOT_LDFLAGS)
383
384 ])
385
386 AC_DEFUN([FLAGS_SETUP_FLAGS],
387 [
388 FLAGS_SETUP_MACOSX_VERSION
389 FLAGS_SETUP_ABI_PROFILE
390
391 FLAGS_SETUP_SHARED_LIBS
392 FLAGS_SETUP_DEBUG_SYMBOLS
393 FLAGS_SETUP_WARNINGS
394 FLAGS_SETUP_QUALITY_CHECKS
395 FLAGS_SETUP_OPTIMIZATION
396
397 FLAGS_SETUP_CFLAGS
398 FLAGS_SETUP_LDFLAGS
399
400 FLAGS_SETUP_ARFLAGS
401 FLAGS_SETUP_STRIPFLAGS
402 FLAGS_SETUP_RCFLAGS
403
404 FLAGS_SETUP_ASFLAGS
405 FLAGS_SETUP_ASFLAGS_CPU_DEP([TARGET])
406 FLAGS_SETUP_ASFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_])
407 ])
408
409 # FLAGS_C_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
410 # IF_FALSE: [RUN-IF-FALSE])
411 # ------------------------------------------------------------
412 # Check that the C compiler supports an argument
413 BASIC_DEFUN_NAMED([FLAGS_C_COMPILER_CHECK_ARGUMENTS],
414 [*ARGUMENT IF_TRUE IF_FALSE], [$@],
415 [
416 AC_MSG_CHECKING([if the C compiler supports "ARG_ARGUMENT"])
417 supports=yes
418
419 saved_cflags="$CFLAGS"
420 CFLAGS="$CFLAGS ARG_ARGUMENT"
421 AC_LANG_PUSH([C])
422 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
423 [supports=no])
424 AC_LANG_POP([C])
425 CFLAGS="$saved_cflags"
426
427 AC_MSG_RESULT([$supports])
428 if test "x$supports" = "xyes" ; then
429 :
430 ARG_IF_TRUE
431 else
432 :
433 ARG_IF_FALSE
434 fi
435 ])
436
437 # FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
438 # IF_FALSE: [RUN-IF-FALSE])
439 # ------------------------------------------------------------
440 # Check that the C++ compiler supports an argument
441 BASIC_DEFUN_NAMED([FLAGS_CXX_COMPILER_CHECK_ARGUMENTS],
442 [*ARGUMENT IF_TRUE IF_FALSE], [$@],
443 [
444 AC_MSG_CHECKING([if the C++ compiler supports "ARG_ARGUMENT"])
445 supports=yes
446
447 saved_cxxflags="$CXXFLAGS"
448 CXXFLAGS="$CXXFLAG ARG_ARGUMENT"
449 AC_LANG_PUSH([C++])
450 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
451 [supports=no])
452 AC_LANG_POP([C++])
453 CXXFLAGS="$saved_cxxflags"
454
455 AC_MSG_RESULT([$supports])
456 if test "x$supports" = "xyes" ; then
457 :
458 ARG_IF_TRUE
459 else
460 :
461 ARG_IF_FALSE
462 fi
463 ])
464
465 # FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
466 # IF_FALSE: [RUN-IF-FALSE])
467 # ------------------------------------------------------------
468 # Check that the C and C++ compilers support an argument
469 BASIC_DEFUN_NAMED([FLAGS_COMPILER_CHECK_ARGUMENTS],
470 [*ARGUMENT IF_TRUE IF_FALSE], [$@],
471 [
472 FLAGS_C_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARG_ARGUMENT],
473 IF_TRUE: [C_COMP_SUPPORTS="yes"],
474 IF_FALSE: [C_COMP_SUPPORTS="no"])
475 FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARG_ARGUMENT],
476 IF_TRUE: [CXX_COMP_SUPPORTS="yes"],
477 IF_FALSE: [CXX_COMP_SUPPORTS="no"])
478
479 AC_MSG_CHECKING([if both compilers support "ARG_ARGUMENT"])
480 supports=no
481 if test "x$C_COMP_SUPPORTS" = "xyes" -a "x$CXX_COMP_SUPPORTS" = "xyes"; then supports=yes; fi
482
483 AC_MSG_RESULT([$supports])
484 if test "x$supports" = "xyes" ; then
485 :
486 ARG_IF_TRUE
487 else
488 :
489 ARG_IF_FALSE
490 fi
491 ])
492
493 # FLAGS_LINKER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
494 # IF_FALSE: [RUN-IF-FALSE])
495 # ------------------------------------------------------------
496 # Check that the linker support an argument
497 BASIC_DEFUN_NAMED([FLAGS_LINKER_CHECK_ARGUMENTS],
498 [*ARGUMENT IF_TRUE IF_FALSE], [$@],
499 [
500 AC_MSG_CHECKING([if linker supports "ARG_ARGUMENT"])
501 supports=yes
502
503 saved_ldflags="$LDFLAGS"
504 LDFLAGS="$LDFLAGS ARG_ARGUMENT"
505 AC_LANG_PUSH([C])
506 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],[[]])],
507 [], [supports=no])
508 AC_LANG_POP([C])
509 LDFLAGS="$saved_ldflags"
510
511 AC_MSG_RESULT([$supports])
512 if test "x$supports" = "xyes" ; then
513 :
514 ARG_IF_TRUE
515 else
516 :
517 ARG_IF_FALSE
518 fi
519 ])