1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 m4_include([flags-cflags.m4])
27 m4_include([flags-ldflags.m4])
28 m4_include([flags-other.m4])
29
30 ################################################################################
31 #
32 # Setup ABI profile (for arm)
33 #
34 AC_DEFUN([FLAGS_SETUP_ABI_PROFILE],
35 [
36 AC_ARG_WITH(abi-profile, [AS_HELP_STRING([--with-abi-profile],
37 [specify ABI profile for ARM builds (arm-vfp-sflt,arm-vfp-hflt,arm-sflt, armv5-vfp-sflt,armv6-vfp-hflt,arm64,aarch64) @<:@toolchain dependent@:>@ ])])
38
39 if test "x$with_abi_profile" != x; then
40 if test "x$OPENJDK_TARGET_CPU" != xarm && \
41 test "x$OPENJDK_TARGET_CPU" != xaarch64; then
42 AC_MSG_ERROR([--with-abi-profile only available on arm/aarch64])
43 fi
44
45 OPENJDK_TARGET_ABI_PROFILE=$with_abi_profile
46 AC_MSG_CHECKING([for ABI profle])
47 AC_MSG_RESULT([$OPENJDK_TARGET_ABI_PROFILE])
48
49 if test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm-vfp-sflt; then
50 ARM_FLOAT_TYPE=vfp-sflt
51 ARM_ARCH_TYPE_FLAGS='-march=armv7-a -mthumb'
52 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm-vfp-hflt; then
53 ARM_FLOAT_TYPE=vfp-hflt
54 ARM_ARCH_TYPE_FLAGS='-march=armv7-a -mthumb'
55 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm-sflt; then
56 ARM_FLOAT_TYPE=sflt
57 ARM_ARCH_TYPE_FLAGS='-march=armv5t -marm'
58 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarmv5-vfp-sflt; then
59 ARM_FLOAT_TYPE=vfp-sflt
60 ARM_ARCH_TYPE_FLAGS='-march=armv5t -marm'
61 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarmv6-vfp-hflt; then
62 ARM_FLOAT_TYPE=vfp-hflt
63 ARM_ARCH_TYPE_FLAGS='-march=armv6 -marm'
64 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm64; then
65 # No special flags, just need to trigger setting JDK_ARCH_ABI_PROP_NAME
66 ARM_FLOAT_TYPE=
67 ARM_ARCH_TYPE_FLAGS=
68 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xaarch64; then
69 # No special flags, just need to trigger setting JDK_ARCH_ABI_PROP_NAME
70 ARM_FLOAT_TYPE=
71 ARM_ARCH_TYPE_FLAGS=
72 else
73 AC_MSG_ERROR([Invalid ABI profile: "$OPENJDK_TARGET_ABI_PROFILE"])
74 fi
75
76 if test "x$ARM_FLOAT_TYPE" = xvfp-sflt; then
77 ARM_FLOAT_TYPE_FLAGS='-mfloat-abi=softfp -mfpu=vfp -DFLOAT_ARCH=-vfp-sflt'
78 elif test "x$ARM_FLOAT_TYPE" = xvfp-hflt; then
79 ARM_FLOAT_TYPE_FLAGS='-mfloat-abi=hard -mfpu=vfp -DFLOAT_ARCH=-vfp-hflt'
80 elif test "x$ARM_FLOAT_TYPE" = xsflt; then
81 ARM_FLOAT_TYPE_FLAGS='-msoft-float -mfpu=vfp'
82 fi
83 AC_MSG_CHECKING([for $ARM_FLOAT_TYPE floating point flags])
84 AC_MSG_RESULT([$ARM_FLOAT_TYPE_FLAGS])
85
86 AC_MSG_CHECKING([for arch type flags])
87 AC_MSG_RESULT([$ARM_ARCH_TYPE_FLAGS])
88
89 # Now set JDK_ARCH_ABI_PROP_NAME. This is equivalent to the last part of the
90 # autoconf target triplet.
91 [ JDK_ARCH_ABI_PROP_NAME=`$ECHO $OPENJDK_TARGET_AUTOCONF_NAME | $SED -e 's/.*-\([^-]*\)$/\1/'` ]
92 # Sanity check that it is a known ABI.
93 if test "x$JDK_ARCH_ABI_PROP_NAME" != xgnu && \
94 test "x$JDK_ARCH_ABI_PROP_NAME" != xgnueabi && \
95 test "x$JDK_ARCH_ABI_PROP_NAME" != xgnueabihf; then
96 AC_MSG_WARN([Unknown autoconf target triplet ABI: "$JDK_ARCH_ABI_PROP_NAME"])
97 fi
98 AC_MSG_CHECKING([for ABI property name])
99 AC_MSG_RESULT([$JDK_ARCH_ABI_PROP_NAME])
100 AC_SUBST(JDK_ARCH_ABI_PROP_NAME)
101 fi
102
103 # When building with an abi profile, the name of that profile is appended on the
104 # bundle platform, which is used in bundle names.
105 if test "x$OPENJDK_TARGET_ABI_PROFILE" != x; then
106 OPENJDK_TARGET_BUNDLE_PLATFORM="$OPENJDK_TARGET_OS_BUNDLE-$OPENJDK_TARGET_ABI_PROFILE"
107 fi
108 ])
109
110 AC_DEFUN([FLAGS_SETUP_MACOSX_VERSION],
111 [
112 # Additional macosx handling
113 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
114 # MACOSX_VERSION_MIN specifies the lowest version of Macosx that the built
115 # binaries should be compatible with, even if compiled on a newer version
116 # of the OS. It currently has a hard coded value. Setting this also limits
117 # exposure to API changes in header files. Bumping this is likely to
118 # require code changes to build.
119 MACOSX_VERSION_MIN=10.9.0
120 MACOSX_VERSION_MIN_NODOTS=${MACOSX_VERSION_MIN//\./}
121
122 AC_SUBST(MACOSX_VERSION_MIN)
123
124 # Setting --with-macosx-version-max=<version> makes it an error to build or
125 # link to macosx APIs that are newer than the given OS version. The expected
126 # format for <version> is either nn.n.n or nn.nn.nn. See /usr/include/AvailabilityMacros.h.
127 AC_ARG_WITH([macosx-version-max], [AS_HELP_STRING([--with-macosx-version-max],
128 [error on use of newer functionality. @<:@macosx@:>@])],
129 [
130 if echo "$with_macosx_version_max" | $GREP -q "^[[0-9]][[0-9]]\.[[0-9]]\.[[0-9]]\$"; then
131 MACOSX_VERSION_MAX=$with_macosx_version_max
132 elif echo "$with_macosx_version_max" | $GREP -q "^[[0-9]][[0-9]]\.[[0-9]][[0-9]]\.[[0-9]][[0-9]]\$"; then
133 MACOSX_VERSION_MAX=$with_macosx_version_max
134 elif test "x$with_macosx_version_max" = "xno"; then
135 # Use build system default
136 MACOSX_VERSION_MAX=
137 else
138 AC_MSG_ERROR([osx version format must be nn.n.n or nn.nn.nn])
139 fi
140 ],
141 [MACOSX_VERSION_MAX=]
142 )
143 MACOSX_VERSION_MAX_NODOTS=${MACOSX_VERSION_MAX//\./}
144
145 AC_SUBST(MACOSX_VERSION_MAX)
146 fi
147 ])
148
149 # Reset the global CFLAGS/LDFLAGS variables and initialize them with the
150 # corresponding configure arguments instead
151 AC_DEFUN_ONCE([FLAGS_SETUP_USER_SUPPLIED_FLAGS],
152 [
153 if test "x$CFLAGS" != "x"; then
154 AC_MSG_WARN([Ignoring CFLAGS($CFLAGS) found in environment. Use --with-extra-cflags])
155 fi
156
157 if test "x$CXXFLAGS" != "x"; then
158 AC_MSG_WARN([Ignoring CXXFLAGS($CXXFLAGS) found in environment. Use --with-extra-cxxflags])
159 fi
160
161 if test "x$LDFLAGS" != "x"; then
162 AC_MSG_WARN([Ignoring LDFLAGS($LDFLAGS) found in environment. Use --with-extra-ldflags])
163 fi
164
165 if test "x$ASFLAGS" != "x"; then
166 AC_MSG_WARN([Ignoring ASFLAGS($ASFLAGS) found in environment. Use --with-extra-asflags])
167 fi
168
169 AC_ARG_WITH(extra-cflags, [AS_HELP_STRING([--with-extra-cflags],
170 [extra flags to be used when compiling jdk c-files])])
171
172 AC_ARG_WITH(extra-cxxflags, [AS_HELP_STRING([--with-extra-cxxflags],
173 [extra flags to be used when compiling jdk c++-files])])
174
175 AC_ARG_WITH(extra-ldflags, [AS_HELP_STRING([--with-extra-ldflags],
176 [extra flags to be used when linking jdk])])
177
178 AC_ARG_WITH(extra-asflags, [AS_HELP_STRING([--with-extra-asflags],
179 [extra flags to be passed to the assembler])])
180
181 USER_CFLAGS="$with_extra_cflags"
182 USER_CXXFLAGS="$with_extra_cxxflags"
183 USER_LDFLAGS="$with_extra_ldflags"
184 USER_ASFLAGS="$with_extra_asflags"
185 ])
186
187 # Setup the sysroot flags and add them to global CFLAGS and LDFLAGS so
188 # that configure can use them while detecting compilers.
189 # TOOLCHAIN_TYPE is available here.
190 # Param 1 - Optional prefix to all variables. (e.g BUILD_)
191 AC_DEFUN([FLAGS_SETUP_SYSROOT_FLAGS],
192 [
193 if test "x[$]$1SYSROOT" != "x"; then
194 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
195 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
196 # Solaris Studio does not have a concept of sysroot. Instead we must
197 # make sure the default include and lib dirs are appended to each
198 # compile and link command line. Must also add -I-xbuiltin to enable
199 # inlining of system functions and intrinsics.
200 $1SYSROOT_CFLAGS="-I-xbuiltin -I[$]$1SYSROOT/usr/include"
201 $1SYSROOT_LDFLAGS="-L[$]$1SYSROOT/usr/lib$OPENJDK_TARGET_CPU_ISADIR \
202 -L[$]$1SYSROOT/lib$OPENJDK_TARGET_CPU_ISADIR"
203 # If the devkit contains the ld linker, make sure we use it.
204 AC_PATH_PROG(SOLARIS_LD, ld, , $DEVKIT_TOOLCHAIN_PATH:$DEVKIT_EXTRA_PATH)
205 # Make sure this ld is runnable.
206 if test -f "$SOLARIS_LD"; then
207 if "$SOLARIS_LD" -V > /dev/null 2> /dev/null; then
208 $1SYSROOT_LDFLAGS="[$]$1SYSROOT_LDFLAGS -Yl,$(dirname $SOLARIS_LD)"
209 else
210 AC_MSG_WARN([Could not run $SOLARIS_LD found in devkit, reverting to system ld])
211 fi
212 fi
213 fi
214 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
215 $1SYSROOT_CFLAGS="--sysroot=[$]$1SYSROOT"
216 $1SYSROOT_LDFLAGS="--sysroot=[$]$1SYSROOT"
217 elif test "x$TOOLCHAIN_TYPE" = xclang; then
218 $1SYSROOT_CFLAGS="-isysroot [$]$1SYSROOT"
219 $1SYSROOT_LDFLAGS="-isysroot [$]$1SYSROOT"
220 fi
221 fi
222
223 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
224 # We also need -iframework<path>/System/Library/Frameworks
225 $1SYSROOT_CFLAGS="[$]$1SYSROOT_CFLAGS -iframework [$]$1SYSROOT/System/Library/Frameworks"
226 $1SYSROOT_LDFLAGS="[$]$1SYSROOT_LDFLAGS -iframework [$]$1SYSROOT/System/Library/Frameworks"
227 # These always need to be set, or we can't find the frameworks embedded in JavaVM.framework
228 # set this here so it doesn't have to be peppered throughout the forest
229 $1SYSROOT_CFLAGS="[$]$1SYSROOT_CFLAGS -F [$]$1SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks"
230 $1SYSROOT_LDFLAGS="[$]$1SYSROOT_LDFLAGS -F [$]$1SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks"
231 fi
232
233 AC_SUBST($1SYSROOT_CFLAGS)
234 AC_SUBST($1SYSROOT_LDFLAGS)
235 ])
236
237 AC_DEFUN_ONCE([FLAGS_PRE_TOOLCHAIN],
238 [
239 # We should always include user supplied flags
240 FLAGS_SETUP_USER_SUPPLIED_FLAGS
241 # The sysroot flags are needed for configure to be able to run the compilers
242 FLAGS_SETUP_SYSROOT_FLAGS
243
244 # For solstudio and xlc, the word size flag is required for correct behavior.
245 # For clang/gcc, the flag is only strictly required for reduced builds, but
246 # set it always where possible (x86, sparc and ppc).
247 if test "x$TOOLCHAIN_TYPE" = xxlc; then
248 MACHINE_FLAG="-q${OPENJDK_TARGET_CPU_BITS}"
249 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
250 MACHINE_FLAG="-m${OPENJDK_TARGET_CPU_BITS}"
251 elif test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
252 if test "x$OPENJDK_TARGET_CPU_ARCH" = xx86 ||
253 test "x$OPENJDK_TARGET_CPU_ARCH" = xsparc ||
254 test "x$OPENJDK_TARGET_CPU_ARCH" = xppc; then
255 MACHINE_FLAG="-m${OPENJDK_TARGET_CPU_BITS}"
256 fi
257 fi
258
259 # FIXME: global flags are not used yet...
260 # The "global" flags will *always* be set. Without them, it is not possible to
261 # get a working compilation.
262 GLOBAL_CFLAGS="$MACHINE_FLAG $SYSROOT_CFLAGS $USER_CFLAGS"
263 GLOBAL_CXXFLAGS="$MACHINE_FLAG $SYSROOT_CFLAGS $USER_CXXFLAGS"
264 GLOBAL_LDFLAGS="$MACHINE_FLAG $SYSROOT_LDFLAGS $USER_LDFLAGS"
265 # FIXME: Don't really know how to do with this, but this was the old behavior
266 GLOBAL_CPPFLAGS="$SYSROOT_CFLAGS"
267 AC_SUBST(GLOBAL_CFLAGS)
268 AC_SUBST(GLOBAL_CXXFLAGS)
269 AC_SUBST(GLOBAL_LDFLAGS)
270 AC_SUBST(GLOBAL_CPPFLAGS)
271
272 # FIXME: For compatilibity, export this as EXTRA_CFLAGS for now.
273 EXTRA_CFLAGS="$MACHINE_FLAG $USER_CFLAGS"
274 EXTRA_CXXFLAGS="$MACHINE_FLAG $USER_CXXFLAGS"
275 EXTRA_LDFLAGS="$MACHINE_FLAG $USER_LDFLAGS"
276 EXTRA_ASFLAGS="$USER_ASFLAGS"
277
278 AC_SUBST(EXTRA_CFLAGS)
279 AC_SUBST(EXTRA_CXXFLAGS)
280 AC_SUBST(EXTRA_LDFLAGS)
281 AC_SUBST(EXTRA_ASFLAGS)
282
283 # For autoconf testing to work, the global flags must also be stored in the
284 # "unnamed" CFLAGS etc.
285 CFLAGS="$GLOBAL_CFLAGS"
286 CXXFLAGS="$GLOBAL_CXXFLAGS"
287 LDFLAGS="$GLOBAL_LDFLAGS"
288 CPPFLAGS="$GLOBAL_CPPFLAGS"
289 ])
290
291 AC_DEFUN([FLAGS_SETUP_TOOLCHAIN_CONTROL],
292 [
293 # COMPILER_TARGET_BITS_FLAG : option for selecting 32- or 64-bit output
294 # COMPILER_COMMAND_FILE_FLAG : option for passing a command file to the compiler
295 # COMPILER_BINDCMD_FILE_FLAG : option for specifying a file which saves the binder
296 # commands produced by the link step (currently AIX only)
297 if test "x$TOOLCHAIN_TYPE" = xxlc; then
298 COMPILER_TARGET_BITS_FLAG="-q"
299 COMPILER_COMMAND_FILE_FLAG="-f"
300 COMPILER_BINDCMD_FILE_FLAG="-bloadmap:"
301 else
302 COMPILER_TARGET_BITS_FLAG="-m"
303 COMPILER_COMMAND_FILE_FLAG="@"
304 COMPILER_BINDCMD_FILE_FLAG=""
305
306 # The solstudio linker does not support @-files.
307 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
308 COMPILER_COMMAND_FILE_FLAG=
309 fi
310
311 # Check if @file is supported by gcc
312 if test "x$TOOLCHAIN_TYPE" = xgcc; then
313 AC_MSG_CHECKING([if @file is supported by gcc])
314 # Extra emtpy "" to prevent ECHO from interpreting '--version' as argument
315 $ECHO "" "--version" > command.file
316 if $CXX @command.file 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD; then
317 AC_MSG_RESULT(yes)
318 COMPILER_COMMAND_FILE_FLAG="@"
319 else
320 AC_MSG_RESULT(no)
321 COMPILER_COMMAND_FILE_FLAG=
322 fi
323 $RM command.file
324 fi
325 fi
326
327 AC_SUBST(COMPILER_TARGET_BITS_FLAG)
328 AC_SUBST(COMPILER_COMMAND_FILE_FLAG)
329 AC_SUBST(COMPILER_BINDCMD_FILE_FLAG)
330
331 # Check that the compiler supports -mX (or -qX on AIX) flags
332 # Set COMPILER_SUPPORTS_TARGET_BITS_FLAG to 'true' if it does
333 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}],
334 IF_TRUE: [COMPILER_SUPPORTS_TARGET_BITS_FLAG=true],
335 IF_FALSE: [COMPILER_SUPPORTS_TARGET_BITS_FLAG=false])
336 AC_SUBST(COMPILER_SUPPORTS_TARGET_BITS_FLAG)
337
338 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
339 CC_OUT_OPTION=-Fo
340 LD_OUT_OPTION=-out:
341 AR_OUT_OPTION=-out:
342 else
343 # The option used to specify the target .o,.a or .so file.
344 # When compiling, how to specify the to be created object file.
345 CC_OUT_OPTION='-o$(SPACE)'
346 # When linking, how to specify the output
347 LD_OUT_OPTION='-o$(SPACE)'
348 # When archiving, how to specify the destination static archive.
349 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
350 AR_OUT_OPTION='-r -cs$(SPACE)'
351 else
352 AR_OUT_OPTION='-rcs$(SPACE)'
353 fi
354 fi
355 AC_SUBST(CC_OUT_OPTION)
356 AC_SUBST(LD_OUT_OPTION)
357 AC_SUBST(AR_OUT_OPTION)
358
359 # Generate make dependency files
360 if test "x$TOOLCHAIN_TYPE" = xgcc; then
361 C_FLAG_DEPS="-MMD -MF"
362 elif test "x$TOOLCHAIN_TYPE" = xclang; then
363 C_FLAG_DEPS="-MMD -MF"
364 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
365 C_FLAG_DEPS="-xMMD -xMF"
366 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
367 C_FLAG_DEPS="-qmakedep=gcc -MF"
368 fi
369 CXX_FLAG_DEPS="$C_FLAG_DEPS"
370 AC_SUBST(C_FLAG_DEPS)
371 AC_SUBST(CXX_FLAG_DEPS)
372 ])
373
374 AC_DEFUN_ONCE([FLAGS_POST_TOOLCHAIN],
375 [
376 FLAGS_SETUP_TOOLCHAIN_CONTROL
377
378 if test "x$BUILD_SYSROOT" != x; then
379 FLAGS_SETUP_SYSROOT_FLAGS([BUILD_])
380 else
381 if test "x$COMPILE_TYPE" != "xcross"; then
382 BUILD_SYSROOT_CFLAGS="$SYSROOT_CFLAGS"
383 BUILD_SYSROOT_LDFLAGS="$SYSROOT_LDFLAGS"
384 fi
385 fi
386 AC_SUBST(BUILD_SYSROOT_CFLAGS)
387 AC_SUBST(BUILD_SYSROOT_LDFLAGS)
388
389 ])
390
391 AC_DEFUN([FLAGS_SETUP_FLAGS],
392 [
393 FLAGS_SETUP_MACOSX_VERSION
394 FLAGS_SETUP_ABI_PROFILE
395
396 FLAGS_SETUP_SHARED_LIBS
397 FLAGS_SETUP_DEBUG_SYMBOLS
398 FLAGS_SETUP_WARNINGS
399 FLAGS_SETUP_QUALITY_CHECKS
400 FLAGS_SETUP_OPTIMIZATION
401
402 FLAGS_SETUP_CFLAGS
403 FLAGS_SETUP_LDFLAGS
404
405 FLAGS_SETUP_ARFLAGS
406 FLAGS_SETUP_STRIPFLAGS
407 FLAGS_SETUP_RCFLAGS
408
409 FLAGS_SETUP_ASFLAGS
410 FLAGS_SETUP_ASFLAGS_CPU_DEP([TARGET])
411 FLAGS_SETUP_ASFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_])
412 ])
413
414 # FLAGS_C_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
415 # IF_FALSE: [RUN-IF-FALSE])
416 # ------------------------------------------------------------
417 # Check that the C compiler supports an argument
418 BASIC_DEFUN_NAMED([FLAGS_C_COMPILER_CHECK_ARGUMENTS],
419 [*ARGUMENT IF_TRUE IF_FALSE PREFIX], [$@],
420 [
421 AC_MSG_CHECKING([if ARG_PREFIX[CC] supports "ARG_ARGUMENT"])
422 supports=yes
423
424 saved_cflags="$CFLAGS"
425 saved_cc="$CC"
426 CFLAGS="$CFLAGS ARG_ARGUMENT"
427 CC="$ARG_PREFIX[CC]"
428 AC_LANG_PUSH([C])
429 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
430 [supports=no])
431 AC_LANG_POP([C])
432 CC="$saved_cc"
433 CFLAGS="$saved_cflags"
434
435 AC_MSG_RESULT([$supports])
436 if test "x$supports" = "xyes" ; then
437 :
438 ARG_IF_TRUE
439 else
440 :
441 ARG_IF_FALSE
442 fi
443 ])
444
445 # FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
446 # IF_FALSE: [RUN-IF-FALSE])
447 # ------------------------------------------------------------
448 # Check that the C++ compiler supports an argument
449 BASIC_DEFUN_NAMED([FLAGS_CXX_COMPILER_CHECK_ARGUMENTS],
450 [*ARGUMENT IF_TRUE IF_FALSE PREFIX], [$@],
451 [
452 AC_MSG_CHECKING([if ARG_PREFIX[CXX] supports "ARG_ARGUMENT"])
453 supports=yes
454
455 saved_cxxflags="$CXXFLAGS"
456 saved_cxx="$CXX"
457 CXXFLAGS="$CXXFLAG ARG_ARGUMENT"
458 CXX="$ARG_PREFIX[CXX]"
459 AC_LANG_PUSH([C++])
460 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
461 [supports=no])
462 AC_LANG_POP([C++])
463 CXX="$saved_cxx"
464 CXXFLAGS="$saved_cxxflags"
465
466 AC_MSG_RESULT([$supports])
467 if test "x$supports" = "xyes" ; then
468 :
469 ARG_IF_TRUE
470 else
471 :
472 ARG_IF_FALSE
473 fi
474 ])
475
476 # FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
477 # IF_FALSE: [RUN-IF-FALSE])
478 # ------------------------------------------------------------
479 # Check that the C and C++ compilers support an argument
480 BASIC_DEFUN_NAMED([FLAGS_COMPILER_CHECK_ARGUMENTS],
481 [*ARGUMENT IF_TRUE IF_FALSE PREFIX], [$@],
482 [
483 FLAGS_C_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARG_ARGUMENT],
484 IF_TRUE: [C_COMP_SUPPORTS="yes"],
485 IF_FALSE: [C_COMP_SUPPORTS="no"],
486 PREFIX: [ARG_PREFIX])
487 FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARG_ARGUMENT],
488 IF_TRUE: [CXX_COMP_SUPPORTS="yes"],
489 IF_FALSE: [CXX_COMP_SUPPORTS="no"],
490 PREFIX: [ARG_PREFIX])
491
492 AC_MSG_CHECKING([if both ARG_PREFIX[CC] and ARG_PREFIX[CXX] support "ARG_ARGUMENT"])
493 supports=no
494 if test "x$C_COMP_SUPPORTS" = "xyes" -a "x$CXX_COMP_SUPPORTS" = "xyes"; then
495 supports=yes;
496 fi
497
498 AC_MSG_RESULT([$supports])
499 if test "x$supports" = "xyes" ; then
500 :
501 ARG_IF_TRUE
502 else
503 :
504 ARG_IF_FALSE
505 fi
506 ])
507
508 # FLAGS_LINKER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
509 # IF_FALSE: [RUN-IF-FALSE])
510 # ------------------------------------------------------------
511 # Check that the linker support an argument
512 BASIC_DEFUN_NAMED([FLAGS_LINKER_CHECK_ARGUMENTS],
513 [*ARGUMENT IF_TRUE IF_FALSE], [$@],
514 [
515 AC_MSG_CHECKING([if linker supports "ARG_ARGUMENT"])
516 supports=yes
517
518 saved_ldflags="$LDFLAGS"
519 LDFLAGS="$LDFLAGS ARG_ARGUMENT"
520 AC_LANG_PUSH([C])
521 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],[[]])],
522 [], [supports=no])
523 AC_LANG_POP([C])
524 LDFLAGS="$saved_ldflags"
525
526 AC_MSG_RESULT([$supports])
527 if test "x$supports" = "xyes" ; then
528 :
529 ARG_IF_TRUE
530 else
531 :
532 ARG_IF_FALSE
533 fi
534 ])