1 #
2 # Copyright (c) 2011, 2020, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 AC_DEFUN([BPERF_CHECK_CORES],
27 [
28 AC_MSG_CHECKING([for number of cores])
29 NUM_CORES=1
30 FOUND_CORES=no
31
32 if test -f /proc/cpuinfo; then
33 # Looks like a Linux (or cygwin) system
34 NUM_CORES=`cat /proc/cpuinfo | grep -c processor`
35 FOUND_CORES=yes
36 elif test -x /usr/sbin/psrinfo; then
37 # Looks like a Solaris system
38 NUM_CORES=`/usr/sbin/psrinfo -v | grep -c on-line`
39 FOUND_CORES=yes
40 elif test -x /usr/sbin/sysctl; then
41 # Looks like a MacOSX system
42 NUM_CORES=`/usr/sbin/sysctl -n hw.ncpu`
43 FOUND_CORES=yes
44 elif test "x$OPENJDK_BUILD_OS" = xaix ; then
45 NUM_LCPU=`lparstat -m 2> /dev/null | $GREP -o "lcpu=[[0-9]]*" | $CUT -d "=" -f 2`
46 if test -n "$NUM_LCPU"; then
47 NUM_CORES=$NUM_LCPU
48 FOUND_CORES=yes
49 fi
50 elif test -n "$NUMBER_OF_PROCESSORS"; then
51 # On windows, look in the env
52 NUM_CORES=$NUMBER_OF_PROCESSORS
53 FOUND_CORES=yes
54 fi
55
56 if test "x$FOUND_CORES" = xyes; then
57 AC_MSG_RESULT([$NUM_CORES])
58 else
59 AC_MSG_RESULT([could not detect number of cores, defaulting to 1])
60 AC_MSG_WARN([This will disable all parallelism from build!])
61 fi
62 ])
63
64 AC_DEFUN([BPERF_CHECK_MEMORY_SIZE],
65 [
66 AC_MSG_CHECKING([for memory size])
67 # Default to 1024 MB
68 MEMORY_SIZE=1024
69 FOUND_MEM=no
70
71 if test -f /proc/meminfo; then
72 # Looks like a Linux (or cygwin) system
73 MEMORY_SIZE=`cat /proc/meminfo | grep MemTotal | awk '{print [$]2}'`
74 MEMORY_SIZE=`expr $MEMORY_SIZE / 1024`
75 FOUND_MEM=yes
76 elif test -x /usr/sbin/prtconf; then
77 # Looks like a Solaris or AIX system
78 MEMORY_SIZE=`/usr/sbin/prtconf 2> /dev/null | grep "^Memory [[Ss]]ize" | awk '{ print [$]3 }'`
79 FOUND_MEM=yes
80 elif test -x /usr/sbin/sysctl; then
81 # Looks like a MacOSX system
82 MEMORY_SIZE=`/usr/sbin/sysctl -n hw.memsize`
83 MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`
84 FOUND_MEM=yes
85 elif test "x$OPENJDK_BUILD_OS" = xwindows; then
86 # Windows, but without cygwin
87 MEMORY_SIZE=`wmic computersystem get totalphysicalmemory -value | grep = | cut -d "=" -f 2-`
88 MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`
89 FOUND_MEM=yes
90 fi
91
92 if test "x$FOUND_MEM" = xyes; then
93 AC_MSG_RESULT([$MEMORY_SIZE MB])
94 else
95 AC_MSG_RESULT([could not detect memory size, defaulting to $MEMORY_SIZE MB])
96 AC_MSG_WARN([This might seriously impact build performance!])
97 fi
98 ])
99
100 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_CORES],
101 [
102 # How many cores do we have on this build system?
103 AC_ARG_WITH(num-cores, [AS_HELP_STRING([--with-num-cores],
104 [number of cores in the build system, e.g. --with-num-cores=8 @<:@probed@:>@])])
105 if test "x$with_num_cores" = x; then
106 # The number of cores were not specified, try to probe them.
107 BPERF_CHECK_CORES
108 else
109 NUM_CORES=$with_num_cores
110 fi
111 AC_SUBST(NUM_CORES)
112 ])
113
114 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_MEMORY],
115 [
116 # How much memory do we have on this build system?
117 AC_ARG_WITH(memory-size, [AS_HELP_STRING([--with-memory-size],
118 [memory (in MB) available in the build system, e.g. --with-memory-size=1024 @<:@probed@:>@])])
119 if test "x$with_memory_size" = x; then
120 # The memory size was not specified, try to probe it.
121 BPERF_CHECK_MEMORY_SIZE
122 else
123 MEMORY_SIZE=$with_memory_size
124 fi
125 AC_SUBST(MEMORY_SIZE)
126 ])
127
128 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_JOBS],
129 [
130 # Provide a decent default number of parallel jobs for make depending on
131 # number of cores, amount of memory and machine architecture.
132 AC_ARG_WITH(jobs, [AS_HELP_STRING([--with-jobs],
133 [number of parallel jobs to let make run @<:@calculated based on cores and memory@:>@])])
134 if test "x$with_jobs" = x; then
135 # Number of jobs was not specified, calculate.
136 AC_MSG_CHECKING([for appropriate number of jobs to run in parallel])
137 # Approximate memory in GB.
138 memory_gb=`expr $MEMORY_SIZE / 1024`
139 # Pick the lowest of memory in gb and number of cores.
140 if test "$memory_gb" -lt "$NUM_CORES"; then
141 JOBS="$memory_gb"
142 else
143 JOBS="$NUM_CORES"
144 fi
145 if test "$JOBS" -eq "0"; then
146 JOBS=1
147 fi
148 AC_MSG_RESULT([$JOBS])
149 else
150 JOBS=$with_jobs
151 fi
152 AC_SUBST(JOBS)
153 ])
154
155 AC_DEFUN_ONCE([BPERF_SETUP_TEST_JOBS],
156 [
157 # The number of test jobs will be chosen automatically if TEST_JOBS is 0
158 AC_ARG_WITH(test-jobs, [AS_HELP_STRING([--with-test-jobs],
159 [number of parallel tests jobs to run @<:@based on build jobs@:>@])])
160 if test "x$with_test_jobs" = x; then
161 TEST_JOBS=0
162 else
163 TEST_JOBS=$with_test_jobs
164 fi
165 AC_SUBST(TEST_JOBS)
166 ])
167
168 AC_DEFUN([BPERF_SETUP_CCACHE],
169 [
170 # Check if ccache is available
171 CCACHE_AVAILABLE=true
172
173 OLD_PATH="$PATH"
174 if test "x$TOOLCHAIN_PATH" != x; then
175 PATH=$TOOLCHAIN_PATH:$PATH
176 fi
177 UTIL_PATH_PROGS(CCACHE, ccache)
178 PATH="$OLD_PATH"
179
180 AC_MSG_CHECKING([if ccache is available])
181 if test "x$TOOLCHAIN_TYPE" != "xgcc" && test "x$TOOLCHAIN_TYPE" != "xclang"; then
182 AC_MSG_RESULT([no, not supported for toolchain type $TOOLCHAIN_TYPE])
183 CCACHE_AVAILABLE=false
184 elif test "x$CCACHE" = "x"; then
185 AC_MSG_RESULT([no, ccache binary missing or not executable])
186 CCACHE_AVAILABLE=false
187 else
188 AC_MSG_RESULT([yes])
189 fi
190
191 CCACHE_STATUS=""
192 UTIL_ARG_ENABLE(NAME: ccache, DEFAULT: false, AVAILABLE: $CCACHE_AVAILABLE,
193 DESC: [enable using ccache to speed up recompilations],
194 CHECKING_MSG: [if ccache is enabled],
195 IF_ENABLED: [
196 CCACHE_VERSION=[`$CCACHE --version | head -n1 | $SED 's/[A-Za-z ]*//'`]
197 CCACHE_STATUS="Active ($CCACHE_VERSION)"
198 ],
199 IF_DISABLED: [
200 CCACHE=""
201 ])
202 AC_SUBST(CCACHE)
203
204 AC_ARG_WITH([ccache-dir],
205 [AS_HELP_STRING([--with-ccache-dir],
206 [where to store ccache files @<:@~/.ccache@:>@])])
207
208 if test "x$with_ccache_dir" != x; then
209 # When using a non home ccache directory, assume the use is to share ccache files
210 # with other users. Thus change the umask.
211 SET_CCACHE_DIR="CCACHE_DIR=$with_ccache_dir CCACHE_UMASK=002"
212 if test "x$CCACHE" = x; then
213 AC_MSG_WARN([--with-ccache-dir has no meaning when ccache is not enabled])
214 fi
215 fi
216
217 if test "x$CCACHE" != x; then
218 BPERF_SETUP_CCACHE_USAGE
219 fi
220 ])
221
222 AC_DEFUN([BPERF_SETUP_CCACHE_USAGE],
223 [
224 if test "x$CCACHE" != x; then
225 if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then
226 HAS_BAD_CCACHE=[`$ECHO $CCACHE_VERSION | \
227 $GREP -e '^1\.' -e '^2\.' -e '^3\.0\.' -e '^3\.1\.'`]
228 if test "x$HAS_BAD_CCACHE" != "x"; then
229 AC_MSG_ERROR([On macosx, ccache 3.2 or later is required, found $CCACHE_VERSION])
230 fi
231 fi
232 if test "x$USE_PRECOMPILED_HEADER" = "xtrue"; then
233 HAS_BAD_CCACHE=[`$ECHO $CCACHE_VERSION | \
234 $GREP -e '^1.*' -e '^2.*' -e '^3\.0.*' -e '^3\.1\.[0123]$'`]
235 if test "x$HAS_BAD_CCACHE" != "x"; then
236 AC_MSG_ERROR([Precompiled headers requires ccache 3.1.4 or later, found $CCACHE_VERSION])
237 fi
238 AC_MSG_CHECKING([if C-compiler supports ccache precompiled headers])
239 CCACHE_PRECOMP_FLAG="-fpch-preprocess"
240 PUSHED_FLAGS="$CXXFLAGS"
241 CXXFLAGS="$CCACHE_PRECOMP_FLAG $CXXFLAGS"
242 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [CC_KNOWS_CCACHE_TRICK=yes], [CC_KNOWS_CCACHE_TRICK=no])
243 CXXFLAGS="$PUSHED_FLAGS"
244 if test "x$CC_KNOWS_CCACHE_TRICK" = xyes; then
245 AC_MSG_RESULT([yes])
246 CFLAGS_CCACHE="$CCACHE_PRECOMP_FLAG"
247 AC_SUBST(CFLAGS_CCACHE)
248 CCACHE_SLOPPINESS=pch_defines,time_macros
249 else
250 AC_MSG_RESULT([no])
251 AC_MSG_ERROR([Cannot use ccache with precompiled headers without compiler support for $CCACHE_PRECOMP_FLAG])
252 fi
253 fi
254
255 CCACHE="CCACHE_COMPRESS=1 $SET_CCACHE_DIR \
256 CCACHE_SLOPPINESS=$CCACHE_SLOPPINESS CCACHE_BASEDIR=$TOPDIR $CCACHE"
257
258 if test "x$SET_CCACHE_DIR" != x; then
259 mkdir -p $CCACHE_DIR > /dev/null 2>&1
260 chmod a+rwxs $CCACHE_DIR > /dev/null 2>&1
261 fi
262 fi
263 ])
264
265 ################################################################################
266 #
267 # Runs icecc-create-env once and prints the error if it fails
268 #
269 # $1: arguments to icecc-create-env
270 # $2: log file
271 #
272 AC_DEFUN([BPERF_RUN_ICECC_CREATE_ENV],
273 [
274 ( cd ${CONFIGURESUPPORT_OUTPUTDIR}/icecc \
275 && ${ICECC_CREATE_ENV} $1 > $2 2>&1 )
276 if test "$?" != "0"; then
277 AC_MSG_NOTICE([icecc-create-env output:])
278 cat $2
279 AC_MSG_ERROR([Failed to create icecc compiler environment])
280 fi
281 ])
282
283 ################################################################################
284 #
285 # Optionally enable distributed compilation of native code using icecc/icecream
286 #
287 AC_DEFUN([BPERF_SETUP_ICECC],
288 [
289 UTIL_ARG_ENABLE(NAME: icecc, DEFAULT: false, RESULT: ENABLE_ICECC,
290 DESC: [enable distributed compilation of native code using icecc/icecream])
291
292 if test "x$ENABLE_ICECC" = "xtrue"; then
293 UTIL_REQUIRE_PROGS(ICECC_CMD, icecc)
294 old_path="$PATH"
295
296 # Look for icecc-create-env in some known places
297 PATH="$PATH:/usr/lib/icecc:/usr/lib64/icecc"
298 UTIL_REQUIRE_PROGS(ICECC_CREATE_ENV, icecc-create-env)
299 # Use icecc-create-env to create a minimal compilation environment that can
300 # be sent to the other hosts in the icecream cluster.
301 icecc_create_env_log="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/icecc_create_env.log"
302 ${MKDIR} -p ${CONFIGURESUPPORT_OUTPUTDIR}/icecc
303 # Older versions of icecc does not have the --gcc parameter
304 if ${ICECC_CREATE_ENV} | $GREP -q -e --gcc; then
305 icecc_gcc_arg="--gcc"
306 fi
307 if test "x${TOOLCHAIN_TYPE}" = "xgcc"; then
308 BPERF_RUN_ICECC_CREATE_ENV([${icecc_gcc_arg} ${CC} ${CXX}], \
309 ${icecc_create_env_log})
310 elif test "x$TOOLCHAIN_TYPE" = "xclang"; then
311 # For clang, the icecc compilerwrapper is needed. It usually resides next
312 # to icecc-create-env.
313 UTIL_REQUIRE_PROGS(ICECC_WRAPPER, compilerwrapper)
314 BPERF_RUN_ICECC_CREATE_ENV([--clang ${CC} ${ICECC_WRAPPER}], ${icecc_create_env_log})
315 else
316 AC_MSG_ERROR([Can only create icecc compiler packages for toolchain types gcc and clang])
317 fi
318 PATH="$old_path"
319 # The bundle with the compiler gets a name based on checksums. Parse log file
320 # to find it.
321 ICECC_ENV_BUNDLE_BASENAME="`${SED} -n '/^creating/s/creating //p' ${icecc_create_env_log}`"
322 ICECC_ENV_BUNDLE="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/${ICECC_ENV_BUNDLE_BASENAME}"
323 if test ! -f ${ICECC_ENV_BUNDLE}; then
324 AC_MSG_ERROR([icecc-create-env did not produce an environment ${ICECC_ENV_BUNDLE}])
325 fi
326 AC_MSG_CHECKING([for icecc build environment for target compiler])
327 AC_MSG_RESULT([${ICECC_ENV_BUNDLE}])
328 ICECC="ICECC_VERSION=${ICECC_ENV_BUNDLE} ICECC_CC=${CC} ICECC_CXX=${CXX} ${ICECC_CMD}"
329
330 if test "x${COMPILE_TYPE}" = "xcross"; then
331 # If cross compiling, create a separate env package for the build compiler
332 # Assume "gcc" or "cc" is gcc and "clang" is clang. Otherwise bail.
333 icecc_create_env_log_build="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/icecc_create_env_build.log"
334 if test "x${BUILD_CC##*/}" = "xgcc" || test "x${BUILD_CC##*/}" = "xcc"; then
335 BPERF_RUN_ICECC_CREATE_ENV([${icecc_gcc_arg} ${BUILD_CC} ${BUILD_CXX}], \
336 ${icecc_create_env_log_build})
337 elif test "x${BUILD_CC##*/}" = "xclang"; then
338 BPERF_RUN_ICECC_CREATE_ENV([--clang ${BUILD_CC} ${ICECC_WRAPPER}], ${icecc_create_env_log_build})
339 else
340 AC_MSG_ERROR([Cannot create icecc compiler package for ${BUILD_CC}])
341 fi
342 ICECC_ENV_BUNDLE_BASENAME="`${SED} -n '/^creating/s/creating //p' ${icecc_create_env_log_build}`"
343 ICECC_ENV_BUNDLE="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/${ICECC_ENV_BUNDLE_BASENAME}"
344 if test ! -f ${ICECC_ENV_BUNDLE}; then
345 AC_MSG_ERROR([icecc-create-env did not produce an environment ${ICECC_ENV_BUNDLE}])
346 fi
347 AC_MSG_CHECKING([for icecc build environment for build compiler])
348 AC_MSG_RESULT([${ICECC_ENV_BUNDLE}])
349 BUILD_ICECC="ICECC_VERSION=${ICECC_ENV_BUNDLE} ICECC_CC=${BUILD_CC} \
350 ICECC_CXX=${BUILD_CXX} ${ICECC_CMD}"
351 else
352 BUILD_ICECC="${ICECC}"
353 fi
354 fi
355
356 AC_SUBST(ICECC)
357 AC_SUBST(BUILD_ICECC)
358 ])
359
360 AC_DEFUN_ONCE([BPERF_SETUP_PRECOMPILED_HEADERS],
361 [
362 # Are precompiled headers available?
363 PRECOMPILED_HEADERS_AVAILABLE=true
364 AC_MSG_CHECKING([if precompiled headers are available])
365 if test "x$ICECC" != "x"; then
366 AC_MSG_RESULT([no, does not work effectively with icecc])
367 PRECOMPILED_HEADERS_AVAILABLE=false
368 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
369 AC_MSG_RESULT([no, does not work with Solaris Studio])
370 PRECOMPILED_HEADERS_AVAILABLE=false
371 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
372 AC_MSG_RESULT([no, does not work with xlc])
373 PRECOMPILED_HEADERS_AVAILABLE=false
374 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
375 # Check that the compiler actually supports precomp headers.
376 echo "int alfa();" > conftest.h
377 $CXX -x c++-header conftest.h -o conftest.hpp.gch 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
378 if test ! -f conftest.hpp.gch; then
379 PRECOMPILED_HEADERS_AVAILABLE=false
380 AC_MSG_RESULT([no, gcc fails to compile properly with -x c++-header])
381 else
382 AC_MSG_RESULT([yes])
383 fi
384 $RM conftest.h conftest.hpp.gch
385 else
386 AC_MSG_RESULT([yes])
387 fi
388
389 UTIL_ARG_ENABLE(NAME: precompiled-headers, DEFAULT: auto,
390 RESULT: USE_PRECOMPILED_HEADER, AVAILABLE: $PRECOMPILED_HEADERS_AVAILABLE,
391 DESC: [enable using precompiled headers when compiling C++])
392 AC_SUBST(USE_PRECOMPILED_HEADER)
393 ])
394
395
396 AC_DEFUN_ONCE([BPERF_SETUP_JAVAC_SERVER],
397 [
398 UTIL_ARG_ENABLE(NAME: javac-server, DEFAULT: true,
399 RESULT: ENABLE_JAVAC_SERVER,
400 DESC: [enable javac server],
401 CHECKING_MSG: [whether to use javac server])
402 AC_SUBST(ENABLE_JAVAC_SERVER)
403 ])