1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ########################################################################
27 # This file is responsible for detecting, verifying and setting up the
28 # toolchain, i.e. the compiler, linker and related utilities. It will setup
29 # proper paths to the binaries, but it will not setup any flags.
30 #
31 # The binaries used is determined by the toolchain type, which is the family of
32 # compilers and related tools that are used.
33 ########################################################################
34
35
36 # All valid toolchains, regardless of platform (used by help.m4)
37 VALID_TOOLCHAINS_all="gcc clang solstudio xlc microsoft"
38
39 # These toolchains are valid on different platforms
40 VALID_TOOLCHAINS_linux="gcc clang"
41 VALID_TOOLCHAINS_solaris="solstudio"
42 VALID_TOOLCHAINS_macosx="gcc clang"
43 VALID_TOOLCHAINS_aix="xlc"
44 VALID_TOOLCHAINS_windows="microsoft"
45
46 # Toolchain descriptions
47 TOOLCHAIN_DESCRIPTION_clang="clang/LLVM"
48 TOOLCHAIN_DESCRIPTION_gcc="GNU Compiler Collection"
49 TOOLCHAIN_DESCRIPTION_microsoft="Microsoft Visual Studio"
50 TOOLCHAIN_DESCRIPTION_solstudio="Oracle Solaris Studio"
51 TOOLCHAIN_DESCRIPTION_xlc="IBM XL C/C++"
52
53 # Minimum supported versions, empty means unspecified
54 TOOLCHAIN_MINIMUM_VERSION_clang="3.2"
55 TOOLCHAIN_MINIMUM_VERSION_gcc="4.8"
56 TOOLCHAIN_MINIMUM_VERSION_microsoft="16.00.30319.01" # VS2010
57 TOOLCHAIN_MINIMUM_VERSION_solstudio="5.13"
58 TOOLCHAIN_MINIMUM_VERSION_xlc=""
59
60 # Minimum supported linker versions, empty means unspecified
61 TOOLCHAIN_MINIMUM_LD_VERSION_gcc="2.18"
62
63 # Prepare the system so that TOOLCHAIN_CHECK_COMPILER_VERSION can be called.
64 # Must have CC_VERSION_NUMBER and CXX_VERSION_NUMBER.
65 # $1 - optional variable prefix for compiler and version variables (BUILD_)
66 # $2 - optional variable prefix for comparable variable (OPENJDK_BUILD_)
67 AC_DEFUN([TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS],
68 [
69 if test "x[$]$1CC_VERSION_NUMBER" != "x[$]$1CXX_VERSION_NUMBER"; then
70 AC_MSG_WARN([C and C++ compiler have different version numbers, [$]$1CC_VERSION_NUMBER vs [$]$1CXX_VERSION_NUMBER.])
71 AC_MSG_WARN([This typically indicates a broken setup, and is not supported])
72 fi
73
74 # We only check CC_VERSION_NUMBER since we assume CXX_VERSION_NUMBER is equal.
75 if [ [[ "[$]$1CC_VERSION_NUMBER" =~ (.*\.){4} ]] ]; then
76 AC_MSG_WARN([C compiler version number has more than four parts (W.X.Y.Z): [$]$1CC_VERSION_NUMBER. Comparisons might be wrong.])
77 fi
78
79 if [ [[ "[$]$1CC_VERSION_NUMBER" =~ [0-9]{6} ]] ]; then
80 AC_MSG_WARN([C compiler version number has a part larger than 99999: [$]$1CC_VERSION_NUMBER. Comparisons might be wrong.])
81 fi
82
83 $2COMPARABLE_ACTUAL_VERSION=`$AWK -F. '{ printf("%05d%05d%05d%05d\n", [$]1, [$]2, [$]3, [$]4) }' <<< "[$]$1CC_VERSION_NUMBER"`
84 ])
85
86 # Check if the configured compiler (C and C++) is of a specific version or
87 # newer. TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS must have been called before.
88 #
89 # Arguments:
90 # VERSION: The version string to check against the found version
91 # IF_AT_LEAST: block to run if the compiler is at least this version (>=)
92 # IF_OLDER_THAN: block to run if the compiler is older than this version (<)
93 # PREFIX: Optional variable prefix for compiler to compare version for (OPENJDK_BUILD_)
94 BASIC_DEFUN_NAMED([TOOLCHAIN_CHECK_COMPILER_VERSION],
95 [*VERSION PREFIX IF_AT_LEAST IF_OLDER_THAN], [$@],
96 [
97 # Need to assign to a variable since m4 is blocked from modifying parts in [].
98 REFERENCE_VERSION=ARG_VERSION
99
100 if [ [[ "$REFERENCE_VERSION" =~ (.*\.){4} ]] ]; then
101 AC_MSG_ERROR([Internal error: Cannot compare to ARG_VERSION, only four parts (W.X.Y.Z) is supported])
102 fi
103
104 if [ [[ "$REFERENCE_VERSION" =~ [0-9]{6} ]] ]; then
105 AC_MSG_ERROR([Internal error: Cannot compare to ARG_VERSION, only parts < 99999 is supported])
106 fi
107
108 # Version comparison method inspired by http://stackoverflow.com/a/24067243
109 COMPARABLE_REFERENCE_VERSION=`$AWK -F. '{ printf("%05d%05d%05d%05d\n", [$]1, [$]2, [$]3, [$]4) }' <<< "$REFERENCE_VERSION"`
110
111 if test [$]ARG_PREFIX[COMPARABLE_ACTUAL_VERSION] -ge $COMPARABLE_REFERENCE_VERSION ; then
112 :
113 ARG_IF_AT_LEAST
114 else
115 :
116 ARG_IF_OLDER_THAN
117 fi
118 ])
119
120 # Prepare the system so that TOOLCHAIN_CHECK_COMPILER_VERSION can be called.
121 # Must have LD_VERSION_NUMBER.
122 # $1 - optional variable prefix for compiler and version variables (BUILD_)
123 # $2 - optional variable prefix for comparable variable (OPENJDK_BUILD_)
124 AC_DEFUN([TOOLCHAIN_PREPARE_FOR_LD_VERSION_COMPARISONS],
125 [
126 if [ [[ "[$]$1LD_VERSION_NUMBER" =~ (.*\.){4} ]] ]; then
127 AC_MSG_WARN([Linker version number has more than four parts (W.X.Y.Z): [$]$1LD_VERSION_NUMBER. Comparisons might be wrong.])
128 fi
129
130 if [ [[ "[$]$1LD_VERSION_NUMBER" =~ [0-9]{6} ]] ]; then
131 AC_MSG_WARN([Linker version number has a part larger than 99999: [$]$1LD_VERSION_NUMBER. Comparisons might be wrong.])
132 fi
133
134 $2COMPARABLE_ACTUAL_LD_VERSION=`$AWK -F. '{ printf("%05d%05d%05d%05d\n", [$]1, [$]2, [$]3, [$]4) }' <<< "[$]$1LD_VERSION_NUMBER"`
135 ])
136
137 # Check if the configured linker is of a specific version or
138 # newer. TOOLCHAIN_PREPARE_FOR_LD_VERSION_COMPARISONS must have been called before.
139 #
140 # Arguments:
141 # VERSION: The version string to check against the found version
142 # IF_AT_LEAST: block to run if the compiler is at least this version (>=)
143 # IF_OLDER_THAN: block to run if the compiler is older than this version (<)
144 # PREFIX: Optional variable prefix for compiler to compare version for (OPENJDK_BUILD_)
145 BASIC_DEFUN_NAMED([TOOLCHAIN_CHECK_LINKER_VERSION],
146 [*VERSION PREFIX IF_AT_LEAST IF_OLDER_THAN], [$@],
147 [
148 # Need to assign to a variable since m4 is blocked from modifying parts in [].
149 REFERENCE_VERSION=ARG_VERSION
150
151 if [ [[ "$REFERENCE_VERSION" =~ (.*\.){4} ]] ]; then
152 AC_MSG_ERROR([Internal error: Cannot compare to ARG_VERSION, only four parts (W.X.Y.Z) is supported])
153 fi
154
155 if [ [[ "$REFERENCE_VERSION" =~ [0-9]{6} ]] ]; then
156 AC_MSG_ERROR([Internal error: Cannot compare to ARG_VERSION, only parts < 99999 is supported])
157 fi
158
159 # Version comparison method inspired by http://stackoverflow.com/a/24067243
160 COMPARABLE_REFERENCE_VERSION=`$AWK -F. '{ printf("%05d%05d%05d%05d\n", [$]1, [$]2, [$]3, [$]4) }' <<< "$REFERENCE_VERSION"`
161
162 if test [$]ARG_PREFIX[COMPARABLE_ACTUAL_LD_VERSION] -ge $COMPARABLE_REFERENCE_VERSION ; then
163 :
164 ARG_IF_AT_LEAST
165 else
166 :
167 ARG_IF_OLDER_THAN
168 fi
169 ])
170
171 # Setup a number of variables describing how native output files are
172 # named on this platform/toolchain.
173 AC_DEFUN([TOOLCHAIN_SETUP_FILENAME_PATTERNS],
174 [
175 # Define filename patterns
176 if test "x$OPENJDK_TARGET_OS" = xwindows; then
177 LIBRARY_PREFIX=
178 SHARED_LIBRARY_SUFFIX='.dll'
179 STATIC_LIBRARY_SUFFIX='.lib'
180 SHARED_LIBRARY='[$]1.dll'
181 STATIC_LIBRARY='[$]1.lib'
182 OBJ_SUFFIX='.obj'
183 else
184 LIBRARY_PREFIX=lib
185 SHARED_LIBRARY_SUFFIX='.so'
186 STATIC_LIBRARY_SUFFIX='.a'
187 SHARED_LIBRARY='lib[$]1.so'
188 STATIC_LIBRARY='lib[$]1.a'
189 OBJ_SUFFIX='.o'
190 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
191 # For full static builds, we're overloading the SHARED_LIBRARY
192 # variables in order to limit the amount of changes required.
193 # It would be better to remove SHARED and just use LIBRARY and
194 # LIBRARY_SUFFIX for libraries that can be built either
195 # shared or static and use STATIC_* for libraries that are
196 # always built statically.
197 if test "x$STATIC_BUILD" = xtrue; then
198 SHARED_LIBRARY='lib[$]1.a'
199 SHARED_LIBRARY_SUFFIX='.a'
200 else
201 SHARED_LIBRARY='lib[$]1.dylib'
202 SHARED_LIBRARY_SUFFIX='.dylib'
203 fi
204 fi
205 fi
206
207 AC_SUBST(LIBRARY_PREFIX)
208 AC_SUBST(SHARED_LIBRARY_SUFFIX)
209 AC_SUBST(STATIC_LIBRARY_SUFFIX)
210 AC_SUBST(SHARED_LIBRARY)
211 AC_SUBST(STATIC_LIBRARY)
212 AC_SUBST(OBJ_SUFFIX)
213 ])
214
215 # Determine which toolchain type to use, and make sure it is valid for this
216 # platform. Setup various information about the selected toolchain.
217 AC_DEFUN_ONCE([TOOLCHAIN_DETERMINE_TOOLCHAIN_TYPE],
218 [
219 AC_ARG_WITH(toolchain-type, [AS_HELP_STRING([--with-toolchain-type],
220 [the toolchain type (or family) to use, use '--help' to show possible values @<:@platform dependent@:>@])])
221
222 # Use indirect variable referencing
223 toolchain_var_name=VALID_TOOLCHAINS_$OPENJDK_BUILD_OS
224 VALID_TOOLCHAINS=${!toolchain_var_name}
225
226 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
227 if test -n "$XCODEBUILD"; then
228 # On Mac OS X, default toolchain to clang after Xcode 5
229 XCODE_VERSION_OUTPUT=`"$XCODEBUILD" -version 2>&1 | $HEAD -n 1`
230 $ECHO "$XCODE_VERSION_OUTPUT" | $GREP "Xcode " > /dev/null
231 if test $? -ne 0; then
232 AC_MSG_NOTICE([xcodebuild output: $XCODE_VERSION_OUTPUT])
233 AC_MSG_ERROR([Failed to determine Xcode version.])
234 fi
235 XCODE_MAJOR_VERSION=`$ECHO $XCODE_VERSION_OUTPUT | \
236 $SED -e 's/^Xcode \(@<:@1-9@:>@@<:@0-9.@:>@*\)/\1/' | \
237 $CUT -f 1 -d .`
238 AC_MSG_NOTICE([Xcode major version: $XCODE_MAJOR_VERSION])
239 if test $XCODE_MAJOR_VERSION -ge 5; then
240 DEFAULT_TOOLCHAIN="clang"
241 else
242 DEFAULT_TOOLCHAIN="gcc"
243 fi
244 else
245 # If Xcode is not installed, but the command line tools are
246 # then we can't run xcodebuild. On these systems we should
247 # default to clang
248 DEFAULT_TOOLCHAIN="clang"
249 fi
250 else
251 # First toolchain type in the list is the default
252 DEFAULT_TOOLCHAIN=${VALID_TOOLCHAINS%% *}
253 fi
254
255 if test "x$with_toolchain_type" = xlist; then
256 # List all toolchains
257 AC_MSG_NOTICE([The following toolchains are valid on this platform:])
258 for toolchain in $VALID_TOOLCHAINS; do
259 toolchain_var_name=TOOLCHAIN_DESCRIPTION_$toolchain
260 TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
261 $PRINTF " %-10s %s\n" $toolchain "$TOOLCHAIN_DESCRIPTION"
262 done
263
264 exit 0
265 elif test "x$with_toolchain_type" != x; then
266 # User override; check that it is valid
267 if test "x${VALID_TOOLCHAINS/$with_toolchain_type/}" = "x${VALID_TOOLCHAINS}"; then
268 AC_MSG_NOTICE([Toolchain type $with_toolchain_type is not valid on this platform.])
269 AC_MSG_NOTICE([Valid toolchains: $VALID_TOOLCHAINS.])
270 AC_MSG_ERROR([Cannot continue.])
271 fi
272 TOOLCHAIN_TYPE=$with_toolchain_type
273 else
274 # No flag given, use default
275 TOOLCHAIN_TYPE=$DEFAULT_TOOLCHAIN
276 fi
277 AC_SUBST(TOOLCHAIN_TYPE)
278
279 TOOLCHAIN_CC_BINARY_clang="clang"
280 TOOLCHAIN_CC_BINARY_gcc="gcc"
281 TOOLCHAIN_CC_BINARY_microsoft="cl$EXE_SUFFIX"
282 TOOLCHAIN_CC_BINARY_solstudio="cc"
283 TOOLCHAIN_CC_BINARY_xlc="xlc_r"
284
285 TOOLCHAIN_CXX_BINARY_clang="clang++"
286 TOOLCHAIN_CXX_BINARY_gcc="g++"
287 TOOLCHAIN_CXX_BINARY_microsoft="cl$EXE_SUFFIX"
288 TOOLCHAIN_CXX_BINARY_solstudio="CC"
289 TOOLCHAIN_CXX_BINARY_xlc="xlC_r"
290
291 # Use indirect variable referencing
292 toolchain_var_name=TOOLCHAIN_DESCRIPTION_$TOOLCHAIN_TYPE
293 TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
294 toolchain_var_name=TOOLCHAIN_MINIMUM_VERSION_$TOOLCHAIN_TYPE
295 TOOLCHAIN_MINIMUM_VERSION=${!toolchain_var_name}
296 toolchain_var_name=TOOLCHAIN_MINIMUM_LD_VERSION_$TOOLCHAIN_TYPE
297 TOOLCHAIN_MINIMUM_LD_VERSION=${!toolchain_var_name}
298 toolchain_var_name=TOOLCHAIN_CC_BINARY_$TOOLCHAIN_TYPE
299 TOOLCHAIN_CC_BINARY=${!toolchain_var_name}
300 toolchain_var_name=TOOLCHAIN_CXX_BINARY_$TOOLCHAIN_TYPE
301 TOOLCHAIN_CXX_BINARY=${!toolchain_var_name}
302
303 TOOLCHAIN_SETUP_FILENAME_PATTERNS
304
305 if test "x$TOOLCHAIN_TYPE" = "x$DEFAULT_TOOLCHAIN"; then
306 AC_MSG_NOTICE([Using default toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION)])
307 else
308 AC_MSG_NOTICE([Using user selected toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION). Default toolchain is $DEFAULT_TOOLCHAIN.])
309 fi
310 ])
311
312 # Before we start detecting the toolchain executables, we might need some
313 # special setup, e.g. additional paths etc.
314 AC_DEFUN_ONCE([TOOLCHAIN_PRE_DETECTION],
315 [
316 # FIXME: Is this needed?
317 AC_LANG(C++)
318
319 # Store the CFLAGS etc passed to the configure script.
320 ORG_CFLAGS="$CFLAGS"
321 ORG_CXXFLAGS="$CXXFLAGS"
322
323 # autoconf magic only relies on PATH, so update it if tools dir is specified
324 OLD_PATH="$PATH"
325
326 # On Windows, we need to detect the visual studio installation first.
327 # This will change the PATH, but we need to keep that new PATH even
328 # after toolchain detection is done, since the compiler (on x86) uses
329 # it for DLL resolution in runtime.
330 if test "x$OPENJDK_BUILD_OS" = "xwindows" \
331 && test "x$TOOLCHAIN_TYPE" = "xmicrosoft"; then
332 TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV
333 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.wsl"; then
334 # Append VS_PATH. In WSL, VS_PATH will not contain the WSL env path needed
335 # for using basic Unix tools, so need to keep the original PATH.
336 BASIC_APPEND_TO_PATH(PATH, $VS_PATH)
337 BASIC_APPEND_TO_PATH(WSLENV, "PATH/l:LIB:INCLUDE")
338 export WSLENV
339 else
340 # Reset path to VS_PATH. It will include everything that was on PATH at the time we
341 # ran TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV.
342 PATH="$VS_PATH"
343 fi
344 # The microsoft toolchain also requires INCLUDE and LIB to be set.
345 export INCLUDE="$VS_INCLUDE"
346 export LIB="$VS_LIB"
347 else
348 if test "x$XCODE_VERSION_OUTPUT" != x; then
349 # For Xcode, we set the Xcode version as TOOLCHAIN_VERSION
350 TOOLCHAIN_VERSION=`$ECHO $XCODE_VERSION_OUTPUT | $CUT -f 2 -d ' '`
351 TOOLCHAIN_DESCRIPTION="$TOOLCHAIN_DESCRIPTION from Xcode $TOOLCHAIN_VERSION"
352 else
353 # Currently we do not define this for other toolchains. This might change as the need arise.
354 TOOLCHAIN_VERSION=
355 fi
356 fi
357 AC_SUBST(TOOLCHAIN_VERSION)
358
359 # Finally add TOOLCHAIN_PATH at the beginning, to allow --with-tools-dir to
360 # override all other locations.
361 if test "x$TOOLCHAIN_PATH" != x; then
362 PATH=$TOOLCHAIN_PATH:$PATH
363 fi
364 ])
365
366 # Restore path, etc
367 AC_DEFUN_ONCE([TOOLCHAIN_POST_DETECTION],
368 [
369 # Restore old path, except for the microsoft toolchain, which requires VS_PATH
370 # to remain in place. Otherwise the compiler will not work in some siutations
371 # in later configure checks.
372 if test "x$TOOLCHAIN_TYPE" != "xmicrosoft"; then
373 PATH="$OLD_PATH"
374 fi
375
376 # Restore the flags to the user specified values.
377 # This is necessary since AC_PROG_CC defaults CFLAGS to "-g -O2"
378 CFLAGS="$ORG_CFLAGS"
379 CXXFLAGS="$ORG_CXXFLAGS"
380 ])
381
382 # Check if a compiler is of the toolchain type we expect, and save the version
383 # information from it. If the compiler does not match the expected type,
384 # this function will abort using AC_MSG_ERROR. If it matches, the version will
385 # be stored in CC_VERSION_NUMBER/CXX_VERSION_NUMBER (as a dotted number), and
386 # the full version string in CC_VERSION_STRING/CXX_VERSION_STRING.
387 #
388 # $1 = compiler to test (CC or CXX)
389 # $2 = human readable name of compiler (C or C++)
390 AC_DEFUN([TOOLCHAIN_EXTRACT_COMPILER_VERSION],
391 [
392 COMPILER=[$]$1
393 COMPILER_NAME=$2
394
395 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
396 # cc -V output typically looks like
397 # cc: Sun C 5.12 Linux_i386 2011/11/16
398 # or
399 # cc: Studio 12.5 Sun C 5.14 SunOS_sparc 2016/05/31
400 COMPILER_VERSION_OUTPUT=`$COMPILER -V 2>&1`
401 # Check that this is likely to be the Solaris Studio cc.
402 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "^.* Sun $COMPILER_NAME" > /dev/null
403 if test $? -ne 0; then
404 ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
405 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
406 AC_MSG_NOTICE([The result from running with -V was: "$COMPILER_VERSION_OUTPUT"])
407 AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
408 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
409 fi
410 # Remove usage instructions (if present), and
411 # collapse compiler output into a single line
412 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
413 $SED -e 's/ *@<:@Uu@:>@sage:.*//'`
414 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
415 $SED -e "s/^.*@<:@ ,\t@:>@$COMPILER_NAME@<:@ ,\t@:>@\(@<:@1-9@:>@\.@<:@0-9@:>@@<:@0-9@:>@*\).*/\1/"`
416 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
417 # xlc -qversion output typically looks like
418 # IBM XL C/C++ for AIX, V11.1 (5724-X13)
419 # Version: 11.01.0000.0015
420 COMPILER_VERSION_OUTPUT=`$COMPILER -qversion 2>&1`
421 # Check that this is likely to be the IBM XL C compiler.
422 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "IBM XL C" > /dev/null
423 if test $? -ne 0; then
424 ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
425 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
426 AC_MSG_NOTICE([The result from running with -qversion was: "$COMPILER_VERSION_OUTPUT"])
427 AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
428 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
429 fi
430 # Collapse compiler output into a single line
431 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
432 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
433 $SED -e 's/^.*, V\(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
434 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
435 # There is no specific version flag, but all output starts with a version string.
436 # First line typically looks something like:
437 # Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 16.00.40219.01 for 80x86
438 COMPILER_VERSION_OUTPUT=`"$COMPILER" 2>&1 | $GREP -v 'ERROR.*UtilTranslatePathList' | $HEAD -n 1 | $TR -d '\r'`
439 # Check that this is likely to be Microsoft CL.EXE.
440 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Microsoft.*Compiler" > /dev/null
441 if test $? -ne 0; then
442 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
443 AC_MSG_NOTICE([The result from running it was: "$COMPILER_VERSION_OUTPUT"])
444 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
445 fi
446 # Collapse compiler output into a single line
447 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
448 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
449 $SED -e 's/^.*ersion.\(@<:@1-9@:>@@<:@0-9.@:>@*\) .*$/\1/'`
450 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
451 # gcc --version output typically looks like
452 # gcc (Ubuntu/Linaro 4.8.1-10ubuntu9) 4.8.1
453 # Copyright (C) 2013 Free Software Foundation, Inc.
454 # This is free software; see the source for copying conditions. There is NO
455 # warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
456 COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
457 # Check that this is likely to be GCC.
458 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Free Software Foundation" > /dev/null
459 if test $? -ne 0; then
460 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
461 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION"])
462 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
463 fi
464 # Remove Copyright and legalese from version string, and
465 # collapse into a single line
466 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
467 $SED -e 's/ *Copyright .*//'`
468 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
469 $SED -e 's/^.* \(@<:@1-9@:>@\.@<:@0-9.@:>@*\)@<:@^0-9.@:>@.*$/\1/'`
470 elif test "x$TOOLCHAIN_TYPE" = xclang; then
471 # clang --version output typically looks like
472 # Apple LLVM version 5.0 (clang-500.2.79) (based on LLVM 3.3svn)
473 # clang version 3.3 (tags/RELEASE_33/final)
474 # or
475 # Debian clang version 3.2-7ubuntu1 (tags/RELEASE_32/final) (based on LLVM 3.2)
476 # Target: x86_64-pc-linux-gnu
477 # Thread model: posix
478 COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
479 # Check that this is likely to be clang
480 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "clang" > /dev/null
481 if test $? -ne 0; then
482 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
483 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION_OUTPUT"])
484 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
485 fi
486 # Collapse compiler output into a single line
487 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
488 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
489 $SED -e 's/^.* version \(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
490 else
491 AC_MSG_ERROR([Unknown toolchain type $TOOLCHAIN_TYPE.])
492 fi
493 # This sets CC_VERSION_NUMBER or CXX_VERSION_NUMBER. (This comment is a grep marker)
494 $1_VERSION_NUMBER="$COMPILER_VERSION_NUMBER"
495 # This sets CC_VERSION_STRING or CXX_VERSION_STRING. (This comment is a grep marker)
496 $1_VERSION_STRING="$COMPILER_VERSION_STRING"
497
498 AC_MSG_NOTICE([Using $TOOLCHAIN_TYPE $COMPILER_NAME compiler version $COMPILER_VERSION_NUMBER @<:@$COMPILER_VERSION_STRING@:>@])
499 ])
500
501 # Try to locate the given C or C++ compiler in the path, or otherwise.
502 #
503 # $1 = compiler to test (CC or CXX)
504 # $2 = human readable name of compiler (C or C++)
505 # $3 = compiler name to search for
506 AC_DEFUN([TOOLCHAIN_FIND_COMPILER],
507 [
508 COMPILER_NAME=$2
509 SEARCH_LIST="$3"
510
511 if test "x[$]$1" != x; then
512 # User has supplied compiler name already, always let that override.
513 AC_MSG_NOTICE([Will use user supplied compiler $1=[$]$1])
514 if test "x`basename [$]$1`" = "x[$]$1"; then
515 # A command without a complete path is provided, search $PATH.
516
517 AC_PATH_PROGS(POTENTIAL_$1, [$]$1)
518 if test "x$POTENTIAL_$1" != x; then
519 $1=$POTENTIAL_$1
520 else
521 AC_MSG_ERROR([User supplied compiler $1=[$]$1 could not be found])
522 fi
523 else
524 # Otherwise it might already be a complete path
525 if test ! -x "[$]$1"; then
526 AC_MSG_ERROR([User supplied compiler $1=[$]$1 does not exist])
527 fi
528 fi
529 else
530 # No user supplied value. Locate compiler ourselves.
531
532 # If we are cross compiling, assume cross compilation tools follows the
533 # cross compilation standard where they are prefixed with the autoconf
534 # standard name for the target. For example the binary
535 # i686-sun-solaris2.10-gcc will cross compile for i686-sun-solaris2.10.
536 # If we are not cross compiling, then the default compiler name will be
537 # used.
538
539 $1=
540 # If TOOLCHAIN_PATH is set, check for all compiler names in there first
541 # before checking the rest of the PATH.
542 # FIXME: Now that we prefix the TOOLS_DIR to the PATH in the PRE_DETECTION
543 # step, this should not be necessary.
544 if test -n "$TOOLCHAIN_PATH"; then
545 PATH_save="$PATH"
546 PATH="$TOOLCHAIN_PATH"
547 AC_PATH_TOOL(TOOLCHAIN_PATH_$1, $SEARCH_LIST)
548 $1=$TOOLCHAIN_PATH_$1
549 PATH="$PATH_save"
550 fi
551
552 # AC_PATH_TOOL can't be run multiple times with the same variable,
553 # so create a new name for this run.
554 if test "x[$]$1" = x; then
555 AC_PATH_TOOL(POTENTIAL_$1, $SEARCH_LIST)
556 $1=$POTENTIAL_$1
557 fi
558
559 if test "x[$]$1" = x; then
560 HELP_MSG_MISSING_DEPENDENCY([devkit])
561 AC_MSG_ERROR([Could not find a $COMPILER_NAME compiler. $HELP_MSG])
562 fi
563 fi
564
565 # Now we have a compiler binary in $1. Make sure it's okay.
566 BASIC_FIXUP_EXECUTABLE($1)
567 TEST_COMPILER="[$]$1"
568
569 AC_MSG_CHECKING([resolved symbolic links for $1])
570 SYMLINK_ORIGINAL="$TEST_COMPILER"
571 BASIC_REMOVE_SYMBOLIC_LINKS(SYMLINK_ORIGINAL)
572 if test "x$TEST_COMPILER" = "x$SYMLINK_ORIGINAL"; then
573 AC_MSG_RESULT([no symlink])
574 else
575 AC_MSG_RESULT([$SYMLINK_ORIGINAL])
576
577 # We can't handle ccache by gcc wrappers, since we need to know if we're
578 # using ccache. Instead ccache usage must be controlled by a configure option.
579 COMPILER_BASENAME=`$BASENAME "$SYMLINK_ORIGINAL"`
580 if test "x$COMPILER_BASENAME" = "xccache"; then
581 AC_MSG_NOTICE([Please use --enable-ccache instead of providing a wrapped compiler.])
582 AC_MSG_ERROR([$TEST_COMPILER is a symbolic link to ccache. This is not supported.])
583 fi
584 fi
585
586 TOOLCHAIN_EXTRACT_COMPILER_VERSION([$1], [$COMPILER_NAME])
587 ])
588
589 # Retrieve the linker version number and store it in LD_VERSION_NUMBER
590 # (as a dotted number), and
591 # the full version string in LD_VERSION_STRING.
592 #
593 # $1 = linker to test (LD or BUILD_LD)
594 # $2 = human readable name of linker (Linker or BuildLinker)
595 AC_DEFUN([TOOLCHAIN_EXTRACT_LD_VERSION],
596 [
597 LINKER=[$]$1
598 LINKER_NAME="$2"
599
600 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
601 # cc -Wl,-V output typically looks like
602 # ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.2329
603
604 # solstudio cc requires us to have an existing file to pass as argument,
605 # but it need not be a syntactically correct C file, so just use
606 # ourself. :) The intermediate 'cat' is needed to stop ld from leaving
607 # a lingering a.out (!).
608 LINKER_VERSION_STRING=`$LD -Wl,-V $TOPDIR/configure 2>&1 | $CAT | $HEAD -n 1 | $SED -e 's/ld: //'`
609 # Extract version number
610 [ LINKER_VERSION_NUMBER=`$ECHO $LINKER_VERSION_STRING | \
611 $SED -e 's/.* \([0-9][0-9]*\.[0-9][0-9]*\)-\([0-9][0-9]*\.[0-9][0-9]*\)/\1.\2/'` ]
612 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
613 LINKER_VERSION_STRING="Unknown"
614 LINKER_VERSION_NUMBER="0.0"
615 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
616 # There is no specific version flag, but all output starts with a version string.
617 # First line typically looks something like:
618 # Microsoft (R) Incremental Linker Version 12.00.31101.0
619 LINKER_VERSION_STRING=`$LD 2>&1 | $HEAD -n 1 | $TR -d '\r'`
620 # Extract version number
621 [ LINKER_VERSION_NUMBER=`$ECHO $LINKER_VERSION_STRING | \
622 $SED -e 's/.* \([0-9][0-9]*\(\.[0-9][0-9]*\)*\).*/\1/'` ]
623 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
624 # gcc -Wl,-version output typically looks like
625 # GNU ld (GNU Binutils for Ubuntu) 2.26.1
626 # Copyright (C) 2015 Free Software Foundation, Inc.
627 # This program is free software; [...]
628 LINKER_VERSION_STRING=`$LD -Wl,-version 2>&1 | $HEAD -n 1`
629 # Extract version number
630 [ LINKER_VERSION_NUMBER=`$ECHO $LINKER_VERSION_STRING | \
631 $SED -e 's/.* \([0-9][0-9]*\(\.[0-9][0-9]*\)*\).*/\1/'` ]
632 elif test "x$TOOLCHAIN_TYPE" = xclang; then
633 # clang -Wl,-v output typically looks like
634 # @(#)PROGRAM:ld PROJECT:ld64-305
635 # configured to support archs: armv6 armv7 armv7s arm64 i386 x86_64 x86_64h armv6m armv7k armv7m armv7em (tvOS)
636 # Library search paths: [...]
637 # or
638 # GNU ld (GNU Binutils for Ubuntu) 2.26.1
639
640 LINKER_VERSION_STRING=`$LD -Wl,-v 2>&1 | $HEAD -n 1`
641 # Check if we're using the GNU ld
642 $ECHO "$LINKER_VERSION_STRING" | $GREP "GNU" > /dev/null
643 if test $? -eq 0; then
644 # Extract version number
645 [ LINKER_VERSION_NUMBER=`$ECHO $LINKER_VERSION_STRING | \
646 $SED -e 's/.* \([0-9][0-9]*\(\.[0-9][0-9]*\)*\).*/\1/'` ]
647 else
648 # Extract version number
649 [ LINKER_VERSION_NUMBER=`$ECHO $LINKER_VERSION_STRING | \
650 $SED -e 's/.*-\([0-9][0-9]*\)/\1/'` ]
651 fi
652 fi
653
654 $1_VERSION_NUMBER="$LINKER_VERSION_NUMBER"
655 $1_VERSION_STRING="$LINKER_VERSION_STRING"
656
657 AC_MSG_NOTICE([Using $TOOLCHAIN_TYPE $LINKER_NAME version $LINKER_VERSION_NUMBER @<:@$LINKER_VERSION_STRING@:>@])
658 ])
659
660 # Detect the core components of the toolchain, i.e. the compilers (CC and CXX),
661 # preprocessor (CPP and CXXCPP), the linker (LD), the assembler (AS) and the
662 # archiver (AR). Verify that the compilers are correct according to the
663 # toolchain type.
664 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_CORE],
665 [
666 #
667 # Setup the compilers (CC and CXX)
668 #
669 TOOLCHAIN_FIND_COMPILER([CC], [C], $TOOLCHAIN_CC_BINARY)
670 # Now that we have resolved CC ourself, let autoconf have its go at it
671 AC_PROG_CC([$CC])
672
673 TOOLCHAIN_FIND_COMPILER([CXX], [C++], $TOOLCHAIN_CXX_BINARY)
674 # Now that we have resolved CXX ourself, let autoconf have its go at it
675 AC_PROG_CXX([$CXX])
676
677 # This is the compiler version number on the form X.Y[.Z]
678 AC_SUBST(CC_VERSION_NUMBER)
679 AC_SUBST(CXX_VERSION_NUMBER)
680
681 TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS
682
683 if test "x$TOOLCHAIN_MINIMUM_VERSION" != x; then
684 TOOLCHAIN_CHECK_COMPILER_VERSION(VERSION: $TOOLCHAIN_MINIMUM_VERSION,
685 IF_OLDER_THAN: [
686 AC_MSG_WARN([You are using $TOOLCHAIN_TYPE older than $TOOLCHAIN_MINIMUM_VERSION. This is not a supported configuration.])
687 ]
688 )
689 fi
690
691 #
692 # Setup the preprocessor (CPP and CXXCPP)
693 #
694 AC_PROG_CPP
695 BASIC_FIXUP_EXECUTABLE(CPP)
696 AC_PROG_CXXCPP
697 BASIC_FIXUP_EXECUTABLE(CXXCPP)
698
699 #
700 # Setup the linker (LD)
701 #
702 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
703 # In the Microsoft toolchain we have a separate LD command "link".
704 # Make sure we reject /usr/bin/link (as determined in CYGWIN_LINK), which is
705 # a cygwin program for something completely different.
706 AC_CHECK_PROG([LD], [link$EXE_SUFFIX],[link$EXE_SUFFIX],,, [$CYGWIN_LINK])
707 BASIC_FIXUP_EXECUTABLE(LD)
708 # Verify that we indeed succeeded with this trick.
709 AC_MSG_CHECKING([if the found link.exe is actually the Visual Studio linker])
710 "$LD" --version > /dev/null
711 if test $? -eq 0 ; then
712 AC_MSG_RESULT([no])
713 AC_MSG_ERROR([This is the Cygwin link tool. Please check your PATH and rerun configure.])
714 else
715 AC_MSG_RESULT([yes])
716 fi
717 LDCXX="$LD"
718 # jaotc being a windows program expects the linker to be supplied with exe suffix.
719 LD_JAOTC="$LD$EXE_SUFFIX"
720 else
721 # All other toolchains use the compiler to link.
722 LD="$CC"
723 LDCXX="$CXX"
724 # jaotc expects 'ld' as the linker rather than the compiler.
725 BASIC_CHECK_TOOLS([LD_JAOTC], ld)
726 BASIC_FIXUP_EXECUTABLE(LD_JAOTC)
727 fi
728 AC_SUBST(LD)
729 AC_SUBST(LD_JAOTC)
730 # FIXME: it should be CXXLD, according to standard (cf CXXCPP)
731 AC_SUBST(LDCXX)
732
733 TOOLCHAIN_EXTRACT_LD_VERSION([LD], [linker])
734 TOOLCHAIN_PREPARE_FOR_LD_VERSION_COMPARISONS
735
736 if test "x$TOOLCHAIN_MINIMUM_LD_VERSION" != x; then
737 TOOLCHAIN_CHECK_LINKER_VERSION(VERSION: $TOOLCHAIN_MINIMUM_LD_VERSION,
738 IF_OLDER_THAN: [
739 AC_MSG_WARN([You are using a linker older than $TOOLCHAIN_MINIMUM_LD_VERSION. This is not a supported configuration.])
740 ]
741 )
742 fi
743
744 #
745 # Setup the assembler (AS)
746 #
747 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
748 BASIC_PATH_PROGS(AS, as)
749 BASIC_FIXUP_EXECUTABLE(AS)
750 if test "x$AS" = x; then
751 AC_MSG_ERROR([Solaris assembler (as) is required. Please install via "pkg install pkg:/developer/assembler".])
752 fi
753 else
754 # FIXME: is this correct for microsoft?
755 AS="$CC -c"
756 fi
757 AC_SUBST(AS)
758
759 #
760 # Setup the archiver (AR)
761 #
762 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
763 # The corresponding ar tool is lib.exe (used to create static libraries)
764 AC_CHECK_PROG([AR], [lib$EXE_SUFFIX],[lib$EXE_SUFFIX],,,)
765 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
766 BASIC_CHECK_TOOLS(AR, ar gcc-ar)
767 else
768 BASIC_CHECK_TOOLS(AR, ar)
769 fi
770 BASIC_FIXUP_EXECUTABLE(AR)
771 ])
772
773 # Setup additional tools that is considered a part of the toolchain, but not the
774 # core part. Many of these are highly platform-specific and do not exist,
775 # and/or are not needed on all platforms.
776 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_EXTRA],
777 [
778 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
779 BASIC_PATH_PROGS(LIPO, lipo)
780 BASIC_FIXUP_EXECUTABLE(LIPO)
781 BASIC_REQUIRE_PROGS(OTOOL, otool)
782 BASIC_FIXUP_EXECUTABLE(OTOOL)
783 BASIC_REQUIRE_PROGS(INSTALL_NAME_TOOL, install_name_tool)
784 BASIC_FIXUP_EXECUTABLE(INSTALL_NAME_TOOL)
785 fi
786
787 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
788 AC_CHECK_PROG([MT], [mt$EXE_SUFFIX], [mt$EXE_SUFFIX],,, [/usr/bin/mt])
789 BASIC_FIXUP_EXECUTABLE(MT)
790 # Setup the resource compiler (RC)
791 AC_CHECK_PROG([RC], [rc$EXE_SUFFIX], [rc$EXE_SUFFIX],,, [/usr/bin/rc])
792 BASIC_FIXUP_EXECUTABLE(RC)
793 AC_CHECK_PROG([DUMPBIN], [dumpbin$EXE_SUFFIX], [dumpbin$EXE_SUFFIX],,,)
794 BASIC_FIXUP_EXECUTABLE(DUMPBIN)
795 # We need to check for 'msbuild.exe' because at the place where we expect to
796 # find 'msbuild.exe' there's also a directory called 'msbuild' and configure
797 # won't find the 'msbuild.exe' executable in that case (and the
798 # 'ac_executable_extensions' is unusable due to performance reasons).
799 # Notice that we intentionally don't fix up the path to MSBUILD because we
800 # will call it in a DOS shell during freetype detection on Windows (see
801 # 'LIB_SETUP_FREETYPE' in "libraries.m4"
802 AC_CHECK_PROG([MSBUILD], [msbuild$EXE_SUFFIX], [msbuild$EXE_SUFFIX],,,)
803 fi
804
805 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
806 BASIC_PATH_PROGS(STRIP, strip)
807 BASIC_FIXUP_EXECUTABLE(STRIP)
808 BASIC_PATH_PROGS(NM, nm)
809 BASIC_FIXUP_EXECUTABLE(NM)
810 BASIC_PATH_PROGS(GNM, gnm)
811 BASIC_FIXUP_EXECUTABLE(GNM)
812 elif test "x$OPENJDK_TARGET_OS" != xwindows; then
813 # FIXME: we should unify this with the solaris case above.
814 BASIC_CHECK_TOOLS(STRIP, strip)
815 BASIC_FIXUP_EXECUTABLE(STRIP)
816 if test "x$TOOLCHAIN_TYPE" = xgcc; then
817 BASIC_CHECK_TOOLS(NM, nm gcc-nm)
818 else
819 BASIC_CHECK_TOOLS(NM, nm)
820 fi
821 BASIC_FIXUP_EXECUTABLE(NM)
822 GNM="$NM"
823 AC_SUBST(GNM)
824 fi
825
826 # objcopy is used for moving debug symbols to separate files when
827 # full debug symbols are enabled.
828 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
829 BASIC_CHECK_TOOLS(OBJCOPY, [gobjcopy objcopy])
830 # Only call fixup if objcopy was found.
831 if test -n "$OBJCOPY"; then
832 BASIC_FIXUP_EXECUTABLE(OBJCOPY)
833 if test "x$OPENJDK_BUILD_OS" = xsolaris; then
834 # objcopy prior to 2.21.1 on solaris is broken and is not usable.
835 # Rewrite objcopy version output to VALID_VERSION or BAD_VERSION.
836 # - version number is last blank separate word on first line
837 # - version number formats that have been seen:
838 # - <major>.<minor>
839 # - <major>.<minor>.<micro>
840 OBJCOPY_VERSION=`$OBJCOPY --version | $HEAD -n 1`
841 # The outer [ ] is to prevent m4 from eating the [] in the sed expression.
842 [ OBJCOPY_VERSION_CHECK=`$ECHO $OBJCOPY_VERSION | $SED -n \
843 -e 's/.* //' \
844 -e '/^[01]\./b bad' \
845 -e '/^2\./{' \
846 -e ' s/^2\.//' \
847 -e ' /^[0-9]$/b bad' \
848 -e ' /^[0-9]\./b bad' \
849 -e ' /^1[0-9]$/b bad' \
850 -e ' /^1[0-9]\./b bad' \
851 -e ' /^20\./b bad' \
852 -e ' /^21\.0$/b bad' \
853 -e ' /^21\.0\./b bad' \
854 -e '}' \
855 -e ':good' \
856 -e 's/.*/VALID_VERSION/p' \
857 -e 'q' \
858 -e ':bad' \
859 -e 's/.*/BAD_VERSION/p' \
860 -e 'q'` ]
861 if test "x$OBJCOPY_VERSION_CHECK" = xBAD_VERSION; then
862 OBJCOPY=
863 AC_MSG_WARN([Ignoring found objcopy since it is broken (prior to 2.21.1). No debug symbols will be generated.])
864 AC_MSG_NOTICE([objcopy reports version $OBJCOPY_VERSION])
865 AC_MSG_NOTICE([Note: patch 149063-01 or newer contains the correct Solaris 10 SPARC version])
866 AC_MSG_NOTICE([Note: patch 149064-01 or newer contains the correct Solaris 10 X86 version])
867 AC_MSG_NOTICE([Note: Solaris 11 Update 1 contains the correct version])
868 fi
869 fi
870 fi
871 fi
872
873 BASIC_CHECK_TOOLS(OBJDUMP, [gobjdump objdump])
874 if test "x$OBJDUMP" != x; then
875 # Only used for compare.sh; we can live without it. BASIC_FIXUP_EXECUTABLE
876 # bails if argument is missing.
877 BASIC_FIXUP_EXECUTABLE(OBJDUMP)
878 fi
879
880 case $TOOLCHAIN_TYPE in
881 gcc|clang|solstudio)
882 BASIC_CHECK_TOOLS(CXXFILT, [c++filt])
883 BASIC_CHECK_NONEMPTY(CXXFILT)
884 BASIC_FIXUP_EXECUTABLE(CXXFILT)
885 ;;
886 esac
887 ])
888
889 # Setup the build tools (i.e, the compiler and linker used to build programs
890 # that should be run on the build platform, not the target platform, as a build
891 # helper). Since the non-cross-compile case uses the normal, target compilers
892 # for this, we can only do this after these have been setup.
893 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_BUILD_COMPILERS],
894 [
895 if test "x$COMPILE_TYPE" = "xcross"; then
896 # Now we need to find a C/C++ compiler that can build executables for the
897 # build platform. We can't use the AC_PROG_CC macro, since it can only be
898 # used once. Also, we need to do this without adding a tools dir to the
899 # path, otherwise we might pick up cross-compilers which don't use standard
900 # naming.
901
902 OLDPATH="$PATH"
903
904 AC_ARG_WITH(build-devkit, [AS_HELP_STRING([--with-build-devkit],
905 [Devkit to use for the build platform toolchain])])
906 if test "x$with_build_devkit" = "xyes"; then
907 AC_MSG_ERROR([--with-build-devkit must have a value])
908 elif test -n "$with_build_devkit"; then
909 if test ! -d "$with_build_devkit"; then
910 AC_MSG_ERROR([--with-build-devkit points to non existing dir: $with_build_devkit])
911 else
912 BASIC_FIXUP_PATH([with_build_devkit])
913 BUILD_DEVKIT_ROOT="$with_build_devkit"
914 # Check for a meta data info file in the root of the devkit
915 if test -f "$BUILD_DEVKIT_ROOT/devkit.info"; then
916 # Process devkit.info so that existing devkit variables are not
917 # modified by this
918 $SED -e "s/^DEVKIT_/BUILD_DEVKIT_/g" \
919 -e "s/\$DEVKIT_ROOT/\$BUILD_DEVKIT_ROOT/g" \
920 -e "s/\$host/\$build/g" \
921 $BUILD_DEVKIT_ROOT/devkit.info \
922 > $CONFIGURESUPPORT_OUTPUTDIR/build-devkit.info
923 . $CONFIGURESUPPORT_OUTPUTDIR/build-devkit.info
924 # This potentially sets the following:
925 # A descriptive name of the devkit
926 BASIC_EVAL_DEVKIT_VARIABLE([BUILD_DEVKIT_NAME])
927 # Corresponds to --with-extra-path
928 BASIC_EVAL_DEVKIT_VARIABLE([BUILD_DEVKIT_EXTRA_PATH])
929 # Corresponds to --with-toolchain-path
930 BASIC_EVAL_DEVKIT_VARIABLE([BUILD_DEVKIT_TOOLCHAIN_PATH])
931 # Corresponds to --with-sysroot
932 BASIC_EVAL_DEVKIT_VARIABLE([BUILD_DEVKIT_SYSROOT])
933 # Skip the Window specific parts
934 fi
935
936 AC_MSG_CHECKING([for build platform devkit])
937 if test "x$BUILD_DEVKIT_NAME" != x; then
938 AC_MSG_RESULT([$BUILD_DEVKIT_NAME in $BUILD_DEVKIT_ROOT])
939 else
940 AC_MSG_RESULT([$BUILD_DEVKIT_ROOT])
941 fi
942
943 BUILD_SYSROOT="$BUILD_DEVKIT_SYSROOT"
944
945 # Fallback default of just /bin if DEVKIT_PATH is not defined
946 if test "x$BUILD_DEVKIT_TOOLCHAIN_PATH" = x; then
947 BUILD_DEVKIT_TOOLCHAIN_PATH="$BUILD_DEVKIT_ROOT/bin"
948 fi
949 PATH="$BUILD_DEVKIT_TOOLCHAIN_PATH:$BUILD_DEVKIT_EXTRA_PATH"
950 fi
951 fi
952
953 # FIXME: we should list the discovered compilers as an exclude pattern!
954 # If we do that, we can do this detection before POST_DETECTION, and still
955 # find the build compilers in the tools dir, if needed.
956 BASIC_REQUIRE_PROGS(BUILD_CC, [cl cc gcc])
957 BASIC_FIXUP_EXECUTABLE(BUILD_CC)
958 BASIC_REQUIRE_PROGS(BUILD_CXX, [cl CC g++])
959 BASIC_FIXUP_EXECUTABLE(BUILD_CXX)
960 BASIC_PATH_PROGS(BUILD_NM, nm gcc-nm)
961 BASIC_FIXUP_EXECUTABLE(BUILD_NM)
962 BASIC_PATH_PROGS(BUILD_AR, ar gcc-ar)
963 BASIC_FIXUP_EXECUTABLE(BUILD_AR)
964 BASIC_PATH_PROGS(BUILD_OBJCOPY, objcopy)
965 BASIC_FIXUP_EXECUTABLE(BUILD_OBJCOPY)
966 BASIC_PATH_PROGS(BUILD_STRIP, strip)
967 BASIC_FIXUP_EXECUTABLE(BUILD_STRIP)
968 # Assume the C compiler is the assembler
969 BUILD_AS="$BUILD_CC -c"
970 # Just like for the target compiler, use the compiler as linker
971 BUILD_LD="$BUILD_CC"
972 BUILD_LDCXX="$BUILD_CXX"
973
974 PATH="$OLDPATH"
975
976 TOOLCHAIN_EXTRACT_COMPILER_VERSION(BUILD_CC, [BuildC])
977 TOOLCHAIN_EXTRACT_COMPILER_VERSION(BUILD_CXX, [BuildC++])
978 TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS([BUILD_], [OPENJDK_BUILD_])
979 TOOLCHAIN_EXTRACT_LD_VERSION(BUILD_LD, [build linker])
980 TOOLCHAIN_PREPARE_FOR_LD_VERSION_COMPARISONS([BUILD_], [OPENJDK_BUILD_])
981 else
982 # If we are not cross compiling, use the normal target compilers for
983 # building the build platform executables.
984 BUILD_CC="$CC"
985 BUILD_CXX="$CXX"
986 BUILD_LD="$LD"
987 BUILD_LDCXX="$LDCXX"
988 BUILD_NM="$NM"
989 BUILD_AS="$AS"
990 BUILD_OBJCOPY="$OBJCOPY"
991 BUILD_STRIP="$STRIP"
992 BUILD_AR="$AR"
993
994 TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS([], [OPENJDK_BUILD_])
995 TOOLCHAIN_PREPARE_FOR_LD_VERSION_COMPARISONS([BUILD_], [OPENJDK_BUILD_])
996 fi
997
998 AC_SUBST(BUILD_CC)
999 AC_SUBST(BUILD_CXX)
1000 AC_SUBST(BUILD_LD)
1001 AC_SUBST(BUILD_LDCXX)
1002 AC_SUBST(BUILD_NM)
1003 AC_SUBST(BUILD_AS)
1004 AC_SUBST(BUILD_AR)
1005 ])
1006
1007 # Do some additional checks on the detected tools.
1008 AC_DEFUN_ONCE([TOOLCHAIN_MISC_CHECKS],
1009 [
1010 # Check for extra potential brokenness.
1011 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
1012 # On Windows, double-check that we got the right compiler.
1013 CC_VERSION_OUTPUT=`$CC 2>&1 | $GREP -v 'ERROR.*UtilTranslatePathList' | $HEAD -n 1 | $TR -d '\r'`
1014 COMPILER_CPU_TEST=`$ECHO $CC_VERSION_OUTPUT | $SED -n "s/^.* \(.*\)$/\1/p"`
1015 if test "x$OPENJDK_TARGET_CPU" = "xx86"; then
1016 if test "x$COMPILER_CPU_TEST" != "x80x86" -a "x$COMPILER_CPU_TEST" != "xx86"; then
1017 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "80x86" or "x86".])
1018 fi
1019 elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
1020 if test "x$COMPILER_CPU_TEST" != "xx64"; then
1021 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "x64".])
1022 fi
1023 fi
1024 fi
1025
1026 if test "x$TOOLCHAIN_TYPE" = xgcc; then
1027 # If this is a --hash-style=gnu system, use --hash-style=both, why?
1028 HAS_GNU_HASH=`$CC -dumpspecs 2>/dev/null | $GREP 'hash-style=gnu'`
1029 # This is later checked when setting flags.
1030 fi
1031
1032 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
1033 # Check if linker has -z noexecstack.
1034 HAS_NOEXECSTACK=`$CC -Wl,--help 2>/dev/null | $GREP 'z noexecstack'`
1035 # This is later checked when setting flags.
1036 fi
1037
1038 # Setup hotspot lecagy names for toolchains
1039 HOTSPOT_TOOLCHAIN_TYPE=$TOOLCHAIN_TYPE
1040 if test "x$TOOLCHAIN_TYPE" = xclang; then
1041 HOTSPOT_TOOLCHAIN_TYPE=gcc
1042 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
1043 HOTSPOT_TOOLCHAIN_TYPE=visCPP
1044 fi
1045 AC_SUBST(HOTSPOT_TOOLCHAIN_TYPE)
1046 ])
1047
1048 # Setup the JTReg Regression Test Harness.
1049 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JTREG],
1050 [
1051 AC_ARG_WITH(jtreg, [AS_HELP_STRING([--with-jtreg],
1052 [Regression Test Harness @<:@probed@:>@])])
1053
1054 if test "x$with_jtreg" = xno; then
1055 # jtreg disabled
1056 AC_MSG_CHECKING([for jtreg test harness])
1057 AC_MSG_RESULT([no, disabled])
1058 elif test "x$with_jtreg" != xyes && test "x$with_jtreg" != x; then
1059 # An explicit path is specified, use it.
1060 JT_HOME="$with_jtreg"
1061 BASIC_FIXUP_PATH([JT_HOME])
1062 if test ! -d "$JT_HOME"; then
1063 AC_MSG_ERROR([jtreg home directory from --with-jtreg=$with_jtreg does not exist])
1064 fi
1065
1066 if test ! -e "$JT_HOME/lib/jtreg.jar"; then
1067 AC_MSG_ERROR([jtreg home directory from --with-jtreg=$with_jtreg is not a valid jtreg home])
1068 fi
1069
1070 JTREGEXE="$JT_HOME/bin/jtreg"
1071 if test ! -x "$JTREGEXE"; then
1072 AC_MSG_ERROR([jtreg home directory from --with-jtreg=$with_jtreg does not contain valid jtreg executable])
1073 fi
1074
1075 AC_MSG_CHECKING([for jtreg test harness])
1076 AC_MSG_RESULT([$JT_HOME])
1077 else
1078 # Try to locate jtreg
1079 if test "x$JT_HOME" != x; then
1080 # JT_HOME set in environment, use it
1081 if test ! -d "$JT_HOME"; then
1082 AC_MSG_WARN([Ignoring JT_HOME pointing to invalid directory: $JT_HOME])
1083 JT_HOME=
1084 else
1085 if test ! -e "$JT_HOME/lib/jtreg.jar"; then
1086 AC_MSG_WARN([Ignoring JT_HOME which is not a valid jtreg home: $JT_HOME])
1087 JT_HOME=
1088 elif test ! -x "$JT_HOME/bin/jtreg"; then
1089 AC_MSG_WARN([Ignoring JT_HOME which does not contain valid jtreg executable: $JT_HOME])
1090 JT_HOME=
1091 else
1092 JTREGEXE="$JT_HOME/bin/jtreg"
1093 AC_MSG_NOTICE([Located jtreg using JT_HOME from environment])
1094 fi
1095 fi
1096 fi
1097
1098 if test "x$JT_HOME" = x; then
1099 # JT_HOME is not set in environment, or was deemed invalid.
1100 # Try to find jtreg on path
1101 BASIC_PATH_PROGS(JTREGEXE, jtreg)
1102 if test "x$JTREGEXE" != x; then
1103 # That's good, now try to derive JT_HOME
1104 JT_HOME=`(cd $($DIRNAME $JTREGEXE)/.. && pwd)`
1105 if test ! -e "$JT_HOME/lib/jtreg.jar"; then
1106 AC_MSG_WARN([Ignoring jtreg from path since a valid jtreg home cannot be found])
1107 JT_HOME=
1108 JTREGEXE=
1109 else
1110 AC_MSG_NOTICE([Located jtreg using jtreg executable in path])
1111 fi
1112 fi
1113 fi
1114
1115 AC_MSG_CHECKING([for jtreg test harness])
1116 if test "x$JT_HOME" != x; then
1117 AC_MSG_RESULT([$JT_HOME])
1118 else
1119 AC_MSG_RESULT([no, not found])
1120
1121 if test "x$with_jtreg" = xyes; then
1122 AC_MSG_ERROR([--with-jtreg was specified, but no jtreg found.])
1123 fi
1124 fi
1125 fi
1126
1127 BASIC_FIXUP_EXECUTABLE(JTREGEXE)
1128 BASIC_FIXUP_PATH(JT_HOME)
1129 AC_SUBST(JT_HOME)
1130 AC_SUBST(JTREGEXE)
1131 ])
1132
1133 # Setup the JIB dependency resolver
1134 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JIB],
1135 [
1136 AC_ARG_WITH(jib, [AS_HELP_STRING([--with-jib],
1137 [Jib dependency management tool @<:@not used@:>@])])
1138
1139 if test "x$with_jib" = xno || test "x$with_jib" = x; then
1140 # jib disabled
1141 AC_MSG_CHECKING([for jib])
1142 AC_MSG_RESULT(no)
1143 elif test "x$with_jib" = xyes; then
1144 AC_MSG_ERROR([Must supply a value to --with-jib])
1145 else
1146 JIB_HOME="${with_jib}"
1147 AC_MSG_CHECKING([for jib])
1148 AC_MSG_RESULT(${JIB_HOME})
1149 if test ! -d "${JIB_HOME}"; then
1150 AC_MSG_ERROR([--with-jib must be a directory])
1151 fi
1152 JIB_JAR=$(ls ${JIB_HOME}/lib/jib-*.jar)
1153 if test ! -f "${JIB_JAR}"; then
1154 AC_MSG_ERROR([Could not find jib jar file in ${JIB_HOME}])
1155 fi
1156 fi
1157
1158 AC_SUBST(JIB_HOME)
1159 ])