1 #
2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
27 # Converts autoconf style CPU name to OpenJDK style, into
28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
30 [
31 # First argument is the cpu name from the trip/quad
32 case "$1" in
33 x86_64)
34 VAR_CPU=x86_64
35 VAR_CPU_ARCH=x86
36 VAR_CPU_BITS=64
37 VAR_CPU_ENDIAN=little
38 ;;
39 i?86)
40 VAR_CPU=x86
41 VAR_CPU_ARCH=x86
42 VAR_CPU_BITS=32
43 VAR_CPU_ENDIAN=little
44 ;;
45 arm*)
46 VAR_CPU=arm
47 VAR_CPU_ARCH=arm
48 VAR_CPU_BITS=32
49 VAR_CPU_ENDIAN=little
50 ;;
51 aarch64)
52 VAR_CPU=aarch64
53 VAR_CPU_ARCH=aarch64
54 VAR_CPU_BITS=64
55 VAR_CPU_ENDIAN=little
56 ;;
57 powerpc)
58 VAR_CPU=ppc
59 VAR_CPU_ARCH=ppc
60 VAR_CPU_BITS=32
61 VAR_CPU_ENDIAN=big
62 ;;
63 powerpc64)
64 VAR_CPU=ppc64
65 VAR_CPU_ARCH=ppc
66 VAR_CPU_BITS=64
67 VAR_CPU_ENDIAN=big
68 ;;
69 powerpc64le)
70 VAR_CPU=ppc64
71 VAR_CPU_ARCH=ppc
72 VAR_CPU_BITS=64
73 VAR_CPU_ENDIAN=little
74 ;;
75 s390)
76 VAR_CPU=s390
77 VAR_CPU_ARCH=s390
78 VAR_CPU_BITS=32
79 VAR_CPU_ENDIAN=big
80 ;;
81 s390x)
82 VAR_CPU=s390x
83 VAR_CPU_ARCH=s390
84 VAR_CPU_BITS=64
85 VAR_CPU_ENDIAN=big
86 ;;
87 sparc)
88 VAR_CPU=sparc
89 VAR_CPU_ARCH=sparc
90 VAR_CPU_BITS=32
91 VAR_CPU_ENDIAN=big
92 ;;
93 sparcv9|sparc64)
94 VAR_CPU=sparcv9
95 VAR_CPU_ARCH=sparc
96 VAR_CPU_BITS=64
97 VAR_CPU_ENDIAN=big
98 ;;
99 *)
100 AC_MSG_ERROR([unsupported cpu $1])
101 ;;
102 esac
103 ])
104
105 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
106 # Converts autoconf style OS name to OpenJDK style, into
107 # VAR_OS, VAR_OS_TYPE and VAR_OS_ENV.
108 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
109 [
110 case "$1" in
111 *linux*)
112 VAR_OS=linux
113 VAR_OS_TYPE=unix
114 ;;
115 *android*)
116 VAR_OS=android
117 VAR_OS_TYPE=unix
118 ;;
119 *solaris*)
120 VAR_OS=solaris
121 VAR_OS_TYPE=unix
122 ;;
123 *darwin*)
124 VAR_OS=macosx
125 VAR_OS_TYPE=unix
126 ;;
127 *ios*)
128 VAR_OS=ios
129 VAR_OS_TYPE=unix
130 ;;
131 *bsd*)
132 VAR_OS=bsd
133 VAR_OS_TYPE=unix
134 ;;
135 *cygwin*)
136 VAR_OS=windows
137 VAR_OS_ENV=windows.cygwin
138 ;;
139 *mingw*)
140 VAR_OS=windows
141 VAR_OS_ENV=windows.msys
142 ;;
143 *aix*)
144 VAR_OS=aix
145 VAR_OS_TYPE=unix
146 ;;
147 *)
148 AC_MSG_ERROR([unsupported operating system $1])
149 ;;
150 esac
151 ])
152
153 # Expects $host_os $host_cpu $build_os and $build_cpu
154 # and $with_target_bits to have been setup!
155 #
156 # Translate the standard triplet(quadruplet) definition
157 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
158 # OPENJDK_BUILD_OS, etc.
159 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
160 [
161 # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
162 # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
163 # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
164 # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
165 OPENJDK_TARGET_AUTOCONF_NAME="$host"
166 OPENJDK_BUILD_AUTOCONF_NAME="$build"
167 AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
168 AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
169
170 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
171 PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
172 PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
173 # ..and setup our own variables. (Do this explicitely to facilitate searching)
174 OPENJDK_BUILD_OS="$VAR_OS"
175 if test "x$VAR_OS_TYPE" != x; then
176 OPENJDK_BUILD_OS_TYPE="$VAR_OS_TYPE"
177 else
178 OPENJDK_BUILD_OS_TYPE="$VAR_OS"
179 fi
180 if test "x$VAR_OS_ENV" != x; then
181 OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
182 else
183 OPENJDK_BUILD_OS_ENV="$VAR_OS"
184 fi
185 OPENJDK_BUILD_CPU="$VAR_CPU"
186 OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
187 OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
188 OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
189 AC_SUBST(OPENJDK_BUILD_OS)
190 AC_SUBST(OPENJDK_BUILD_OS_TYPE)
191 AC_SUBST(OPENJDK_BUILD_OS_ENV)
192 AC_SUBST(OPENJDK_BUILD_CPU)
193 AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
194 AC_SUBST(OPENJDK_BUILD_CPU_BITS)
195 AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
196
197 AC_MSG_CHECKING([openjdk-build os-cpu])
198 AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
199
200 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
201 PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
202 PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
203 # ... and setup our own variables. (Do this explicitely to facilitate searching)
204 OPENJDK_TARGET_OS="$VAR_OS"
205 if test "x$VAR_OS_TYPE" != x; then
206 OPENJDK_TARGET_OS_TYPE="$VAR_OS_TYPE"
207 else
208 OPENJDK_TARGET_OS_TYPE="$VAR_OS"
209 fi
210 if test "x$VAR_OS_ENV" != x; then
211 OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
212 else
213 OPENJDK_TARGET_OS_ENV="$VAR_OS"
214 fi
215 OPENJDK_TARGET_CPU="$VAR_CPU"
216 OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
217 OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
218 OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
219 AC_SUBST(OPENJDK_TARGET_OS)
220 AC_SUBST(OPENJDK_TARGET_OS_TYPE)
221 AC_SUBST(OPENJDK_TARGET_OS_ENV)
222 AC_SUBST(OPENJDK_TARGET_CPU)
223 AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
224 AC_SUBST(OPENJDK_TARGET_CPU_BITS)
225 AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
226
227 AC_MSG_CHECKING([openjdk-target os-cpu])
228 AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
229 ])
230
231 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
232 # accordingly. Must be done after setting up build and target system, but before
233 # doing anything else with these values.
234 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
235 [
236 AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
237 [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
238
239 # We have three types of compiles:
240 # native == normal compilation, target system == build system
241 # cross == traditional cross compilation, target system != build system; special toolchain needed
242 # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
243 #
244 if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
245 # We're doing a proper cross-compilation
246 COMPILE_TYPE="cross"
247 else
248 COMPILE_TYPE="native"
249 fi
250
251 if test "x$with_target_bits" != x; then
252 if test "x$COMPILE_TYPE" = "xcross"; then
253 AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
254 fi
255
256 if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
257 # A reduced build is requested
258 COMPILE_TYPE="reduced"
259 OPENJDK_TARGET_CPU_BITS=32
260 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
261 OPENJDK_TARGET_CPU=x86
262 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
263 OPENJDK_TARGET_CPU=sparc
264 else
265 AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
266 fi
267 elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
268 AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
269 elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
270 AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
271 else
272 AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
273 fi
274 fi
275 AC_SUBST(COMPILE_TYPE)
276
277 AC_MSG_CHECKING([compilation type])
278 AC_MSG_RESULT([$COMPILE_TYPE])
279 ])
280
281 # Setup the legacy variables, for controlling the old makefiles.
282 #
283 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
284 [
285 # Also store the legacy naming of the cpu.
286 # Ie i586 and amd64 instead of x86 and x86_64
287 OPENJDK_TARGET_CPU_LEGACY="$OPENJDK_TARGET_CPU"
288 if test "x$OPENJDK_TARGET_CPU" = xx86; then
289 OPENJDK_TARGET_CPU_LEGACY="i586"
290 elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
291 # On all platforms except MacOSX replace x86_64 with amd64.
292 OPENJDK_TARGET_CPU_LEGACY="amd64"
293 fi
294 AC_SUBST(OPENJDK_TARGET_CPU_LEGACY)
295
296 # And the second legacy naming of the cpu.
297 # Ie i386 and amd64 instead of x86 and x86_64.
298 OPENJDK_TARGET_CPU_LEGACY_LIB="$OPENJDK_TARGET_CPU"
299 if test "x$OPENJDK_TARGET_CPU" = xx86; then
300 OPENJDK_TARGET_CPU_LEGACY_LIB="i386"
301 elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then
302 OPENJDK_TARGET_CPU_LEGACY_LIB="amd64"
303 fi
304 AC_SUBST(OPENJDK_TARGET_CPU_LEGACY_LIB)
305
306 # This is the name of the cpu (but using i386 and amd64 instead of
307 # x86 and x86_64, respectively), preceeded by a /, to be used when
308 # locating libraries. On macosx, it's empty, though.
309 OPENJDK_TARGET_CPU_LIBDIR="/$OPENJDK_TARGET_CPU_LEGACY_LIB"
310 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
311 OPENJDK_TARGET_CPU_LIBDIR=""
312 fi
313 AC_SUBST(OPENJDK_TARGET_CPU_LIBDIR)
314
315 # OPENJDK_TARGET_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
316 # /amd64 or /sparcv9. This string is appended to some library paths, like this:
317 # /usr/lib${OPENJDK_TARGET_CPU_ISADIR}/libexample.so
318 OPENJDK_TARGET_CPU_ISADIR=""
319 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
320 if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
321 OPENJDK_TARGET_CPU_ISADIR="/amd64"
322 elif test "x$OPENJDK_TARGET_CPU" = xsparcv9; then
323 OPENJDK_TARGET_CPU_ISADIR="/sparcv9"
324 fi
325 fi
326 AC_SUBST(OPENJDK_TARGET_CPU_ISADIR)
327
328 # Setup OPENJDK_TARGET_CPU_OSARCH, which is used to set the os.arch Java system property
329 OPENJDK_TARGET_CPU_OSARCH="$OPENJDK_TARGET_CPU"
330 if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$OPENJDK_TARGET_CPU" = xx86; then
331 # On linux only, we replace x86 with i386.
332 OPENJDK_TARGET_CPU_OSARCH="i386"
333 elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
334 # On all platforms except macosx, we replace x86_64 with amd64.
335 OPENJDK_TARGET_CPU_OSARCH="amd64"
336 fi
337 AC_SUBST(OPENJDK_TARGET_CPU_OSARCH)
338
339 OPENJDK_TARGET_CPU_JLI="$OPENJDK_TARGET_CPU"
340 if test "x$OPENJDK_TARGET_CPU" = xx86; then
341 OPENJDK_TARGET_CPU_JLI="i386"
342 elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
343 # On all platforms except macosx, we replace x86_64 with amd64.
344 OPENJDK_TARGET_CPU_JLI="amd64"
345 fi
346 # Now setup the -D flags for building libjli.
347 OPENJDK_TARGET_CPU_JLI_CFLAGS="-DLIBARCHNAME='\"$OPENJDK_TARGET_CPU_JLI\"'"
348 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
349 if test "x$OPENJDK_TARGET_CPU_ARCH" = xsparc; then
350 OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"sparc\"' -DLIBARCH64NAME='\"sparcv9\"'"
351 elif test "x$OPENJDK_TARGET_CPU_ARCH" = xx86; then
352 OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"i386\"' -DLIBARCH64NAME='\"amd64\"'"
353 fi
354 fi
355 AC_SUBST(OPENJDK_TARGET_CPU_JLI_CFLAGS)
356
357 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
358 OPENJDK_TARGET_OS_EXPORT_DIR=macosx
359 else
360 OPENJDK_TARGET_OS_EXPORT_DIR=${OPENJDK_TARGET_OS_TYPE}
361 fi
362 AC_SUBST(OPENJDK_TARGET_OS_EXPORT_DIR)
363
364 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
365 A_LP64="LP64:="
366 # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
367 # unpack200.exe
368 if test "x$OPENJDK_TARGET_OS" = xlinux || test "x$OPENJDK_TARGET_OS" = xmacosx; then
369 ADD_LP64="-D_LP64=1"
370 fi
371 fi
372 AC_SUBST(LP64,$A_LP64)
373
374 if test "x$COMPILE_TYPE" = "xcross"; then
375 # FIXME: ... or should this include reduced builds..?
376 DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_TARGET_CPU_LEGACY"
377 else
378 DEFINE_CROSS_COMPILE_ARCH=""
379 fi
380 AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
381
382 # ZERO_ARCHDEF is used to enable architecture-specific code
383 case "${OPENJDK_TARGET_CPU}" in
384 ppc) ZERO_ARCHDEF=PPC32 ;;
385 ppc64) ZERO_ARCHDEF=PPC64 ;;
386 s390*) ZERO_ARCHDEF=S390 ;;
387 sparc*) ZERO_ARCHDEF=SPARC ;;
388 x86_64*) ZERO_ARCHDEF=AMD64 ;;
389 x86) ZERO_ARCHDEF=IA32 ;;
390 *) ZERO_ARCHDEF=$(echo "${OPENJDK_TARGET_CPU_LEGACY_LIB}" | tr a-z A-Z)
391 esac
392 AC_SUBST(ZERO_ARCHDEF)
393 ])
394
395 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
396 [
397 if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
398 REQUIRED_OS_NAME=SunOS
399 REQUIRED_OS_VERSION=5.10
400 fi
401 if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
402 REQUIRED_OS_NAME=Linux
403 REQUIRED_OS_VERSION=2.6
404 fi
405 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
406 REQUIRED_OS_NAME=Windows
407 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
408 REQUIRED_OS_VERSION=5.2
409 else
410 REQUIRED_OS_VERSION=5.1
411 fi
412 fi
413 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
414 REQUIRED_OS_NAME=Darwin
415 REQUIRED_OS_VERSION=11.2
416 fi
417
418 AC_SUBST(REQUIRED_OS_NAME)
419 AC_SUBST(REQUIRED_OS_VERSION)
420 ])
421
422 #%%% Build and target systems %%%
423 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
424 [
425 # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
426 # is confusing; it assumes you are cross-compiling a cross-compiler (!) and "target" is thus the target of the
427 # product you're building. The target of this build is called "host". Since this is confusing to most people, we
428 # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
429 # to use the configure naming style.
430 AC_CANONICAL_BUILD
431 AC_CANONICAL_HOST
432 AC_CANONICAL_TARGET
433
434 PLATFORM_EXTRACT_TARGET_AND_BUILD
435 PLATFORM_SETUP_TARGET_CPU_BITS
436 PLATFORM_SET_RELEASE_FILE_OS_VALUES
437 PLATFORM_SETUP_LEGACY_VARS
438 ])
439
440 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
441 [
442 ###############################################################################
443
444 # Note that this is the build platform OS version!
445
446 OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
447 OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
448 OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
449 OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
450 AC_SUBST(OS_VERSION_MAJOR)
451 AC_SUBST(OS_VERSION_MINOR)
452 AC_SUBST(OS_VERSION_MICRO)
453 ])
454
455 # Support macro for PLATFORM_SETUP_OPENJDK_TARGET_BITS.
456 # Add -mX to various FLAGS variables.
457 AC_DEFUN([PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS],
458 [
459 # When we add flags to the "official" CFLAGS etc, we need to
460 # keep track of these additions in ADDED_CFLAGS etc. These
461 # will later be checked to make sure only controlled additions
462 # have been made to CFLAGS etc.
463 ADDED_CFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
464 ADDED_CXXFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
465 ADDED_LDFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
466
467 CFLAGS="${CFLAGS}${ADDED_CFLAGS}"
468 CXXFLAGS="${CXXFLAGS}${ADDED_CXXFLAGS}"
469 LDFLAGS="${LDFLAGS}${ADDED_LDFLAGS}"
470
471 CFLAGS_JDK="${CFLAGS_JDK}${ADDED_CFLAGS}"
472 CXXFLAGS_JDK="${CXXFLAGS_JDK}${ADDED_CXXFLAGS}"
473 LDFLAGS_JDK="${LDFLAGS_JDK}${ADDED_LDFLAGS}"
474 ])
475
476 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
477 [
478 ###############################################################################
479 #
480 # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
481 # (The JVM can use 32 or 64 bit Java pointers but that decision
482 # is made at runtime.)
483 #
484
485 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xaix; then
486 # Always specify -m flag on Solaris
487 # And -q on AIX because otherwise the compiler produces 32-bit objects by default
488 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
489 elif test "x$COMPILE_TYPE" = xreduced; then
490 if test "x$OPENJDK_TARGET_OS_TYPE" = xunix; then
491 # Specify -m if running reduced on unix platforms
492 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
493 fi
494 fi
495
496 # Make compilation sanity check
497 AC_CHECK_HEADERS([stdio.h], , [
498 AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
499 if test "x$COMPILE_TYPE" = xreduced; then
500 HELP_MSG_MISSING_DEPENDENCY([reduced])
501 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
502 elif test "x$COMPILE_TYPE" = xcross; then
503 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
504 fi
505 AC_MSG_ERROR([Cannot continue.])
506 ])
507
508 AC_CHECK_SIZEOF([int *], [1111])
509
510 # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
511 if test "x$ac_cv_sizeof_int_p" = x; then
512 # The test failed, lets stick to the assumed value.
513 AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
514 else
515 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
516
517 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
518 # This situation may happen on 64-bit platforms where the compiler by default only generates 32-bit objects
519 # Let's try to implicitely set the compilers target architecture and retry the test
520 AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS).])
521 AC_MSG_NOTICE([Retrying with platforms compiler target bits flag to ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}])
522 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
523
524 # We have to unset 'ac_cv_sizeof_int_p' first, otherwise AC_CHECK_SIZEOF will use the previously cached value!
525 unset ac_cv_sizeof_int_p
526 # And we have to undef the definition of SIZEOF_INT_P in confdefs.h by the previous invocation of AC_CHECK_SIZEOF
527 cat >>confdefs.h <<_ACEOF
528 #undef SIZEOF_INT_P
529 _ACEOF
530
531 AC_CHECK_SIZEOF([int *], [1111])
532
533 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
534
535 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
536 AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
537 if test "x$COMPILE_TYPE" = xreduced; then
538 HELP_MSG_MISSING_DEPENDENCY([reduced])
539 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
540 elif test "x$COMPILE_TYPE" = xcross; then
541 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
542 fi
543 AC_MSG_ERROR([Cannot continue.])
544 fi
545 fi
546 fi
547
548 AC_MSG_CHECKING([for target address size])
549 AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
550 ])
551
552 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
553 [
554 ###############################################################################
555 #
556 # Is the target little of big endian?
557 #
558 AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
559
560 if test "x$ENDIAN" = xuniversal_endianness; then
561 AC_MSG_ERROR([Building with both big and little endianness is not supported])
562 fi
563 if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
564 AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
565 fi
566 ])