1 #
2 # Copyright (c) 2011, 2015, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Reset the global CFLAGS/LDFLAGS variables and initialize them with the
27 # corresponding configure arguments instead
28 AC_DEFUN_ONCE([FLAGS_SETUP_USER_SUPPLIED_FLAGS],
29 [
30 if test "x$CFLAGS" != "x${ADDED_CFLAGS}"; then
31 AC_MSG_WARN([Ignoring CFLAGS($CFLAGS) found in environment. Use --with-extra-cflags])
32 fi
33
34 if test "x$CXXFLAGS" != "x${ADDED_CXXFLAGS}"; then
35 AC_MSG_WARN([Ignoring CXXFLAGS($CXXFLAGS) found in environment. Use --with-extra-cxxflags])
36 fi
37
38 if test "x$LDFLAGS" != "x${ADDED_LDFLAGS}"; then
39 AC_MSG_WARN([Ignoring LDFLAGS($LDFLAGS) found in environment. Use --with-extra-ldflags])
40 fi
41
42 AC_ARG_WITH(extra-cflags, [AS_HELP_STRING([--with-extra-cflags],
43 [extra flags to be used when compiling jdk c-files])])
44
45 AC_ARG_WITH(extra-cxxflags, [AS_HELP_STRING([--with-extra-cxxflags],
46 [extra flags to be used when compiling jdk c++-files])])
47
48 AC_ARG_WITH(extra-ldflags, [AS_HELP_STRING([--with-extra-ldflags],
49 [extra flags to be used when linking jdk])])
50
51 EXTRA_CFLAGS="$with_extra_cflags"
52 EXTRA_CXXFLAGS="$with_extra_cxxflags"
53 EXTRA_LDFLAGS="$with_extra_ldflags"
54
55 # Hotspot needs these set in their legacy form
56 LEGACY_EXTRA_CFLAGS="$LEGACY_EXTRA_CFLAGS $EXTRA_CFLAGS"
57 LEGACY_EXTRA_CXXFLAGS="$LEGACY_EXTRA_CXXFLAGS $EXTRA_CXXFLAGS"
58 LEGACY_EXTRA_LDFLAGS="$LEGACY_EXTRA_LDFLAGS $EXTRA_LDFLAGS"
59
60 AC_SUBST(LEGACY_EXTRA_CFLAGS)
61 AC_SUBST(LEGACY_EXTRA_CXXFLAGS)
62 AC_SUBST(LEGACY_EXTRA_LDFLAGS)
63
64 # The global CFLAGS and LDLAGS variables are used by configure tests and
65 # should include the extra parameters
66 CFLAGS="$EXTRA_CFLAGS"
67 CXXFLAGS="$EXTRA_CXXFLAGS"
68 LDFLAGS="$EXTRA_LDFLAGS"
69 CPPFLAGS=""
70 ])
71
72 # Setup the sysroot flags and add them to global CFLAGS and LDFLAGS so
73 # that configure can use them while detecting compilers.
74 # TOOLCHAIN_TYPE is available here.
75 AC_DEFUN_ONCE([FLAGS_SETUP_SYSROOT_FLAGS],
76 [
77 if test "x$SYSROOT" != "x"; then
78 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
79 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
80 # Solaris Studio does not have a concept of sysroot. Instead we must
81 # make sure the default include and lib dirs are appended to each
82 # compile and link command line.
83 SYSROOT_CFLAGS="-I$SYSROOT/usr/include"
84 SYSROOT_LDFLAGS="-L$SYSROOT/usr/lib$OPENJDK_TARGET_CPU_ISADIR \
85 -L$SYSROOT/lib$OPENJDK_TARGET_CPU_ISADIR \
86 -L$SYSROOT/usr/ccs/lib$OPENJDK_TARGET_CPU_ISADIR"
87 fi
88 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
89 SYSROOT_CFLAGS="--sysroot=$SYSROOT"
90 SYSROOT_LDFLAGS="--sysroot=$SYSROOT"
91 elif test "x$TOOLCHAIN_TYPE" = xclang; then
92 SYSROOT_CFLAGS="-isysroot $SYSROOT"
93 SYSROOT_LDFLAGS="-isysroot $SYSROOT"
94 fi
95 # Propagate the sysroot args to hotspot
96 LEGACY_EXTRA_CFLAGS="$LEGACY_EXTRA_CFLAGS $SYSROOT_CFLAGS"
97 LEGACY_EXTRA_CXXFLAGS="$LEGACY_EXTRA_CXXFLAGS $SYSROOT_CFLAGS"
98 LEGACY_EXTRA_LDFLAGS="$LEGACY_EXTRA_LDFLAGS $SYSROOT_LDFLAGS"
99 # The global CFLAGS and LDFLAGS variables need these for configure to function
100 CFLAGS="$CFLAGS $SYSROOT_CFLAGS"
101 CPPFLAGS="$CPPFLAGS $SYSROOT_CFLAGS"
102 CXXFLAGS="$CXXFLAGS $SYSROOT_CFLAGS"
103 LDFLAGS="$LDFLAGS $SYSROOT_LDFLAGS"
104 fi
105
106 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
107 # We also need -iframework<path>/System/Library/Frameworks
108 SYSROOT_CFLAGS="$SYSROOT_CFLAGS -iframework $SYSROOT/System/Library/Frameworks"
109 SYSROOT_LDFLAGS="$SYSROOT_LDFLAGS -iframework $SYSROOT/System/Library/Frameworks"
110 # These always need to be set, or we can't find the frameworks embedded in JavaVM.framework
111 # set this here so it doesn't have to be peppered throughout the forest
112 SYSROOT_CFLAGS="$SYSROOT_CFLAGS -F $SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks"
113 SYSROOT_LDFLAGS="$SYSROOT_LDFLAGS -F $SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks"
114 fi
115
116 AC_SUBST(SYSROOT_CFLAGS)
117 AC_SUBST(SYSROOT_LDFLAGS)
118 ])
119
120 AC_DEFUN_ONCE([FLAGS_SETUP_INIT_FLAGS],
121 [
122 # Option used to tell the compiler whether to create 32- or 64-bit executables
123 if test "x$TOOLCHAIN_TYPE" = xxlc; then
124 COMPILER_TARGET_BITS_FLAG="-q"
125 else
126 COMPILER_TARGET_BITS_FLAG="-m"
127 fi
128 AC_SUBST(COMPILER_TARGET_BITS_FLAG)
129
130 # FIXME: figure out if we should select AR flags depending on OS or toolchain.
131 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
132 ARFLAGS="-r"
133 elif test "x$OPENJDK_TARGET_OS" = xaix; then
134 ARFLAGS="-X64"
135 elif test "x$OPENJDK_TARGET_OS" = xwindows; then
136 # lib.exe is used as AR to create static libraries.
137 ARFLAGS="-nologo -NODEFAULTLIB:MSVCRT"
138 else
139 ARFLAGS=""
140 fi
141 AC_SUBST(ARFLAGS)
142
143 ## Setup strip.
144 # FIXME: should this really be per platform, or should it be per toolchain type?
145 # strip is not provided by clang or solstudio; so guessing platform makes most sense.
146 # FIXME: we should really only export STRIPFLAGS from here, not POST_STRIP_CMD.
147 if test "x$OPENJDK_TARGET_OS" = xlinux; then
148 STRIPFLAGS="-g"
149 elif test "x$OPENJDK_TARGET_OS" = xsolaris; then
150 STRIPFLAGS="-x"
151 elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
152 STRIPFLAGS="-S"
153 elif test "x$OPENJDK_TARGET_OS" = xaix; then
154 STRIPFLAGS="-X32_64"
155 fi
156
157 AC_SUBST(STRIPFLAGS)
158
159 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
160 CC_OUT_OPTION=-Fo
161 EXE_OUT_OPTION=-out:
162 LD_OUT_OPTION=-out:
163 AR_OUT_OPTION=-out:
164 else
165 # The option used to specify the target .o,.a or .so file.
166 # When compiling, how to specify the to be created object file.
167 CC_OUT_OPTION='-o$(SPACE)'
168 # When linking, how to specify the to be created executable.
169 EXE_OUT_OPTION='-o$(SPACE)'
170 # When linking, how to specify the to be created dynamically linkable library.
171 LD_OUT_OPTION='-o$(SPACE)'
172 # When archiving, how to specify the to be create static archive for object files.
173 AR_OUT_OPTION='rcs$(SPACE)'
174 fi
175 AC_SUBST(CC_OUT_OPTION)
176 AC_SUBST(EXE_OUT_OPTION)
177 AC_SUBST(LD_OUT_OPTION)
178 AC_SUBST(AR_OUT_OPTION)
179
180 # On Windows, we need to set RC flags.
181 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
182 RC_FLAGS="-nologo -l0x409"
183 if test "x$VARIANT" = xOPT; then
184 RC_FLAGS="$RC_FLAGS -DNDEBUG"
185 fi
186
187 # The version variables used to create RC_FLAGS may be overridden
188 # in a custom configure script, or possibly the command line.
189 # Let those variables be expanded at make time in spec.gmk.
190 # The \$ are escaped to the shell, and the $(...) variables
191 # are evaluated by make.
192 RC_FLAGS="$RC_FLAGS \
193 -D\"JDK_BUILD_ID=\$(FULL_VERSION)\" \
194 -D\"JDK_COMPANY=\$(COMPANY_NAME)\" \
195 -D\"JDK_COMPONENT=\$(PRODUCT_NAME) \$(JDK_RC_PLATFORM_NAME) binary\" \
196 -D\"JDK_VER=\$(JDK_MINOR_VERSION).\$(JDK_MICRO_VERSION).\$(if \$(JDK_UPDATE_VERSION),\$(JDK_UPDATE_VERSION),0).\$(COOKED_BUILD_NUMBER)\" \
197 -D\"JDK_COPYRIGHT=Copyright \xA9 $COPYRIGHT_YEAR\" \
198 -D\"JDK_NAME=\$(PRODUCT_NAME) \$(JDK_RC_PLATFORM_NAME) \$(JDK_MINOR_VERSION) \$(JDK_UPDATE_META_TAG)\" \
199 -D\"JDK_FVER=\$(JDK_MINOR_VERSION),\$(JDK_MICRO_VERSION),\$(if \$(JDK_UPDATE_VERSION),\$(JDK_UPDATE_VERSION),0),\$(COOKED_BUILD_NUMBER)\""
200 fi
201 AC_SUBST(RC_FLAGS)
202
203 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
204 # silence copyright notice and other headers.
205 COMMON_CCXXFLAGS="$COMMON_CCXXFLAGS -nologo"
206 fi
207 ])
208
209 AC_DEFUN_ONCE([FLAGS_SETUP_COMPILER_FLAGS_FOR_LIBS],
210 [
211 ###############################################################################
212 #
213 # How to compile shared libraries.
214 #
215
216 if test "x$TOOLCHAIN_TYPE" = xgcc; then
217 PICFLAG="-fPIC"
218 C_FLAG_REORDER=''
219 CXX_FLAG_REORDER=''
220
221 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
222 # Linking is different on MacOSX
223 if test "x$BUILD_STATIC" = xtrue; then
224 SHARED_LIBRARY_FLAGS ='-undefined dynamic_lookup'
225 else
226 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0 $PICFLAG"
227 fi
228 SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker @loader_path/.'
229 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
230 SET_SHARED_LIBRARY_NAME='-Xlinker -install_name -Xlinker @rpath/[$]1'
231 SET_SHARED_LIBRARY_MAPFILE=''
232 else
233 # Default works for linux, might work on other platforms as well.
234 SHARED_LIBRARY_FLAGS='-shared'
235 SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
236 SET_SHARED_LIBRARY_ORIGIN="-Xlinker -z -Xlinker origin $SET_EXECUTABLE_ORIGIN"
237 SET_SHARED_LIBRARY_NAME='-Xlinker -soname=[$]1'
238 SET_SHARED_LIBRARY_MAPFILE='-Xlinker -version-script=[$]1'
239 fi
240 elif test "x$TOOLCHAIN_TYPE" = xclang; then
241 PICFLAG=''
242 C_FLAG_REORDER=''
243 CXX_FLAG_REORDER=''
244
245 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
246 # Linking is different on MacOSX
247 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0 $PICFLAG"
248 SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker @loader_path/.'
249 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
250 SET_SHARED_LIBRARY_NAME='-Xlinker -install_name -Xlinker @rpath/[$]1'
251 SET_SHARED_LIBRARY_MAPFILE=''
252 else
253 # Default works for linux, might work on other platforms as well.
254 SHARED_LIBRARY_FLAGS='-shared'
255 SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
256 SET_SHARED_LIBRARY_ORIGIN="-Xlinker -z -Xlinker origin $SET_EXECUTABLE_ORIGIN"
257 SET_SHARED_LIBRARY_NAME='-Xlinker -soname=[$]1'
258 SET_SHARED_LIBRARY_MAPFILE='-Xlinker -version-script=[$]1'
259 fi
260 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
261 PICFLAG="-KPIC"
262 C_FLAG_REORDER='-xF'
263 CXX_FLAG_REORDER='-xF'
264 SHARED_LIBRARY_FLAGS="-G"
265 SET_EXECUTABLE_ORIGIN='-R\$$$$ORIGIN[$]1'
266 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
267 SET_SHARED_LIBRARY_NAME=''
268 SET_SHARED_LIBRARY_MAPFILE='-M[$]1'
269 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
270 PICFLAG="-qpic=large"
271 C_FLAG_REORDER=''
272 CXX_FLAG_REORDER=''
273 SHARED_LIBRARY_FLAGS="-qmkshrobj"
274 SET_EXECUTABLE_ORIGIN=""
275 SET_SHARED_LIBRARY_ORIGIN=''
276 SET_SHARED_LIBRARY_NAME=''
277 SET_SHARED_LIBRARY_MAPFILE=''
278 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
279 PICFLAG=""
280 C_FLAG_REORDER=''
281 CXX_FLAG_REORDER=''
282 SHARED_LIBRARY_FLAGS="-LD"
283 SET_EXECUTABLE_ORIGIN=''
284 SET_SHARED_LIBRARY_ORIGIN=''
285 SET_SHARED_LIBRARY_NAME=''
286 SET_SHARED_LIBRARY_MAPFILE=''
287 fi
288
289 AC_SUBST(C_FLAG_REORDER)
290 AC_SUBST(CXX_FLAG_REORDER)
291 AC_SUBST(SET_EXECUTABLE_ORIGIN)
292 AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
293 AC_SUBST(SET_SHARED_LIBRARY_NAME)
294 AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
295
296 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
297 CFLAGS_JDK="${CFLAGS_JDK} -D__solaris__"
298 CXXFLAGS_JDK="${CXXFLAGS_JDK} -D__solaris__"
299 CFLAGS_JDKLIB_EXTRA='-xstrconst'
300 fi
301 # The (cross) compiler is now configured, we can now test capabilities
302 # of the target platform.
303 ])
304
305 # Documentation on common flags used for solstudio in HIGHEST.
306 #
307 # WARNING: Use of OPTIMIZATION_LEVEL=HIGHEST in your Makefile needs to be
308 # done with care, there are some assumptions below that need to
309 # be understood about the use of pointers, and IEEE behavior.
310 #
311 # -fns: Use non-standard floating point mode (not IEEE 754)
312 # -fsimple: Do some simplification of floating point arithmetic (not IEEE 754)
313 # -fsingle: Use single precision floating point with 'float'
314 # -xalias_level=basic: Assume memory references via basic pointer types do not alias
315 # (Source with excessing pointer casting and data access with mixed
316 # pointer types are not recommended)
317 # -xbuiltin=%all: Use intrinsic or inline versions for math/std functions
318 # (If you expect perfect errno behavior, do not use this)
319 # -xdepend: Loop data dependency optimizations (need -xO3 or higher)
320 # -xrestrict: Pointer parameters to functions do not overlap
321 # (Similar to -xalias_level=basic usage, but less obvious sometimes.
322 # If you pass in multiple pointers to the same data, do not use this)
323 # -xlibmil: Inline some library routines
324 # (If you expect perfect errno behavior, do not use this)
325 # -xlibmopt: Use optimized math routines (CURRENTLY DISABLED)
326 # (If you expect perfect errno behavior, do not use this)
327 # Can cause undefined external on Solaris 8 X86 on __sincos, removing for now
328
329 # FIXME: this will never happen since sparc != sparcv9, ie 32 bit, which we don't build anymore.
330 # Bug?
331 #if test "x$OPENJDK_TARGET_CPU" = xsparc; then
332 # CFLAGS_JDK="${CFLAGS_JDK} -xmemalign=4s"
333 # CXXFLAGS_JDK="${CXXFLAGS_JDK} -xmemalign=4s"
334 #fi
335
336 AC_DEFUN_ONCE([FLAGS_SETUP_COMPILER_FLAGS_FOR_OPTIMIZATION],
337 [
338
339 ###############################################################################
340 #
341 # Setup the opt flags for different compilers
342 # and different operating systems.
343 #
344
345 # FIXME: this was indirectly the old default, but just inherited.
346 # if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
347 # C_FLAG_DEPS="-MMD -MF"
348 # fi
349
350 # Generate make dependency files
351 if test "x$TOOLCHAIN_TYPE" = xgcc; then
352 C_FLAG_DEPS="-MMD -MF"
353 elif test "x$TOOLCHAIN_TYPE" = xclang; then
354 C_FLAG_DEPS="-MMD -MF"
355 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
356 C_FLAG_DEPS="-xMMD -xMF"
357 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
358 C_FLAG_DEPS="-qmakedep=gcc -MF"
359 fi
360 CXX_FLAG_DEPS="$C_FLAG_DEPS"
361 AC_SUBST(C_FLAG_DEPS)
362 AC_SUBST(CXX_FLAG_DEPS)
363
364 # Debug symbols
365 if test "x$TOOLCHAIN_TYPE" = xgcc; then
366 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64" && test "x$DEBUG_LEVEL" = "xfastdebug"; then
367 # reduce from default "-g2" option to save space
368 CFLAGS_DEBUG_SYMBOLS="-g1"
369 CXXFLAGS_DEBUG_SYMBOLS="-g1"
370 else
371 CFLAGS_DEBUG_SYMBOLS="-g"
372 CXXFLAGS_DEBUG_SYMBOLS="-g"
373 fi
374 elif test "x$TOOLCHAIN_TYPE" = xclang; then
375 CFLAGS_DEBUG_SYMBOLS="-g"
376 CXXFLAGS_DEBUG_SYMBOLS="-g"
377 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
378 CFLAGS_DEBUG_SYMBOLS="-g -xs"
379 # FIXME: likely a bug, this disables debug symbols rather than enables them
380 CXXFLAGS_DEBUG_SYMBOLS="-g0 -xs"
381 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
382 CFLAGS_DEBUG_SYMBOLS="-g"
383 CXXFLAGS_DEBUG_SYMBOLS="-g"
384 fi
385 AC_SUBST(CFLAGS_DEBUG_SYMBOLS)
386 AC_SUBST(CXXFLAGS_DEBUG_SYMBOLS)
387
388 # bounds, memory and behavior checking options
389 if test "x$TOOLCHAIN_TYPE" = xgcc; then
390 case $DEBUG_LEVEL in
391 release )
392 # no adjustment
393 ;;
394 fastdebug )
395 # no adjustment
396 ;;
397 slowdebug )
398 # Add runtime stack smashing and undefined behavior checks.
399 # Not all versions of gcc support -fstack-protector
400 STACK_PROTECTOR_CFLAG="-fstack-protector-all"
401 FLAGS_COMPILER_CHECK_ARGUMENTS([$STACK_PROTECTOR_CFLAG], [], [STACK_PROTECTOR_CFLAG=""])
402
403 CFLAGS_DEBUG_OPTIONS="$STACK_PROTECTOR_CFLAG --param ssp-buffer-size=1"
404 CXXFLAGS_DEBUG_OPTIONS="$STACK_PROTECTOR_CFLAG --param ssp-buffer-size=1"
405 ;;
406 esac
407 fi
408
409 # Optimization levels
410 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
411 CC_HIGHEST="$CC_HIGHEST -fns -fsimple -fsingle -xbuiltin=%all -xdepend -xrestrict -xlibmil"
412
413 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
414 # FIXME: seems we always set -xregs=no%frameptr; put it elsewhere more global?
415 C_O_FLAG_HIGHEST="-xO4 -Wu,-O4~yz $CC_HIGHEST -xalias_level=basic -xregs=no%frameptr"
416 C_O_FLAG_HI="-xO4 -Wu,-O4~yz -xregs=no%frameptr"
417 C_O_FLAG_NORM="-xO2 -Wu,-O2~yz -xregs=no%frameptr"
418 C_O_FLAG_DEBUG="-xregs=no%frameptr"
419 C_O_FLAG_NONE="-xregs=no%frameptr"
420 CXX_O_FLAG_HIGHEST="-xO4 -Qoption ube -O4~yz $CC_HIGHEST -xregs=no%frameptr"
421 CXX_O_FLAG_HI="-xO4 -Qoption ube -O4~yz -xregs=no%frameptr"
422 CXX_O_FLAG_NORM="-xO2 -Qoption ube -O2~yz -xregs=no%frameptr"
423 CXX_O_FLAG_DEBUG="-xregs=no%frameptr"
424 CXX_O_FLAG_NONE="-xregs=no%frameptr"
425 if test "x$OPENJDK_TARGET_CPU_BITS" = "x32"; then
426 C_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST -xchip=pentium"
427 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_HIGHEST -xchip=pentium"
428 fi
429 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
430 C_O_FLAG_HIGHEST="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0 $CC_HIGHEST -xalias_level=basic -xprefetch=auto,explicit -xchip=ultra"
431 C_O_FLAG_HI="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0"
432 C_O_FLAG_NORM="-xO2 -Wc,-Qrm-s -Wc,-Qiselect-T0"
433 C_O_FLAG_DEBUG=""
434 C_O_FLAG_NONE=""
435 CXX_O_FLAG_HIGHEST="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0 $CC_HIGHEST -xprefetch=auto,explicit -xchip=ultra"
436 CXX_O_FLAG_HI="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
437 CXX_O_FLAG_NORM="-xO2 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
438 C_O_FLAG_DEBUG=""
439 CXX_O_FLAG_NONE=""
440 fi
441 else
442 # The remaining toolchains share opt flags between CC and CXX;
443 # setup for C and duplicate afterwards.
444 if test "x$TOOLCHAIN_TYPE" = xgcc; then
445 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
446 # On MacOSX we optimize for size, something
447 # we should do for all platforms?
448 C_O_FLAG_HIGHEST="-Os"
449 C_O_FLAG_HI="-Os"
450 C_O_FLAG_NORM="-Os"
451 else
452 C_O_FLAG_HIGHEST="-O3"
453 C_O_FLAG_HI="-O3"
454 C_O_FLAG_NORM="-O2"
455 fi
456 C_O_FLAG_DEBUG="-O0"
457 C_O_FLAG_NONE="-O0"
458 elif test "x$TOOLCHAIN_TYPE" = xclang; then
459 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
460 # On MacOSX we optimize for size, something
461 # we should do for all platforms?
462 C_O_FLAG_HIGHEST="-Os"
463 C_O_FLAG_HI="-Os"
464 C_O_FLAG_NORM="-Os"
465 else
466 C_O_FLAG_HIGHEST="-O3"
467 C_O_FLAG_HI="-O3"
468 C_O_FLAG_NORM="-O2"
469 fi
470 C_O_FLAG_DEBUG="-O0"
471 C_O_FLAG_NONE="-O0"
472 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
473 C_O_FLAG_HIGHEST="-O3"
474 C_O_FLAG_HI="-O3 -qstrict"
475 C_O_FLAG_NORM="-O2"
476 C_O_FLAG_DEBUG="-qnoopt"
477 C_O_FLAG_NONE="-qnoop"
478 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
479 C_O_FLAG_HIGHEST="-O2"
480 C_O_FLAG_HI="-O1"
481 C_O_FLAG_NORM="-O1"
482 C_O_FLAG_DEBUG="-Od"
483 C_O_FLAG_NONE="-Od"
484 fi
485 CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
486 CXX_O_FLAG_HI="$C_O_FLAG_HI"
487 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
488 CXX_O_FLAG_DEBUG="$C_O_FLAG_DEBUG"
489 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
490 fi
491
492 # Adjust optimization flags according to debug level.
493 case $DEBUG_LEVEL in
494 release )
495 # no adjustment
496 ;;
497 fastdebug )
498 # Not quite so much optimization
499 C_O_FLAG_HI="$C_O_FLAG_NORM"
500 CXX_O_FLAG_HI="$CXX_O_FLAG_NORM"
501 ;;
502 slowdebug )
503 # Disable optimization
504 C_O_FLAG_HIGHEST="$C_O_FLAG_DEBUG"
505 C_O_FLAG_HI="$C_O_FLAG_DEBUG"
506 C_O_FLAG_NORM="$C_O_FLAG_DEBUG"
507 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_DEBUG"
508 CXX_O_FLAG_HI="$CXX_O_FLAG_DEBUG"
509 CXX_O_FLAG_NORM="$CXX_O_FLAG_DEBUG"
510 ;;
511 esac
512
513 AC_SUBST(C_O_FLAG_HIGHEST)
514 AC_SUBST(C_O_FLAG_HI)
515 AC_SUBST(C_O_FLAG_NORM)
516 AC_SUBST(C_O_FLAG_DEBUG)
517 AC_SUBST(C_O_FLAG_NONE)
518 AC_SUBST(CXX_O_FLAG_HIGHEST)
519 AC_SUBST(CXX_O_FLAG_HI)
520 AC_SUBST(CXX_O_FLAG_NORM)
521 AC_SUBST(CXX_O_FLAG_DEBUG)
522 AC_SUBST(CXX_O_FLAG_NONE)
523 ])
524
525 AC_DEFUN_ONCE([FLAGS_SETUP_COMPILER_FLAGS_FOR_JDK],
526 [
527 # Special extras...
528 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
529 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
530 CFLAGS_JDKLIB_EXTRA="${CFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
531 CXXFLAGS_JDKLIB_EXTRA="${CXXFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
532 fi
533 CFLAGS_JDKLIB_EXTRA="${CFLAGS_JDKLIB_EXTRA} -errtags=yes -errfmt"
534 CXXFLAGS_JDKLIB_EXTRA="${CXXFLAGS_JDKLIB_EXTRA} -errtags=yes -errfmt"
535 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
536 CFLAGS_JDK="${CFLAGS_JDK} -qchars=signed -qfullpath -qsaveopt"
537 CXXFLAGS_JDK="${CXXFLAGS_JDK} -qchars=signed -qfullpath -qsaveopt"
538 fi
539
540 CFLAGS_JDK="${CFLAGS_JDK} $EXTRA_CFLAGS"
541 CXXFLAGS_JDK="${CXXFLAGS_JDK} $EXTRA_CXXFLAGS"
542 LDFLAGS_JDK="${LDFLAGS_JDK} $EXTRA_LDFLAGS"
543
544 ###############################################################################
545 #
546 # Now setup the CFLAGS and LDFLAGS for the JDK build.
547 # Later we will also have CFLAGS and LDFLAGS for the hotspot subrepo build.
548 #
549
550 # Setup compiler/platform specific flags into
551 # CFLAGS_JDK - C Compiler flags
552 # CXXFLAGS_JDK - C++ Compiler flags
553 # COMMON_CCXXFLAGS_JDK - common to C and C++
554 if test "x$TOOLCHAIN_TYPE" = xgcc; then
555 if test "x$OPENJDK_TARGET_CPU" = xx86; then
556 # Force compatibility with i586 on 32 bit intel platforms.
557 COMMON_CCXXFLAGS="${COMMON_CCXXFLAGS} -march=i586"
558 fi
559 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS $COMMON_CCXXFLAGS_JDK -Wall -Wextra -Wno-unused -Wno-unused-parameter -Wformat=2 \
560 -pipe -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
561 case $OPENJDK_TARGET_CPU_ARCH in
562 arm )
563 # on arm we don't prevent gcc to omit frame pointer but do prevent strict aliasing
564 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
565 ;;
566 ppc )
567 # on ppc we don't prevent gcc to omit frame pointer but do prevent strict aliasing
568 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
569 ;;
570 * )
571 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -fno-omit-frame-pointer"
572 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
573 ;;
574 esac
575 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
576 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS $COMMON_CCXXFLAGS_JDK -DTRACING -DMACRO_MEMSYS_OPS -DBREAKPTS"
577 if test "x$OPENJDK_TARGET_CPU_ARCH" = xx86; then
578 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DcpuIntel -Di586 -D$OPENJDK_TARGET_CPU_LEGACY_LIB"
579 fi
580
581 CFLAGS_JDK="$CFLAGS_JDK -xc99=%none -xCC -errshort=tags -Xa -v -mt -W0,-noglobal"
582 CXXFLAGS_JDK="$CXXFLAGS_JDK -errtags=yes +w -mt -features=no%except -DCC_NOEX -norunpath -xnolib"
583 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
584 CFLAGS_JDK="$CFLAGS_JDK -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
585 CXXFLAGS_JDK="$CXXFLAGS_JDK -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
586 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
587 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS $COMMON_CCXXFLAGS_JDK \
588 -Zi -MD -Zc:wchar_t- -W3 -wd4800 \
589 -DWIN32_LEAN_AND_MEAN \
590 -D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE \
591 -D_WINSOCK_DEPRECATED_NO_WARNINGS \
592 -DWIN32 -DIAL"
593 if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
594 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_AMD64_ -Damd64"
595 else
596 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_X86_ -Dx86"
597 fi
598 # If building with Visual Studio 2010, we can still use _STATIC_CPPLIB to
599 # avoid bundling msvcpNNN.dll. Doesn't work with newer versions of visual
600 # studio.
601 if test "x$TOOLCHAIN_VERSION" = "x2010"; then
602 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK \
603 -D_STATIC_CPPLIB -D_DISABLE_DEPRECATE_STATIC_CPPLIB"
604 fi
605 fi
606
607 ###############################################################################
608
609 # Adjust flags according to debug level.
610 case $DEBUG_LEVEL in
611 fastdebug | slowdebug )
612 CFLAGS_JDK="$CFLAGS_JDK $CFLAGS_DEBUG_SYMBOLS $CFLAGS_DEBUG_OPTIONS"
613 CXXFLAGS_JDK="$CXXFLAGS_JDK $CXXFLAGS_DEBUG_SYMBOLS $CXXFLAGS_DEBUG_OPTIONS"
614 JAVAC_FLAGS="$JAVAC_FLAGS -g"
615 ;;
616 release )
617 ;;
618 * )
619 AC_MSG_ERROR([Unrecognized \$DEBUG_LEVEL: $DEBUG_LEVEL])
620 ;;
621 esac
622
623 # Setup LP64
624 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK $ADD_LP64"
625
626 # Set some common defines. These works for all compilers, but assume
627 # -D is universally accepted.
628
629 # Setup endianness
630 if test "x$OPENJDK_TARGET_CPU_ENDIAN" = xlittle; then
631 # The macro _LITTLE_ENDIAN needs to be defined the same to avoid the
632 # Sun C compiler warning message: warning: macro redefined: _LITTLE_ENDIAN
633 # (The Solaris X86 system defines this in file /usr/include/sys/isa_defs.h).
634 # Note: -Dmacro is the same as #define macro 1
635 # -Dmacro= is the same as #define macro
636 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
637 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_LITTLE_ENDIAN="
638 else
639 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_LITTLE_ENDIAN"
640 fi
641 else
642 # Same goes for _BIG_ENDIAN. Do we really need to set *ENDIAN on Solaris if they
643 # are defined in the system?
644 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
645 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_BIG_ENDIAN="
646 else
647 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_BIG_ENDIAN"
648 fi
649 fi
650
651 # Setup target OS define. Use OS target name but in upper case.
652 OPENJDK_TARGET_OS_UPPERCASE=`$ECHO $OPENJDK_TARGET_OS | $TR 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
653 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D$OPENJDK_TARGET_OS_UPPERCASE"
654
655 # Setup target CPU
656 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DARCH='\"$OPENJDK_TARGET_CPU_LEGACY\"' -D$OPENJDK_TARGET_CPU_LEGACY"
657
658 # Setup debug/release defines
659 if test "x$DEBUG_LEVEL" = xrelease; then
660 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DNDEBUG"
661 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
662 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DTRIMMED"
663 fi
664 else
665 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DDEBUG"
666 fi
667
668 # Setup release name
669 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DRELEASE='\"\$(RELEASE)\"'"
670
671
672 # Set some additional per-OS defines.
673 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
674 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_ALLBSD_SOURCE -D_DARWIN_UNLIMITED_SELECT"
675 elif test "x$OPENJDK_TARGET_OS" = xaix; then
676 # FIXME: PPC64 should not be here.
677 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DPPC64"
678 elif test "x$OPENJDK_TARGET_OS" = xbsd; then
679 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_ALLBSD_SOURCE"
680 fi
681
682 # Additional macosx handling
683 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
684 # Setting these parameters makes it an error to link to macosx APIs that are
685 # newer than the given OS version and makes the linked binaries compatible
686 # even if built on a newer version of the OS.
687 # The expected format is X.Y.Z
688 MACOSX_VERSION_MIN=10.7.0
689 AC_SUBST(MACOSX_VERSION_MIN)
690
691 # The macro takes the version with no dots, ex: 1070
692 # Let the flags variables get resolved in make for easier override on make
693 # command line.
694 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DMAC_OS_X_VERSION_MAX_ALLOWED=\$(subst .,,\$(MACOSX_VERSION_MIN)) -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
695 LDFLAGS_JDK="$LDFLAGS_JDK -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
696 fi
697
698 # Setup some hard coded includes
699 COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK \
700 -I${JDK_TOPDIR}/src/java.base/share/native/include \
701 -I${JDK_TOPDIR}/src/java.base/$OPENJDK_TARGET_OS/native/include \
702 -I${JDK_TOPDIR}/src/java.base/$OPENJDK_TARGET_OS_TYPE/native/include \
703 -I${JDK_TOPDIR}/src/java.base/share/native/libjava \
704 -I${JDK_TOPDIR}/src/java.base/$OPENJDK_TARGET_OS_TYPE/native/libjava"
705
706 # The shared libraries are compiled using the picflag.
707 CFLAGS_JDKLIB="$COMMON_CCXXFLAGS_JDK $CFLAGS_JDK $PICFLAG $CFLAGS_JDKLIB_EXTRA"
708 CXXFLAGS_JDKLIB="$COMMON_CCXXFLAGS_JDK $CXXFLAGS_JDK $PICFLAG $CXXFLAGS_JDKLIB_EXTRA"
709
710 # Executable flags
711 CFLAGS_JDKEXE="$COMMON_CCXXFLAGS_JDK $CFLAGS_JDK"
712 CXXFLAGS_JDKEXE="$COMMON_CCXXFLAGS_JDK $CXXFLAGS_JDK"
713
714 AC_SUBST(CFLAGS_JDKLIB)
715 AC_SUBST(CFLAGS_JDKEXE)
716 AC_SUBST(CXXFLAGS_JDKLIB)
717 AC_SUBST(CXXFLAGS_JDKEXE)
718
719 # Flags for compiling test libraries
720 CFLAGS_TESTLIB="$COMMON_CCXXFLAGS_JDK $CFLAGS_JDK $PICFLAG $CFLAGS_JDKLIB_EXTRA"
721 CXXFLAGS_TESTLIB="$COMMON_CCXXFLAGS_JDK $CXXFLAGS_JDK $PICFLAG $CXXFLAGS_JDKLIB_EXTRA"
722
723 # Flags for compiling test executables
724 CFLAGS_TESTEXE="$COMMON_CCXXFLAGS_JDK $CFLAGS_JDK"
725 CXXFLAGS_TESTEXE="$COMMON_CCXXFLAGS_JDK $CXXFLAGS_JDK"
726
727 AC_SUBST(CFLAGS_TESTLIB)
728 AC_SUBST(CFLAGS_TESTEXE)
729 AC_SUBST(CXXFLAGS_TESTLIB)
730 AC_SUBST(CXXFLAGS_TESTEXE)
731
732 # Setup LDFLAGS et al.
733 #
734
735 # Now this is odd. The JDK native libraries have to link against libjvm.so
736 # On 32-bit machines there is normally two distinct libjvm.so:s, client and server.
737 # Which should we link to? Are we lucky enough that the binary api to the libjvm.so library
738 # is identical for client and server? Yes. Which is picked at runtime (client or server)?
739 # Neither, since the chosen libjvm.so has already been loaded by the launcher, all the following
740 # libraries will link to whatever is in memory. Yuck.
741 #
742 # Thus we offer the compiler to find libjvm.so first in server then in client. It works. Ugh.
743 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
744 LDFLAGS_JDK="$LDFLAGS_JDK -nologo -opt:ref -incremental:no"
745 if test "x$OPENJDK_TARGET_CPU_BITS" = "x32"; then
746 LDFLAGS_JDK="$LDFLAGS_JDK -safeseh"
747 fi
748 # TODO: make -debug optional "--disable-full-debug-symbols"
749 LDFLAGS_JDK="$LDFLAGS_JDK -debug"
750 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
751 # If this is a --hash-style=gnu system, use --hash-style=both, why?
752 # We have previously set HAS_GNU_HASH if this is the case
753 if test -n "$HAS_GNU_HASH"; then
754 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker --hash-style=both"
755 fi
756 if test "x$OPENJDK_TARGET_OS" = xlinux; then
757 # And since we now know that the linker is gnu, then add -z defs, to forbid
758 # undefined symbols in object files.
759 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -z -Xlinker defs"
760 case $DEBUG_LEVEL in
761 release )
762 # tell linker to optimize libraries.
763 # Should this be supplied to the OSS linker as well?
764 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -O1"
765 ;;
766 slowdebug )
767 if test "x$HAS_LINKER_NOW" = "xtrue"; then
768 # do relocations at load
769 LDFLAGS_JDK="$LDFLAGS_JDK $LINKER_NOW_FLAG"
770 LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK $LINKER_NOW_FLAG"
771 fi
772 if test "x$HAS_LINKER_RELRO" = "xtrue"; then
773 # mark relocations read only
774 LDFLAGS_JDK="$LDFLAGS_JDK $LINKER_RELRO_FLAG"
775 LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK $LINKER_RELRO_FLAG"
776 fi
777 ;;
778 fastdebug )
779 if test "x$HAS_LINKER_RELRO" = "xtrue"; then
780 # mark relocations read only
781 LDFLAGS_JDK="$LDFLAGS_JDK $LINKER_RELRO_FLAG"
782 LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK $LINKER_RELRO_FLAG"
783 fi
784 ;;
785 * )
786 AC_MSG_ERROR([Unrecognized \$DEBUG_LEVEL: $DEBUG_LEVEL])
787 ;;
788 esac
789 fi
790 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
791 LDFLAGS_JDK="$LDFLAGS_JDK -z defs -xildoff -ztext"
792 LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK -norunpath -xnolib"
793 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
794 LDFLAGS_JDK="${LDFLAGS_JDK} -brtl -bnolibpath -liconv -bexpall -bernotok"
795 fi
796
797 # Customize LDFLAGS for executables
798
799 LDFLAGS_JDKEXE="${LDFLAGS_JDK}"
800
801 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
802 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
803 LDFLAGS_STACK_SIZE=1048576
804 else
805 LDFLAGS_STACK_SIZE=327680
806 fi
807 LDFLAGS_JDKEXE="${LDFLAGS_JDKEXE} /STACK:$LDFLAGS_STACK_SIZE"
808 elif test "x$OPENJDK_TARGET_OS" = xlinux; then
809 LDFLAGS_JDKEXE="$LDFLAGS_JDKEXE -Xlinker --allow-shlib-undefined"
810 fi
811
812 # Customize LDFLAGS for libs
813 LDFLAGS_JDKLIB="${LDFLAGS_JDK}"
814
815 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
816 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -dll -libpath:${OUTPUT_ROOT}/support/modules_libs/java.base"
817 LDFLAGS_JDKLIB_SUFFIX=""
818 else
819 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} ${SHARED_LIBRARY_FLAGS} \
820 -L${OUTPUT_ROOT}/support/modules_libs/java.base${OPENJDK_TARGET_CPU_LIBDIR}"
821
822 # On some platforms (mac) the linker warns about non existing -L dirs.
823 # Add server first if available. Linking aginst client does not always produce the same results.
824 # Only add client dir if client is being built. Add minimal (note not minimal1) if only building minimal1.
825 # Default to server for other variants.
826 if test "x$JVM_VARIANT_SERVER" = xtrue; then
827 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${OUTPUT_ROOT}/support/modules_libs/java.base${OPENJDK_TARGET_CPU_LIBDIR}/server"
828 elif test "x$JVM_VARIANT_CLIENT" = xtrue; then
829 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${OUTPUT_ROOT}/support/modules_libs/java.base${OPENJDK_TARGET_CPU_LIBDIR}/client"
830 elif test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
831 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${OUTPUT_ROOT}/support/modules_libs/java.base${OPENJDK_TARGET_CPU_LIBDIR}/minimal"
832 else
833 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${OUTPUT_ROOT}/support/modules_libs/java.base${OPENJDK_TARGET_CPU_LIBDIR}/server"
834 fi
835
836 LDFLAGS_JDKLIB_SUFFIX="-ljava -ljvm"
837 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
838 LDFLAGS_JDKLIB_SUFFIX="$LDFLAGS_JDKLIB_SUFFIX -lc"
839 fi
840 fi
841
842 AC_SUBST(LDFLAGS_JDKLIB)
843 AC_SUBST(LDFLAGS_JDKEXE)
844 AC_SUBST(LDFLAGS_JDKLIB_SUFFIX)
845 AC_SUBST(LDFLAGS_JDKEXE_SUFFIX)
846 AC_SUBST(LDFLAGS_CXX_JDK)
847
848 LDFLAGS_TESTLIB="$LDFLAGS_JDKLIB"
849 LDFLAGS_TESTEXE="$LDFLAGS_JDKEXE"
850 LDFLAGS_TESTLIB_SUFFIX="$LDFLAGS_JDKLIB_SUFFIX"
851 LDFLAGS_TESTEXE_SUFFIX="$LDFLAGS_JDKEXE_SUFFIX"
852
853 AC_SUBST(LDFLAGS_TESTLIB)
854 AC_SUBST(LDFLAGS_TESTEXE)
855 AC_SUBST(LDFLAGS_TESTLIB_SUFFIX)
856 AC_SUBST(LDFLAGS_TESTEXE_SUFFIX)
857 ])
858
859 # FLAGS_COMPILER_CHECK_ARGUMENTS([ARGUMENT], [RUN-IF-TRUE],
860 # [RUN-IF-FALSE])
861 # ------------------------------------------------------------
862 # Check that the c and c++ compilers support an argument
863 AC_DEFUN([FLAGS_COMPILER_CHECK_ARGUMENTS],
864 [
865 AC_MSG_CHECKING([if compiler supports "$1"])
866 supports=yes
867
868 saved_cflags="$CFLAGS"
869 CFLAGS="$CFLAGS $1"
870 AC_LANG_PUSH([C])
871 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
872 [supports=no])
873 AC_LANG_POP([C])
874 CFLAGS="$saved_cflags"
875
876 saved_cxxflags="$CXXFLAGS"
877 CXXFLAGS="$CXXFLAG $1"
878 AC_LANG_PUSH([C++])
879 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
880 [supports=no])
881 AC_LANG_POP([C++])
882 CXXFLAGS="$saved_cxxflags"
883
884 AC_MSG_RESULT([$supports])
885 if test "x$supports" = "xyes" ; then
886 m4_ifval([$2], [$2], [:])
887 else
888 m4_ifval([$3], [$3], [:])
889 fi
890 ])
891
892 # FLAGS_LINKER_CHECK_ARGUMENTS([ARGUMENT], [RUN-IF-TRUE],
893 # [RUN-IF-FALSE])
894 # ------------------------------------------------------------
895 # Check that the linker support an argument
896 AC_DEFUN([FLAGS_LINKER_CHECK_ARGUMENTS],
897 [
898 AC_MSG_CHECKING([if linker supports "$1"])
899 supports=yes
900
901 saved_ldflags="$LDFLAGS"
902 LDFLAGS="$LDFLAGS $1"
903 AC_LANG_PUSH([C])
904 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],[[]])],
905 [], [supports=no])
906 AC_LANG_POP([C])
907 LDFLAGS="$saved_ldflags"
908
909 AC_MSG_RESULT([$supports])
910 if test "x$supports" = "xyes" ; then
911 m4_ifval([$2], [$2], [:])
912 else
913 m4_ifval([$3], [$3], [:])
914 fi
915 ])
916
917 AC_DEFUN_ONCE([FLAGS_SETUP_COMPILER_FLAGS_MISC],
918 [
919 # Some Zero and Shark settings.
920 # ZERO_ARCHFLAG tells the compiler which mode to build for
921 case "${OPENJDK_TARGET_CPU}" in
922 s390)
923 ZERO_ARCHFLAG="${COMPILER_TARGET_BITS_FLAG}31"
924 ;;
925 *)
926 ZERO_ARCHFLAG="${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
927 esac
928 FLAGS_COMPILER_CHECK_ARGUMENTS([$ZERO_ARCHFLAG], [], [ZERO_ARCHFLAG=""])
929 AC_SUBST(ZERO_ARCHFLAG)
930
931 # Check that the compiler supports -mX (or -qX on AIX) flags
932 # Set COMPILER_SUPPORTS_TARGET_BITS_FLAG to 'true' if it does
933 FLAGS_COMPILER_CHECK_ARGUMENTS([${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}],
934 [COMPILER_SUPPORTS_TARGET_BITS_FLAG=true],
935 [COMPILER_SUPPORTS_TARGET_BITS_FLAG=false])
936 AC_SUBST(COMPILER_SUPPORTS_TARGET_BITS_FLAG)
937
938 AC_ARG_ENABLE([warnings-as-errors], [AS_HELP_STRING([--disable-warnings-as-errors],
939 [do not consider native warnings to be an error @<:@enabled@:>@])])
940
941 AC_MSG_CHECKING([if native warnings are errors])
942 if test "x$enable_warnings_as_errors" = "xyes"; then
943 AC_MSG_RESULT([yes (explicitely set)])
944 WARNINGS_AS_ERRORS=true
945 elif test "x$enable_warnings_as_errors" = "xno"; then
946 AC_MSG_RESULT([no])
947 WARNINGS_AS_ERRORS=false
948 elif test "x$enable_warnings_as_errors" = "x"; then
949 AC_MSG_RESULT([yes (default)])
950 WARNINGS_AS_ERRORS=true
951 else
952 AC_MSG_ERROR([--enable-warnings-as-errors accepts no argument])
953 fi
954 AC_SUBST(WARNINGS_AS_ERRORS)
955
956 case "${TOOLCHAIN_TYPE}" in
957 microsoft)
958 DISABLE_WARNING_PREFIX="-wd"
959 CFLAGS_WARNINGS_ARE_ERRORS="-WX"
960 ;;
961 solstudio)
962 DISABLE_WARNING_PREFIX="-erroff="
963 CFLAGS_WARNINGS_ARE_ERRORS="-errtags -errwarn=%all"
964 ;;
965 gcc)
966 # Prior to gcc 4.4, a -Wno-X where X is unknown for that version of gcc will cause an error
967 FLAGS_COMPILER_CHECK_ARGUMENTS([-Wno-this-is-a-warning-that-do-not-exist],
968 [GCC_CAN_DISABLE_WARNINGS=true],
969 [GCC_CAN_DISABLE_WARNINGS=false]
970 )
971 if test "x$GCC_CAN_DISABLE_WARNINGS" = "xtrue"; then
972 DISABLE_WARNING_PREFIX="-Wno-"
973 else
974 DISABLE_WARNING_PREFIX=
975 fi
976 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
977 ;;
978 clang)
979 DISABLE_WARNING_PREFIX="-Wno-"
980 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
981 ;;
982 esac
983 AC_SUBST(DISABLE_WARNING_PREFIX)
984 AC_SUBST(CFLAGS_WARNINGS_ARE_ERRORS)
985 ])