1 #
2 # Copyright (c) 2011, 2014, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
27 # If so, then append $1 to $2 \
28 # Also set JVM_ARG_OK to true/false depending on outcome.
29 AC_DEFUN([ADD_JVM_ARG_IF_OK],
30 [
31 $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
32 $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
33 OUTPUT=`$3 $1 -version 2>&1`
34 FOUND_WARN=`$ECHO "$OUTPUT" | grep -i warn`
35 FOUND_VERSION=`$ECHO $OUTPUT | grep " version \""`
36 if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
37 $2="[$]$2 $1"
38 JVM_ARG_OK=true
39 else
40 $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
41 $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
42 JVM_ARG_OK=false
43 fi
44 ])
45
46 # Appends a string to a path variable, only adding the : when needed.
47 AC_DEFUN([BASIC_APPEND_TO_PATH],
48 [
49 if test "x$2" != x; then
50 if test "x[$]$1" = x; then
51 $1="$2"
52 else
53 $1="[$]$1:$2"
54 fi
55 fi
56 ])
57
58 # Prepends a string to a path variable, only adding the : when needed.
59 AC_DEFUN([BASIC_PREPEND_TO_PATH],
60 [
61 if test "x$2" != x; then
62 if test "x[$]$1" = x; then
63 $1="$2"
64 else
65 $1="$2:[$]$1"
66 fi
67 fi
68 ])
69
70 # This will make sure the given variable points to a full and proper
71 # path. This means:
72 # 1) There will be no spaces in the path. On unix platforms,
73 # spaces in the path will result in an error. On Windows,
74 # the path will be rewritten using short-style to be space-free.
75 # 2) The path will be absolute, and it will be in unix-style (on
76 # cygwin).
77 # $1: The name of the variable to fix
78 AC_DEFUN([BASIC_FIXUP_PATH],
79 [
80 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
81 BASIC_FIXUP_PATH_CYGWIN($1)
82 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
83 BASIC_FIXUP_PATH_MSYS($1)
84 else
85 # We're on a unix platform. Hooray! :)
86 path="[$]$1"
87 has_space=`$ECHO "$path" | $GREP " "`
88 if test "x$has_space" != x; then
89 AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
90 AC_MSG_ERROR([Spaces are not allowed in this path.])
91 fi
92
93 # Use eval to expand a potential ~
94 eval path="$path"
95 if test ! -f "$path" && test ! -d "$path"; then
96 AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
97 fi
98
99 $1="`cd "$path"; $THEPWDCMD -L`"
100 fi
101 ])
102
103 # This will make sure the given variable points to a executable
104 # with a full and proper path. This means:
105 # 1) There will be no spaces in the path. On unix platforms,
106 # spaces in the path will result in an error. On Windows,
107 # the path will be rewritten using short-style to be space-free.
108 # 2) The path will be absolute, and it will be in unix-style (on
109 # cygwin).
110 # Any arguments given to the executable is preserved.
111 # If the input variable does not have a directory specification, then
112 # it need to be in the PATH.
113 # $1: The name of the variable to fix
114 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
115 [
116 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
117 BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
118 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
119 BASIC_FIXUP_EXECUTABLE_MSYS($1)
120 else
121 # We're on a unix platform. Hooray! :)
122 # First separate the path from the arguments. This will split at the first
123 # space.
124 complete="[$]$1"
125 path="${complete%% *}"
126 tmp="$complete EOL"
127 arguments="${tmp#* }"
128
129 # Cannot rely on the command "which" here since it doesn't always work.
130 is_absolute_path=`$ECHO "$path" | $GREP ^/`
131 if test -z "$is_absolute_path"; then
132 # Path to executable is not absolute. Find it.
133 IFS_save="$IFS"
134 IFS=:
135 for p in $PATH; do
136 if test -f "$p/$path" && test -x "$p/$path"; then
137 new_path="$p/$path"
138 break
139 fi
140 done
141 IFS="$IFS_save"
142 else
143 # This is an absolute path, we can use it without further modifications.
144 new_path="$path"
145 fi
146
147 if test "x$new_path" = x; then
148 AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
149 has_space=`$ECHO "$complete" | $GREP " "`
150 if test "x$has_space" != x; then
151 AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
152 fi
153 AC_MSG_ERROR([Cannot locate the the path of $1])
154 fi
155 fi
156
157 # Now join together the path and the arguments once again
158 if test "x$arguments" != xEOL; then
159 new_complete="$new_path ${arguments% *}"
160 else
161 new_complete="$new_path"
162 fi
163
164 if test "x$complete" != "x$new_complete"; then
165 $1="$new_complete"
166 AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
167 fi
168 ])
169
170 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
171 [
172 if test "x$OPENJDK_BUILD_OS" != xwindows; then
173 # Follow a chain of symbolic links. Use readlink
174 # where it exists, else fall back to horribly
175 # complicated shell code.
176 if test "x$READLINK_TESTED" != yes; then
177 # On MacOSX there is a readlink tool with a different
178 # purpose than the GNU readlink tool. Check the found readlink.
179 ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
180 if test "x$ISGNU" = x; then
181 # A readlink that we do not know how to use.
182 # Are there other non-GNU readlinks out there?
183 READLINK_TESTED=yes
184 READLINK=
185 fi
186 fi
187
188 if test "x$READLINK" != x; then
189 $1=`$READLINK -f [$]$1`
190 else
191 # Save the current directory for restoring afterwards
192 STARTDIR=$PWD
193 COUNTER=0
194 sym_link_dir=`$DIRNAME [$]$1`
195 sym_link_file=`$BASENAME [$]$1`
196 cd $sym_link_dir
197 # Use -P flag to resolve symlinks in directories.
198 cd `$THEPWDCMD -P`
199 sym_link_dir=`$THEPWDCMD -P`
200 # Resolve file symlinks
201 while test $COUNTER -lt 20; do
202 ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
203 if test "x$ISLINK" == x; then
204 # This is not a symbolic link! We are done!
205 break
206 fi
207 # Again resolve directory symlinks since the target of the just found
208 # link could be in a different directory
209 cd `$DIRNAME $ISLINK`
210 sym_link_dir=`$THEPWDCMD -P`
211 sym_link_file=`$BASENAME $ISLINK`
212 let COUNTER=COUNTER+1
213 done
214 cd $STARTDIR
215 $1=$sym_link_dir/$sym_link_file
216 fi
217 fi
218 ])
219
220 # Register a --with argument but mark it as deprecated
221 # $1: The name of the with argument to deprecate, not including --with-
222 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
223 [
224 AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
225 [Deprecated. Option is kept for backwards compatibility and is ignored])],
226 [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
227 ])
228
229 # Register a --enable argument but mark it as deprecated
230 # $1: The name of the with argument to deprecate, not including --enable-
231 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
232 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
233 [
234 AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
235 [Deprecated. Option is kept for backwards compatibility and is ignored])])
236 if test "x$enable_$2" != x; then
237 AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
238 fi
239 ])
240
241 AC_DEFUN_ONCE([BASIC_INIT],
242 [
243 # Save the original command line. This is passed to us by the wrapper configure script.
244 AC_SUBST(CONFIGURE_COMMAND_LINE)
245 # Save the path variable before it gets changed
246 ORIGINAL_PATH="$PATH"
247 AC_SUBST(ORIGINAL_PATH)
248 DATE_WHEN_CONFIGURED=`LANG=C date`
249 AC_SUBST(DATE_WHEN_CONFIGURED)
250 AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
251 AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
252 ])
253
254 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
255 # $1: variable to check
256 AC_DEFUN([BASIC_CHECK_NONEMPTY],
257 [
258 if test "x[$]$1" = x; then
259 AC_MSG_ERROR([Could not find required tool for $1])
260 fi
261 ])
262
263 # Check that there are no unprocessed overridden variables left.
264 # If so, they are an incorrect argument and we will exit with an error.
265 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],
266 [
267 if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then
268 # Replace the separating ! with spaces before presenting for end user.
269 unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }
270 AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])
271 fi
272 ])
273
274 # Setup a tool for the given variable. If correctly specified by the user,
275 # use that value, otherwise search for the tool using the supplied code snippet.
276 # $1: variable to set
277 # $2: code snippet to call to look for the tool
278 AC_DEFUN([BASIC_SETUP_TOOL],
279 [
280 # Publish this variable in the help.
281 AC_ARG_VAR($1, [Override default value for $1])
282
283 if test "x[$]$1" = x; then
284 # The variable is not set by user, try to locate tool using the code snippet
285 $2
286 else
287 # The variable is set, but is it from the command line or the environment?
288
289 # Try to remove the string !$1! from our list.
290 try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}
291 if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then
292 # If it failed, the variable was not from the command line. Ignore it,
293 # but warn the user (except for BASH, which is always set by the calling BASH).
294 if test "x$1" != xBASH; then
295 AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])
296 fi
297 # Try to locate tool using the code snippet
298 $2
299 else
300 # If it succeeded, then it was overridden by the user. We will use it
301 # for the tool.
302
303 # First remove it from the list of overridden variables, so we can test
304 # for unknown variables in the end.
305 CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"
306
307 # Check if the provided tool contains a complete path.
308 tool_specified="[$]$1"
309 tool_basename="${tool_specified##*/}"
310 if test "x$tool_basename" = "x$tool_specified"; then
311 # A command without a complete path is provided, search $PATH.
312 AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])
313 AC_PATH_PROG($1, $tool_basename)
314 if test "x[$]$1" = x; then
315 AC_MSG_ERROR([User supplied tool $tool_basename could not be found])
316 fi
317 else
318 # Otherwise we believe it is a complete path. Use it as it is.
319 AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])
320 AC_MSG_CHECKING([for $1])
321 if test ! -x "$tool_specified"; then
322 AC_MSG_RESULT([not found])
323 AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])
324 fi
325 AC_MSG_RESULT([$tool_specified])
326 fi
327 fi
328 fi
329 ])
330
331 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool
332 # $1: variable to set
333 # $2: executable name (or list of names) to look for
334 AC_DEFUN([BASIC_PATH_PROGS],
335 [
336 BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2)])
337 ])
338
339 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool
340 # $1: variable to set
341 # $2: executable name (or list of names) to look for
342 AC_DEFUN([BASIC_CHECK_TOOLS],
343 [
344 BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])
345 ])
346
347 # Like BASIC_PATH_PROGS but fails if no tool was found.
348 # $1: variable to set
349 # $2: executable name (or list of names) to look for
350 AC_DEFUN([BASIC_REQUIRE_PROGS],
351 [
352 BASIC_PATH_PROGS($1, $2)
353 BASIC_CHECK_NONEMPTY($1)
354 ])
355
356 # Like BASIC_SETUP_TOOL but fails if no tool was found.
357 # $1: variable to set
358 # $2: autoconf macro to call to look for the special tool
359 AC_DEFUN([BASIC_REQUIRE_SPECIAL],
360 [
361 BASIC_SETUP_TOOL($1, [$2])
362 BASIC_CHECK_NONEMPTY($1)
363 ])
364
365 # Setup the most fundamental tools that relies on not much else to set up,
366 # but is used by much of the early bootstrap code.
367 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
368 [
369 # Start with tools that do not need have cross compilation support
370 # and can be expected to be found in the default PATH. These tools are
371 # used by configure. Nor are these tools expected to be found in the
372 # devkit from the builddeps server either, since they are
373 # needed to download the devkit.
374
375 # First are all the simple required tools.
376 BASIC_REQUIRE_PROGS(BASENAME, basename)
377 BASIC_REQUIRE_PROGS(BASH, bash)
378 BASIC_REQUIRE_PROGS(CAT, cat)
379 BASIC_REQUIRE_PROGS(CHMOD, chmod)
380 BASIC_REQUIRE_PROGS(CMP, cmp)
381 BASIC_REQUIRE_PROGS(COMM, comm)
382 BASIC_REQUIRE_PROGS(CP, cp)
383 BASIC_REQUIRE_PROGS(CUT, cut)
384 BASIC_REQUIRE_PROGS(DATE, date)
385 BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])
386 BASIC_REQUIRE_PROGS(DIRNAME, dirname)
387 BASIC_REQUIRE_PROGS(ECHO, echo)
388 BASIC_REQUIRE_PROGS(EXPR, expr)
389 BASIC_REQUIRE_PROGS(FILE, file)
390 BASIC_REQUIRE_PROGS(FIND, find)
391 BASIC_REQUIRE_PROGS(HEAD, head)
392 BASIC_REQUIRE_PROGS(LN, ln)
393 BASIC_REQUIRE_PROGS(LS, ls)
394 BASIC_REQUIRE_PROGS(MKDIR, mkdir)
395 BASIC_REQUIRE_PROGS(MKTEMP, mktemp)
396 BASIC_REQUIRE_PROGS(MV, mv)
397 BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])
398 BASIC_REQUIRE_PROGS(PRINTF, printf)
399 BASIC_REQUIRE_PROGS(RM, rm)
400 BASIC_REQUIRE_PROGS(SH, sh)
401 BASIC_REQUIRE_PROGS(SORT, sort)
402 BASIC_REQUIRE_PROGS(TAIL, tail)
403 BASIC_REQUIRE_PROGS(TAR, tar)
404 BASIC_REQUIRE_PROGS(TEE, tee)
405 BASIC_REQUIRE_PROGS(TOUCH, touch)
406 BASIC_REQUIRE_PROGS(TR, tr)
407 BASIC_REQUIRE_PROGS(UNAME, uname)
408 BASIC_REQUIRE_PROGS(UNIQ, uniq)
409 BASIC_REQUIRE_PROGS(WC, wc)
410 BASIC_REQUIRE_PROGS(WHICH, which)
411 BASIC_REQUIRE_PROGS(XARGS, xargs)
412
413 # Then required tools that require some special treatment.
414 BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])
415 BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])
416 BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])
417 BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])
418 BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])
419
420 # Always force rm.
421 RM="$RM -f"
422
423 # pwd behaves differently on various platforms and some don't support the -L flag.
424 # Always use the bash builtin pwd to get uniform behavior.
425 THEPWDCMD=pwd
426
427 # These are not required on all platforms
428 BASIC_PATH_PROGS(CYGPATH, cygpath)
429 BASIC_PATH_PROGS(READLINK, [greadlink readlink])
430 BASIC_PATH_PROGS(DF, df)
431 BASIC_PATH_PROGS(SETFILE, SetFile)
432 BASIC_PATH_PROGS(CPIO, [cpio bsdcpio])
433 ])
434
435 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
436 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
437 [
438 # Save the current directory this script was started from
439 CURDIR="$PWD"
440
441 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
442 PATH_SEP=";"
443 BASIC_CHECK_PATHS_WINDOWS
444 else
445 PATH_SEP=":"
446 fi
447 AC_SUBST(PATH_SEP)
448
449 # We get the top-level directory from the supporting wrappers.
450 AC_MSG_CHECKING([for top-level directory])
451 AC_MSG_RESULT([$TOPDIR])
452 AC_SUBST(TOPDIR)
453
454 # We can only call BASIC_FIXUP_PATH after BASIC_CHECK_PATHS_WINDOWS.
455 BASIC_FIXUP_PATH(CURDIR)
456 BASIC_FIXUP_PATH(TOPDIR)
457 # SRC_ROOT is a traditional alias for TOPDIR.
458 SRC_ROOT=$TOPDIR
459
460 # Locate the directory of this script.
461 AUTOCONF_DIR=$TOPDIR/common/autoconf
462 ])
463
464 AC_DEFUN_ONCE([BASIC_SETUP_DEVKIT],
465 [
466 AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
467 [use this devkit for compilers, tools and resources])],
468 [
469 BASIC_FIXUP_PATH([with_devkit])
470 DEVKIT_ROOT="$with_devkit"
471 # Check for a meta data info file in the root of the devkit
472 if test -f "$DEVKIT_ROOT/devkit.info"; then
473 # This potentially sets the following:
474 # DEVKIT_NAME: A descriptive name of the devkit
475 # DEVKIT_TOOLCHAIN_PATH: Corresponds to --with-toolchain-path
476 # DEVKIT_EXTRA_PATH: Corresponds to --with-extra-path
477 # DEVKIT_SYSROOT: Corresponds to --with-sysroot
478 . $DEVKIT_ROOT/devkit.info
479 fi
480
481 AC_MSG_CHECKING([for devkit])
482 if test "x$DEVKIT_NAME" != x; then
483 AC_MSG_RESULT([$DEVKIT_NAME in $DEVKIT_ROOT])
484 else
485 AC_MSG_RESULT([$DEVKIT_ROOT])
486 fi
487
488 if test "x$DEVKIT_EXTRA_PATH" != x; then
489 BASIC_PREPEND_TO_PATH([EXTRA_PATH],$DEVKIT_EXTRA_PATH)
490 fi
491
492 # Fallback default of just /bin if DEVKIT_PATH is not defined
493 if test "x$DEVKIT_TOOLCHAIN_PATH" = x; then
494 DEVKIT_TOOLCHAIN_PATH="$DEVKIT_ROOT/bin"
495 fi
496 BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$DEVKIT_TOOLCHAIN_PATH)
497
498 # If DEVKIT_SYSROOT is set, use that, otherwise try a couple of known
499 # places for backwards compatiblity.
500 if test "x$DEVKIT_SYSROOT" != x; then
501 SYSROOT="$DEVKIT_SYSROOT"
502 elif test -d "$DEVKIT_ROOT/$host_alias/libc"; then
503 SYSROOT="$DEVKIT_ROOT/$host_alias/libc"
504 elif test -d "$DEVKIT_ROOT/$host/sys-root"; then
505 SYSROOT="$DEVKIT_ROOT/$host/sys-root"
506 fi
507 ]
508 )
509
510 # You can force the sysroot if the sysroot encoded into the compiler tools
511 # is not correct.
512 AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
513 [alias for --with-sysroot for backwards compatability])],
514 [SYSROOT=$with_sys_root]
515 )
516
517 AC_ARG_WITH(sysroot, [AS_HELP_STRING([--with-sysroot],
518 [use this directory as sysroot])],
519 [SYSROOT=$with_sysroot]
520 )
521
522 AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
523 [alias for --with-toolchain-path for backwards compatibility])],
524 [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_tools_dir)]
525 )
526
527 AC_ARG_WITH([toolchain-path], [AS_HELP_STRING([--with-toolchain-path],
528 [prepend these directories when searching for toolchain binaries (compilers etc)])],
529 [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_toolchain_path)]
530 )
531
532 AC_ARG_WITH([extra-path], [AS_HELP_STRING([--with-extra-path],
533 [prepend these directories to the default path])],
534 [BASIC_PREPEND_TO_PATH([EXTRA_PATH],$with_extra_path)]
535 )
536
537 if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then
538 # detect if Xcode is installed by running xcodebuild -version
539 # if no Xcode installed, xcodebuild exits with 1
540 # if Xcode is installed, even if xcode-select is misconfigured, then it exits with 0
541 if /usr/bin/xcodebuild -version >/dev/null 2>&1; then
542 # We need to use xcodebuild in the toolchain dir provided by the user, this will
543 # fall back on the stub binary in /usr/bin/xcodebuild
544 AC_PATH_PROG([XCODEBUILD], [xcodebuild], [/usr/bin/xcodebuild], [$TOOLCHAIN_PATH])
545 else
546 # this should result in SYSROOT being empty, unless --with-sysroot is provided
547 # when only the command line tools are installed there are no SDKs, so headers
548 # are copied into the system frameworks
549 XCODEBUILD=
550 AC_SUBST(XCODEBUILD)
551 fi
552
553 AC_MSG_CHECKING([for sdk name])
554 AC_ARG_WITH([sdk-name], [AS_HELP_STRING([--with-sdk-name],
555 [use the platform SDK of the given name. @<:@macosx@:>@])],
556 [SDKNAME=$with_sdk_name]
557 )
558 AC_MSG_RESULT([$SDKNAME])
559
560 # if toolchain path is specified then don't rely on system headers, they may not compile
561 HAVE_SYSTEM_FRAMEWORK_HEADERS=0
562 test -z "$TOOLCHAIN_PATH" && \
563 HAVE_SYSTEM_FRAMEWORK_HEADERS=`test ! -f /System/Library/Frameworks/Foundation.framework/Headers/Foundation.h; echo $?`
564
565 if test -z "$SYSROOT"; then
566 if test -n "$XCODEBUILD"; then
567 # if we don't have system headers, use default SDK name (last resort)
568 if test -z "$SDKNAME" -a $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
569 SDKNAME=${SDKNAME:-macosx}
570 fi
571
572 if test -n "$SDKNAME"; then
573 # Call xcodebuild to determine SYSROOT
574 SYSROOT=`"$XCODEBUILD" -sdk $SDKNAME -version | grep '^Path: ' | sed 's/Path: //'`
575 fi
576 else
577 if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
578 AC_MSG_ERROR([No xcodebuild tool and no system framework headers found, use --with-sysroot or --with-sdk-name to provide a path to a valid SDK])
579 fi
580 fi
581 else
582 # warn user if --with-sdk-name was also set
583 if test -n "$with_sdk_name"; then
584 AC_MSG_WARN([Both SYSROOT and --with-sdk-name are set, only SYSROOT will be used])
585 fi
586 fi
587
588 if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0 -a -z "$SYSROOT"; then
589 # If no system framework headers, then SYSROOT must be set, or we won't build
590 AC_MSG_ERROR([Unable to determine SYSROOT and no headers found in /System/Library/Frameworks. Check Xcode configuration, --with-sysroot or --with-sdk-name arguments.])
591 fi
592
593 # Perform a basic sanity test
594 if test ! -f "$SYSROOT/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then
595 if test -z "$SYSROOT"; then
596 AC_MSG_ERROR([Unable to find required framework headers, provide a path to an SDK via --with-sysroot or --with-sdk-name and be sure Xcode is installed properly])
597 else
598 AC_MSG_ERROR([Invalid SDK or SYSROOT path, dependent framework headers not found])
599 fi
600 fi
601
602 # set SDKROOT too, Xcode tools will pick it up
603 AC_SUBST(SDKROOT,$SYSROOT)
604 fi
605
606 # Prepend the extra path to the global path
607 BASIC_PREPEND_TO_PATH([PATH],$EXTRA_PATH)
608
609 if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
610 # Add extra search paths on solaris for utilities like ar and as etc...
611 PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
612 fi
613
614 AC_MSG_CHECKING([for sysroot])
615 AC_MSG_RESULT([$SYSROOT])
616 AC_MSG_CHECKING([for toolchain path])
617 AC_MSG_RESULT([$TOOLCHAIN_PATH])
618 AC_MSG_CHECKING([for extra path])
619 AC_MSG_RESULT([$EXTRA_PATH])
620 ])
621
622 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
623 [
624
625 AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
626 [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
627 [ CONF_NAME=${with_conf_name} ])
628
629 # Test from where we are running configure, in or outside of src root.
630 AC_MSG_CHECKING([where to store configuration])
631 if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \
632 || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \
633 || test "x$CURDIR" = "x$SRC_ROOT/make" ; then
634 # We are running configure from the src root.
635 # Create a default ./build/target-variant-debuglevel output root.
636 if test "x${CONF_NAME}" = x; then
637 AC_MSG_RESULT([in default location])
638 CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
639 else
640 AC_MSG_RESULT([in build directory with custom name])
641 fi
642 OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
643 $MKDIR -p "$OUTPUT_ROOT"
644 if test ! -d "$OUTPUT_ROOT"; then
645 AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
646 fi
647 else
648 # We are running configure from outside of the src dir.
649 # Then use the current directory as output dir!
650 # If configuration is situated in normal build directory, just use the build
651 # directory name as configuration name, otherwise use the complete path.
652 if test "x${CONF_NAME}" = x; then
653 CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
654 fi
655 OUTPUT_ROOT="$CURDIR"
656 AC_MSG_RESULT([in current directory])
657
658 # WARNING: This might be a bad thing to do. You need to be sure you want to
659 # have a configuration in this directory. Do some sanity checks!
660
661 if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
662 # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
663 # other files
664 files_present=`$LS $OUTPUT_ROOT`
665 # Configure has already touched config.log and confdefs.h in the current dir when this check
666 # is performed.
667 filtered_files=`$ECHO "$files_present" | $SED -e 's/config.log//g' -e 's/confdefs.h//g' -e 's/ //g' \
668 | $TR -d '\n'`
669 if test "x$filtered_files" != x; then
670 AC_MSG_NOTICE([Current directory is $CURDIR.])
671 AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
672 AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
673 AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
674 AC_MSG_NOTICE([seriously mess up just about everything.])
675 AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
676 AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
677 AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
678 fi
679 fi
680 fi
681 AC_MSG_CHECKING([what configuration name to use])
682 AC_MSG_RESULT([$CONF_NAME])
683
684 BASIC_FIXUP_PATH(OUTPUT_ROOT)
685
686 AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
687 AC_SUBST(CONF_NAME, $CONF_NAME)
688 AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
689
690 # The spec.gmk file contains all variables for the make system.
691 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
692 # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
693 AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
694 # The bootcycle-spec.gmk file contains support for boot cycle builds.
695 AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
696 # The compare.sh is used to compare the build output to other builds.
697 AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
698 # The generated Makefile knows where the spec.gmk is and where the source is.
699 # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
700 # which will look for generated configurations
701 AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
702 ])
703
704 AC_DEFUN_ONCE([BASIC_SETUP_LOGGING],
705 [
706 # Setup default logging of stdout and stderr to build.log in the output root.
707 BUILD_LOG='$(OUTPUT_ROOT)/build.log'
708 BUILD_LOG_PREVIOUS='$(OUTPUT_ROOT)/build.log.old'
709 BUILD_LOG_WRAPPER='$(BASH) $(SRC_ROOT)/common/bin/logger.sh $(BUILD_LOG)'
710 AC_SUBST(BUILD_LOG)
711 AC_SUBST(BUILD_LOG_PREVIOUS)
712 AC_SUBST(BUILD_LOG_WRAPPER)
713 ])
714
715
716 #%%% Simple tools %%%
717
718 # Check if we have found a usable version of make
719 # $1: the path to a potential make binary (or empty)
720 # $2: the description on how we found this
721 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
722 [
723 MAKE_CANDIDATE="$1"
724 DESCRIPTION="$2"
725 if test "x$MAKE_CANDIDATE" != x; then
726 AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
727 MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
728 IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
729 if test "x$IS_GNU_MAKE" = x; then
730 AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
731 else
732 IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP -e '3\.8[[12]]' -e '4\.'`
733 if test "x$IS_MODERN_MAKE" = x; then
734 AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version 3.81 or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
735 else
736 if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
737 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
738 MAKE_EXPECTED_ENV='cygwin'
739 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
740 MAKE_EXPECTED_ENV='msys'
741 else
742 AC_MSG_ERROR([Unknown Windows environment])
743 fi
744 MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
745 IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
746 else
747 # Not relevant for non-Windows
748 IS_MAKE_CORRECT_ENV=true
749 fi
750 if test "x$IS_MAKE_CORRECT_ENV" = x; then
751 AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
752 else
753 FOUND_MAKE=$MAKE_CANDIDATE
754 BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
755 fi
756 fi
757 fi
758 fi
759 ])
760
761 AC_DEFUN([BASIC_CHECK_MAKE_OUTPUT_SYNC],
762 [
763 # Check if make supports the output sync option and if so, setup using it.
764 AC_MSG_CHECKING([if make --output-sync is supported])
765 if $MAKE --version -O > /dev/null 2>&1; then
766 OUTPUT_SYNC_SUPPORTED=true
767 AC_MSG_RESULT([yes])
768 AC_MSG_CHECKING([for output-sync value])
769 AC_ARG_WITH([output-sync], [AS_HELP_STRING([--with-output-sync],
770 [set make output sync type if supported by make. @<:@recurse@:>@])],
771 [OUTPUT_SYNC=$with_output_sync])
772 if test "x$OUTPUT_SYNC" = "x"; then
773 OUTPUT_SYNC=none
774 fi
775 AC_MSG_RESULT([$OUTPUT_SYNC])
776 if ! $MAKE --version -O$OUTPUT_SYNC > /dev/null 2>&1; then
777 AC_MSG_ERROR([Make did not the support the value $OUTPUT_SYNC as output sync type.])
778 fi
779 else
780 OUTPUT_SYNC_SUPPORTED=false
781 AC_MSG_RESULT([no])
782 fi
783 AC_SUBST(OUTPUT_SYNC_SUPPORTED)
784 AC_SUBST(OUTPUT_SYNC)
785 ])
786
787 # Goes looking for a usable version of GNU make.
788 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
789 [
790 # We need to find a recent version of GNU make. Especially on Solaris, this can be tricky.
791 if test "x$MAKE" != x; then
792 # User has supplied a make, test it.
793 if test ! -f "$MAKE"; then
794 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not found.])
795 fi
796 BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
797 if test "x$FOUND_MAKE" = x; then
798 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make 3.81 or newer.])
799 fi
800 else
801 # Try our hardest to locate a correct version of GNU make
802 AC_PATH_PROGS(CHECK_GMAKE, gmake)
803 BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
804
805 if test "x$FOUND_MAKE" = x; then
806 AC_PATH_PROGS(CHECK_MAKE, make)
807 BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
808 fi
809
810 if test "x$FOUND_MAKE" = x; then
811 if test "x$TOOLCHAIN_PATH" != x; then
812 # We have a toolchain path, check that as well before giving up.
813 OLD_PATH=$PATH
814 PATH=$TOOLCHAIN_PATH:$PATH
815 AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
816 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
817 if test "x$FOUND_MAKE" = x; then
818 AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
819 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
820 fi
821 PATH=$OLD_PATH
822 fi
823 fi
824
825 if test "x$FOUND_MAKE" = x; then
826 AC_MSG_ERROR([Cannot find GNU make 3.81 or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
827 fi
828 fi
829
830 MAKE=$FOUND_MAKE
831 AC_SUBST(MAKE)
832 AC_MSG_NOTICE([Using GNU make 3.81 (or later) at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
833
834 BASIC_CHECK_MAKE_OUTPUT_SYNC
835 ])
836
837 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
838 [
839 # Test if find supports -delete
840 AC_MSG_CHECKING([if find supports -delete])
841 FIND_DELETE="-delete"
842
843 DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
844
845 echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
846
847 TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
848 if test -f $DELETEDIR/TestIfFindSupportsDelete; then
849 # No, it does not.
850 rm $DELETEDIR/TestIfFindSupportsDelete
851 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
852 # AIX 'find' is buggy if called with '-exec {} \+' and an empty file list
853 FIND_DELETE="-print | xargs rm"
854 else
855 FIND_DELETE="-exec rm \{\} \+"
856 fi
857 AC_MSG_RESULT([no])
858 else
859 AC_MSG_RESULT([yes])
860 fi
861 rmdir $DELETEDIR
862 AC_SUBST(FIND_DELETE)
863 ])
864
865 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
866 [
867 BASIC_CHECK_GNU_MAKE
868
869 BASIC_CHECK_FIND_DELETE
870
871 # These tools might not be installed by default,
872 # need hint on how to install them.
873 BASIC_REQUIRE_PROGS(UNZIP, unzip)
874 BASIC_REQUIRE_PROGS(ZIP, zip)
875
876 # Non-required basic tools
877
878 BASIC_PATH_PROGS(LDD, ldd)
879 if test "x$LDD" = "x"; then
880 # List shared lib dependencies is used for
881 # debug output and checking for forbidden dependencies.
882 # We can build without it.
883 LDD="true"
884 fi
885 BASIC_PATH_PROGS(OTOOL, otool)
886 if test "x$OTOOL" = "x"; then
887 OTOOL="true"
888 fi
889 BASIC_PATH_PROGS(READELF, [greadelf readelf])
890 BASIC_PATH_PROGS(HG, hg)
891 BASIC_PATH_PROGS(STAT, stat)
892 BASIC_PATH_PROGS(TIME, time)
893 # Check if it's GNU time
894 IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
895 if test "x$IS_GNU_TIME" != x; then
896 IS_GNU_TIME=yes
897 else
898 IS_GNU_TIME=no
899 fi
900 AC_SUBST(IS_GNU_TIME)
901
902 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
903 BASIC_REQUIRE_PROGS(COMM, comm)
904 fi
905
906 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
907 BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)
908 BASIC_REQUIRE_PROGS(XATTR, xattr)
909 BASIC_PATH_PROGS(CODESIGN, codesign)
910 if test "x$CODESIGN" != "x"; then
911 # Verify that the openjdk_codesign certificate is present
912 AC_MSG_CHECKING([if openjdk_codesign certificate is present])
913 rm -f codesign-testfile
914 touch codesign-testfile
915 codesign -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
916 rm -f codesign-testfile
917 if test "x$CODESIGN" = x; then
918 AC_MSG_RESULT([no])
919 else
920 AC_MSG_RESULT([yes])
921 fi
922 fi
923 fi
924 ])
925
926 # Check if build directory is on local disk. If not possible to determine,
927 # we prefer to claim it's local.
928 # Argument 1: directory to test
929 # Argument 2: what to do if it is on local disk
930 # Argument 3: what to do otherwise (remote disk or failure)
931 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
932 [
933 # df -l lists only local disks; if the given directory is not found then
934 # a non-zero exit code is given
935 if test "x$DF" = x; then
936 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
937 # msys does not have df; use Windows "net use" instead.
938 IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
939 if test "x$IS_NETWORK_DISK" = x; then
940 $2
941 else
942 $3
943 fi
944 else
945 # No df here, say it's local
946 $2
947 fi
948 else
949 if $DF -l $1 > /dev/null 2>&1; then
950 $2
951 else
952 $3
953 fi
954 fi
955 ])
956
957 # Check that source files have basic read permissions set. This might
958 # not be the case in cygwin in certain conditions.
959 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
960 [
961 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
962 file_to_test="$SRC_ROOT/LICENSE"
963 if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
964 AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
965 fi
966 fi
967 ])
968
969 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
970 [
971 # Did user specify any unknown variables?
972 BASIC_CHECK_LEFTOVER_OVERRIDDEN
973
974 AC_MSG_CHECKING([if build directory is on local disk])
975 BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
976 [OUTPUT_DIR_IS_LOCAL="yes"],
977 [OUTPUT_DIR_IS_LOCAL="no"])
978 AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
979
980 BASIC_CHECK_SRC_PERMS
981
982 # Check if the user has any old-style ALT_ variables set.
983 FOUND_ALT_VARIABLES=`env | grep ^ALT_`
984
985 # Before generating output files, test if they exist. If they do, this is a reconfigure.
986 # Since we can't properly handle the dependencies for this, warn the user about the situation
987 if test -e $OUTPUT_ROOT/spec.gmk; then
988 IS_RECONFIGURE=yes
989 else
990 IS_RECONFIGURE=no
991 fi
992 ])