1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 ###############################################################################
  27 # Create a function/macro that takes a series of named arguments. The call is
  28 # similar to AC_DEFUN, but the setup of the function looks like this:
  29 # BASIC_DEFUN_NAMED([MYFUNC], [FOO *BAR], [$@], [
  30 # ... do something
  31 #   AC_MSG_NOTICE([Value of BAR is ARG_BAR])
  32 # ])
  33 # A star (*) in front of a named argument means that it is required and it's
  34 # presence will be verified. To pass e.g. the first value as a normal indexed
  35 # argument, use [m4_shift($@)] as the third argument instead of [$@]. These
  36 # arguments are referenced in the function by their name prefixed by ARG_, e.g.
  37 # "ARG_FOO".
  38 #
  39 # The generated function can be called like this:
  40 # MYFUNC(FOO: [foo-val],
  41 #     BAR: [
  42 #         $ECHO hello world
  43 #     ])
  44 # Note that the argument value must start on the same line as the argument name.
  45 #
  46 # Argument 1: Name of the function to define
  47 # Argument 2: List of legal named arguments, with a * prefix for required arguments
  48 # Argument 3: Argument array to treat as named, typically $@
  49 # Argument 4: The main function body
  50 AC_DEFUN([BASIC_DEFUN_NAMED],
  51 [
  52   AC_DEFUN($1, [
  53     m4_foreach(arg, m4_split($2), [
  54       m4_if(m4_bregexp(arg, [^\*]), -1,
  55         [
  56           m4_set_add(legal_named_args, arg)
  57         ],
  58         [
  59           m4_set_add(legal_named_args, m4_substr(arg, 1))
  60           m4_set_add(required_named_args, m4_substr(arg, 1))
  61         ]
  62       )
  63     ])
  64 
  65     m4_foreach([arg], [$3], [
  66       m4_define(arg_name, m4_substr(arg, 0, m4_bregexp(arg, [: ])))
  67       m4_set_contains(legal_named_args, arg_name, [],[AC_MSG_ERROR([Internal error: arg_name is not a valid named argument to [$1]. Valid arguments are 'm4_set_contents(legal_named_args, [ ])'.])])
  68       m4_set_remove(required_named_args, arg_name)
  69       m4_set_remove(legal_named_args, arg_name)
  70       m4_pushdef([ARG_][]arg_name, m4_substr(arg, m4_incr(m4_incr(m4_bregexp(arg, [: ])))))
  71       m4_set_add(defined_args, arg_name)
  72       m4_undefine([arg_name])
  73     ])
  74     m4_set_empty(required_named_args, [], [
  75       AC_MSG_ERROR([Internal error: Required named arguments are missing for [$1]. Missing arguments: 'm4_set_contents(required_named_args, [ ])'])
  76     ])
  77     m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([legal_named_args])), [
  78       m4_pushdef([ARG_][]arg, [])
  79       m4_set_add(defined_args, arg)
  80     ])
  81     m4_set_delete(legal_named_args)
  82     m4_set_delete(required_named_args)
  83 
  84     # Execute function body
  85     $4
  86 
  87     m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([defined_args])), [
  88       m4_popdef([ARG_][]arg)
  89     ])
  90 
  91     m4_set_delete(defined_args)
  92   ])
  93 ])
  94 
  95 ###############################################################################
  96 # Check if a list of space-separated words are selected only from a list of
  97 # space-separated legal words. Typical use is to see if a user-specified
  98 # set of words is selected from a set of legal words.
  99 #
 100 # Sets the specified variable to list of non-matching (offending) words, or to
 101 # the empty string if all words are matching the legal set.
 102 #
 103 # $1: result variable name
 104 # $2: list of values to check
 105 # $3: list of legal values
 106 AC_DEFUN([BASIC_GET_NON_MATCHING_VALUES],
 107 [
 108   # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
 109   # Notice that the original variant fails on SLES 10 and 11
 110   # Some grep versions (at least bsd) behaves strangely on the base case with
 111   # no legal_values, so make it explicit.
 112   values_to_check=`$ECHO $2 | $TR ' ' '\n'`
 113   legal_values=`$ECHO $3 | $TR ' ' '\n'`
 114   if test -z "$legal_values"; then
 115     $1="$2"
 116   else
 117     result=`$GREP -Fvx "$legal_values" <<< "$values_to_check" | $GREP -v '^$'`
 118     $1=${result//$'\n'/ }
 119   fi
 120 ])
 121 
 122 ###############################################################################
 123 # Sort a space-separated list, and remove duplicates.
 124 #
 125 # Sets the specified variable to the resulting list.
 126 #
 127 # $1: result variable name
 128 # $2: list of values to sort
 129 AC_DEFUN([BASIC_SORT_LIST],
 130 [
 131   values_to_sort=`$ECHO $2 | $TR ' ' '\n'`
 132   result=`$SORT -u <<< "$values_to_sort" | $GREP -v '^$'`
 133   $1=${result//$'\n'/ }
 134 ])
 135 
 136 ###############################################################################
 137 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
 138 # If so, then append $1 to $2 \
 139 # Also set JVM_ARG_OK to true/false depending on outcome.
 140 AC_DEFUN([ADD_JVM_ARG_IF_OK],
 141 [
 142   $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
 143   $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
 144   OUTPUT=`$3 $1 -version 2>&1`
 145   FOUND_WARN=`$ECHO "$OUTPUT" | $GREP -i warn`
 146   FOUND_VERSION=`$ECHO $OUTPUT | $GREP " version \""`
 147   if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
 148     $2="[$]$2 $1"
 149     JVM_ARG_OK=true
 150   else
 151     $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
 152     $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
 153     JVM_ARG_OK=false
 154   fi
 155 ])
 156 
 157 # Appends a string to a path variable, only adding the : when needed.
 158 AC_DEFUN([BASIC_APPEND_TO_PATH],
 159 [
 160   if test "x$2" != x; then
 161     if test "x[$]$1" = x; then
 162       $1="$2"
 163     else
 164       $1="[$]$1:$2"
 165     fi
 166   fi
 167 ])
 168 
 169 # Prepends a string to a path variable, only adding the : when needed.
 170 AC_DEFUN([BASIC_PREPEND_TO_PATH],
 171 [
 172   if test "x$2" != x; then
 173     if test "x[$]$1" = x; then
 174       $1="$2"
 175     else
 176       $1="$2:[$]$1"
 177     fi
 178   fi
 179 ])
 180 
 181 ###############################################################################
 182 # This will make sure the given variable points to a full and proper
 183 # path. This means:
 184 # 1) There will be no spaces in the path. On unix platforms,
 185 #    spaces in the path will result in an error. On Windows,
 186 #    the path will be rewritten using short-style to be space-free.
 187 # 2) The path will be absolute, and it will be in unix-style (on
 188 #     cygwin).
 189 # $1: The name of the variable to fix
 190 AC_DEFUN([BASIC_FIXUP_PATH],
 191 [
 192   # Only process if variable expands to non-empty
 193 
 194   if test "x[$]$1" != x; then
 195     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 196       BASIC_FIXUP_PATH_CYGWIN($1)
 197     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 198       BASIC_FIXUP_PATH_MSYS($1)
 199     else
 200       # We're on a unix platform. Hooray! :)
 201       path="[$]$1"
 202       has_space=`$ECHO "$path" | $GREP " "`
 203       if test "x$has_space" != x; then
 204         AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
 205         AC_MSG_ERROR([Spaces are not allowed in this path.])
 206       fi
 207 
 208       # Use eval to expand a potential ~
 209       eval path="$path"
 210       if test ! -f "$path" && test ! -d "$path"; then
 211         AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
 212       fi
 213 
 214       if test -d "$path"; then
 215         $1="`cd "$path"; $THEPWDCMD -L`"
 216       else
 217         dir="`$DIRNAME "$path"`"
 218         base="`$BASENAME "$path"`"
 219         $1="`cd "$dir"; $THEPWDCMD -L`/$base"
 220       fi
 221     fi
 222   fi
 223 ])
 224 
 225 ###############################################################################
 226 # This will make sure the given variable points to a executable
 227 # with a full and proper path. This means:
 228 # 1) There will be no spaces in the path. On unix platforms,
 229 #    spaces in the path will result in an error. On Windows,
 230 #    the path will be rewritten using short-style to be space-free.
 231 # 2) The path will be absolute, and it will be in unix-style (on
 232 #     cygwin).
 233 # Any arguments given to the executable is preserved.
 234 # If the input variable does not have a directory specification, then
 235 # it need to be in the PATH.
 236 # $1: The name of the variable to fix
 237 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
 238 [
 239   # Only process if variable expands to non-empty
 240 
 241   if test "x[$]$1" != x; then
 242     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 243       BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
 244     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 245       BASIC_FIXUP_EXECUTABLE_MSYS($1)
 246     else
 247       # We're on a unix platform. Hooray! :)
 248       # First separate the path from the arguments. This will split at the first
 249       # space.
 250       complete="[$]$1"
 251       path="${complete%% *}"
 252       tmp="$complete EOL"
 253       arguments="${tmp#* }"
 254 
 255       # Cannot rely on the command "which" here since it doesn't always work.
 256       is_absolute_path=`$ECHO "$path" | $GREP ^/`
 257       if test -z "$is_absolute_path"; then
 258         # Path to executable is not absolute. Find it.
 259         IFS_save="$IFS"
 260         IFS=:
 261         for p in $PATH; do
 262           if test -f "$p/$path" && test -x "$p/$path"; then
 263             new_path="$p/$path"
 264             break
 265           fi
 266         done
 267         IFS="$IFS_save"
 268       else
 269         # This is an absolute path, we can use it without further modifications.
 270         new_path="$path"
 271       fi
 272 
 273       if test "x$new_path" = x; then
 274         AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
 275         has_space=`$ECHO "$complete" | $GREP " "`
 276         if test "x$has_space" != x; then
 277           AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
 278         fi
 279         AC_MSG_ERROR([Cannot locate the the path of $1])
 280       fi
 281     fi
 282 
 283     # Now join together the path and the arguments once again
 284     if test "x$arguments" != xEOL; then
 285       new_complete="$new_path ${arguments% *}"
 286     else
 287       new_complete="$new_path"
 288     fi
 289 
 290     if test "x$complete" != "x$new_complete"; then
 291       $1="$new_complete"
 292       AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
 293     fi
 294   fi
 295 ])
 296 
 297 ###############################################################################
 298 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
 299 [
 300   if test "x$OPENJDK_BUILD_OS" != xwindows; then
 301     # Follow a chain of symbolic links. Use readlink
 302     # where it exists, else fall back to horribly
 303     # complicated shell code.
 304     if test "x$READLINK_TESTED" != yes; then
 305       # On MacOSX there is a readlink tool with a different
 306       # purpose than the GNU readlink tool. Check the found readlink.
 307       READLINK_ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
 308       # If READLINK_ISGNU is empty, then it's a non-GNU readlink. Don't use it.
 309       READLINK_TESTED=yes
 310     fi
 311 
 312     if test "x$READLINK" != x && test "x$READLINK_ISGNU" != x; then
 313       $1=`$READLINK -f [$]$1`
 314     else
 315       # Save the current directory for restoring afterwards
 316       STARTDIR=$PWD
 317       COUNTER=0
 318       sym_link_dir=`$DIRNAME [$]$1`
 319       sym_link_file=`$BASENAME [$]$1`
 320       cd $sym_link_dir
 321       # Use -P flag to resolve symlinks in directories.
 322       cd `$THEPWDCMD -P`
 323       sym_link_dir=`$THEPWDCMD -P`
 324       # Resolve file symlinks
 325       while test $COUNTER -lt 20; do
 326         ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
 327         if test "x$ISLINK" == x; then
 328           # This is not a symbolic link! We are done!
 329           break
 330         fi
 331         # Again resolve directory symlinks since the target of the just found
 332         # link could be in a different directory
 333         cd `$DIRNAME $ISLINK`
 334         sym_link_dir=`$THEPWDCMD -P`
 335         sym_link_file=`$BASENAME $ISLINK`
 336         let COUNTER=COUNTER+1
 337       done
 338       cd $STARTDIR
 339       $1=$sym_link_dir/$sym_link_file
 340     fi
 341   fi
 342 ])
 343 
 344 ###############################################################################
 345 # Register a --with argument but mark it as deprecated
 346 # $1: The name of the with argument to deprecate, not including --with-
 347 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
 348 [
 349   AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
 350       [Deprecated. Option is kept for backwards compatibility and is ignored])],
 351       [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
 352 ])
 353 
 354 ###############################################################################
 355 # Register a --enable argument but mark it as deprecated
 356 # $1: The name of the with argument to deprecate, not including --enable-
 357 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
 358 # $3: Messages to user.
 359 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
 360 [
 361   AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
 362       [Deprecated. Option is kept for backwards compatibility and is ignored])])
 363   if test "x$enable_$2" != x; then
 364     AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
 365 
 366     if test "x$3" != x; then
 367       AC_MSG_WARN([$3])
 368     fi
 369 
 370   fi
 371 ])
 372 
 373 ###############################################################################
 374 AC_DEFUN_ONCE([BASIC_INIT],
 375 [
 376   # Save the original command line. This is passed to us by the wrapper configure script.
 377   AC_SUBST(CONFIGURE_COMMAND_LINE)
 378   # Save the path variable before it gets changed
 379   ORIGINAL_PATH="$PATH"
 380   AC_SUBST(ORIGINAL_PATH)
 381   DATE_WHEN_CONFIGURED=`LANG=C date`
 382   AC_SUBST(DATE_WHEN_CONFIGURED)
 383   AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
 384 ])
 385 
 386 ###############################################################################
 387 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
 388 # $1: variable to check
 389 AC_DEFUN([BASIC_CHECK_NONEMPTY],
 390 [
 391   if test "x[$]$1" = x; then
 392     AC_MSG_ERROR([Could not find required tool for $1])
 393   fi
 394 ])
 395 
 396 ###############################################################################
 397 # Check that there are no unprocessed overridden variables left.
 398 # If so, they are an incorrect argument and we will exit with an error.
 399 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],
 400 [
 401   if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then
 402     # Replace the separating ! with spaces before presenting for end user.
 403     unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }
 404     AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])
 405   fi
 406 ])
 407 
 408 ###############################################################################
 409 # Setup a tool for the given variable. If correctly specified by the user,
 410 # use that value, otherwise search for the tool using the supplied code snippet.
 411 # $1: variable to set
 412 # $2: code snippet to call to look for the tool
 413 # $3: code snippet to call if variable was used to find tool
 414 AC_DEFUN([BASIC_SETUP_TOOL],
 415 [
 416   # Publish this variable in the help.
 417   AC_ARG_VAR($1, [Override default value for $1])
 418 
 419   if [[ -z "${$1+x}" ]]; then
 420     # The variable is not set by user, try to locate tool using the code snippet
 421     $2
 422   else
 423     # The variable is set, but is it from the command line or the environment?
 424 
 425     # Try to remove the string !$1! from our list.
 426     try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}
 427     if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then
 428       # If it failed, the variable was not from the command line. Ignore it,
 429       # but warn the user (except for BASH, which is always set by the calling BASH).
 430       if test "x$1" != xBASH; then
 431         AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])
 432       fi
 433       # Try to locate tool using the code snippet
 434       $2
 435     else
 436       # If it succeeded, then it was overridden by the user. We will use it
 437       # for the tool.
 438 
 439       # First remove it from the list of overridden variables, so we can test
 440       # for unknown variables in the end.
 441       CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"
 442 
 443       # Check if we try to supply an empty value
 444       if test "x[$]$1" = x; then
 445         AC_MSG_NOTICE([Setting user supplied tool $1= (no value)])
 446         AC_MSG_CHECKING([for $1])
 447         AC_MSG_RESULT([disabled])
 448       else
 449         # Check if the provided tool contains a complete path.
 450         tool_specified="[$]$1"
 451         tool_basename="${tool_specified##*/}"
 452         if test "x$tool_basename" = "x$tool_specified"; then
 453           # A command without a complete path is provided, search $PATH.
 454           AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])
 455           AC_PATH_PROG($1, $tool_basename)
 456           if test "x[$]$1" = x; then
 457             AC_MSG_ERROR([User supplied tool $tool_basename could not be found])
 458           fi
 459         else
 460           # Otherwise we believe it is a complete path. Use it as it is.
 461           AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])
 462           AC_MSG_CHECKING([for $1])
 463           if test ! -x "$tool_specified"; then
 464             AC_MSG_RESULT([not found])
 465             AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])
 466           fi
 467           AC_MSG_RESULT([$tool_specified])
 468         fi
 469       fi
 470     fi
 471     $3
 472   fi
 473 ])
 474 
 475 ###############################################################################
 476 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool
 477 # $1: variable to set
 478 # $2: executable name (or list of names) to look for
 479 # $3: [path]
 480 AC_DEFUN([BASIC_PATH_PROGS],
 481 [
 482   BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2, , $3)])
 483 ])
 484 
 485 ###############################################################################
 486 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool
 487 # $1: variable to set
 488 # $2: executable name (or list of names) to look for
 489 AC_DEFUN([BASIC_CHECK_TOOLS],
 490 [
 491   BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])
 492 ])
 493 
 494 ###############################################################################
 495 # Like BASIC_PATH_PROGS but fails if no tool was found.
 496 # $1: variable to set
 497 # $2: executable name (or list of names) to look for
 498 # $3: [path]
 499 AC_DEFUN([BASIC_REQUIRE_PROGS],
 500 [
 501   BASIC_PATH_PROGS($1, $2, , $3)
 502   BASIC_CHECK_NONEMPTY($1)
 503 ])
 504 
 505 ###############################################################################
 506 # Like BASIC_SETUP_TOOL but fails if no tool was found.
 507 # $1: variable to set
 508 # $2: autoconf macro to call to look for the special tool
 509 AC_DEFUN([BASIC_REQUIRE_SPECIAL],
 510 [
 511   BASIC_SETUP_TOOL($1, [$2])
 512   BASIC_CHECK_NONEMPTY($1)
 513 ])
 514 
 515 ###############################################################################
 516 # Setup the most fundamental tools that relies on not much else to set up,
 517 # but is used by much of the early bootstrap code.
 518 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
 519 [
 520   # Start with tools that do not need have cross compilation support
 521   # and can be expected to be found in the default PATH. These tools are
 522   # used by configure.
 523 
 524   # First are all the simple required tools.
 525   BASIC_REQUIRE_PROGS(BASENAME, basename)
 526   BASIC_REQUIRE_PROGS(BASH, bash)
 527   BASIC_REQUIRE_PROGS(CAT, cat)
 528   BASIC_REQUIRE_PROGS(CHMOD, chmod)
 529   BASIC_REQUIRE_PROGS(CMP, cmp)
 530   BASIC_REQUIRE_PROGS(COMM, comm)
 531   BASIC_REQUIRE_PROGS(CP, cp)
 532   BASIC_REQUIRE_PROGS(CUT, cut)
 533   BASIC_REQUIRE_PROGS(DATE, date)
 534   BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])
 535   BASIC_REQUIRE_PROGS(DIRNAME, dirname)
 536   BASIC_REQUIRE_PROGS(ECHO, echo)
 537   BASIC_REQUIRE_PROGS(EXPR, expr)
 538   BASIC_REQUIRE_PROGS(FILE, file)
 539   BASIC_REQUIRE_PROGS(FIND, find)
 540   BASIC_REQUIRE_PROGS(HEAD, head)
 541   BASIC_REQUIRE_PROGS(GUNZIP, gunzip)
 542   BASIC_REQUIRE_PROGS(GZIP, pigz gzip)
 543   BASIC_REQUIRE_PROGS(LN, ln)
 544   BASIC_REQUIRE_PROGS(LS, ls)
 545   BASIC_REQUIRE_PROGS(MKDIR, mkdir)
 546   BASIC_REQUIRE_PROGS(MKTEMP, mktemp)
 547   BASIC_REQUIRE_PROGS(MV, mv)
 548   BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])
 549   BASIC_REQUIRE_PROGS(PRINTF, printf)
 550   BASIC_REQUIRE_PROGS(READLINK, [greadlink readlink])
 551   BASIC_REQUIRE_PROGS(RM, rm)
 552   BASIC_REQUIRE_PROGS(RMDIR, rmdir)
 553   BASIC_REQUIRE_PROGS(SH, sh)
 554   BASIC_REQUIRE_PROGS(SORT, sort)
 555   BASIC_REQUIRE_PROGS(TAIL, tail)
 556   BASIC_REQUIRE_PROGS(TAR, gtar tar)
 557   BASIC_REQUIRE_PROGS(TEE, tee)
 558   BASIC_REQUIRE_PROGS(TOUCH, touch)
 559   BASIC_REQUIRE_PROGS(TR, tr)
 560   BASIC_REQUIRE_PROGS(UNAME, uname)
 561   BASIC_REQUIRE_PROGS(UNIQ, uniq)
 562   BASIC_REQUIRE_PROGS(WC, wc)
 563   BASIC_REQUIRE_PROGS(WHICH, which)
 564   BASIC_REQUIRE_PROGS(XARGS, xargs)
 565 
 566   # Then required tools that require some special treatment.
 567   BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])
 568   BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])
 569   BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])
 570   BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])
 571   BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])
 572 
 573   # Always force rm.
 574   RM="$RM -f"
 575 
 576   # pwd behaves differently on various platforms and some don't support the -L flag.
 577   # Always use the bash builtin pwd to get uniform behavior.
 578   THEPWDCMD=pwd
 579 
 580   # These are not required on all platforms
 581   BASIC_PATH_PROGS(CYGPATH, cygpath)
 582   BASIC_PATH_PROGS(DF, df)
 583   BASIC_PATH_PROGS(CPIO, [cpio bsdcpio])
 584   BASIC_PATH_PROGS(NICE, nice)
 585   BASIC_PATH_PROGS(PANDOC, pandoc)
 586 ])
 587 
 588 ###############################################################################
 589 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
 590 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
 591 [
 592   # Save the current directory this script was started from
 593   CURDIR="$PWD"
 594 
 595   # We might need to rewrite ORIGINAL_PATH, if it includes "#", to quote them
 596   # for make. We couldn't do this when we retrieved ORIGINAL_PATH, since SED
 597   # was not available at that time.
 598   REWRITTEN_PATH=`$ECHO "$ORIGINAL_PATH" | $SED -e 's/#/\\\\#/g'`
 599   if test "x$REWRITTEN_PATH" != "x$ORIGINAL_PATH"; then
 600     ORIGINAL_PATH="$REWRITTEN_PATH"
 601     AC_MSG_NOTICE([Rewriting ORIGINAL_PATH to $REWRITTEN_PATH])
 602   fi
 603 
 604   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 605     PATH_SEP=";"
 606     BASIC_CHECK_PATHS_WINDOWS
 607   else
 608     PATH_SEP=":"
 609   fi
 610   AC_SUBST(PATH_SEP)
 611 
 612   # We get the top-level directory from the supporting wrappers.
 613   AC_MSG_CHECKING([for top-level directory])
 614   AC_MSG_RESULT([$TOPDIR])
 615   AC_SUBST(TOPDIR)
 616 
 617   # We can only call BASIC_FIXUP_PATH after BASIC_CHECK_PATHS_WINDOWS.
 618   BASIC_FIXUP_PATH(CURDIR)
 619   BASIC_FIXUP_PATH(TOPDIR)
 620 
 621   # Locate the directory of this script.
 622   AUTOCONF_DIR=$TOPDIR/make/autoconf
 623 
 624   # Setup username (for use in adhoc version strings etc)
 625   # Outer [ ] to quote m4.
 626   [ USERNAME=`$ECHO "$USER" | $TR -d -c '[a-z][A-Z][0-9]'` ]
 627   AC_SUBST(USERNAME)
 628 ])
 629 
 630 ###############################################################################
 631 # Evaluates platform specific overrides for devkit variables.
 632 # $1: Name of variable
 633 AC_DEFUN([BASIC_EVAL_DEVKIT_VARIABLE],
 634 [
 635   if test "x[$]$1" = x; then
 636     eval $1="\${$1_${OPENJDK_TARGET_CPU}}"
 637   fi
 638 ])
 639 
 640 ###############################################################################
 641 AC_DEFUN_ONCE([BASIC_SETUP_DEVKIT],
 642 [
 643   AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
 644       [use this devkit for compilers, tools and resources])])
 645 
 646   if test "x$with_devkit" = xyes; then
 647     AC_MSG_ERROR([--with-devkit must have a value])
 648   elif test "x$with_devkit" != x && test "x$with_devkit" != xno; then
 649     BASIC_FIXUP_PATH([with_devkit])
 650     DEVKIT_ROOT="$with_devkit"
 651     # Check for a meta data info file in the root of the devkit
 652     if test -f "$DEVKIT_ROOT/devkit.info"; then
 653       . $DEVKIT_ROOT/devkit.info
 654       # This potentially sets the following:
 655       # A descriptive name of the devkit
 656       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_NAME])
 657       # Corresponds to --with-extra-path
 658       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_EXTRA_PATH])
 659       # Corresponds to --with-toolchain-path
 660       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_TOOLCHAIN_PATH])
 661       # Corresponds to --with-sysroot
 662       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_SYSROOT])
 663 
 664       # Identifies the Visual Studio version in the devkit
 665       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_VERSION])
 666       # The Visual Studio include environment variable
 667       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_INCLUDE])
 668       # The Visual Studio lib environment variable
 669       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_LIB])
 670       # Corresponds to --with-msvcr-dll
 671       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCR_DLL])
 672       # Corresponds to --with-msvcp-dll
 673       BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCP_DLL])
 674     fi
 675 
 676     AC_MSG_CHECKING([for devkit])
 677     if test "x$DEVKIT_NAME" != x; then
 678       AC_MSG_RESULT([$DEVKIT_NAME in $DEVKIT_ROOT])
 679     else
 680       AC_MSG_RESULT([$DEVKIT_ROOT])
 681     fi
 682 
 683     BASIC_PREPEND_TO_PATH([EXTRA_PATH],$DEVKIT_EXTRA_PATH)
 684 
 685     # Fallback default of just /bin if DEVKIT_PATH is not defined
 686     if test "x$DEVKIT_TOOLCHAIN_PATH" = x; then
 687       DEVKIT_TOOLCHAIN_PATH="$DEVKIT_ROOT/bin"
 688     fi
 689     BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$DEVKIT_TOOLCHAIN_PATH)
 690 
 691     # If DEVKIT_SYSROOT is set, use that, otherwise try a couple of known
 692     # places for backwards compatiblity.
 693     if test "x$DEVKIT_SYSROOT" != x; then
 694       SYSROOT="$DEVKIT_SYSROOT"
 695     elif test -d "$DEVKIT_ROOT/$host_alias/libc"; then
 696       SYSROOT="$DEVKIT_ROOT/$host_alias/libc"
 697     elif test -d "$DEVKIT_ROOT/$host/sys-root"; then
 698       SYSROOT="$DEVKIT_ROOT/$host/sys-root"
 699     fi
 700 
 701     if test "x$DEVKIT_ROOT" != x; then
 702       DEVKIT_LIB_DIR="$DEVKIT_ROOT/lib"
 703       if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 704         DEVKIT_LIB_DIR="$DEVKIT_ROOT/lib64"
 705       fi
 706       AC_SUBST(DEVKIT_LIB_DIR)
 707     fi
 708   fi
 709 
 710   # You can force the sysroot if the sysroot encoded into the compiler tools
 711   # is not correct.
 712   AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
 713       [alias for --with-sysroot for backwards compatability])],
 714       [SYSROOT=$with_sys_root]
 715   )
 716 
 717   AC_ARG_WITH(sysroot, [AS_HELP_STRING([--with-sysroot],
 718       [use this directory as sysroot])],
 719       [SYSROOT=$with_sysroot]
 720   )
 721 
 722   AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
 723       [alias for --with-toolchain-path for backwards compatibility])],
 724       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_tools_dir)]
 725   )
 726 
 727   AC_ARG_WITH([toolchain-path], [AS_HELP_STRING([--with-toolchain-path],
 728       [prepend these directories when searching for toolchain binaries (compilers etc)])],
 729       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_toolchain_path)]
 730   )
 731 
 732   AC_ARG_WITH([extra-path], [AS_HELP_STRING([--with-extra-path],
 733       [prepend these directories to the default path])],
 734       [BASIC_PREPEND_TO_PATH([EXTRA_PATH],$with_extra_path)]
 735   )
 736 
 737   if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then
 738     # If a devkit has been supplied, find xcodebuild in the toolchain_path.
 739     # If not, detect if Xcode is installed by running xcodebuild -version
 740     # if no Xcode installed, xcodebuild exits with 1
 741     # if Xcode is installed, even if xcode-select is misconfigured, then it exits with 0
 742     if test "x$DEVKIT_ROOT" != x || /usr/bin/xcodebuild -version >/dev/null 2>&1; then
 743       # We need to use xcodebuild in the toolchain dir provided by the user, this will
 744       # fall back on the stub binary in /usr/bin/xcodebuild
 745       AC_PATH_PROG([XCODEBUILD], [xcodebuild], [/usr/bin/xcodebuild], [$TOOLCHAIN_PATH])
 746     else
 747       # this should result in SYSROOT being empty, unless --with-sysroot is provided
 748       # when only the command line tools are installed there are no SDKs, so headers
 749       # are copied into the system frameworks
 750       XCODEBUILD=
 751       AC_SUBST(XCODEBUILD)
 752     fi
 753 
 754     AC_MSG_CHECKING([for sdk name])
 755     AC_ARG_WITH([sdk-name], [AS_HELP_STRING([--with-sdk-name],
 756         [use the platform SDK of the given name. @<:@macosx@:>@])],
 757         [SDKNAME=$with_sdk_name]
 758     )
 759     AC_MSG_RESULT([$SDKNAME])
 760 
 761     # if toolchain path is specified then don't rely on system headers, they may not compile
 762     HAVE_SYSTEM_FRAMEWORK_HEADERS=0
 763     test -z "$TOOLCHAIN_PATH" && \
 764       HAVE_SYSTEM_FRAMEWORK_HEADERS=`test ! -f /System/Library/Frameworks/Foundation.framework/Headers/Foundation.h; echo $?`
 765 
 766     if test -z "$SYSROOT"; then
 767       if test -n "$XCODEBUILD"; then
 768         # if we don't have system headers, use default SDK name (last resort)
 769         if test -z "$SDKNAME" -a $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
 770           SDKNAME=${SDKNAME:-macosx}
 771         fi
 772 
 773         if test -n "$SDKNAME"; then
 774           # Call xcodebuild to determine SYSROOT
 775           SYSROOT=`"$XCODEBUILD" -sdk $SDKNAME -version | $GREP '^Path: ' | $SED 's/Path: //'`
 776         fi
 777       else
 778         if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
 779           AC_MSG_ERROR([No xcodebuild tool and no system framework headers found, use --with-sysroot or --with-sdk-name to provide a path to a valid SDK])
 780         fi
 781       fi
 782     else
 783       # warn user if --with-sdk-name was also set
 784       if test -n "$with_sdk_name"; then
 785         AC_MSG_WARN([Both SYSROOT and --with-sdk-name are set, only SYSROOT will be used])
 786       fi
 787     fi
 788 
 789     if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0 -a -z "$SYSROOT"; then
 790       # If no system framework headers, then SYSROOT must be set, or we won't build
 791       AC_MSG_ERROR([Unable to determine SYSROOT and no headers found in /System/Library/Frameworks. Check Xcode configuration, --with-sysroot or --with-sdk-name arguments.])
 792     fi
 793 
 794     # Perform a basic sanity test
 795     if test ! -f "$SYSROOT/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then
 796       if test -z "$SYSROOT"; then
 797         AC_MSG_ERROR([Unable to find required framework headers, provide a path to an SDK via --with-sysroot or --with-sdk-name and be sure Xcode is installed properly])
 798       else
 799         AC_MSG_ERROR([Invalid SDK or SYSROOT path, dependent framework headers not found])
 800       fi
 801     fi
 802 
 803     # set SDKROOT too, Xcode tools will pick it up
 804     SDKROOT="$SYSROOT"
 805     AC_SUBST(SDKROOT)
 806   fi
 807 
 808   # Prepend the extra path to the global path
 809   BASIC_PREPEND_TO_PATH([PATH],$EXTRA_PATH)
 810 
 811   AC_MSG_CHECKING([for sysroot])
 812   AC_MSG_RESULT([$SYSROOT])
 813   AC_MSG_CHECKING([for toolchain path])
 814   AC_MSG_RESULT([$TOOLCHAIN_PATH])
 815   AC_MSG_CHECKING([for extra path])
 816   AC_MSG_RESULT([$EXTRA_PATH])
 817 ])
 818 
 819 ###############################################################################
 820 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
 821 [
 822 
 823   AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
 824       [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
 825       [ CONF_NAME=${with_conf_name} ])
 826 
 827   # Test from where we are running configure, in or outside of src root.
 828   AC_MSG_CHECKING([where to store configuration])
 829   if test "x$CURDIR" = "x$TOPDIR" || test "x$CURDIR" = "x$CUSTOM_ROOT" \
 830       || test "x$CURDIR" = "x$TOPDIR/make/autoconf" \
 831       || test "x$CURDIR" = "x$TOPDIR/make" ; then
 832     # We are running configure from the src root.
 833     # Create a default ./build/target-variant-debuglevel output root.
 834     if test "x${CONF_NAME}" = x; then
 835       AC_MSG_RESULT([in default location])
 836       CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${JVM_VARIANTS_WITH_AND}-${DEBUG_LEVEL}"
 837     else
 838       AC_MSG_RESULT([in build directory with custom name])
 839     fi
 840 
 841     if test "x$CUSTOM_ROOT" != x; then
 842       OUTPUTDIR="${CUSTOM_ROOT}/build/${CONF_NAME}"
 843     else
 844       OUTPUTDIR="${TOPDIR}/build/${CONF_NAME}"
 845     fi
 846     $MKDIR -p "$OUTPUTDIR"
 847     if test ! -d "$OUTPUTDIR"; then
 848       AC_MSG_ERROR([Could not create build directory $OUTPUTDIR])
 849     fi
 850   else
 851     # We are running configure from outside of the src dir.
 852     # Then use the current directory as output dir!
 853     # If configuration is situated in normal build directory, just use the build
 854     # directory name as configuration name, otherwise use the complete path.
 855     if test "x${CONF_NAME}" = x; then
 856       CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${TOPDIR}/build/!!"`
 857     fi
 858     OUTPUTDIR="$CURDIR"
 859     AC_MSG_RESULT([in current directory])
 860 
 861     # WARNING: This might be a bad thing to do. You need to be sure you want to
 862     # have a configuration in this directory. Do some sanity checks!
 863 
 864     if test ! -e "$OUTPUTDIR/spec.gmk"; then
 865       # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
 866       # other files
 867       files_present=`$LS $OUTPUTDIR`
 868       # Configure has already touched config.log and confdefs.h in the current dir when this check
 869       # is performed.
 870       filtered_files=`$ECHO "$files_present" \
 871           | $SED -e 's/config.log//g' \
 872               -e 's/configure.log//g' \
 873               -e 's/confdefs.h//g' \
 874               -e 's/configure-support//g' \
 875               -e 's/ //g' \
 876           | $TR -d '\n'`
 877       if test "x$filtered_files" != x; then
 878         AC_MSG_NOTICE([Current directory is $CURDIR.])
 879         AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
 880         AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
 881         AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
 882         AC_MSG_NOTICE([seriously mess up just about everything.])
 883         AC_MSG_NOTICE([Try 'cd $TOPDIR' and restart configure])
 884         AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
 885         AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
 886       fi
 887     fi
 888   fi
 889   AC_MSG_CHECKING([what configuration name to use])
 890   AC_MSG_RESULT([$CONF_NAME])
 891 
 892   BASIC_FIXUP_PATH(OUTPUTDIR)
 893 
 894   CONFIGURESUPPORT_OUTPUTDIR="$OUTPUTDIR/configure-support"
 895   $MKDIR -p "$CONFIGURESUPPORT_OUTPUTDIR"
 896 
 897   SPEC="$OUTPUTDIR/spec.gmk"
 898   AC_SUBST(SPEC)
 899   AC_SUBST(CONF_NAME)
 900   AC_SUBST(OUTPUTDIR)
 901   AC_SUBST(CONFIGURESUPPORT_OUTPUTDIR)
 902 
 903   # The spec.gmk file contains all variables for the make system.
 904   AC_CONFIG_FILES([$OUTPUTDIR/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
 905   # The bootcycle-spec.gmk file contains support for boot cycle builds.
 906   AC_CONFIG_FILES([$OUTPUTDIR/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
 907   # The buildjdk-spec.gmk file contains support for building a buildjdk when cross compiling.
 908   AC_CONFIG_FILES([$OUTPUTDIR/buildjdk-spec.gmk:$AUTOCONF_DIR/buildjdk-spec.gmk.in])
 909   # The compare.sh is used to compare the build output to other builds.
 910   AC_CONFIG_FILES([$OUTPUTDIR/compare.sh:$AUTOCONF_DIR/compare.sh.in])
 911   # The generated Makefile knows where the spec.gmk is and where the source is.
 912   # You can run make from the OUTPUTDIR, or from the top-level Makefile
 913   # which will look for generated configurations
 914   AC_CONFIG_FILES([$OUTPUTDIR/Makefile:$AUTOCONF_DIR/Makefile.in])
 915 ])
 916 
 917 #%%% Simple tools %%%
 918 
 919 ###############################################################################
 920 # Check if we have found a usable version of make
 921 # $1: the path to a potential make binary (or empty)
 922 # $2: the description on how we found this
 923 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
 924 [
 925   MAKE_CANDIDATE="$1"
 926   DESCRIPTION="$2"
 927 
 928   # On Cygwin, we require a newer version of make than on other platforms
 929   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 930     MAKE_VERSION_EXPR="-e 4\."
 931     MAKE_REQUIRED_VERSION="4.0"
 932    else
 933     MAKE_VERSION_EXPR="-e 3\.8[[12]] -e 4\."
 934     MAKE_REQUIRED_VERSION="3.81"
 935   fi
 936 
 937   if test "x$MAKE_CANDIDATE" != x; then
 938     AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
 939     MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
 940     IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
 941     if test "x$IS_GNU_MAKE" = x; then
 942       AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
 943     else
 944       IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP $MAKE_VERSION_EXPR`
 945       if test "x$IS_MODERN_MAKE" = x; then
 946         AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version $MAKE_REQUIRED_VERSION or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
 947       else
 948         if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
 949           if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 950             MAKE_EXPECTED_ENV='cygwin'
 951           elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 952             MAKE_EXPECTED_ENV='msys'
 953           else
 954             AC_MSG_ERROR([Unknown Windows environment])
 955           fi
 956           MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
 957           IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
 958         else
 959           # Not relevant for non-Windows
 960           IS_MAKE_CORRECT_ENV=true
 961         fi
 962         if test "x$IS_MAKE_CORRECT_ENV" = x; then
 963           AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
 964         else
 965           FOUND_MAKE=$MAKE_CANDIDATE
 966           BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
 967         fi
 968       fi
 969     fi
 970   fi
 971 ])
 972 
 973 ###############################################################################
 974 AC_DEFUN([BASIC_CHECK_MAKE_OUTPUT_SYNC],
 975 [
 976   # Check if make supports the output sync option and if so, setup using it.
 977   AC_MSG_CHECKING([if make --output-sync is supported])
 978   if $MAKE --version -O > /dev/null 2>&1; then
 979     OUTPUT_SYNC_SUPPORTED=true
 980     AC_MSG_RESULT([yes])
 981     AC_MSG_CHECKING([for output-sync value])
 982     AC_ARG_WITH([output-sync], [AS_HELP_STRING([--with-output-sync],
 983       [set make output sync type if supported by make. @<:@recurse@:>@])],
 984       [OUTPUT_SYNC=$with_output_sync])
 985     if test "x$OUTPUT_SYNC" = "x"; then
 986       OUTPUT_SYNC=none
 987     fi
 988     AC_MSG_RESULT([$OUTPUT_SYNC])
 989     if ! $MAKE --version -O$OUTPUT_SYNC > /dev/null 2>&1; then
 990       AC_MSG_ERROR([Make did not the support the value $OUTPUT_SYNC as output sync type.])
 991     fi
 992   else
 993     OUTPUT_SYNC_SUPPORTED=false
 994     AC_MSG_RESULT([no])
 995   fi
 996   AC_SUBST(OUTPUT_SYNC_SUPPORTED)
 997   AC_SUBST(OUTPUT_SYNC)
 998 ])
 999 
1000 ###############################################################################
1001 # Goes looking for a usable version of GNU make.
1002 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
1003 [
1004   BASIC_SETUP_TOOL([MAKE],
1005   [
1006     # Try our hardest to locate a correct version of GNU make
1007     AC_PATH_PROGS(CHECK_GMAKE, gmake)
1008     BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
1009 
1010     if test "x$FOUND_MAKE" = x; then
1011       AC_PATH_PROGS(CHECK_MAKE, make)
1012       BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
1013     fi
1014 
1015     if test "x$FOUND_MAKE" = x; then
1016       if test "x$TOOLCHAIN_PATH" != x; then
1017         # We have a toolchain path, check that as well before giving up.
1018         OLD_PATH=$PATH
1019         PATH=$TOOLCHAIN_PATH:$PATH
1020         AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
1021         BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
1022         if test "x$FOUND_MAKE" = x; then
1023           AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
1024           BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
1025         fi
1026         PATH=$OLD_PATH
1027       fi
1028     fi
1029 
1030     if test "x$FOUND_MAKE" = x; then
1031       AC_MSG_ERROR([Cannot find GNU make $MAKE_REQUIRED_VERSION or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
1032     fi
1033   ],[
1034     # If MAKE was set by user, verify the version
1035     BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
1036     if test "x$FOUND_MAKE" = x; then
1037       AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make $MAKE_REQUIRED_VERSION or newer.])
1038     fi
1039   ])
1040 
1041   MAKE=$FOUND_MAKE
1042   AC_SUBST(MAKE)
1043   AC_MSG_NOTICE([Using GNU make at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
1044 
1045   BASIC_CHECK_MAKE_OUTPUT_SYNC
1046 ])
1047 
1048 ###############################################################################
1049 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
1050 [
1051   # Test if find supports -delete
1052   AC_MSG_CHECKING([if find supports -delete])
1053   FIND_DELETE="-delete"
1054 
1055   DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
1056 
1057   echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
1058 
1059   TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
1060   if test -f $DELETEDIR/TestIfFindSupportsDelete; then
1061     # No, it does not.
1062     $RM $DELETEDIR/TestIfFindSupportsDelete
1063     if test "x$OPENJDK_TARGET_OS" = "xaix"; then
1064       # AIX 'find' is buggy if called with '-exec {} \+' and an empty file list
1065       FIND_DELETE="-print | $XARGS $RM"
1066     else
1067       FIND_DELETE="-exec $RM \{\} \+"
1068     fi
1069     AC_MSG_RESULT([no])
1070   else
1071     AC_MSG_RESULT([yes])
1072   fi
1073   $RMDIR $DELETEDIR
1074   AC_SUBST(FIND_DELETE)
1075 ])
1076 
1077 ###############################################################################
1078 AC_DEFUN([BASIC_CHECK_TAR],
1079 [
1080   # Test which kind of tar was found
1081   if test "x$($TAR --version | $GREP "GNU tar")" != "x"; then
1082     TAR_TYPE="gnu"
1083   elif test "x$($TAR --version | $GREP "bsdtar")" != "x"; then
1084     TAR_TYPE="bsd"
1085   elif test "x$($TAR -v | $GREP "bsdtar")" != "x"; then
1086     TAR_TYPE="bsd"
1087   elif test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
1088     TAR_TYPE="solaris"
1089   fi
1090   AC_MSG_CHECKING([what type of tar was found])
1091   AC_MSG_RESULT([$TAR_TYPE])
1092 
1093   TAR_CREATE_FILE_PARAM=""
1094 
1095   if test "x$TAR_TYPE" = "xgnu"; then
1096     TAR_INCLUDE_PARAM="T"
1097     TAR_SUPPORTS_TRANSFORM="true"
1098     if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
1099       # When using gnu tar for Solaris targets, need to use compatibility mode
1100       TAR_CREATE_EXTRA_PARAM="--format=ustar"
1101     fi
1102   else
1103     TAR_INCLUDE_PARAM="I"
1104     TAR_SUPPORTS_TRANSFORM="false"
1105   fi
1106   AC_SUBST(TAR_TYPE)
1107   AC_SUBST(TAR_CREATE_EXTRA_PARAM)
1108   AC_SUBST(TAR_INCLUDE_PARAM)
1109   AC_SUBST(TAR_SUPPORTS_TRANSFORM)
1110 ])
1111 
1112 ###############################################################################
1113 AC_DEFUN([BASIC_CHECK_GREP],
1114 [
1115   # Test that grep supports -Fx with a list of pattern which includes null pattern.
1116   # This is a problem for the grep resident on AIX.
1117   AC_MSG_CHECKING([that grep ($GREP) -Fx handles empty lines in the pattern list correctly])
1118   # Multiple subsequent spaces..
1119   STACK_SPACES='aaa   bbb   ccc'
1120   # ..converted to subsequent newlines, causes STACK_LIST to be a list with some empty
1121   # patterns in it.
1122   STACK_LIST=${STACK_SPACES// /$'\n'}
1123   NEEDLE_SPACES='ccc bbb aaa'
1124   NEEDLE_LIST=${NEEDLE_SPACES// /$'\n'}
1125   RESULT="$($GREP -Fvx "$STACK_LIST" <<< "$NEEDLE_LIST")"
1126   if test "x$RESULT" == "x"; then
1127     AC_MSG_RESULT([yes])
1128   else
1129     if test "x$OPENJDK_TARGET_OS" = "xaix"; then
1130       ADDINFO="Please make sure you use GNU grep, usually found at /opt/freeware/bin."
1131     fi
1132     AC_MSG_ERROR([grep does not handle -Fx correctly. ${ADDINFO}])
1133   fi
1134 ])
1135 
1136 ###############################################################################
1137 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
1138 [
1139   BASIC_CHECK_GNU_MAKE
1140 
1141   BASIC_CHECK_FIND_DELETE
1142   BASIC_CHECK_TAR
1143   BASIC_CHECK_GREP
1144 
1145   # These tools might not be installed by default,
1146   # need hint on how to install them.
1147   BASIC_REQUIRE_PROGS(UNZIP, unzip)
1148   # Since zip uses "ZIP" as a environment variable for passing options, we need
1149   # to name our variable differently, hence ZIPEXE.
1150   BASIC_REQUIRE_PROGS(ZIPEXE, zip)
1151 
1152   # Non-required basic tools
1153 
1154   BASIC_PATH_PROGS(LDD, ldd)
1155   if test "x$LDD" = "x"; then
1156     # List shared lib dependencies is used for
1157     # debug output and checking for forbidden dependencies.
1158     # We can build without it.
1159     LDD="true"
1160   fi
1161   BASIC_PATH_PROGS(READELF, [greadelf readelf])
1162   BASIC_PATH_PROGS(DOT, dot)
1163   BASIC_PATH_PROGS(HG, hg)
1164   BASIC_PATH_PROGS(STAT, stat)
1165   BASIC_PATH_PROGS(TIME, time)
1166   BASIC_PATH_PROGS(FLOCK, flock)
1167   # Dtrace is usually found in /usr/sbin on Solaris, but that directory may not
1168   # be in the user path.
1169   BASIC_PATH_PROGS(DTRACE, dtrace, $PATH:/usr/sbin)
1170   BASIC_PATH_PROGS(PATCH, [gpatch patch])
1171   # Check if it's GNU time
1172   IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
1173   if test "x$IS_GNU_TIME" != x; then
1174     IS_GNU_TIME=yes
1175   else
1176     IS_GNU_TIME=no
1177   fi
1178   AC_SUBST(IS_GNU_TIME)
1179 
1180   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
1181     BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)
1182     BASIC_REQUIRE_PROGS(XATTR, xattr)
1183     BASIC_PATH_PROGS(CODESIGN, codesign)
1184     if test "x$CODESIGN" != "x"; then
1185       # Verify that the openjdk_codesign certificate is present
1186       AC_MSG_CHECKING([if openjdk_codesign certificate is present])
1187       $RM codesign-testfile
1188       $TOUCH codesign-testfile
1189       $CODESIGN -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
1190       $RM codesign-testfile
1191       if test "x$CODESIGN" = x; then
1192         AC_MSG_RESULT([no])
1193       else
1194         AC_MSG_RESULT([yes])
1195       fi
1196     fi
1197     BASIC_REQUIRE_PROGS(SETFILE, SetFile)
1198   elif test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
1199     BASIC_REQUIRE_PROGS(ELFEDIT, elfedit)
1200   fi
1201 ])
1202 
1203 ###############################################################################
1204 # Check if build directory is on local disk. If not possible to determine,
1205 # we prefer to claim it's local.
1206 # Argument 1: directory to test
1207 # Argument 2: what to do if it is on local disk
1208 # Argument 3: what to do otherwise (remote disk or failure)
1209 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
1210 [
1211   # df -l lists only local disks; if the given directory is not found then
1212   # a non-zero exit code is given
1213   if test "x$DF" = x; then
1214     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
1215       # msys does not have df; use Windows "net use" instead.
1216       IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
1217       if test "x$IS_NETWORK_DISK" = x; then
1218         $2
1219       else
1220         $3
1221       fi
1222     else
1223       # No df here, say it's local
1224       $2
1225     fi
1226   else
1227     # JDK-8189619
1228     # df on AIX does not understand -l. On modern AIXes it understands "-T local" which
1229     # is the same. On older AIXes we just continue to live with a "not local build" warning.
1230     if test "x$OPENJDK_TARGET_OS" = xaix; then
1231       DF_LOCAL_ONLY_OPTION='-T local'
1232     else
1233       DF_LOCAL_ONLY_OPTION='-l'
1234     fi
1235     if $DF $DF_LOCAL_ONLY_OPTION $1 > /dev/null 2>&1; then
1236       $2
1237     else
1238       $3
1239     fi
1240   fi
1241 ])
1242 
1243 ###############################################################################
1244 # Check that source files have basic read permissions set. This might
1245 # not be the case in cygwin in certain conditions.
1246 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
1247 [
1248   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
1249     file_to_test="$TOPDIR/LICENSE"
1250     if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
1251       AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
1252     fi
1253   fi
1254 ])
1255 
1256 ###############################################################################
1257 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
1258 [
1259   AC_MSG_CHECKING([if build directory is on local disk])
1260   BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUTDIR,
1261       [OUTPUT_DIR_IS_LOCAL="yes"],
1262       [OUTPUT_DIR_IS_LOCAL="no"])
1263   AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
1264 
1265   BASIC_CHECK_SRC_PERMS
1266 
1267   # Check if the user has any old-style ALT_ variables set.
1268   FOUND_ALT_VARIABLES=`env | grep ^ALT_`
1269 
1270   # Before generating output files, test if they exist. If they do, this is a reconfigure.
1271   # Since we can't properly handle the dependencies for this, warn the user about the situation
1272   if test -e $OUTPUTDIR/spec.gmk; then
1273     IS_RECONFIGURE=yes
1274   else
1275     IS_RECONFIGURE=no
1276   fi
1277 ])
1278 
1279 ###############################################################################
1280 # Check for support for specific options in bash
1281 AC_DEFUN_ONCE([BASIC_CHECK_BASH_OPTIONS],
1282 [
1283   # Check bash version
1284   # Extra [ ] to stop m4 mangling
1285   [ BASH_VER=`$BASH --version | $SED -n  -e 's/^.*bash.*ersion *\([0-9.]*\).*$/\1/ p'` ]
1286   AC_MSG_CHECKING([bash version])
1287   AC_MSG_RESULT([$BASH_VER])
1288 
1289   BASH_MAJOR=`$ECHO $BASH_VER | $CUT -d . -f 1`
1290   BASH_MINOR=`$ECHO $BASH_VER | $CUT -d . -f 2`
1291   if test $BASH_MAJOR -lt 3 || (test $BASH_MAJOR -eq 3 && test $BASH_MINOR -lt 2); then
1292     AC_MSG_ERROR([bash version 3.2 or better is required])
1293   fi
1294 
1295   # Test if bash supports pipefail.
1296   AC_MSG_CHECKING([if bash supports pipefail])
1297   if ${BASH} -c 'set -o pipefail'; then
1298     BASH_ARGS="$BASH_ARGS -o pipefail"
1299     AC_MSG_RESULT([yes])
1300   else
1301     AC_MSG_RESULT([no])
1302   fi
1303 
1304   AC_MSG_CHECKING([if bash supports errexit (-e)])
1305   if ${BASH} -e -c 'true'; then
1306     BASH_ARGS="$BASH_ARGS -e"
1307     AC_MSG_RESULT([yes])
1308   else
1309     AC_MSG_RESULT([no])
1310   fi
1311 
1312   AC_SUBST(BASH_ARGS)
1313 ])
1314 
1315 ################################################################################
1316 #
1317 # Default make target
1318 #
1319 AC_DEFUN_ONCE([BASIC_SETUP_DEFAULT_MAKE_TARGET],
1320 [
1321   AC_ARG_WITH(default-make-target, [AS_HELP_STRING([--with-default-make-target],
1322       [set the default make target @<:@exploded-image@:>@])])
1323   if test "x$with_default_make_target" = "x" \
1324       || test "x$with_default_make_target" = "xyes"; then
1325     DEFAULT_MAKE_TARGET="exploded-image"
1326   elif test "x$with_default_make_target" = "xno"; then
1327     AC_MSG_ERROR([--without-default-make-target is not a valid option])
1328   else
1329     DEFAULT_MAKE_TARGET="$with_default_make_target"
1330   fi
1331 
1332   AC_SUBST(DEFAULT_MAKE_TARGET)
1333 ])
1334 
1335 ###############################################################################
1336 # Setup the default value for LOG=
1337 #
1338 AC_DEFUN_ONCE([BASIC_SETUP_DEFAULT_LOG],
1339 [
1340   AC_ARG_WITH(log, [AS_HELP_STRING([--with-log],
1341       [[default vaue for make LOG argument [warn]]])])
1342   AC_MSG_CHECKING([for default LOG value])
1343   if test "x$with_log" = x; then
1344     DEFAULT_LOG=""
1345   else
1346     # Syntax for valid LOG options is a bit too complex for it to be worth
1347     # implementing a test for correctness in configure. Just accept it.
1348     DEFAULT_LOG=$with_log
1349   fi
1350   AC_MSG_RESULT([$DEFAULT_LOG])
1351   AC_SUBST(DEFAULT_LOG)
1352 ])
1353 
1354 ###############################################################################
1355 # Code to run after AC_OUTPUT
1356 AC_DEFUN_ONCE([BASIC_POST_CONFIG_OUTPUT],
1357 [
1358   # Try to move config.log (generated by autoconf) to the configure-support directory.
1359   if test -e ./config.log; then
1360     $MV -f ./config.log "$CONFIGURESUPPORT_OUTPUTDIR/config.log" 2> /dev/null
1361   fi
1362 
1363   # Rotate our log file (configure.log)
1364   if test -e "$OUTPUTDIR/configure.log.old"; then
1365     $RM -f "$OUTPUTDIR/configure.log.old"
1366   fi
1367   if test -e "$OUTPUTDIR/configure.log"; then
1368     $MV -f "$OUTPUTDIR/configure.log" "$OUTPUTDIR/configure.log.old" 2> /dev/null
1369   fi
1370 
1371   # Move configure.log from current directory to the build output root
1372   if test -e ./configure.log; then
1373     $MV -f ./configure.log "$OUTPUTDIR/configure.log" 2> /dev/null
1374   fi
1375 
1376   # Make the compare script executable
1377   $CHMOD +x $OUTPUTDIR/compare.sh
1378 ])