1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ###############################################################################
27 # Create a function/macro that takes a series of named arguments. The call is
28 # similar to AC_DEFUN, but the setup of the function looks like this:
29 # BASIC_DEFUN_NAMED([MYFUNC], [FOO *BAR], [$@], [
30 # ... do something
31 # AC_MSG_NOTICE([Value of BAR is ARG_BAR])
32 # ])
33 # A star (*) in front of a named argument means that it is required and it's
34 # presence will be verified. To pass e.g. the first value as a normal indexed
35 # argument, use [m4_shift($@)] as the third argument instead of [$@]. These
36 # arguments are referenced in the function by their name prefixed by ARG_, e.g.
37 # "ARG_FOO".
38 #
39 # The generated function can be called like this:
40 # MYFUNC(FOO: [foo-val],
41 # BAR: [
42 # $ECHO hello world
43 # ])
44 # Note that the argument value must start on the same line as the argument name.
45 #
46 # Argument 1: Name of the function to define
47 # Argument 2: List of legal named arguments, with a * prefix for required arguments
48 # Argument 3: Argument array to treat as named, typically $@
49 # Argument 4: The main function body
50 AC_DEFUN([BASIC_DEFUN_NAMED],
51 [
52 AC_DEFUN($1, [
53 m4_foreach(arg, m4_split($2), [
54 m4_if(m4_bregexp(arg, [^\*]), -1,
55 [
56 m4_set_add(legal_named_args, arg)
57 ],
58 [
59 m4_set_add(legal_named_args, m4_substr(arg, 1))
60 m4_set_add(required_named_args, m4_substr(arg, 1))
61 ]
62 )
63 ])
64
65 m4_foreach([arg], [$3], [
66 m4_define(arg_name, m4_substr(arg, 0, m4_bregexp(arg, [: ])))
67 m4_set_contains(legal_named_args, arg_name, [],[AC_MSG_ERROR([Internal error: arg_name is not a valid named argument to [$1]. Valid arguments are 'm4_set_contents(legal_named_args, [ ])'.])])
68 m4_set_remove(required_named_args, arg_name)
69 m4_set_remove(legal_named_args, arg_name)
70 m4_pushdef([ARG_][]arg_name, m4_substr(arg, m4_incr(m4_incr(m4_bregexp(arg, [: ])))))
71 m4_set_add(defined_args, arg_name)
72 m4_undefine([arg_name])
73 ])
74 m4_set_empty(required_named_args, [], [
75 AC_MSG_ERROR([Internal error: Required named arguments are missing for [$1]. Missing arguments: 'm4_set_contents(required_named_args, [ ])'])
76 ])
77 m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([legal_named_args])), [
78 m4_pushdef([ARG_][]arg, [])
79 m4_set_add(defined_args, arg)
80 ])
81 m4_set_delete(legal_named_args)
82 m4_set_delete(required_named_args)
83
84 # Execute function body
85 $4
86
87 m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([defined_args])), [
88 m4_popdef([ARG_][]arg)
89 ])
90
91 m4_set_delete(defined_args)
92 ])
93 ])
94
95 ###############################################################################
96 # Check if a list of space-separated words are selected only from a list of
97 # space-separated legal words. Typical use is to see if a user-specified
98 # set of words is selected from a set of legal words.
99 #
100 # Sets the specified variable to list of non-matching (offending) words, or to
101 # the empty string if all words are matching the legal set.
102 #
103 # $1: result variable name
104 # $2: list of values to check
105 # $3: list of legal values
106 AC_DEFUN([BASIC_GET_NON_MATCHING_VALUES],
107 [
108 # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
109 # Notice that the original variant fails on SLES 10 and 11
110 # Some grep versions (at least bsd) behaves strangely on the base case with
111 # no legal_values, so make it explicit.
112 values_to_check=`$ECHO $2 | $TR ' ' '\n'`
113 legal_values=`$ECHO $3 | $TR ' ' '\n'`
114 if test -z "$legal_values"; then
115 $1="$2"
116 else
117 result=`$GREP -Fvx "$legal_values" <<< "$values_to_check" | $GREP -v '^$'`
118 $1=${result//$'\n'/ }
119 fi
120 ])
121
122 ###############################################################################
123 # Check if a list of space-separated words contains any word(s) from a list of
124 # space-separated illegal words. Typical use is to see if a user-specified
125 # set of words contains any from a set of illegal words.
126 #
127 # Sets the specified variable to list of matching illegal words, or to
128 # the empty string if no words are matching the illegal set.
129 #
130 # $1: result variable name
131 # $2: list of values to check
132 # $3: list of illegal values
133 AC_DEFUN([BASIC_GET_MATCHING_VALUES],
134 [
135 # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
136 # Notice that the original variant fails on SLES 10 and 11
137 # Some grep versions (at least bsd) behaves strangely on the base case with
138 # no legal_values, so make it explicit.
139 values_to_check=`$ECHO $2 | $TR ' ' '\n'`
140 illegal_values=`$ECHO $3 | $TR ' ' '\n'`
141 if test -z "$illegal_values"; then
142 $1=""
143 else
144 result=`$GREP -Fx "$illegal_values" <<< "$values_to_check" | $GREP -v '^$'`
145 $1=${result//$'\n'/ }
146 fi
147 ])
148
149 ###############################################################################
150 # Sort a space-separated list, and remove duplicates.
151 #
152 # Sets the specified variable to the resulting list.
153 #
154 # $1: result variable name
155 # $2: list of values to sort
156 AC_DEFUN([BASIC_SORT_LIST],
157 [
158 values_to_sort=`$ECHO $2 | $TR ' ' '\n'`
159 result=`$SORT -u <<< "$values_to_sort" | $GREP -v '^$'`
160 $1=${result//$'\n'/ }
161 ])
162
163 ###############################################################################
164 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
165 # If so, then append $1 to $2 \
166 # Also set JVM_ARG_OK to true/false depending on outcome.
167 AC_DEFUN([ADD_JVM_ARG_IF_OK],
168 [
169 $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
170 $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
171 OUTPUT=`$3 $1 -version 2>&1`
172 FOUND_WARN=`$ECHO "$OUTPUT" | $GREP -i warn`
173 FOUND_VERSION=`$ECHO $OUTPUT | $GREP " version \""`
174 if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
175 $2="[$]$2 $1"
176 JVM_ARG_OK=true
177 else
178 $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
179 $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
180 JVM_ARG_OK=false
181 fi
182 ])
183
184 # Appends a string to a path variable, only adding the : when needed.
185 AC_DEFUN([BASIC_APPEND_TO_PATH],
186 [
187 if test "x$2" != x; then
188 if test "x[$]$1" = x; then
189 $1="$2"
190 else
191 $1="[$]$1:$2"
192 fi
193 fi
194 ])
195
196 # Prepends a string to a path variable, only adding the : when needed.
197 AC_DEFUN([BASIC_PREPEND_TO_PATH],
198 [
199 if test "x$2" != x; then
200 if test "x[$]$1" = x; then
201 $1="$2"
202 else
203 $1="$2:[$]$1"
204 fi
205 fi
206 ])
207
208 ###############################################################################
209 # This will make sure the given variable points to a full and proper
210 # path. This means:
211 # 1) There will be no spaces in the path. On unix platforms,
212 # spaces in the path will result in an error. On Windows,
213 # the path will be rewritten using short-style to be space-free.
214 # 2) The path will be absolute, and it will be in unix-style (on
215 # cygwin).
216 # $1: The name of the variable to fix
217 AC_DEFUN([BASIC_FIXUP_PATH],
218 [
219 # Only process if variable expands to non-empty
220
221 if test "x[$]$1" != x; then
222 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
223 BASIC_FIXUP_PATH_CYGWIN($1)
224 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
225 BASIC_FIXUP_PATH_MSYS($1)
226 else
227 # We're on a unix platform. Hooray! :)
228 path="[$]$1"
229 has_space=`$ECHO "$path" | $GREP " "`
230 if test "x$has_space" != x; then
231 AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
232 AC_MSG_ERROR([Spaces are not allowed in this path.])
233 fi
234
235 # Use eval to expand a potential ~
236 eval path="$path"
237 if test ! -f "$path" && test ! -d "$path"; then
238 AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
239 fi
240
241 if test -d "$path"; then
242 $1="`cd "$path"; $THEPWDCMD -L`"
243 else
244 dir="`$DIRNAME "$path"`"
245 base="`$BASENAME "$path"`"
246 $1="`cd "$dir"; $THEPWDCMD -L`/$base"
247 fi
248 fi
249 fi
250 ])
251
252 ###############################################################################
253 # This will make sure the given variable points to a executable
254 # with a full and proper path. This means:
255 # 1) There will be no spaces in the path. On unix platforms,
256 # spaces in the path will result in an error. On Windows,
257 # the path will be rewritten using short-style to be space-free.
258 # 2) The path will be absolute, and it will be in unix-style (on
259 # cygwin).
260 # Any arguments given to the executable is preserved.
261 # If the input variable does not have a directory specification, then
262 # it need to be in the PATH.
263 # $1: The name of the variable to fix
264 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
265 [
266 # Only process if variable expands to non-empty
267
268 if test "x[$]$1" != x; then
269 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
270 BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
271 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
272 BASIC_FIXUP_EXECUTABLE_MSYS($1)
273 else
274 # We're on a unix platform. Hooray! :)
275 # First separate the path from the arguments. This will split at the first
276 # space.
277 complete="[$]$1"
278 path="${complete%% *}"
279 tmp="$complete EOL"
280 arguments="${tmp#* }"
281
282 # Cannot rely on the command "which" here since it doesn't always work.
283 is_absolute_path=`$ECHO "$path" | $GREP ^/`
284 if test -z "$is_absolute_path"; then
285 # Path to executable is not absolute. Find it.
286 IFS_save="$IFS"
287 IFS=:
288 for p in $PATH; do
289 if test -f "$p/$path" && test -x "$p/$path"; then
290 new_path="$p/$path"
291 break
292 fi
293 done
294 IFS="$IFS_save"
295 else
296 # This is an absolute path, we can use it without further modifications.
297 new_path="$path"
298 fi
299
300 if test "x$new_path" = x; then
301 AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
302 has_space=`$ECHO "$complete" | $GREP " "`
303 if test "x$has_space" != x; then
304 AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
305 fi
306 AC_MSG_ERROR([Cannot locate the the path of $1])
307 fi
308 fi
309
310 # Now join together the path and the arguments once again
311 if test "x$arguments" != xEOL; then
312 new_complete="$new_path ${arguments% *}"
313 else
314 new_complete="$new_path"
315 fi
316
317 if test "x$complete" != "x$new_complete"; then
318 $1="$new_complete"
319 AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
320 fi
321 fi
322 ])
323
324 ###############################################################################
325 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
326 [
327 if test "x$OPENJDK_BUILD_OS" != xwindows; then
328 # Follow a chain of symbolic links. Use readlink
329 # where it exists, else fall back to horribly
330 # complicated shell code.
331 if test "x$READLINK_TESTED" != yes; then
332 # On MacOSX there is a readlink tool with a different
333 # purpose than the GNU readlink tool. Check the found readlink.
334 READLINK_ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
335 # If READLINK_ISGNU is empty, then it's a non-GNU readlink. Don't use it.
336 READLINK_TESTED=yes
337 fi
338
339 if test "x$READLINK" != x && test "x$READLINK_ISGNU" != x; then
340 $1=`$READLINK -f [$]$1`
341 else
342 # Save the current directory for restoring afterwards
343 STARTDIR=$PWD
344 COUNTER=0
345 sym_link_dir=`$DIRNAME [$]$1`
346 sym_link_file=`$BASENAME [$]$1`
347 cd $sym_link_dir
348 # Use -P flag to resolve symlinks in directories.
349 cd `$THEPWDCMD -P`
350 sym_link_dir=`$THEPWDCMD -P`
351 # Resolve file symlinks
352 while test $COUNTER -lt 20; do
353 ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
354 if test "x$ISLINK" == x; then
355 # This is not a symbolic link! We are done!
356 break
357 fi
358 # Again resolve directory symlinks since the target of the just found
359 # link could be in a different directory
360 cd `$DIRNAME $ISLINK`
361 sym_link_dir=`$THEPWDCMD -P`
362 sym_link_file=`$BASENAME $ISLINK`
363 let COUNTER=COUNTER+1
364 done
365 cd $STARTDIR
366 $1=$sym_link_dir/$sym_link_file
367 fi
368 fi
369 ])
370
371 ###############################################################################
372 # Register a --with argument but mark it as deprecated
373 # $1: The name of the with argument to deprecate, not including --with-
374 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
375 [
376 AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
377 [Deprecated. Option is kept for backwards compatibility and is ignored])],
378 [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
379 ])
380
381 ###############################################################################
382 # Register a --enable argument but mark it as deprecated
383 # $1: The name of the with argument to deprecate, not including --enable-
384 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
385 # $3: Messages to user.
386 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
387 [
388 AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
389 [Deprecated. Option is kept for backwards compatibility and is ignored])])
390 if test "x$enable_$2" != x; then
391 AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
392
393 if test "x$3" != x; then
394 AC_MSG_WARN([$3])
395 fi
396
397 fi
398 ])
399
400 ###############################################################################
401 AC_DEFUN_ONCE([BASIC_INIT],
402 [
403 # Save the original command line. This is passed to us by the wrapper configure script.
404 AC_SUBST(CONFIGURE_COMMAND_LINE)
405 # Save the path variable before it gets changed
406 ORIGINAL_PATH="$PATH"
407 AC_SUBST(ORIGINAL_PATH)
408 DATE_WHEN_CONFIGURED=`LANG=C date`
409 AC_SUBST(DATE_WHEN_CONFIGURED)
410 AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
411 ])
412
413 ###############################################################################
414 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
415 # $1: variable to check
416 AC_DEFUN([BASIC_CHECK_NONEMPTY],
417 [
418 if test "x[$]$1" = x; then
419 AC_MSG_ERROR([Could not find required tool for $1])
420 fi
421 ])
422
423 ###############################################################################
424 # Check that there are no unprocessed overridden variables left.
425 # If so, they are an incorrect argument and we will exit with an error.
426 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],
427 [
428 if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then
429 # Replace the separating ! with spaces before presenting for end user.
430 unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }
431 AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])
432 fi
433 ])
434
435 ###############################################################################
436 # Setup a tool for the given variable. If correctly specified by the user,
437 # use that value, otherwise search for the tool using the supplied code snippet.
438 # $1: variable to set
439 # $2: code snippet to call to look for the tool
440 # $3: code snippet to call if variable was used to find tool
441 AC_DEFUN([BASIC_SETUP_TOOL],
442 [
443 # Publish this variable in the help.
444 AC_ARG_VAR($1, [Override default value for $1])
445
446 if [[ -z "${$1+x}" ]]; then
447 # The variable is not set by user, try to locate tool using the code snippet
448 $2
449 else
450 # The variable is set, but is it from the command line or the environment?
451
452 # Try to remove the string !$1! from our list.
453 try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}
454 if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then
455 # If it failed, the variable was not from the command line. Ignore it,
456 # but warn the user (except for BASH, which is always set by the calling BASH).
457 if test "x$1" != xBASH; then
458 AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])
459 fi
460 # Try to locate tool using the code snippet
461 $2
462 else
463 # If it succeeded, then it was overridden by the user. We will use it
464 # for the tool.
465
466 # First remove it from the list of overridden variables, so we can test
467 # for unknown variables in the end.
468 CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"
469
470 # Check if we try to supply an empty value
471 if test "x[$]$1" = x; then
472 AC_MSG_NOTICE([Setting user supplied tool $1= (no value)])
473 AC_MSG_CHECKING([for $1])
474 AC_MSG_RESULT([disabled])
475 else
476 # Check if the provided tool contains a complete path.
477 tool_specified="[$]$1"
478 tool_basename="${tool_specified##*/}"
479 if test "x$tool_basename" = "x$tool_specified"; then
480 # A command without a complete path is provided, search $PATH.
481 AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])
482 AC_PATH_PROG($1, $tool_basename)
483 if test "x[$]$1" = x; then
484 AC_MSG_ERROR([User supplied tool $tool_basename could not be found])
485 fi
486 else
487 # Otherwise we believe it is a complete path. Use it as it is.
488 AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])
489 AC_MSG_CHECKING([for $1])
490 if test ! -x "$tool_specified"; then
491 AC_MSG_RESULT([not found])
492 AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])
493 fi
494 AC_MSG_RESULT([$tool_specified])
495 fi
496 fi
497 fi
498 $3
499 fi
500 ])
501
502 ###############################################################################
503 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool
504 # $1: variable to set
505 # $2: executable name (or list of names) to look for
506 # $3: [path]
507 AC_DEFUN([BASIC_PATH_PROGS],
508 [
509 BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2, , $3)])
510 ])
511
512 ###############################################################################
513 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool
514 # $1: variable to set
515 # $2: executable name (or list of names) to look for
516 AC_DEFUN([BASIC_CHECK_TOOLS],
517 [
518 BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])
519 ])
520
521 ###############################################################################
522 # Like BASIC_PATH_PROGS but fails if no tool was found.
523 # $1: variable to set
524 # $2: executable name (or list of names) to look for
525 # $3: [path]
526 AC_DEFUN([BASIC_REQUIRE_PROGS],
527 [
528 BASIC_PATH_PROGS($1, $2, , $3)
529 BASIC_CHECK_NONEMPTY($1)
530 ])
531
532 ###############################################################################
533 # Like BASIC_SETUP_TOOL but fails if no tool was found.
534 # $1: variable to set
535 # $2: autoconf macro to call to look for the special tool
536 AC_DEFUN([BASIC_REQUIRE_SPECIAL],
537 [
538 BASIC_SETUP_TOOL($1, [$2])
539 BASIC_CHECK_NONEMPTY($1)
540 ])
541
542 ###############################################################################
543 # Setup the most fundamental tools that relies on not much else to set up,
544 # but is used by much of the early bootstrap code.
545 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
546 [
547 # Start with tools that do not need have cross compilation support
548 # and can be expected to be found in the default PATH. These tools are
549 # used by configure.
550
551 # First are all the simple required tools.
552 BASIC_REQUIRE_PROGS(BASENAME, basename)
553 BASIC_REQUIRE_PROGS(BASH, bash)
554 BASIC_REQUIRE_PROGS(CAT, cat)
555 BASIC_REQUIRE_PROGS(CHMOD, chmod)
556 BASIC_REQUIRE_PROGS(CMP, cmp)
557 BASIC_REQUIRE_PROGS(COMM, comm)
558 BASIC_REQUIRE_PROGS(CP, cp)
559 BASIC_REQUIRE_PROGS(CUT, cut)
560 BASIC_REQUIRE_PROGS(DATE, date)
561 BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])
562 BASIC_REQUIRE_PROGS(DIRNAME, dirname)
563 BASIC_REQUIRE_PROGS(ECHO, echo)
564 BASIC_REQUIRE_PROGS(EXPR, expr)
565 BASIC_REQUIRE_PROGS(FILE, file)
566 BASIC_REQUIRE_PROGS(FIND, find)
567 BASIC_REQUIRE_PROGS(HEAD, head)
568 BASIC_REQUIRE_PROGS(GUNZIP, gunzip)
569 BASIC_REQUIRE_PROGS(GZIP, pigz gzip)
570 BASIC_REQUIRE_PROGS(LN, ln)
571 BASIC_REQUIRE_PROGS(LS, ls)
572 BASIC_REQUIRE_PROGS(MKDIR, mkdir)
573 BASIC_REQUIRE_PROGS(MKTEMP, mktemp)
574 BASIC_REQUIRE_PROGS(MV, mv)
575 BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])
576 BASIC_REQUIRE_PROGS(PRINTF, printf)
577 BASIC_REQUIRE_PROGS(READLINK, [greadlink readlink])
578 BASIC_REQUIRE_PROGS(RM, rm)
579 BASIC_REQUIRE_PROGS(RMDIR, rmdir)
580 BASIC_REQUIRE_PROGS(SH, sh)
581 BASIC_REQUIRE_PROGS(SORT, sort)
582 BASIC_REQUIRE_PROGS(TAIL, tail)
583 BASIC_REQUIRE_PROGS(TAR, gtar tar)
584 BASIC_REQUIRE_PROGS(TEE, tee)
585 BASIC_REQUIRE_PROGS(TOUCH, touch)
586 BASIC_REQUIRE_PROGS(TR, tr)
587 BASIC_REQUIRE_PROGS(UNAME, uname)
588 BASIC_REQUIRE_PROGS(UNIQ, uniq)
589 BASIC_REQUIRE_PROGS(WC, wc)
590 BASIC_REQUIRE_PROGS(WHICH, which)
591 BASIC_REQUIRE_PROGS(XARGS, xargs)
592
593 # Then required tools that require some special treatment.
594 BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])
595 BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])
596 BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])
597 BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])
598 BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])
599
600 # Always force rm.
601 RM="$RM -f"
602
603 # pwd behaves differently on various platforms and some don't support the -L flag.
604 # Always use the bash builtin pwd to get uniform behavior.
605 THEPWDCMD=pwd
606
607 # These are not required on all platforms
608 BASIC_PATH_PROGS(CYGPATH, cygpath)
609 BASIC_PATH_PROGS(DF, df)
610 BASIC_PATH_PROGS(CPIO, [cpio bsdcpio])
611 BASIC_PATH_PROGS(NICE, nice)
612 BASIC_PATH_PROGS(PANDOC, pandoc)
613 ])
614
615 ###############################################################################
616 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
617 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
618 [
619 # Save the current directory this script was started from
620 CURDIR="$PWD"
621
622 # We might need to rewrite ORIGINAL_PATH, if it includes "#", to quote them
623 # for make. We couldn't do this when we retrieved ORIGINAL_PATH, since SED
624 # was not available at that time.
625 REWRITTEN_PATH=`$ECHO "$ORIGINAL_PATH" | $SED -e 's/#/\\\\#/g'`
626 if test "x$REWRITTEN_PATH" != "x$ORIGINAL_PATH"; then
627 ORIGINAL_PATH="$REWRITTEN_PATH"
628 AC_MSG_NOTICE([Rewriting ORIGINAL_PATH to $REWRITTEN_PATH])
629 fi
630
631 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
632 PATH_SEP=";"
633 BASIC_CHECK_PATHS_WINDOWS
634 else
635 PATH_SEP=":"
636 fi
637 AC_SUBST(PATH_SEP)
638
639 # We get the top-level directory from the supporting wrappers.
640 AC_MSG_CHECKING([for top-level directory])
641 AC_MSG_RESULT([$TOPDIR])
642 AC_SUBST(TOPDIR)
643
644 # We can only call BASIC_FIXUP_PATH after BASIC_CHECK_PATHS_WINDOWS.
645 BASIC_FIXUP_PATH(CURDIR)
646 BASIC_FIXUP_PATH(TOPDIR)
647
648 # Locate the directory of this script.
649 AUTOCONF_DIR=$TOPDIR/make/autoconf
650
651 # Setup username (for use in adhoc version strings etc)
652 # Outer [ ] to quote m4.
653 [ USERNAME=`$ECHO "$USER" | $TR -d -c '[a-z][A-Z][0-9]'` ]
654 AC_SUBST(USERNAME)
655 ])
656
657 ###############################################################################
658 # Evaluates platform specific overrides for devkit variables.
659 # $1: Name of variable
660 AC_DEFUN([BASIC_EVAL_DEVKIT_VARIABLE],
661 [
662 if test "x[$]$1" = x; then
663 eval $1="\${$1_${OPENJDK_TARGET_CPU}}"
664 fi
665 ])
666
667 ###############################################################################
668 AC_DEFUN_ONCE([BASIC_SETUP_DEVKIT],
669 [
670 AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
671 [use this devkit for compilers, tools and resources])])
672
673 if test "x$with_devkit" = xyes; then
674 AC_MSG_ERROR([--with-devkit must have a value])
675 elif test "x$with_devkit" != x && test "x$with_devkit" != xno; then
676 BASIC_FIXUP_PATH([with_devkit])
677 DEVKIT_ROOT="$with_devkit"
678 # Check for a meta data info file in the root of the devkit
679 if test -f "$DEVKIT_ROOT/devkit.info"; then
680 . $DEVKIT_ROOT/devkit.info
681 # This potentially sets the following:
682 # A descriptive name of the devkit
683 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_NAME])
684 # Corresponds to --with-extra-path
685 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_EXTRA_PATH])
686 # Corresponds to --with-toolchain-path
687 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_TOOLCHAIN_PATH])
688 # Corresponds to --with-sysroot
689 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_SYSROOT])
690
691 # Identifies the Visual Studio version in the devkit
692 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_VERSION])
693 # The Visual Studio include environment variable
694 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_INCLUDE])
695 # The Visual Studio lib environment variable
696 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_LIB])
697 # Corresponds to --with-msvcr-dll
698 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCR_DLL])
699 # Corresponds to --with-msvcp-dll
700 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCP_DLL])
701 # Corresponds to --with-ucrt-dll-dir
702 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_UCRT_DLL_DIR])
703 fi
704
705 AC_MSG_CHECKING([for devkit])
706 if test "x$DEVKIT_NAME" != x; then
707 AC_MSG_RESULT([$DEVKIT_NAME in $DEVKIT_ROOT])
708 else
709 AC_MSG_RESULT([$DEVKIT_ROOT])
710 fi
711
712 BASIC_PREPEND_TO_PATH([EXTRA_PATH],$DEVKIT_EXTRA_PATH)
713
714 # Fallback default of just /bin if DEVKIT_PATH is not defined
715 if test "x$DEVKIT_TOOLCHAIN_PATH" = x; then
716 DEVKIT_TOOLCHAIN_PATH="$DEVKIT_ROOT/bin"
717 fi
718 BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$DEVKIT_TOOLCHAIN_PATH)
719
720 # If DEVKIT_SYSROOT is set, use that, otherwise try a couple of known
721 # places for backwards compatiblity.
722 if test "x$DEVKIT_SYSROOT" != x; then
723 SYSROOT="$DEVKIT_SYSROOT"
724 elif test -d "$DEVKIT_ROOT/$host_alias/libc"; then
725 SYSROOT="$DEVKIT_ROOT/$host_alias/libc"
726 elif test -d "$DEVKIT_ROOT/$host/sys-root"; then
727 SYSROOT="$DEVKIT_ROOT/$host/sys-root"
728 fi
729
730 if test "x$DEVKIT_ROOT" != x; then
731 DEVKIT_LIB_DIR="$DEVKIT_ROOT/lib"
732 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
733 DEVKIT_LIB_DIR="$DEVKIT_ROOT/lib64"
734 fi
735 AC_SUBST(DEVKIT_LIB_DIR)
736 fi
737 fi
738
739 # You can force the sysroot if the sysroot encoded into the compiler tools
740 # is not correct.
741 AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
742 [alias for --with-sysroot for backwards compatability])],
743 [SYSROOT=$with_sys_root]
744 )
745
746 AC_ARG_WITH(sysroot, [AS_HELP_STRING([--with-sysroot],
747 [use this directory as sysroot])],
748 [SYSROOT=$with_sysroot]
749 )
750
751 AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
752 [alias for --with-toolchain-path for backwards compatibility])],
753 [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_tools_dir)]
754 )
755
756 AC_ARG_WITH([toolchain-path], [AS_HELP_STRING([--with-toolchain-path],
757 [prepend these directories when searching for toolchain binaries (compilers etc)])],
758 [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_toolchain_path)]
759 )
760
761 AC_ARG_WITH([extra-path], [AS_HELP_STRING([--with-extra-path],
762 [prepend these directories to the default path])],
763 [BASIC_PREPEND_TO_PATH([EXTRA_PATH],$with_extra_path)]
764 )
765
766 if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then
767 # If a devkit has been supplied, find xcodebuild in the toolchain_path.
768 # If not, detect if Xcode is installed by running xcodebuild -version
769 # if no Xcode installed, xcodebuild exits with 1
770 # if Xcode is installed, even if xcode-select is misconfigured, then it exits with 0
771 if test "x$DEVKIT_ROOT" != x || /usr/bin/xcodebuild -version >/dev/null 2>&1; then
772 # We need to use xcodebuild in the toolchain dir provided by the user, this will
773 # fall back on the stub binary in /usr/bin/xcodebuild
774 AC_PATH_PROG([XCODEBUILD], [xcodebuild], [/usr/bin/xcodebuild], [$TOOLCHAIN_PATH])
775 else
776 # this should result in SYSROOT being empty, unless --with-sysroot is provided
777 # when only the command line tools are installed there are no SDKs, so headers
778 # are copied into the system frameworks
779 XCODEBUILD=
780 AC_SUBST(XCODEBUILD)
781 fi
782
783 AC_MSG_CHECKING([for sdk name])
784 AC_ARG_WITH([sdk-name], [AS_HELP_STRING([--with-sdk-name],
785 [use the platform SDK of the given name. @<:@macosx@:>@])],
786 [SDKNAME=$with_sdk_name]
787 )
788 AC_MSG_RESULT([$SDKNAME])
789
790 # if toolchain path is specified then don't rely on system headers, they may not compile
791 HAVE_SYSTEM_FRAMEWORK_HEADERS=0
792 test -z "$TOOLCHAIN_PATH" && \
793 HAVE_SYSTEM_FRAMEWORK_HEADERS=`test ! -f /System/Library/Frameworks/Foundation.framework/Headers/Foundation.h; echo $?`
794
795 if test -z "$SYSROOT"; then
796 if test -n "$XCODEBUILD"; then
797 # if we don't have system headers, use default SDK name (last resort)
798 if test -z "$SDKNAME" -a $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
799 SDKNAME=${SDKNAME:-macosx}
800 fi
801
802 if test -n "$SDKNAME"; then
803 # Call xcodebuild to determine SYSROOT
804 SYSROOT=`"$XCODEBUILD" -sdk $SDKNAME -version | $GREP '^Path: ' | $SED 's/Path: //'`
805 fi
806 else
807 if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
808 AC_MSG_ERROR([No xcodebuild tool and no system framework headers found, use --with-sysroot or --with-sdk-name to provide a path to a valid SDK])
809 fi
810 fi
811 else
812 # warn user if --with-sdk-name was also set
813 if test -n "$with_sdk_name"; then
814 AC_MSG_WARN([Both SYSROOT and --with-sdk-name are set, only SYSROOT will be used])
815 fi
816 fi
817
818 if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0 -a -z "$SYSROOT"; then
819 # If no system framework headers, then SYSROOT must be set, or we won't build
820 AC_MSG_ERROR([Unable to determine SYSROOT and no headers found in /System/Library/Frameworks. Check Xcode configuration, --with-sysroot or --with-sdk-name arguments.])
821 fi
822
823 # Perform a basic sanity test
824 if test ! -f "$SYSROOT/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then
825 if test -z "$SYSROOT"; then
826 AC_MSG_ERROR([Unable to find required framework headers, provide a path to an SDK via --with-sysroot or --with-sdk-name and be sure Xcode is installed properly])
827 else
828 AC_MSG_ERROR([Invalid SDK or SYSROOT path, dependent framework headers not found])
829 fi
830 fi
831
832 # set SDKROOT too, Xcode tools will pick it up
833 SDKROOT="$SYSROOT"
834 AC_SUBST(SDKROOT)
835 fi
836
837 # Prepend the extra path to the global path
838 BASIC_PREPEND_TO_PATH([PATH],$EXTRA_PATH)
839
840 AC_MSG_CHECKING([for sysroot])
841 AC_MSG_RESULT([$SYSROOT])
842 AC_MSG_CHECKING([for toolchain path])
843 AC_MSG_RESULT([$TOOLCHAIN_PATH])
844 AC_MSG_CHECKING([for extra path])
845 AC_MSG_RESULT([$EXTRA_PATH])
846 ])
847
848 ###############################################################################
849 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
850 [
851
852 AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
853 [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
854 [ CONF_NAME=${with_conf_name} ])
855
856 # Test from where we are running configure, in or outside of src root.
857 AC_MSG_CHECKING([where to store configuration])
858 if test "x$CURDIR" = "x$TOPDIR" || test "x$CURDIR" = "x$CUSTOM_ROOT" \
859 || test "x$CURDIR" = "x$TOPDIR/make/autoconf" \
860 || test "x$CURDIR" = "x$TOPDIR/make" ; then
861 # We are running configure from the src root.
862 # Create a default ./build/target-variant-debuglevel output root.
863 if test "x${CONF_NAME}" = x; then
864 AC_MSG_RESULT([in default location])
865 CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${JVM_VARIANTS_WITH_AND}-${DEBUG_LEVEL}"
866 else
867 AC_MSG_RESULT([in build directory with custom name])
868 fi
869
870 if test "x$CUSTOM_ROOT" != x; then
871 OUTPUTDIR="${CUSTOM_ROOT}/build/${CONF_NAME}"
872 else
873 OUTPUTDIR="${TOPDIR}/build/${CONF_NAME}"
874 fi
875 $MKDIR -p "$OUTPUTDIR"
876 if test ! -d "$OUTPUTDIR"; then
877 AC_MSG_ERROR([Could not create build directory $OUTPUTDIR])
878 fi
879 else
880 # We are running configure from outside of the src dir.
881 # Then use the current directory as output dir!
882 # If configuration is situated in normal build directory, just use the build
883 # directory name as configuration name, otherwise use the complete path.
884 if test "x${CONF_NAME}" = x; then
885 CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${TOPDIR}/build/!!"`
886 fi
887 OUTPUTDIR="$CURDIR"
888 AC_MSG_RESULT([in current directory])
889
890 # WARNING: This might be a bad thing to do. You need to be sure you want to
891 # have a configuration in this directory. Do some sanity checks!
892
893 if test ! -e "$OUTPUTDIR/spec.gmk"; then
894 # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
895 # other files
896 files_present=`$LS $OUTPUTDIR`
897 # Configure has already touched config.log and confdefs.h in the current dir when this check
898 # is performed.
899 filtered_files=`$ECHO "$files_present" \
900 | $SED -e 's/config.log//g' \
901 -e 's/configure.log//g' \
902 -e 's/confdefs.h//g' \
903 -e 's/configure-support//g' \
904 -e 's/ //g' \
905 | $TR -d '\n'`
906 if test "x$filtered_files" != x; then
907 AC_MSG_NOTICE([Current directory is $CURDIR.])
908 AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
909 AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
910 AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
911 AC_MSG_NOTICE([seriously mess up just about everything.])
912 AC_MSG_NOTICE([Try 'cd $TOPDIR' and restart configure])
913 AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
914 AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
915 fi
916 fi
917 fi
918 AC_MSG_CHECKING([what configuration name to use])
919 AC_MSG_RESULT([$CONF_NAME])
920
921 BASIC_FIXUP_PATH(OUTPUTDIR)
922
923 CONFIGURESUPPORT_OUTPUTDIR="$OUTPUTDIR/configure-support"
924 $MKDIR -p "$CONFIGURESUPPORT_OUTPUTDIR"
925
926 SPEC="$OUTPUTDIR/spec.gmk"
927 AC_SUBST(SPEC)
928 AC_SUBST(CONF_NAME)
929 AC_SUBST(OUTPUTDIR)
930 AC_SUBST(CONFIGURESUPPORT_OUTPUTDIR)
931
932 # The spec.gmk file contains all variables for the make system.
933 AC_CONFIG_FILES([$OUTPUTDIR/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
934 # The bootcycle-spec.gmk file contains support for boot cycle builds.
935 AC_CONFIG_FILES([$OUTPUTDIR/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
936 # The buildjdk-spec.gmk file contains support for building a buildjdk when cross compiling.
937 AC_CONFIG_FILES([$OUTPUTDIR/buildjdk-spec.gmk:$AUTOCONF_DIR/buildjdk-spec.gmk.in])
938 # The compare.sh is used to compare the build output to other builds.
939 AC_CONFIG_FILES([$OUTPUTDIR/compare.sh:$AUTOCONF_DIR/compare.sh.in])
940 # The generated Makefile knows where the spec.gmk is and where the source is.
941 # You can run make from the OUTPUTDIR, or from the top-level Makefile
942 # which will look for generated configurations
943 AC_CONFIG_FILES([$OUTPUTDIR/Makefile:$AUTOCONF_DIR/Makefile.in])
944 ])
945
946 #%%% Simple tools %%%
947
948 ###############################################################################
949 # Check if we have found a usable version of make
950 # $1: the path to a potential make binary (or empty)
951 # $2: the description on how we found this
952 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
953 [
954 MAKE_CANDIDATE="$1"
955 DESCRIPTION="$2"
956
957 # On Cygwin, we require a newer version of make than on other platforms
958 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
959 MAKE_VERSION_EXPR="-e 4\."
960 MAKE_REQUIRED_VERSION="4.0"
961 else
962 MAKE_VERSION_EXPR="-e 3\.8[[12]] -e 4\."
963 MAKE_REQUIRED_VERSION="3.81"
964 fi
965
966 if test "x$MAKE_CANDIDATE" != x; then
967 AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
968 MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
969 IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
970 if test "x$IS_GNU_MAKE" = x; then
971 AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
972 else
973 IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP $MAKE_VERSION_EXPR`
974 if test "x$IS_MODERN_MAKE" = x; then
975 AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version $MAKE_REQUIRED_VERSION or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
976 else
977 if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
978 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
979 MAKE_EXPECTED_ENV='cygwin'
980 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
981 MAKE_EXPECTED_ENV='msys'
982 else
983 AC_MSG_ERROR([Unknown Windows environment])
984 fi
985 MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
986 IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
987 else
988 # Not relevant for non-Windows
989 IS_MAKE_CORRECT_ENV=true
990 fi
991 if test "x$IS_MAKE_CORRECT_ENV" = x; then
992 AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
993 else
994 FOUND_MAKE=$MAKE_CANDIDATE
995 BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
996 fi
997 fi
998 fi
999 fi
1000 ])
1001
1002 ###############################################################################
1003 AC_DEFUN([BASIC_CHECK_MAKE_OUTPUT_SYNC],
1004 [
1005 # Check if make supports the output sync option and if so, setup using it.
1006 AC_MSG_CHECKING([if make --output-sync is supported])
1007 if $MAKE --version -O > /dev/null 2>&1; then
1008 OUTPUT_SYNC_SUPPORTED=true
1009 AC_MSG_RESULT([yes])
1010 AC_MSG_CHECKING([for output-sync value])
1011 AC_ARG_WITH([output-sync], [AS_HELP_STRING([--with-output-sync],
1012 [set make output sync type if supported by make. @<:@recurse@:>@])],
1013 [OUTPUT_SYNC=$with_output_sync])
1014 if test "x$OUTPUT_SYNC" = "x"; then
1015 OUTPUT_SYNC=none
1016 fi
1017 AC_MSG_RESULT([$OUTPUT_SYNC])
1018 if ! $MAKE --version -O$OUTPUT_SYNC > /dev/null 2>&1; then
1019 AC_MSG_ERROR([Make did not the support the value $OUTPUT_SYNC as output sync type.])
1020 fi
1021 else
1022 OUTPUT_SYNC_SUPPORTED=false
1023 AC_MSG_RESULT([no])
1024 fi
1025 AC_SUBST(OUTPUT_SYNC_SUPPORTED)
1026 AC_SUBST(OUTPUT_SYNC)
1027 ])
1028
1029 ###############################################################################
1030 # Goes looking for a usable version of GNU make.
1031 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
1032 [
1033 BASIC_SETUP_TOOL([MAKE],
1034 [
1035 # Try our hardest to locate a correct version of GNU make
1036 AC_PATH_PROGS(CHECK_GMAKE, gmake)
1037 BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
1038
1039 if test "x$FOUND_MAKE" = x; then
1040 AC_PATH_PROGS(CHECK_MAKE, make)
1041 BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
1042 fi
1043
1044 if test "x$FOUND_MAKE" = x; then
1045 if test "x$TOOLCHAIN_PATH" != x; then
1046 # We have a toolchain path, check that as well before giving up.
1047 OLD_PATH=$PATH
1048 PATH=$TOOLCHAIN_PATH:$PATH
1049 AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
1050 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
1051 if test "x$FOUND_MAKE" = x; then
1052 AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
1053 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
1054 fi
1055 PATH=$OLD_PATH
1056 fi
1057 fi
1058
1059 if test "x$FOUND_MAKE" = x; then
1060 AC_MSG_ERROR([Cannot find GNU make $MAKE_REQUIRED_VERSION or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
1061 fi
1062 ],[
1063 # If MAKE was set by user, verify the version
1064 BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
1065 if test "x$FOUND_MAKE" = x; then
1066 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make $MAKE_REQUIRED_VERSION or newer.])
1067 fi
1068 ])
1069
1070 MAKE=$FOUND_MAKE
1071 AC_SUBST(MAKE)
1072 AC_MSG_NOTICE([Using GNU make at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
1073
1074 BASIC_CHECK_MAKE_OUTPUT_SYNC
1075 ])
1076
1077 ###############################################################################
1078 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
1079 [
1080 # Test if find supports -delete
1081 AC_MSG_CHECKING([if find supports -delete])
1082 FIND_DELETE="-delete"
1083
1084 DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
1085
1086 echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
1087
1088 TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
1089 if test -f $DELETEDIR/TestIfFindSupportsDelete; then
1090 # No, it does not.
1091 $RM $DELETEDIR/TestIfFindSupportsDelete
1092 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
1093 # AIX 'find' is buggy if called with '-exec {} \+' and an empty file list
1094 FIND_DELETE="-print | $XARGS $RM"
1095 else
1096 FIND_DELETE="-exec $RM \{\} \+"
1097 fi
1098 AC_MSG_RESULT([no])
1099 else
1100 AC_MSG_RESULT([yes])
1101 fi
1102 $RMDIR $DELETEDIR
1103 AC_SUBST(FIND_DELETE)
1104 ])
1105
1106 ###############################################################################
1107 AC_DEFUN([BASIC_CHECK_TAR],
1108 [
1109 # Test which kind of tar was found
1110 if test "x$($TAR --version | $GREP "GNU tar")" != "x"; then
1111 TAR_TYPE="gnu"
1112 elif test "x$($TAR --version | $GREP "bsdtar")" != "x"; then
1113 TAR_TYPE="bsd"
1114 elif test "x$($TAR -v | $GREP "bsdtar")" != "x"; then
1115 TAR_TYPE="bsd"
1116 elif test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
1117 TAR_TYPE="solaris"
1118 fi
1119 AC_MSG_CHECKING([what type of tar was found])
1120 AC_MSG_RESULT([$TAR_TYPE])
1121
1122 TAR_CREATE_FILE_PARAM=""
1123
1124 if test "x$TAR_TYPE" = "xgnu"; then
1125 TAR_INCLUDE_PARAM="T"
1126 TAR_SUPPORTS_TRANSFORM="true"
1127 if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
1128 # When using gnu tar for Solaris targets, need to use compatibility mode
1129 TAR_CREATE_EXTRA_PARAM="--format=ustar"
1130 fi
1131 else
1132 TAR_INCLUDE_PARAM="I"
1133 TAR_SUPPORTS_TRANSFORM="false"
1134 fi
1135 AC_SUBST(TAR_TYPE)
1136 AC_SUBST(TAR_CREATE_EXTRA_PARAM)
1137 AC_SUBST(TAR_INCLUDE_PARAM)
1138 AC_SUBST(TAR_SUPPORTS_TRANSFORM)
1139 ])
1140
1141 ###############################################################################
1142 AC_DEFUN([BASIC_CHECK_GREP],
1143 [
1144 # Test that grep supports -Fx with a list of pattern which includes null pattern.
1145 # This is a problem for the grep resident on AIX.
1146 AC_MSG_CHECKING([that grep ($GREP) -Fx handles empty lines in the pattern list correctly])
1147 # Multiple subsequent spaces..
1148 STACK_SPACES='aaa bbb ccc'
1149 # ..converted to subsequent newlines, causes STACK_LIST to be a list with some empty
1150 # patterns in it.
1151 STACK_LIST=${STACK_SPACES// /$'\n'}
1152 NEEDLE_SPACES='ccc bbb aaa'
1153 NEEDLE_LIST=${NEEDLE_SPACES// /$'\n'}
1154 RESULT="$($GREP -Fvx "$STACK_LIST" <<< "$NEEDLE_LIST")"
1155 if test "x$RESULT" == "x"; then
1156 AC_MSG_RESULT([yes])
1157 else
1158 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
1159 ADDINFO="Please make sure you use GNU grep, usually found at /opt/freeware/bin."
1160 fi
1161 AC_MSG_ERROR([grep does not handle -Fx correctly. ${ADDINFO}])
1162 fi
1163 ])
1164
1165 ###############################################################################
1166 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
1167 [
1168 BASIC_CHECK_GNU_MAKE
1169
1170 BASIC_CHECK_FIND_DELETE
1171 BASIC_CHECK_TAR
1172 BASIC_CHECK_GREP
1173
1174 # These tools might not be installed by default,
1175 # need hint on how to install them.
1176 BASIC_REQUIRE_PROGS(UNZIP, unzip)
1177 # Since zip uses "ZIP" as a environment variable for passing options, we need
1178 # to name our variable differently, hence ZIPEXE.
1179 BASIC_REQUIRE_PROGS(ZIPEXE, zip)
1180
1181 # Non-required basic tools
1182
1183 BASIC_PATH_PROGS(LDD, ldd)
1184 if test "x$LDD" = "x"; then
1185 # List shared lib dependencies is used for
1186 # debug output and checking for forbidden dependencies.
1187 # We can build without it.
1188 LDD="true"
1189 fi
1190 BASIC_PATH_PROGS(READELF, [greadelf readelf])
1191 BASIC_PATH_PROGS(DOT, dot)
1192 BASIC_PATH_PROGS(HG, hg)
1193 BASIC_PATH_PROGS(STAT, stat)
1194 BASIC_PATH_PROGS(TIME, time)
1195 BASIC_PATH_PROGS(FLOCK, flock)
1196 # Dtrace is usually found in /usr/sbin on Solaris, but that directory may not
1197 # be in the user path.
1198 BASIC_PATH_PROGS(DTRACE, dtrace, $PATH:/usr/sbin)
1199 BASIC_PATH_PROGS(PATCH, [gpatch patch])
1200 # Check if it's GNU time
1201 IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
1202 if test "x$IS_GNU_TIME" != x; then
1203 IS_GNU_TIME=yes
1204 else
1205 IS_GNU_TIME=no
1206 fi
1207 AC_SUBST(IS_GNU_TIME)
1208
1209 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
1210 BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)
1211 BASIC_REQUIRE_PROGS(MIG, mig)
1212 BASIC_REQUIRE_PROGS(XATTR, xattr)
1213 BASIC_PATH_PROGS(CODESIGN, codesign)
1214 if test "x$CODESIGN" != "x"; then
1215 # Verify that the openjdk_codesign certificate is present
1216 AC_MSG_CHECKING([if openjdk_codesign certificate is present])
1217 $RM codesign-testfile
1218 $TOUCH codesign-testfile
1219 $CODESIGN -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
1220 $RM codesign-testfile
1221 if test "x$CODESIGN" = x; then
1222 AC_MSG_RESULT([no])
1223 else
1224 AC_MSG_RESULT([yes])
1225 fi
1226 fi
1227 BASIC_REQUIRE_PROGS(SETFILE, SetFile)
1228 elif test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
1229 BASIC_REQUIRE_PROGS(ELFEDIT, elfedit)
1230 fi
1231 ])
1232
1233 ###############################################################################
1234 # Check if build directory is on local disk. If not possible to determine,
1235 # we prefer to claim it's local.
1236 # Argument 1: directory to test
1237 # Argument 2: what to do if it is on local disk
1238 # Argument 3: what to do otherwise (remote disk or failure)
1239 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
1240 [
1241 # df -l lists only local disks; if the given directory is not found then
1242 # a non-zero exit code is given
1243 if test "x$DF" = x; then
1244 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
1245 # msys does not have df; use Windows "net use" instead.
1246 IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
1247 if test "x$IS_NETWORK_DISK" = x; then
1248 $2
1249 else
1250 $3
1251 fi
1252 else
1253 # No df here, say it's local
1254 $2
1255 fi
1256 else
1257 # JDK-8189619
1258 # df on AIX does not understand -l. On modern AIXes it understands "-T local" which
1259 # is the same. On older AIXes we just continue to live with a "not local build" warning.
1260 if test "x$OPENJDK_TARGET_OS" = xaix; then
1261 DF_LOCAL_ONLY_OPTION='-T local'
1262 else
1263 DF_LOCAL_ONLY_OPTION='-l'
1264 fi
1265 if $DF $DF_LOCAL_ONLY_OPTION $1 > /dev/null 2>&1; then
1266 $2
1267 else
1268 $3
1269 fi
1270 fi
1271 ])
1272
1273 ###############################################################################
1274 # Check that source files have basic read permissions set. This might
1275 # not be the case in cygwin in certain conditions.
1276 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
1277 [
1278 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
1279 file_to_test="$TOPDIR/LICENSE"
1280 if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
1281 AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
1282 fi
1283 fi
1284 ])
1285
1286 ###############################################################################
1287 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
1288 [
1289 AC_MSG_CHECKING([if build directory is on local disk])
1290 BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUTDIR,
1291 [OUTPUT_DIR_IS_LOCAL="yes"],
1292 [OUTPUT_DIR_IS_LOCAL="no"])
1293 AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
1294
1295 BASIC_CHECK_SRC_PERMS
1296
1297 # Check if the user has any old-style ALT_ variables set.
1298 FOUND_ALT_VARIABLES=`env | grep ^ALT_`
1299
1300 # Before generating output files, test if they exist. If they do, this is a reconfigure.
1301 # Since we can't properly handle the dependencies for this, warn the user about the situation
1302 if test -e $OUTPUTDIR/spec.gmk; then
1303 IS_RECONFIGURE=yes
1304 else
1305 IS_RECONFIGURE=no
1306 fi
1307 ])
1308
1309 ###############################################################################
1310 # Check for support for specific options in bash
1311 AC_DEFUN_ONCE([BASIC_CHECK_BASH_OPTIONS],
1312 [
1313 # Check bash version
1314 # Extra [ ] to stop m4 mangling
1315 [ BASH_VER=`$BASH --version | $SED -n -e 's/^.*bash.*ersion *\([0-9.]*\).*$/\1/ p'` ]
1316 AC_MSG_CHECKING([bash version])
1317 AC_MSG_RESULT([$BASH_VER])
1318
1319 BASH_MAJOR=`$ECHO $BASH_VER | $CUT -d . -f 1`
1320 BASH_MINOR=`$ECHO $BASH_VER | $CUT -d . -f 2`
1321 if test $BASH_MAJOR -lt 3 || (test $BASH_MAJOR -eq 3 && test $BASH_MINOR -lt 2); then
1322 AC_MSG_ERROR([bash version 3.2 or better is required])
1323 fi
1324
1325 # Test if bash supports pipefail.
1326 AC_MSG_CHECKING([if bash supports pipefail])
1327 if ${BASH} -c 'set -o pipefail'; then
1328 BASH_ARGS="$BASH_ARGS -o pipefail"
1329 AC_MSG_RESULT([yes])
1330 else
1331 AC_MSG_RESULT([no])
1332 fi
1333
1334 AC_MSG_CHECKING([if bash supports errexit (-e)])
1335 if ${BASH} -e -c 'true'; then
1336 BASH_ARGS="$BASH_ARGS -e"
1337 AC_MSG_RESULT([yes])
1338 else
1339 AC_MSG_RESULT([no])
1340 fi
1341
1342 AC_SUBST(BASH_ARGS)
1343 ])
1344
1345 ################################################################################
1346 #
1347 # Default make target
1348 #
1349 AC_DEFUN_ONCE([BASIC_SETUP_DEFAULT_MAKE_TARGET],
1350 [
1351 AC_ARG_WITH(default-make-target, [AS_HELP_STRING([--with-default-make-target],
1352 [set the default make target @<:@exploded-image@:>@])])
1353 if test "x$with_default_make_target" = "x" \
1354 || test "x$with_default_make_target" = "xyes"; then
1355 DEFAULT_MAKE_TARGET="exploded-image"
1356 elif test "x$with_default_make_target" = "xno"; then
1357 AC_MSG_ERROR([--without-default-make-target is not a valid option])
1358 else
1359 DEFAULT_MAKE_TARGET="$with_default_make_target"
1360 fi
1361
1362 AC_SUBST(DEFAULT_MAKE_TARGET)
1363 ])
1364
1365 ###############################################################################
1366 # Setup the default value for LOG=
1367 #
1368 AC_DEFUN_ONCE([BASIC_SETUP_DEFAULT_LOG],
1369 [
1370 AC_ARG_WITH(log, [AS_HELP_STRING([--with-log],
1371 [[default vaue for make LOG argument [warn]]])])
1372 AC_MSG_CHECKING([for default LOG value])
1373 if test "x$with_log" = x; then
1374 DEFAULT_LOG=""
1375 else
1376 # Syntax for valid LOG options is a bit too complex for it to be worth
1377 # implementing a test for correctness in configure. Just accept it.
1378 DEFAULT_LOG=$with_log
1379 fi
1380 AC_MSG_RESULT([$DEFAULT_LOG])
1381 AC_SUBST(DEFAULT_LOG)
1382 ])
1383
1384 ###############################################################################
1385 # Code to run after AC_OUTPUT
1386 AC_DEFUN_ONCE([BASIC_POST_CONFIG_OUTPUT],
1387 [
1388 # Try to move config.log (generated by autoconf) to the configure-support directory.
1389 if test -e ./config.log; then
1390 $MV -f ./config.log "$CONFIGURESUPPORT_OUTPUTDIR/config.log" 2> /dev/null
1391 fi
1392
1393 # Rotate our log file (configure.log)
1394 if test -e "$OUTPUTDIR/configure.log.old"; then
1395 $RM -f "$OUTPUTDIR/configure.log.old"
1396 fi
1397 if test -e "$OUTPUTDIR/configure.log"; then
1398 $MV -f "$OUTPUTDIR/configure.log" "$OUTPUTDIR/configure.log.old" 2> /dev/null
1399 fi
1400
1401 # Move configure.log from current directory to the build output root
1402 if test -e ./configure.log; then
1403 $MV -f ./configure.log "$OUTPUTDIR/configure.log" 2> /dev/null
1404 fi
1405
1406 # Make the compare script executable
1407 $CHMOD +x $OUTPUTDIR/compare.sh
1408 ])