1 #
2 # Copyright (c) 2011, 2020, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ################################################################################
27 #
28 # Setup flags for C/C++ compiler
29 #
30
31 ###############################################################################
32 #
33 # How to compile shared libraries.
34 #
35 AC_DEFUN([FLAGS_SETUP_SHARED_LIBS],
36 [
37 if test "x$TOOLCHAIN_TYPE" = xgcc; then
38 # Default works for linux, might work on other platforms as well.
39 SHARED_LIBRARY_FLAGS='-shared'
40 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
41 SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
42 SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
43 SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
44
45 elif test "x$TOOLCHAIN_TYPE" = xclang; then
46 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
47 # Linking is different on MacOSX
48 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0"
49 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,@loader_path$(or [$]1,/.)'
50 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
51 SET_SHARED_LIBRARY_NAME='-Wl,-install_name,@rpath/[$]1'
52 SET_SHARED_LIBRARY_MAPFILE='-Wl,-exported_symbols_list,[$]1'
53
54 else
55 # Default works for linux, might work on other platforms as well.
56 SHARED_LIBRARY_FLAGS='-shared'
57 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
58 SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
59 SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
60
61 # arm specific settings
62 if test "x$OPENJDK_TARGET_CPU" = "xarm"; then
63 # '-Wl,-z,origin' isn't used on arm.
64 SET_SHARED_LIBRARY_ORIGIN='-Wl,-rpath,\$$$$ORIGIN[$]1'
65 else
66 SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
67 fi
68 fi
69
70 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
71 SHARED_LIBRARY_FLAGS="-qmkshrobj -bM:SRE -bnoentry"
72 SET_EXECUTABLE_ORIGIN=""
73 SET_SHARED_LIBRARY_ORIGIN=''
74 SET_SHARED_LIBRARY_NAME=''
75 SET_SHARED_LIBRARY_MAPFILE=''
76
77 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
78 SHARED_LIBRARY_FLAGS="-dll"
79 SET_EXECUTABLE_ORIGIN=''
80 SET_SHARED_LIBRARY_ORIGIN=''
81 SET_SHARED_LIBRARY_NAME=''
82 SET_SHARED_LIBRARY_MAPFILE='-def:[$]1'
83 fi
84
85 AC_SUBST(SET_EXECUTABLE_ORIGIN)
86 AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
87 AC_SUBST(SET_SHARED_LIBRARY_NAME)
88 AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
89 AC_SUBST(SHARED_LIBRARY_FLAGS)
90 ])
91
92 AC_DEFUN([FLAGS_SETUP_DEBUG_SYMBOLS],
93 [
94 # By default don't set any specific assembler debug
95 # info flags for toolchains unless we know they work.
96 # See JDK-8207057.
97 ASFLAGS_DEBUG_SYMBOLS=""
98 # Debug symbols
99 if test "x$TOOLCHAIN_TYPE" = xgcc; then
100 CFLAGS_DEBUG_SYMBOLS="-g"
101 ASFLAGS_DEBUG_SYMBOLS="-g"
102 elif test "x$TOOLCHAIN_TYPE" = xclang; then
103 CFLAGS_DEBUG_SYMBOLS="-g"
104 ASFLAGS_DEBUG_SYMBOLS="-g"
105 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
106 CFLAGS_DEBUG_SYMBOLS="-g1"
107 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
108 CFLAGS_DEBUG_SYMBOLS="-Z7"
109 fi
110
111 AC_SUBST(CFLAGS_DEBUG_SYMBOLS)
112 AC_SUBST(ASFLAGS_DEBUG_SYMBOLS)
113 ])
114
115 AC_DEFUN([FLAGS_SETUP_WARNINGS],
116 [
117 # Set default value.
118 if test "x$TOOLCHAIN_TYPE" != xxlc; then
119 WARNINGS_AS_ERRORS_DEFAULT=true
120 else
121 WARNINGS_AS_ERRORS_DEFAULT=false
122 fi
123
124 UTIL_ARG_ENABLE(NAME: warnings-as-errors, DEFAULT: $WARNINGS_AS_ERRORS_DEFAULT,
125 RESULT: WARNINGS_AS_ERRORS,
126 DEFAULT_DESC: [auto],
127 DESC: [consider native warnings to be an error])
128 AC_SUBST(WARNINGS_AS_ERRORS)
129
130 case "${TOOLCHAIN_TYPE}" in
131 microsoft)
132 DISABLE_WARNING_PREFIX="-wd"
133 CFLAGS_WARNINGS_ARE_ERRORS="-WX"
134
135 WARNINGS_ENABLE_ALL="-W3"
136 DISABLED_WARNINGS="4800"
137 ;;
138
139 gcc)
140 DISABLE_WARNING_PREFIX="-Wno-"
141 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
142
143 # Additional warnings that are not activated by -Wall and -Wextra
144 WARNINGS_ENABLE_ADDITIONAL="-Wpointer-arith -Wsign-compare \
145 -Wunused-function -Wundef -Wunused-value -Wreturn-type \
146 -Wtrampolines"
147 WARNINGS_ENABLE_ADDITIONAL_CXX="-Woverloaded-virtual -Wreorder"
148 WARNINGS_ENABLE_ALL_CFLAGS="-Wall -Wextra -Wformat=2 $WARNINGS_ENABLE_ADDITIONAL"
149 WARNINGS_ENABLE_ALL_CXXFLAGS="$WARNINGS_ENABLE_ALL_CFLAGS $WARNINGS_ENABLE_ADDITIONAL_CXX"
150
151 DISABLED_WARNINGS="unused-parameter unused"
152 BUILD_CC_DISABLE_WARNING_PREFIX="-Wno-"
153 ;;
154
155 clang)
156 DISABLE_WARNING_PREFIX="-Wno-"
157 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
158
159 # Additional warnings that are not activated by -Wall and -Wextra
160 WARNINGS_ENABLE_ADDITIONAL="-Wpointer-arith -Wsign-compare -Wreorder \
161 -Wunused-function -Wundef -Wunused-value -Woverloaded-virtual"
162 WARNINGS_ENABLE_ALL="-Wall -Wextra -Wformat=2 $WARNINGS_ENABLE_ADDITIONAL"
163
164 DISABLED_WARNINGS="unknown-warning-option unused-parameter unused"
165
166 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
167 # missing-method-return-type triggers in JavaNativeFoundation framework
168 DISABLED_WARNINGS="$DISABLED_WARNINGS missing-method-return-type"
169 fi
170
171 ;;
172
173 xlc)
174 DISABLE_WARNING_PREFIX="-Wno-"
175 CFLAGS_WARNINGS_ARE_ERRORS="-qhalt=w"
176
177 # Possibly a better subset than "all" is "lan:trx:ret:zea:cmp:ret"
178 WARNINGS_ENABLE_ALL="-qinfo=all -qformat=all"
179 DISABLED_WARNINGS=""
180 ;;
181 esac
182 AC_SUBST(DISABLE_WARNING_PREFIX)
183 AC_SUBST(BUILD_CC_DISABLE_WARNING_PREFIX)
184 AC_SUBST(CFLAGS_WARNINGS_ARE_ERRORS)
185 AC_SUBST(DISABLED_WARNINGS)
186 AC_SUBST(DISABLED_WARNINGS_C)
187 AC_SUBST(DISABLED_WARNINGS_CXX)
188 ])
189
190 AC_DEFUN([FLAGS_SETUP_QUALITY_CHECKS],
191 [
192 # bounds, memory and behavior checking options
193 if test "x$TOOLCHAIN_TYPE" = xgcc; then
194 case $DEBUG_LEVEL in
195 release )
196 # no adjustment
197 ;;
198 fastdebug )
199 # no adjustment
200 ;;
201 slowdebug )
202 # FIXME: By adding this to C(XX)FLAGS_DEBUG_OPTIONS/JVM_CFLAGS_SYMBOLS it
203 # get's added conditionally on whether we produce debug symbols or not.
204 # This is most likely not really correct.
205
206 # Add runtime stack smashing and undefined behavior checks.
207 CFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
208 CXXFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
209
210 JVM_CFLAGS_SYMBOLS="$JVM_CFLAGS_SYMBOLS -fstack-protector-all --param ssp-buffer-size=1"
211 ;;
212 esac
213 fi
214 ])
215
216 AC_DEFUN([FLAGS_SETUP_OPTIMIZATION],
217 [
218 if test "x$TOOLCHAIN_TYPE" = xgcc; then
219 C_O_FLAG_HIGHEST_JVM="-O3"
220 C_O_FLAG_HIGHEST="-O3"
221 C_O_FLAG_HI="-O3"
222 C_O_FLAG_NORM="-O2"
223 C_O_FLAG_SIZE="-Os"
224 C_O_FLAG_DEBUG="-O0"
225 C_O_FLAG_DEBUG_JVM="-O0"
226 C_O_FLAG_NONE="-O0"
227 # -D_FORTIFY_SOURCE=2 hardening option needs optimization (at least -O1) enabled
228 # set for lower O-levels -U_FORTIFY_SOURCE to overwrite previous settings
229 if test "x$OPENJDK_TARGET_OS" = xlinux -a "x$DEBUG_LEVEL" = "xfastdebug"; then
230 ENABLE_FORTIFY_CFLAGS="-D_FORTIFY_SOURCE=2"
231 DISABLE_FORTIFY_CFLAGS="-U_FORTIFY_SOURCE"
232 C_O_FLAG_HIGHEST_JVM="${C_O_FLAG_HIGHEST_JVM} ${ENABLE_FORTIFY_CFLAGS}"
233 C_O_FLAG_HIGHEST="${C_O_FLAG_HIGHEST} ${ENABLE_FORTIFY_CFLAGS}"
234 C_O_FLAG_HI="${C_O_FLAG_HI} ${ENABLE_FORTIFY_CFLAGS}"
235 C_O_FLAG_NORM="${C_O_FLAG_NORM} ${ENABLE_FORTIFY_CFLAGS}"
236 C_O_FLAG_SIZE="${C_O_FLAG_SIZE} ${DISABLE_FORTIFY_CFLAGS}"
237 C_O_FLAG_DEBUG="${C_O_FLAG_DEBUG} ${DISABLE_FORTIFY_CFLAGS}"
238 C_O_FLAG_DEBUG_JVM="${C_O_FLAG_DEBUG_JVM} ${DISABLE_FORTIFY_CFLAGS}"
239 C_O_FLAG_NONE="${C_O_FLAG_NONE} ${DISABLE_FORTIFY_CFLAGS}"
240 fi
241 elif test "x$TOOLCHAIN_TYPE" = xclang; then
242 C_O_FLAG_HIGHEST_JVM="-O3"
243 C_O_FLAG_HIGHEST="-O3"
244 C_O_FLAG_HI="-O3"
245 C_O_FLAG_NORM="-O2"
246 C_O_FLAG_DEBUG_JVM="-O0"
247 C_O_FLAG_SIZE="-Os"
248 C_O_FLAG_DEBUG="-O0"
249 C_O_FLAG_NONE="-O0"
250 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
251 C_O_FLAG_HIGHEST_JVM="-O3 -qhot=level=1 -qinline -qinlglue"
252 C_O_FLAG_HIGHEST="-O3 -qhot=level=1 -qinline -qinlglue"
253 C_O_FLAG_HI="-O3 -qinline -qinlglue"
254 C_O_FLAG_NORM="-O2"
255 C_O_FLAG_DEBUG="-qnoopt"
256 # FIXME: Value below not verified.
257 C_O_FLAG_DEBUG_JVM=""
258 C_O_FLAG_NONE="-qnoopt"
259 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
260 C_O_FLAG_HIGHEST_JVM="-O2 -Oy-"
261 C_O_FLAG_HIGHEST="-O2"
262 C_O_FLAG_HI="-O1"
263 C_O_FLAG_NORM="-O1"
264 C_O_FLAG_DEBUG="-Od"
265 C_O_FLAG_DEBUG_JVM=""
266 C_O_FLAG_NONE="-Od"
267 C_O_FLAG_SIZE="-Os"
268 fi
269
270 # Now copy to C++ flags
271 CXX_O_FLAG_HIGHEST_JVM="$C_O_FLAG_HIGHEST_JVM"
272 CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
273 CXX_O_FLAG_HI="$C_O_FLAG_HI"
274 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
275 CXX_O_FLAG_DEBUG="$C_O_FLAG_DEBUG"
276 CXX_O_FLAG_DEBUG_JVM="$C_O_FLAG_DEBUG_JVM"
277 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
278 CXX_O_FLAG_SIZE="$C_O_FLAG_SIZE"
279
280 # Adjust optimization flags according to debug level.
281 case $DEBUG_LEVEL in
282 release )
283 # no adjustment
284 ;;
285 fastdebug )
286 # Not quite so much optimization
287 C_O_FLAG_HI="$C_O_FLAG_NORM"
288 CXX_O_FLAG_HI="$CXX_O_FLAG_NORM"
289 ;;
290 slowdebug )
291 # Disable optimization
292 C_O_FLAG_HIGHEST_JVM="$C_O_FLAG_DEBUG_JVM"
293 C_O_FLAG_HIGHEST="$C_O_FLAG_DEBUG"
294 C_O_FLAG_HI="$C_O_FLAG_DEBUG"
295 C_O_FLAG_NORM="$C_O_FLAG_DEBUG"
296 C_O_FLAG_SIZE="$C_O_FLAG_DEBUG"
297 CXX_O_FLAG_HIGHEST_JVM="$CXX_O_FLAG_DEBUG_JVM"
298 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_DEBUG"
299 CXX_O_FLAG_HI="$CXX_O_FLAG_DEBUG"
300 CXX_O_FLAG_NORM="$CXX_O_FLAG_DEBUG"
301 CXX_O_FLAG_SIZE="$CXX_O_FLAG_DEBUG"
302 ;;
303 esac
304
305 AC_SUBST(C_O_FLAG_HIGHEST_JVM)
306 AC_SUBST(C_O_FLAG_HIGHEST)
307 AC_SUBST(C_O_FLAG_HI)
308 AC_SUBST(C_O_FLAG_NORM)
309 AC_SUBST(C_O_FLAG_NONE)
310 AC_SUBST(C_O_FLAG_SIZE)
311 AC_SUBST(CXX_O_FLAG_HIGHEST_JVM)
312 AC_SUBST(CXX_O_FLAG_HIGHEST)
313 AC_SUBST(CXX_O_FLAG_HI)
314 AC_SUBST(CXX_O_FLAG_NORM)
315 AC_SUBST(CXX_O_FLAG_NONE)
316 AC_SUBST(CXX_O_FLAG_SIZE)
317 ])
318
319 AC_DEFUN([FLAGS_SETUP_CFLAGS],
320 [
321 ### CFLAGS
322
323 FLAGS_SETUP_CFLAGS_HELPER
324
325 FLAGS_OS=$OPENJDK_TARGET_OS
326 FLAGS_OS_TYPE=$OPENJDK_TARGET_OS_TYPE
327 FLAGS_CPU=$OPENJDK_TARGET_CPU
328 FLAGS_CPU_ARCH=$OPENJDK_TARGET_CPU_ARCH
329 FLAGS_CPU_BITS=$OPENJDK_TARGET_CPU_BITS
330 FLAGS_CPU_ENDIAN=$OPENJDK_TARGET_CPU_ENDIAN
331 FLAGS_CPU_LEGACY=$OPENJDK_TARGET_CPU_LEGACY
332 FLAGS_CPU_LEGACY_LIB=$OPENJDK_TARGET_CPU_LEGACY_LIB
333
334 FLAGS_SETUP_CFLAGS_CPU_DEP([TARGET])
335
336 # Repeat the check for the BUILD_CC and BUILD_CXX. Need to also reset CFLAGS
337 # since any target specific flags will likely not work with the build compiler.
338 CC_OLD="$CC"
339 CXX_OLD="$CXX"
340 CFLAGS_OLD="$CFLAGS"
341 CXXFLAGS_OLD="$CXXFLAGS"
342 CC="$BUILD_CC"
343 CXX="$BUILD_CXX"
344 CFLAGS=""
345 CXXFLAGS=""
346
347 FLAGS_OS=$OPENJDK_BUILD_OS
348 FLAGS_OS_TYPE=$OPENJDK_BUILD_OS_TYPE
349 FLAGS_CPU=$OPENJDK_BUILD_CPU
350 FLAGS_CPU_ARCH=$OPENJDK_BUILD_CPU_ARCH
351 FLAGS_CPU_BITS=$OPENJDK_BUILD_CPU_BITS
352 FLAGS_CPU_ENDIAN=$OPENJDK_BUILD_CPU_ENDIAN
353 FLAGS_CPU_LEGACY=$OPENJDK_BUILD_CPU_LEGACY
354 FLAGS_CPU_LEGACY_LIB=$OPENJDK_BUILD_CPU_LEGACY_LIB
355
356 FLAGS_SETUP_CFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_], [BUILD_])
357
358 CC="$CC_OLD"
359 CXX="$CXX_OLD"
360 CFLAGS="$CFLAGS_OLD"
361 CXXFLAGS="$CXXFLAGS_OLD"
362 ])
363
364 ################################################################################
365 # platform independent
366 AC_DEFUN([FLAGS_SETUP_CFLAGS_HELPER],
367 [
368 #### OS DEFINES, these should be independent on toolchain
369 if test "x$OPENJDK_TARGET_OS" = xlinux; then
370 CFLAGS_OS_DEF_JVM="-DLINUX"
371 CFLAGS_OS_DEF_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
372 elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
373 CFLAGS_OS_DEF_JVM="-D_ALLBSD_SOURCE -D_DARWIN_C_SOURCE -D_XOPEN_SOURCE"
374 CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE -D_DARWIN_UNLIMITED_SELECT"
375 elif test "x$OPENJDK_TARGET_OS" = xaix; then
376 CFLAGS_OS_DEF_JVM="-DAIX"
377 elif test "x$OPENJDK_TARGET_OS" = xbsd; then
378 CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE"
379 elif test "x$OPENJDK_TARGET_OS" = xwindows; then
380 CFLAGS_OS_DEF_JVM="-D_WINDOWS -DWIN32 -D_JNI_IMPLEMENTATION_"
381 fi
382
383 CFLAGS_OS_DEF_JDK="$CFLAGS_OS_DEF_JDK -D$OPENJDK_TARGET_OS_UPPERCASE"
384
385 #### GLOBAL DEFINES
386 # Set some common defines. These works for all compilers, but assume
387 # -D is universally accepted.
388
389 # Always enable optional macros for VM.
390 ALWAYS_CFLAGS_JVM="-D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
391
392 # Setup some hard coded includes
393 ALWAYS_CFLAGS_JDK=" \
394 -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base \
395 -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base/\$(OPENJDK_TARGET_OS_INCLUDE_SUBDIR) \
396 -I${TOPDIR}/src/java.base/share/native/libjava \
397 -I${TOPDIR}/src/java.base/$OPENJDK_TARGET_OS_TYPE/native/libjava \
398 -I${TOPDIR}/src/hotspot/share/include \
399 -I${TOPDIR}/src/hotspot/os/${HOTSPOT_TARGET_OS_TYPE}/include"
400
401 ###############################################################################
402
403 # Adjust flags according to debug level.
404 # Setup debug/release defines
405 if test "x$DEBUG_LEVEL" = xrelease; then
406 DEBUG_CFLAGS_JDK="-DNDEBUG"
407 else
408 DEBUG_CFLAGS_JDK="-DDEBUG"
409
410 if test "x$TOOLCHAIN_TYPE" = xxlc; then
411 # We need '-qminimaltoc' or '-qpic=large -bbigtoc' if the TOC overflows.
412 # Hotspot now overflows its 64K TOC (currently only for debug),
413 # so for debug we build with '-qpic=large -bbigtoc'.
414 DEBUG_CFLAGS_JVM="-qpic=large"
415 fi
416 fi
417
418 if test "x$DEBUG_LEVEL" != xrelease; then
419 DEBUG_OPTIONS_FLAGS_JDK="$CFLAGS_DEBUG_OPTIONS"
420 DEBUG_SYMBOLS_CFLAGS_JDK="$CFLAGS_DEBUG_SYMBOLS"
421 fi
422
423 #### TOOLCHAIN DEFINES
424
425 if test "x$TOOLCHAIN_TYPE" = xgcc; then
426 ALWAYS_DEFINES_JVM="-D_GNU_SOURCE -D_REENTRANT"
427 elif test "x$TOOLCHAIN_TYPE" = xclang; then
428 ALWAYS_DEFINES_JVM="-D_GNU_SOURCE"
429 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
430 ALWAYS_DEFINES_JVM="-D_REENTRANT"
431 ALWAYS_DEFINES_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
432 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
433 ALWAYS_DEFINES_JDK="-DWIN32_LEAN_AND_MEAN -D_CRT_SECURE_NO_DEPRECATE \
434 -D_CRT_NONSTDC_NO_DEPRECATE -DWIN32 -DIAL"
435 ALWAYS_DEFINES_JVM="-DNOMINMAX -DWIN32_LEAN_AND_MEAN"
436 fi
437
438 ###############################################################################
439 #
440 #
441 # CFLAGS BASIC
442 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
443 # COMMON to gcc and clang
444 TOOLCHAIN_CFLAGS_JVM="-pipe -fno-rtti -fno-exceptions \
445 -fvisibility=hidden -fno-strict-aliasing -fno-omit-frame-pointer"
446 fi
447
448 if test "x$TOOLCHAIN_TYPE" = xgcc; then
449 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -fcheck-new -fstack-protector"
450 TOOLCHAIN_CFLAGS_JDK="-pipe -fstack-protector"
451 # reduce lib size on linux in link step, this needs also special compile flags
452 # do this on s390x also for libjvm (where serviceability agent is not supported)
453 if test "x$ENABLE_LINKTIME_GC" = xtrue; then
454 TOOLCHAIN_CFLAGS_JDK="$TOOLCHAIN_CFLAGS_JDK -ffunction-sections -fdata-sections"
455 if test "x$OPENJDK_TARGET_CPU" = xs390x; then
456 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -ffunction-sections -fdata-sections"
457 fi
458 fi
459 # technically NOT for CXX (but since this gives *worse* performance, use
460 # no-strict-aliasing everywhere!)
461 TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing"
462
463 elif test "x$TOOLCHAIN_TYPE" = xclang; then
464 # Restrict the debug information created by Clang to avoid
465 # too big object files and speed the build up a little bit
466 # (see http://llvm.org/bugs/show_bug.cgi?id=7554)
467 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -flimit-debug-info"
468
469 # In principle the stack alignment below is cpu- and ABI-dependent and
470 # should agree with values of StackAlignmentInBytes in various
471 # src/hotspot/cpu/*/globalDefinitions_*.hpp files, but this value currently
472 # works for all platforms.
473 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -mno-omit-leaf-frame-pointer -mstack-alignment=16"
474
475 if test "x$OPENJDK_TARGET_OS" = xlinux; then
476 if test "x$DEBUG_LEVEL" = xrelease; then
477 # Clang does not inline as much as GCC does for functions with "inline" keyword by default.
478 # This causes noticeable slowdown in pause time for G1, and possibly in other areas.
479 # Increasing the inline hint threshold avoids the slowdown for Clang-built JVM.
480 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -mllvm -inlinehint-threshold=100000"
481 fi
482 TOOLCHAIN_CFLAGS_JDK="-pipe"
483 TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing" # technically NOT for CXX
484 fi
485
486 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
487 # Suggested additions: -qsrcmsg to get improved error reporting
488 # set -qtbtable=full for a better traceback table/better stacks in hs_err when xlc16 is used
489 TOOLCHAIN_CFLAGS_JDK="-qtbtable=full -qchars=signed -qfullpath -qsaveopt -qstackprotect" # add on both CFLAGS
490 TOOLCHAIN_CFLAGS_JVM="-qtbtable=full -qtune=balanced \
491 -qalias=noansi -qstrict -qtls=default -qnortti -qnoeh -qignerrno -qstackprotect"
492 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
493 TOOLCHAIN_CFLAGS_JVM="-nologo -MD -MP"
494 TOOLCHAIN_CFLAGS_JDK="-nologo -MD -Zc:wchar_t-"
495 fi
496
497 # CFLAGS C language level for JDK sources (hotspot only uses C++)
498 # Ideally we would have a common level across all toolchains so that all sources
499 # are sure to conform to the same standard. Unfortunately neither our sources nor
500 # our toolchains are in a condition to support that. But what we loosely aim for is
501 # C99 level.
502 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang || test "x$TOOLCHAIN_TYPE" = xxlc; then
503 # Explicitly set C99. clang and xlclang support the same flag.
504 LANGSTD_CFLAGS="-std=c99"
505 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
506 # MSVC doesn't support C99/C11 explicitly, unless you compile as C++:
507 # LANGSTD_CFLAGS="-TP"
508 # but that requires numerous changes to the sources files. So we are limited
509 # to C89/C90 plus whatever extensions Visual Studio has decided to implement.
510 # This is the lowest bar for shared code.
511 LANGSTD_CFLAGS=""
512 fi
513 TOOLCHAIN_CFLAGS_JDK_CONLY="$LANGSTD_CFLAGS $TOOLCHAIN_CFLAGS_JDK_CONLY"
514
515 # CXXFLAGS C++ language level for all of JDK, including Hotspot.
516 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang || test "x$TOOLCHAIN_TYPE" = xxlc; then
517 LANGSTD_CXXFLAGS="-std=c++14"
518 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
519 LANGSTD_CXXFLAGS="-std:c++14"
520 else
521 AC_MSG_ERROR([Don't know how to enable C++14 for this toolchain])
522 fi
523 TOOLCHAIN_CFLAGS_JDK_CXXONLY="$TOOLCHAIN_CFLAGS_JDK_CXXONLY $LANGSTD_CXXFLAGS"
524 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM $LANGSTD_CXXFLAGS"
525 ADLC_LANGSTD_CXXFLAGS="$LANGSTD_CXXFLAGS"
526
527 # CFLAGS WARNINGS STUFF
528 # Set JVM_CFLAGS warning handling
529 if test "x$TOOLCHAIN_TYPE" = xgcc; then
530 WARNING_CFLAGS_JDK_CONLY="$WARNINGS_ENABLE_ALL_CFLAGS"
531 WARNING_CFLAGS_JDK_CXXONLY="$WARNINGS_ENABLE_ALL_CXXFLAGS"
532 WARNING_CFLAGS_JVM="$WARNINGS_ENABLE_ALL_CXXFLAGS"
533
534 elif test "x$TOOLCHAIN_TYPE" = xclang; then
535 WARNING_CFLAGS="$WARNINGS_ENABLE_ALL"
536
537 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
538 WARNING_CFLAGS="$WARNINGS_ENABLE_ALL"
539
540 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
541 WARNING_CFLAGS="" # currently left empty
542 fi
543
544 # Set some additional per-OS defines.
545
546 # Additional macosx handling
547 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
548 OS_CFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=$MACOSX_VERSION_MIN_NODOTS \
549 -mmacosx-version-min=$MACOSX_VERSION_MIN"
550
551 if test -n "$MACOSX_VERSION_MAX"; then
552 OS_CFLAGS="$OS_CFLAGS \
553 -DMAC_OS_X_VERSION_MAX_ALLOWED=$MACOSX_VERSION_MAX_NODOTS"
554 fi
555 fi
556
557 # Where does this really belong??
558 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
559 PICFLAG="-fPIC"
560 PIEFLAG="-fPIE"
561 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
562 # '-qpic' defaults to 'qpic=small'. This means that the compiler generates only
563 # one instruction for accessing the TOC. If the TOC grows larger than 64K, the linker
564 # will have to patch this single instruction with a call to some out-of-order code which
565 # does the load from the TOC. This is of course slower, and we also would have
566 # to use '-bbigtoc' for linking anyway so we could also change the PICFLAG to 'qpic=large'.
567 # With 'qpic=large' the compiler will by default generate a two-instruction sequence which
568 # can be patched directly by the linker and does not require a jump to out-of-order code.
569 #
570 # Since large TOC causes perf. overhead, only pay it where we must. Currently this is
571 # for all libjvm variants (both gtest and normal) but no other binaries. So, build
572 # libjvm with -qpic=large and link with -bbigtoc.
573 JVM_PICFLAG="-qpic=large"
574 JDK_PICFLAG="-qpic"
575 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
576 PICFLAG=""
577 fi
578
579 if test "x$TOOLCHAIN_TYPE" != xxlc; then
580 JVM_PICFLAG="$PICFLAG"
581 JDK_PICFLAG="$PICFLAG"
582 fi
583
584 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
585 # Linking is different on MacOSX
586 JDK_PICFLAG=''
587 if test "x$STATIC_BUILD" = xtrue; then
588 JVM_PICFLAG=""
589 fi
590 fi
591
592 # Optional POSIX functionality needed by the JVM
593 #
594 # Check if clock_gettime is available and in which library. This indicates
595 # availability of CLOCK_MONOTONIC for hotspot. But we don't need to link, so
596 # don't let it update LIBS.
597 save_LIBS="$LIBS"
598 AC_SEARCH_LIBS(clock_gettime, rt, [HAS_CLOCK_GETTIME=true], [])
599 if test "x$LIBS" = "x-lrt "; then
600 CLOCK_GETTIME_IN_LIBRT=true
601 fi
602 LIBS="$save_LIBS"
603
604 if test "x$HAS_CLOCK_GETTIME" = "xtrue"; then
605 OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DSUPPORTS_CLOCK_MONOTONIC"
606 if test "x$CLOCK_GETTIME_IN_LIBRT" = "xtrue"; then
607 OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DNEEDS_LIBRT"
608 fi
609 fi
610
611 # Extra flags needed when building optional static versions of certain
612 # JDK libraries.
613 STATIC_LIBS_CFLAGS="-DSTATIC_BUILD=1"
614 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
615 STATIC_LIBS_CFLAGS="$STATIC_LIBS_CFLAGS -ffunction-sections -fdata-sections \
616 -DJNIEXPORT='__attribute__((visibility(\"hidden\")))'"
617 else
618 STATIC_LIBS_CFLAGS="$STATIC_LIBS_CFLAGS -DJNIEXPORT="
619 fi
620 if test "x$TOOLCHAIN_TYPE" = xgcc; then
621 # Disable relax-relocation to enable compatibility with older linkers
622 RELAX_RELOCATIONS_FLAG="-Xassembler -mrelax-relocations=no"
623 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${RELAX_RELOCATIONS_FLAG}],
624 IF_TRUE: [STATIC_LIBS_CFLAGS="$STATIC_LIBS_CFLAGS ${RELAX_RELOCATIONS_FLAG}"])
625 fi
626 AC_SUBST(STATIC_LIBS_CFLAGS)
627 ])
628
629 ################################################################################
630 # $1 - Either BUILD or TARGET to pick the correct OS/CPU variables to check
631 # conditionals against.
632 # $2 - Optional prefix for each variable defined.
633 # $3 - Optional prefix for compiler variables (either BUILD_ or nothing).
634 AC_DEFUN([FLAGS_SETUP_CFLAGS_CPU_DEP],
635 [
636 #### CPU DEFINES, these should (in theory) be independent on toolchain
637
638 # Setup target CPU
639 # Setup endianness
640 if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
641 $1_DEFINES_CPU_JVM="-DVM_LITTLE_ENDIAN"
642 $1_DEFINES_CPU_JDK="-D_LITTLE_ENDIAN"
643 else
644 $1_DEFINES_CPU_JDK="-D_BIG_ENDIAN"
645 fi
646
647 # setup CPU bit size
648 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -DARCH='\"$FLAGS_CPU_LEGACY\"' \
649 -D$FLAGS_CPU_LEGACY"
650
651 if test "x$FLAGS_CPU_BITS" = x64; then
652 # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
653 # unpack200.exe.
654 if test "x$FLAGS_OS" = xlinux || test "x$FLAGS_OS" = xmacosx; then
655 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_LP64=1"
656 fi
657 if test "x$FLAGS_OS" != xaix; then
658 # xlc on AIX defines _LP64=1 by default and issues a warning if we redefine it.
659 $1_DEFINES_CPU_JVM="${$1_DEFINES_CPU_JVM} -D_LP64=1"
660 fi
661 fi
662
663 # toolchain dependend, per-cpu
664 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
665 if test "x$FLAGS_CPU" = xaarch64; then
666 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_ARM64_ -Darm64"
667 elif test "x$FLAGS_CPU" = xx86_64; then
668 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_AMD64_ -Damd64"
669 else
670 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_X86_ -Dx86"
671 fi
672 fi
673
674 # CFLAGS PER CPU
675 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
676 # COMMON to gcc and clang
677 if test "x$FLAGS_CPU" = xx86; then
678 # Force compatibility with i586 on 32 bit intel platforms.
679 $1_CFLAGS_CPU="-march=i586"
680 fi
681 fi
682
683 if test "x$TOOLCHAIN_TYPE" = xgcc; then
684 if test "x$FLAGS_CPU" = xaarch64; then
685 # -Wno-psabi to get rid of annoying "note: parameter passing for argument of type '<type> changed in GCC 9.1"
686 $1_CFLAGS_CPU="-Wno-psabi"
687 elif test "x$FLAGS_CPU" = xarm; then
688 # -Wno-psabi to get rid of annoying "note: the mangling of 'va_list' has changed in GCC 4.4"
689 $1_CFLAGS_CPU="-fsigned-char -Wno-psabi $ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS -DJDK_ARCH_ABI_PROP_NAME='\"\$(JDK_ARCH_ABI_PROP_NAME)\"'"
690 $1_CFLAGS_CPU_JVM="-DARM"
691 elif test "x$FLAGS_CPU_ARCH" = xppc; then
692 $1_CFLAGS_CPU_JVM="-minsert-sched-nops=regroup_exact -mno-multiple -mno-string"
693 if test "x$FLAGS_CPU" = xppc64; then
694 # -mminimal-toc fixes `relocation truncated to fit' error for gcc 4.1.
695 # Use ppc64 instructions, but schedule for power5
696 $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -mminimal-toc -mcpu=powerpc64 -mtune=power5"
697 elif test "x$FLAGS_CPU" = xppc64le; then
698 # Little endian machine uses ELFv2 ABI.
699 # Use Power8, this is the first CPU to support PPC64 LE with ELFv2 ABI.
700 $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -DABI_ELFv2 -mcpu=power8 -mtune=power8"
701 fi
702 elif test "x$FLAGS_CPU" = xs390x; then
703 $1_CFLAGS_CPU="-mbackchain -march=z10"
704 fi
705
706 if test "x$FLAGS_CPU_ARCH" != xarm && test "x$FLAGS_CPU_ARCH" != xppc; then
707 # for all archs except arm and ppc, prevent gcc to omit frame pointer
708 $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
709 fi
710
711 elif test "x$TOOLCHAIN_TYPE" = xclang; then
712 if test "x$FLAGS_OS" = xlinux; then
713 # ppc test not really needed for clang
714 if test "x$FLAGS_CPU_ARCH" != xarm && test "x$FLAGS_CPU_ARCH" != xppc; then
715 # for all archs except arm and ppc, prevent gcc to omit frame pointer
716 $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
717 fi
718 fi
719
720 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
721 if test "x$FLAGS_CPU" = xppc64; then
722 $1_CFLAGS_CPU_JVM="-qarch=ppc64"
723 fi
724
725 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
726 if test "x$FLAGS_CPU" = xx86; then
727 $1_CFLAGS_CPU_JVM="-arch:IA32"
728 elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then
729 if test "x$DEBUG_LEVEL" != xrelease; then
730 # NOTE: This is probably redundant; -homeparams is default on
731 # non-release builds.
732 $1_CFLAGS_CPU_JVM="-homeparams"
733 fi
734 fi
735 fi
736
737 if test "x$TOOLCHAIN_TYPE" = xgcc; then
738 FLAGS_SETUP_GCC6_COMPILER_FLAGS($1, $3)
739 $1_TOOLCHAIN_CFLAGS="${$1_GCC6_CFLAGS}"
740
741 $1_WARNING_CFLAGS_JVM="-Wno-format-zero-length -Wtype-limits -Wuninitialized"
742 fi
743
744 # Prevent the __FILE__ macro from generating absolute paths into the built
745 # binaries. Depending on toolchain, different mitigations are possible.
746 # * GCC and Clang of new enough versions have -fmacro-prefix-map.
747 # * For most other toolchains, supplying all source files and -I flags as
748 # relative paths fixes the issue.
749 FILE_MACRO_CFLAGS=
750 if test "x$ALLOW_ABSOLUTE_PATHS_IN_OUTPUT" = "xfalse"; then
751 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
752 # Check if compiler supports -fmacro-prefix-map. If so, use that to make
753 # the __FILE__ macro resolve to paths relative to the workspace root.
754 workspace_root_trailing_slash="${WORKSPACE_ROOT%/}/"
755 FILE_MACRO_CFLAGS="-fmacro-prefix-map=${workspace_root_trailing_slash}="
756 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${FILE_MACRO_CFLAGS}],
757 PREFIX: $3,
758 IF_FALSE: [
759 FILE_MACRO_CFLAGS=
760 ]
761 )
762 fi
763 fi
764 AC_SUBST(FILE_MACRO_CFLAGS)
765
766 # EXPORT to API
767 CFLAGS_JVM_COMMON="$ALWAYS_CFLAGS_JVM $ALWAYS_DEFINES_JVM \
768 $TOOLCHAIN_CFLAGS_JVM ${$1_TOOLCHAIN_CFLAGS_JVM} \
769 $OS_CFLAGS $OS_CFLAGS_JVM $CFLAGS_OS_DEF_JVM $DEBUG_CFLAGS_JVM \
770 $WARNING_CFLAGS $WARNING_CFLAGS_JVM $JVM_PICFLAG $FILE_MACRO_CFLAGS"
771
772 CFLAGS_JDK_COMMON="$ALWAYS_CFLAGS_JDK $ALWAYS_DEFINES_JDK $TOOLCHAIN_CFLAGS_JDK \
773 $OS_CFLAGS $CFLAGS_OS_DEF_JDK $DEBUG_CFLAGS_JDK $DEBUG_OPTIONS_FLAGS_JDK \
774 $WARNING_CFLAGS $WARNING_CFLAGS_JDK $DEBUG_SYMBOLS_CFLAGS_JDK \
775 $FILE_MACRO_CFLAGS"
776
777 # Use ${$2EXTRA_CFLAGS} to block EXTRA_CFLAGS to be added to build flags.
778 # (Currently we don't have any OPENJDK_BUILD_EXTRA_CFLAGS, but that might
779 # change in the future.)
780
781 CFLAGS_JDK_COMMON_CONLY="$TOOLCHAIN_CFLAGS_JDK_CONLY \
782 $WARNING_CFLAGS_JDK_CONLY ${$2EXTRA_CFLAGS}"
783 CFLAGS_JDK_COMMON_CXXONLY="$ALWAYS_DEFINES_JDK_CXXONLY \
784 $TOOLCHAIN_CFLAGS_JDK_CXXONLY \
785 ${$1_TOOLCHAIN_CFLAGS_JDK_CXXONLY} \
786 $WARNING_CFLAGS_JDK_CXXONLY ${$2EXTRA_CXXFLAGS}"
787
788 $1_CFLAGS_JVM="${$1_DEFINES_CPU_JVM} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JVM} ${$1_TOOLCHAIN_CFLAGS} ${$1_WARNING_CFLAGS_JVM}"
789 $1_CFLAGS_JDK="${$1_DEFINES_CPU_JDK} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JDK} ${$1_TOOLCHAIN_CFLAGS}"
790
791 $2JVM_CFLAGS="$CFLAGS_JVM_COMMON ${$1_CFLAGS_JVM} ${$2EXTRA_CXXFLAGS}"
792
793 $2CFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CONLY ${$1_CFLAGS_JDK} $PIEFLAG"
794 $2CXXFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CXXONLY ${$1_CFLAGS_JDK} $PIEFLAG"
795 $2CFLAGS_JDKLIB="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CONLY ${$1_CFLAGS_JDK} \
796 $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
797 $2CXXFLAGS_JDKLIB="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CXXONLY ${$1_CFLAGS_JDK} \
798 $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
799
800 AC_SUBST($2JVM_CFLAGS)
801 AC_SUBST($2CFLAGS_JDKLIB)
802 AC_SUBST($2CFLAGS_JDKEXE)
803 AC_SUBST($2CXXFLAGS_JDKLIB)
804 AC_SUBST($2CXXFLAGS_JDKEXE)
805 AC_SUBST($2ADLC_LANGSTD_CXXFLAGS)
806
807 COMPILER_FP_CONTRACT_OFF_FLAG="-ffp-contract=off"
808 # Check that the compiler supports -ffp-contract=off flag
809 # Set FDLIBM_CFLAGS to -ffp-contract=off if it does. Empty
810 # otherwise.
811 # These flags are required for GCC-based builds of
812 # fdlibm with optimization without losing precision.
813 # Notably, -ffp-contract=off needs to be added for GCC >= 4.6.
814 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
815 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${COMPILER_FP_CONTRACT_OFF_FLAG}],
816 PREFIX: $3,
817 IF_TRUE: [$2FDLIBM_CFLAGS=${COMPILER_FP_CONTRACT_OFF_FLAG}],
818 IF_FALSE: [$2FDLIBM_CFLAGS=""])
819 fi
820 AC_SUBST($2FDLIBM_CFLAGS)
821 ])
822
823 # FLAGS_SETUP_GCC6_COMPILER_FLAGS([PREFIX])
824 # Arguments:
825 # $1 - Prefix for each variable defined.
826 # $2 - Prefix for compiler variables (either BUILD_ or nothing).
827 AC_DEFUN([FLAGS_SETUP_GCC6_COMPILER_FLAGS],
828 [
829 # These flags are required for GCC 6 builds as undefined behaviour in OpenJDK code
830 # runs afoul of the more aggressive versions of these optimisations.
831 # Notably, value range propagation now assumes that the this pointer of C++
832 # member functions is non-null.
833 NO_DELETE_NULL_POINTER_CHECKS_CFLAG="-fno-delete-null-pointer-checks"
834 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_DELETE_NULL_POINTER_CHECKS_CFLAG],
835 PREFIX: $2, IF_FALSE: [NO_DELETE_NULL_POINTER_CHECKS_CFLAG=""])
836 NO_LIFETIME_DSE_CFLAG="-fno-lifetime-dse"
837 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_LIFETIME_DSE_CFLAG],
838 PREFIX: $2, IF_FALSE: [NO_LIFETIME_DSE_CFLAG=""])
839 $1_GCC6_CFLAGS="${NO_DELETE_NULL_POINTER_CHECKS_CFLAG} ${NO_LIFETIME_DSE_CFLAG}"
840 ])