1 #
2 # Copyright (c) 2011, 2020, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ################################################################################
27 #
28
29 AC_DEFUN([FLAGS_SETUP_LDFLAGS],
30 [
31 FLAGS_SETUP_LDFLAGS_HELPER
32
33 # Setup the target toolchain
34
35 # On some platforms (mac) the linker warns about non existing -L dirs.
36 # For any of the variants server, client or minimal, the dir matches the
37 # variant name. The "main" variant should be used for linking. For the
38 # rest, the dir is just server.
39 if HOTSPOT_CHECK_JVM_VARIANT(server) || HOTSPOT_CHECK_JVM_VARIANT(client) \
40 || HOTSPOT_CHECK_JVM_VARIANT(minimal); then
41 TARGET_JVM_VARIANT_PATH=$JVM_VARIANT_MAIN
42 else
43 TARGET_JVM_VARIANT_PATH=server
44 fi
45 FLAGS_SETUP_LDFLAGS_CPU_DEP([TARGET])
46
47 # Setup the build toolchain
48
49 # When building a buildjdk, it's always only the server variant
50 BUILD_JVM_VARIANT_PATH=server
51
52 FLAGS_SETUP_LDFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_])
53
54 LDFLAGS_TESTEXE="${TARGET_LDFLAGS_JDK_LIBPATH}"
55 AC_SUBST(LDFLAGS_TESTEXE)
56 AC_SUBST(ADLC_LDFLAGS)
57 ])
58
59 ################################################################################
60
61 # CPU independent LDFLAGS setup, used for both target and build toolchain.
62 AC_DEFUN([FLAGS_SETUP_LDFLAGS_HELPER],
63 [
64 # Setup basic LDFLAGS
65 if test "x$TOOLCHAIN_TYPE" = xgcc; then
66 # Add -z,defs, to forbid undefined symbols in object files.
67 # add -z,relro (mark relocations read only) for all libs
68 # add -z,now ("full relro" - more of the Global Offset Table GOT is marked read only)
69 BASIC_LDFLAGS="-Wl,--hash-style=gnu -Wl,-z,defs -Wl,-z,relro -Wl,-z,now"
70 # Linux : remove unused code+data in link step
71 if test "x$ENABLE_LINKTIME_GC" = xtrue; then
72 if test "x$OPENJDK_TARGET_CPU" = xs390x; then
73 BASIC_LDFLAGS="$BASIC_LDFLAGS -Wl,--gc-sections -Wl,--print-gc-sections"
74 else
75 BASIC_LDFLAGS_JDK_ONLY="$BASIC_LDFLAGS_JDK_ONLY -Wl,--gc-sections"
76 fi
77 fi
78
79 BASIC_LDFLAGS_JVM_ONLY="-Wl,-O1"
80
81 elif test "x$TOOLCHAIN_TYPE" = xclang; then
82 BASIC_LDFLAGS_JVM_ONLY="-mno-omit-leaf-frame-pointer -mstack-alignment=16 \
83 -fPIC"
84
85 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
86 BASIC_LDFLAGS="-b64 -brtl -bnorwexec -bnolibpath -bexpall -bernotok -btextpsize:64K \
87 -bdatapsize:64K -bstackpsize:64K"
88 # libjvm.so has gotten too large for normal TOC size; compile with qpic=large and link with bigtoc
89 BASIC_LDFLAGS_JVM_ONLY="-Wl,-lC_r -bbigtoc"
90
91 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
92 BASIC_LDFLAGS="-nologo -opt:ref"
93 BASIC_LDFLAGS_JDK_ONLY="-incremental:no"
94 BASIC_LDFLAGS_JVM_ONLY="-opt:icf,8 -subsystem:windows"
95 fi
96
97 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
98 if test -n "$HAS_NOEXECSTACK"; then
99 BASIC_LDFLAGS="$BASIC_LDFLAGS -Wl,-z,noexecstack"
100 fi
101 fi
102
103 # Setup OS-dependent LDFLAGS
104 if test "x$TOOLCHAIN_TYPE" = xclang || test "x$TOOLCHAIN_TYPE" = xgcc; then
105 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
106 # Assume clang or gcc.
107 # FIXME: We should really generalize SET_SHARED_LIBRARY_ORIGIN instead.
108 OS_LDFLAGS_JVM_ONLY="-Wl,-rpath,@loader_path/. -Wl,-rpath,@loader_path/.."
109 OS_LDFLAGS_JDK_ONLY="-mmacosx-version-min=$MACOSX_VERSION_MIN"
110 fi
111 fi
112
113 # Setup debug level-dependent LDFLAGS
114 if test "x$TOOLCHAIN_TYPE" = xgcc; then
115 if test "x$OPENJDK_TARGET_OS" = xlinux; then
116 if test x$DEBUG_LEVEL = xrelease; then
117 DEBUGLEVEL_LDFLAGS_JDK_ONLY="$DEBUGLEVEL_LDFLAGS_JDK_ONLY -Wl,-O1"
118 fi
119 fi
120
121 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
122 # We need '-qminimaltoc' or '-qpic=large -bbigtoc' if the TOC overflows.
123 # Hotspot now overflows its 64K TOC (currently only for debug),
124 # so we build with '-qpic=large -bbigtoc'.
125 if test "x$DEBUG_LEVEL" != xrelease; then
126 DEBUGLEVEL_LDFLAGS_JVM_ONLY="$DEBUGLEVEL_LDFLAGS_JVM_ONLY -bbigtoc"
127 fi
128 fi
129
130 # Setup LDFLAGS for linking executables
131 if test "x$TOOLCHAIN_TYPE" = xgcc; then
132 EXECUTABLE_LDFLAGS="$EXECUTABLE_LDFLAGS -Wl,--allow-shlib-undefined"
133 # Enabling pie on 32 bit builds prevents the JVM from allocating a continuous
134 # java heap.
135 if test "x$OPENJDK_TARGET_CPU_BITS" != "x32"; then
136 EXECUTABLE_LDFLAGS="$EXECUTABLE_LDFLAGS -pie"
137 fi
138 fi
139
140 if test "x$ALLOW_ABSOLUTE_PATHS_IN_OUTPUT" = "xfalse"; then
141 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
142 BASIC_LDFLAGS="$BASIC_LDFLAGS -pdbaltpath:%_PDB%"
143 fi
144 fi
145
146 # Export some intermediate variables for compatibility
147 LDFLAGS_CXX_JDK="$BASIC_LDFLAGS_ONLYCXX $BASIC_LDFLAGS_ONLYCXX_JDK_ONLY $DEBUGLEVEL_LDFLAGS_JDK_ONLY"
148 AC_SUBST(LDFLAGS_CXX_JDK)
149 ])
150
151 ################################################################################
152 # $1 - Either BUILD or TARGET to pick the correct OS/CPU variables to check
153 # conditionals against.
154 # $2 - Optional prefix for each variable defined.
155 AC_DEFUN([FLAGS_SETUP_LDFLAGS_CPU_DEP],
156 [
157 # Setup CPU-dependent basic LDFLAGS. These can differ between the target and
158 # build toolchain.
159 if test "x$TOOLCHAIN_TYPE" = xgcc; then
160 if test "x${OPENJDK_$1_CPU}" = xx86; then
161 $1_CPU_LDFLAGS_JVM_ONLY="-march=i586"
162 elif test "x$OPENJDK_$1_CPU" = xarm; then
163 $1_CPU_LDFLAGS_JVM_ONLY="${$1_CPU_LDFLAGS_JVM_ONLY} -fsigned-char"
164 $1_CPU_LDFLAGS="$ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS"
165 fi
166
167 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
168 if test "x${OPENJDK_$1_CPU}" = "xx86"; then
169 $1_CPU_LDFLAGS="-safeseh"
170 # NOTE: Old build added -machine. Probably not needed.
171 $1_CPU_LDFLAGS_JVM_ONLY="-machine:I386"
172 $1_CPU_EXECUTABLE_LDFLAGS="-stack:327680"
173 else
174 $1_CPU_LDFLAGS_JVM_ONLY="-machine:AMD64"
175 $1_CPU_EXECUTABLE_LDFLAGS="-stack:1048576"
176 fi
177 fi
178
179 # JVM_VARIANT_PATH depends on if this is build or target...
180 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
181 $1_LDFLAGS_JDK_LIBPATH="-libpath:${OUTPUTDIR}/support/modules_libs/java.base"
182 else
183 $1_LDFLAGS_JDK_LIBPATH="-L\$(SUPPORT_OUTPUTDIR)/modules_libs/java.base \
184 -L\$(SUPPORT_OUTPUTDIR)/modules_libs/java.base/${$1_JVM_VARIANT_PATH}"
185 fi
186
187 # Export variables according to old definitions, prefix with $2 if present.
188 LDFLAGS_JDK_COMMON="$BASIC_LDFLAGS $BASIC_LDFLAGS_JDK_ONLY \
189 $OS_LDFLAGS_JDK_ONLY $DEBUGLEVEL_LDFLAGS_JDK_ONLY ${$2EXTRA_LDFLAGS}"
190 $2LDFLAGS_JDKLIB="$LDFLAGS_JDK_COMMON $BASIC_LDFLAGS_JDK_LIB_ONLY \
191 ${$1_LDFLAGS_JDK_LIBPATH} $SHARED_LIBRARY_FLAGS"
192 $2LDFLAGS_JDKEXE="$LDFLAGS_JDK_COMMON $EXECUTABLE_LDFLAGS \
193 ${$1_CPU_EXECUTABLE_LDFLAGS}"
194
195 $2JVM_LDFLAGS="$BASIC_LDFLAGS $BASIC_LDFLAGS_JVM_ONLY $OS_LDFLAGS_JVM_ONLY \
196 $DEBUGLEVEL_LDFLAGS $DEBUGLEVEL_LDFLAGS_JVM_ONLY $BASIC_LDFLAGS_ONLYCXX \
197 ${$1_CPU_LDFLAGS} ${$1_CPU_LDFLAGS_JVM_ONLY} ${$2EXTRA_LDFLAGS}"
198
199 AC_SUBST($2LDFLAGS_JDKLIB)
200 AC_SUBST($2LDFLAGS_JDKEXE)
201
202 AC_SUBST($2JVM_LDFLAGS)
203 ])