1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 m4_include([flags-cflags.m4])
27 m4_include([flags-ldflags.m4])
28 m4_include([flags-other.m4])
29
30 ################################################################################
31 #
32 # Setup ABI profile (for arm)
33 #
34 AC_DEFUN([FLAGS_SETUP_ABI_PROFILE],
35 [
36 AC_ARG_WITH(abi-profile, [AS_HELP_STRING([--with-abi-profile],
37 [specify ABI profile for ARM builds (arm-vfp-sflt,arm-vfp-hflt,arm-sflt, armv5-vfp-sflt,armv6-vfp-hflt,arm64,aarch64) @<:@toolchain dependent@:>@ ])])
38
39 if test "x$with_abi_profile" != x; then
40 if test "x$OPENJDK_TARGET_CPU" != xarm && \
41 test "x$OPENJDK_TARGET_CPU" != xaarch64; then
42 AC_MSG_ERROR([--with-abi-profile only available on arm/aarch64])
43 fi
44
45 OPENJDK_TARGET_ABI_PROFILE=$with_abi_profile
46 AC_MSG_CHECKING([for ABI profle])
47 AC_MSG_RESULT([$OPENJDK_TARGET_ABI_PROFILE])
48
49 if test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm-vfp-sflt; then
50 ARM_FLOAT_TYPE=vfp-sflt
51 ARM_ARCH_TYPE_FLAGS='-march=armv7-a -mthumb'
52 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm-vfp-hflt; then
53 ARM_FLOAT_TYPE=vfp-hflt
54 ARM_ARCH_TYPE_FLAGS='-march=armv7-a -mthumb'
55 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm-sflt; then
56 ARM_FLOAT_TYPE=sflt
57 ARM_ARCH_TYPE_FLAGS='-march=armv5t -marm'
58 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarmv5-vfp-sflt; then
59 ARM_FLOAT_TYPE=vfp-sflt
60 ARM_ARCH_TYPE_FLAGS='-march=armv5t -marm'
61 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarmv6-vfp-hflt; then
62 ARM_FLOAT_TYPE=vfp-hflt
63 ARM_ARCH_TYPE_FLAGS='-march=armv6 -marm'
64 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xarm64; then
65 # No special flags, just need to trigger setting JDK_ARCH_ABI_PROP_NAME
66 ARM_FLOAT_TYPE=
67 ARM_ARCH_TYPE_FLAGS=
68 elif test "x$OPENJDK_TARGET_ABI_PROFILE" = xaarch64; then
69 # No special flags, just need to trigger setting JDK_ARCH_ABI_PROP_NAME
70 ARM_FLOAT_TYPE=
71 ARM_ARCH_TYPE_FLAGS=
72 else
73 AC_MSG_ERROR([Invalid ABI profile: "$OPENJDK_TARGET_ABI_PROFILE"])
74 fi
75
76 if test "x$ARM_FLOAT_TYPE" = xvfp-sflt; then
77 ARM_FLOAT_TYPE_FLAGS='-mfloat-abi=softfp -mfpu=vfp -DFLOAT_ARCH=-vfp-sflt'
78 elif test "x$ARM_FLOAT_TYPE" = xvfp-hflt; then
79 ARM_FLOAT_TYPE_FLAGS='-mfloat-abi=hard -mfpu=vfp -DFLOAT_ARCH=-vfp-hflt'
80 elif test "x$ARM_FLOAT_TYPE" = xsflt; then
81 ARM_FLOAT_TYPE_FLAGS='-msoft-float -mfpu=vfp'
82 fi
83 AC_MSG_CHECKING([for $ARM_FLOAT_TYPE floating point flags])
84 AC_MSG_RESULT([$ARM_FLOAT_TYPE_FLAGS])
85
86 AC_MSG_CHECKING([for arch type flags])
87 AC_MSG_RESULT([$ARM_ARCH_TYPE_FLAGS])
88
89 # Now set JDK_ARCH_ABI_PROP_NAME. This is equivalent to the last part of the
90 # autoconf target triplet.
91 [ JDK_ARCH_ABI_PROP_NAME=`$ECHO $OPENJDK_TARGET_AUTOCONF_NAME | $SED -e 's/.*-\([^-]*\)$/\1/'` ]
92 # Sanity check that it is a known ABI.
93 if test "x$JDK_ARCH_ABI_PROP_NAME" != xgnu && \
94 test "x$JDK_ARCH_ABI_PROP_NAME" != xgnueabi && \
95 test "x$JDK_ARCH_ABI_PROP_NAME" != xgnueabihf; then
96 AC_MSG_WARN([Unknown autoconf target triplet ABI: "$JDK_ARCH_ABI_PROP_NAME"])
97 fi
98 AC_MSG_CHECKING([for ABI property name])
99 AC_MSG_RESULT([$JDK_ARCH_ABI_PROP_NAME])
100 AC_SUBST(JDK_ARCH_ABI_PROP_NAME)
101 fi
102
103 # When building with an abi profile, the name of that profile is appended on the
104 # bundle platform, which is used in bundle names.
105 if test "x$OPENJDK_TARGET_ABI_PROFILE" != x; then
106 OPENJDK_TARGET_BUNDLE_PLATFORM="$OPENJDK_TARGET_OS_BUNDLE-$OPENJDK_TARGET_ABI_PROFILE"
107 fi
108 ])
109
110 AC_DEFUN([FLAGS_SETUP_MACOSX_VERSION],
111 [
112 # Additional macosx handling
113 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
114 # MACOSX_VERSION_MIN specifies the lowest version of Macosx that the built
115 # binaries should be compatible with, even if compiled on a newer version
116 # of the OS. It currently has a hard coded value. Setting this also limits
117 # exposure to API changes in header files. Bumping this is likely to
118 # require code changes to build.
119 MACOSX_VERSION_MIN=10.9.0
120 MACOSX_VERSION_MIN_NODOTS=${MACOSX_VERSION_MIN//\./}
121
122 AC_SUBST(MACOSX_VERSION_MIN)
123
124 # Setting --with-macosx-version-max=<version> makes it an error to build or
125 # link to macosx APIs that are newer than the given OS version. The expected
126 # format for <version> is either nn.n.n or nn.nn.nn. See /usr/include/AvailabilityMacros.h.
127 AC_ARG_WITH([macosx-version-max], [AS_HELP_STRING([--with-macosx-version-max],
128 [error on use of newer functionality. @<:@macosx@:>@])],
129 [
130 if echo "$with_macosx_version_max" | $GREP -q "^[[0-9]][[0-9]]\.[[0-9]]\.[[0-9]]\$"; then
131 MACOSX_VERSION_MAX=$with_macosx_version_max
132 elif echo "$with_macosx_version_max" | $GREP -q "^[[0-9]][[0-9]]\.[[0-9]][[0-9]]\.[[0-9]][[0-9]]\$"; then
133 MACOSX_VERSION_MAX=$with_macosx_version_max
134 elif test "x$with_macosx_version_max" = "xno"; then
135 # Use build system default
136 MACOSX_VERSION_MAX=
137 else
138 AC_MSG_ERROR([osx version format must be nn.n.n or nn.nn.nn])
139 fi
140 ],
141 [MACOSX_VERSION_MAX=]
142 )
143 MACOSX_VERSION_MAX_NODOTS=${MACOSX_VERSION_MAX//\./}
144
145 AC_SUBST(MACOSX_VERSION_MAX)
146 fi
147 ])
148
149 # Reset the global CFLAGS/LDFLAGS variables and initialize them with the
150 # corresponding configure arguments instead
151 AC_DEFUN_ONCE([FLAGS_SETUP_USER_SUPPLIED_FLAGS],
152 [
153 if test "x$CFLAGS" != "x"; then
154 AC_MSG_WARN([Ignoring CFLAGS($CFLAGS) found in environment. Use --with-extra-cflags])
155 fi
156
157 if test "x$CXXFLAGS" != "x"; then
158 AC_MSG_WARN([Ignoring CXXFLAGS($CXXFLAGS) found in environment. Use --with-extra-cxxflags])
159 fi
160
161 if test "x$LDFLAGS" != "x"; then
162 AC_MSG_WARN([Ignoring LDFLAGS($LDFLAGS) found in environment. Use --with-extra-ldflags])
163 fi
164
165 if test "x$ASFLAGS" != "x"; then
166 AC_MSG_WARN([Ignoring ASFLAGS($ASFLAGS) found in environment. Use --with-extra-asflags])
167 fi
168
169 AC_ARG_WITH(extra-cflags, [AS_HELP_STRING([--with-extra-cflags],
170 [extra flags to be used when compiling jdk c-files])])
171
172 AC_ARG_WITH(extra-cxxflags, [AS_HELP_STRING([--with-extra-cxxflags],
173 [extra flags to be used when compiling jdk c++-files])])
174
175 AC_ARG_WITH(extra-ldflags, [AS_HELP_STRING([--with-extra-ldflags],
176 [extra flags to be used when linking jdk])])
177
178 AC_ARG_WITH(extra-asflags, [AS_HELP_STRING([--with-extra-asflags],
179 [extra flags to be passed to the assembler])])
180
181 USER_CFLAGS="$with_extra_cflags"
182 USER_CXXFLAGS="$with_extra_cxxflags"
183 USER_LDFLAGS="$with_extra_ldflags"
184 USER_ASFLAGS="$with_extra_asflags"
185 ])
186
187 # Setup the sysroot flags and add them to global CFLAGS and LDFLAGS so
188 # that configure can use them while detecting compilers.
189 # TOOLCHAIN_TYPE is available here.
190 # Param 1 - Optional prefix to all variables. (e.g BUILD_)
191 AC_DEFUN([FLAGS_SETUP_SYSROOT_FLAGS],
192 [
193 if test "x[$]$1SYSROOT" != "x"; then
194 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
195 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
196 # Solaris Studio does not have a concept of sysroot. Instead we must
197 # make sure the default include and lib dirs are appended to each
198 # compile and link command line. Must also add -I-xbuiltin to enable
199 # inlining of system functions and intrinsics.
200 $1SYSROOT_CFLAGS="-I-xbuiltin -I[$]$1SYSROOT/usr/include"
201 $1SYSROOT_LDFLAGS="-L[$]$1SYSROOT/usr/lib$OPENJDK_TARGET_CPU_ISADIR \
202 -L[$]$1SYSROOT/lib$OPENJDK_TARGET_CPU_ISADIR"
203 # If the devkit contains the ld linker, make sure we use it.
204 AC_PATH_PROG(SOLARIS_LD, ld, , $DEVKIT_TOOLCHAIN_PATH:$DEVKIT_EXTRA_PATH)
205 # Make sure this ld is runnable.
206 if test -f "$SOLARIS_LD"; then
207 if "$SOLARIS_LD" -V > /dev/null 2> /dev/null; then
208 $1SYSROOT_LDFLAGS="[$]$1SYSROOT_LDFLAGS -Yl,$(dirname $SOLARIS_LD)"
209 else
210 AC_MSG_WARN([Could not run $SOLARIS_LD found in devkit, reverting to system ld])
211 fi
212 fi
213 fi
214 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
215 $1SYSROOT_CFLAGS="--sysroot=[$]$1SYSROOT"
216 $1SYSROOT_LDFLAGS="--sysroot=[$]$1SYSROOT"
217 elif test "x$TOOLCHAIN_TYPE" = xclang; then
218 $1SYSROOT_CFLAGS="-isysroot [$]$1SYSROOT"
219 $1SYSROOT_LDFLAGS="-isysroot [$]$1SYSROOT"
220 fi
221 fi
222
223 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
224 # We also need -iframework<path>/System/Library/Frameworks
225 $1SYSROOT_CFLAGS="[$]$1SYSROOT_CFLAGS -iframework [$]$1SYSROOT/System/Library/Frameworks"
226 $1SYSROOT_LDFLAGS="[$]$1SYSROOT_LDFLAGS -iframework [$]$1SYSROOT/System/Library/Frameworks"
227 if test -d "[$]$1SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks" ; then
228 # These always need to be set on macOS 10.X, or we can't find the frameworks embedded in JavaVM.framework
229 # set this here so it doesn't have to be peppered throughout the forest
230 $1SYSROOT_CFLAGS="[$]$1SYSROOT_CFLAGS -F [$]$1SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks"
231 $1SYSROOT_LDFLAGS="[$]$1SYSROOT_LDFLAGS -F [$]$1SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks"
232 fi
233 fi
234
235 AC_SUBST($1SYSROOT_CFLAGS)
236 AC_SUBST($1SYSROOT_LDFLAGS)
237 ])
238
239 AC_DEFUN_ONCE([FLAGS_PRE_TOOLCHAIN],
240 [
241 # We should always include user supplied flags
242 FLAGS_SETUP_USER_SUPPLIED_FLAGS
243 # The sysroot flags are needed for configure to be able to run the compilers
244 FLAGS_SETUP_SYSROOT_FLAGS
245
246 # For solstudio and xlc, the word size flag is required for correct behavior.
247 # For clang/gcc, the flag is only strictly required for reduced builds, but
248 # set it always where possible (x86, sparc and ppc).
249 if test "x$TOOLCHAIN_TYPE" = xxlc; then
250 MACHINE_FLAG="-q${OPENJDK_TARGET_CPU_BITS}"
251 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
252 MACHINE_FLAG="-m${OPENJDK_TARGET_CPU_BITS}"
253 elif test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
254 if test "x$OPENJDK_TARGET_CPU_ARCH" = xx86 ||
255 test "x$OPENJDK_TARGET_CPU_ARCH" = xsparc ||
256 test "x$OPENJDK_TARGET_CPU_ARCH" = xppc; then
257 MACHINE_FLAG="-m${OPENJDK_TARGET_CPU_BITS}"
258 fi
259 fi
260
261 # FIXME: global flags are not used yet...
262 # The "global" flags will *always* be set. Without them, it is not possible to
263 # get a working compilation.
264 GLOBAL_CFLAGS="$MACHINE_FLAG $SYSROOT_CFLAGS $USER_CFLAGS"
265 GLOBAL_CXXFLAGS="$MACHINE_FLAG $SYSROOT_CFLAGS $USER_CXXFLAGS"
266 GLOBAL_LDFLAGS="$MACHINE_FLAG $SYSROOT_LDFLAGS $USER_LDFLAGS"
267 # FIXME: Don't really know how to do with this, but this was the old behavior
268 GLOBAL_CPPFLAGS="$SYSROOT_CFLAGS"
269 AC_SUBST(GLOBAL_CFLAGS)
270 AC_SUBST(GLOBAL_CXXFLAGS)
271 AC_SUBST(GLOBAL_LDFLAGS)
272 AC_SUBST(GLOBAL_CPPFLAGS)
273
274 # FIXME: For compatilibity, export this as EXTRA_CFLAGS for now.
275 EXTRA_CFLAGS="$MACHINE_FLAG $USER_CFLAGS"
276 EXTRA_CXXFLAGS="$MACHINE_FLAG $USER_CXXFLAGS"
277 EXTRA_LDFLAGS="$MACHINE_FLAG $USER_LDFLAGS"
278 EXTRA_ASFLAGS="$USER_ASFLAGS"
279
280 AC_SUBST(EXTRA_CFLAGS)
281 AC_SUBST(EXTRA_CXXFLAGS)
282 AC_SUBST(EXTRA_LDFLAGS)
283 AC_SUBST(EXTRA_ASFLAGS)
284
285 # For autoconf testing to work, the global flags must also be stored in the
286 # "unnamed" CFLAGS etc.
287 CFLAGS="$GLOBAL_CFLAGS"
288 CXXFLAGS="$GLOBAL_CXXFLAGS"
289 LDFLAGS="$GLOBAL_LDFLAGS"
290 CPPFLAGS="$GLOBAL_CPPFLAGS"
291 ])
292
293 AC_DEFUN([FLAGS_SETUP_TOOLCHAIN_CONTROL],
294 [
295 # COMPILER_TARGET_BITS_FLAG : option for selecting 32- or 64-bit output
296 # COMPILER_COMMAND_FILE_FLAG : option for passing a command file to the compiler
297 # COMPILER_BINDCMD_FILE_FLAG : option for specifying a file which saves the binder
298 # commands produced by the link step (currently AIX only)
299 if test "x$TOOLCHAIN_TYPE" = xxlc; then
300 COMPILER_TARGET_BITS_FLAG="-q"
301 COMPILER_COMMAND_FILE_FLAG="-f"
302 COMPILER_BINDCMD_FILE_FLAG="-bloadmap:"
303 else
304 COMPILER_TARGET_BITS_FLAG="-m"
305 COMPILER_COMMAND_FILE_FLAG="@"
306 COMPILER_BINDCMD_FILE_FLAG=""
307
308 # The solstudio linker does not support @-files.
309 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
310 COMPILER_COMMAND_FILE_FLAG=
311 fi
312
313 # Check if @file is supported by gcc
314 if test "x$TOOLCHAIN_TYPE" = xgcc; then
315 AC_MSG_CHECKING([if @file is supported by gcc])
316 # Extra emtpy "" to prevent ECHO from interpreting '--version' as argument
317 $ECHO "" "--version" > command.file
318 if $CXX @command.file 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD; then
319 AC_MSG_RESULT(yes)
320 COMPILER_COMMAND_FILE_FLAG="@"
321 else
322 AC_MSG_RESULT(no)
323 COMPILER_COMMAND_FILE_FLAG=
324 fi
325 $RM command.file
326 fi
327 fi
328
329 AC_SUBST(COMPILER_TARGET_BITS_FLAG)
330 AC_SUBST(COMPILER_COMMAND_FILE_FLAG)
331 AC_SUBST(COMPILER_BINDCMD_FILE_FLAG)
332
333 # Check that the compiler supports -mX (or -qX on AIX) flags
334 # Set COMPILER_SUPPORTS_TARGET_BITS_FLAG to 'true' if it does
335 FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}],
336 IF_TRUE: [COMPILER_SUPPORTS_TARGET_BITS_FLAG=true],
337 IF_FALSE: [COMPILER_SUPPORTS_TARGET_BITS_FLAG=false])
338 AC_SUBST(COMPILER_SUPPORTS_TARGET_BITS_FLAG)
339
340 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
341 CC_OUT_OPTION=-Fo
342 LD_OUT_OPTION=-out:
343 AR_OUT_OPTION=-out:
344 else
345 # The option used to specify the target .o,.a or .so file.
346 # When compiling, how to specify the to be created object file.
347 CC_OUT_OPTION='-o$(SPACE)'
348 # When linking, how to specify the output
349 LD_OUT_OPTION='-o$(SPACE)'
350 # When archiving, how to specify the destination static archive.
351 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
352 AR_OUT_OPTION='-r -cs$(SPACE)'
353 else
354 AR_OUT_OPTION='-rcs$(SPACE)'
355 fi
356 fi
357 AC_SUBST(CC_OUT_OPTION)
358 AC_SUBST(LD_OUT_OPTION)
359 AC_SUBST(AR_OUT_OPTION)
360
361 # Generate make dependency files
362 if test "x$TOOLCHAIN_TYPE" = xgcc; then
363 C_FLAG_DEPS="-MMD -MF"
364 elif test "x$TOOLCHAIN_TYPE" = xclang; then
365 C_FLAG_DEPS="-MMD -MF"
366 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
367 C_FLAG_DEPS="-xMMD -xMF"
368 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
369 C_FLAG_DEPS="-qmakedep=gcc -MF"
370 fi
371 CXX_FLAG_DEPS="$C_FLAG_DEPS"
372 AC_SUBST(C_FLAG_DEPS)
373 AC_SUBST(CXX_FLAG_DEPS)
374 ])
375
376 AC_DEFUN_ONCE([FLAGS_POST_TOOLCHAIN],
377 [
378 FLAGS_SETUP_TOOLCHAIN_CONTROL
379
380 if test "x$BUILD_SYSROOT" != x; then
381 FLAGS_SETUP_SYSROOT_FLAGS([BUILD_])
382 else
383 if test "x$COMPILE_TYPE" != "xcross"; then
384 BUILD_SYSROOT_CFLAGS="$SYSROOT_CFLAGS"
385 BUILD_SYSROOT_LDFLAGS="$SYSROOT_LDFLAGS"
386 fi
387 fi
388 AC_SUBST(BUILD_SYSROOT_CFLAGS)
389 AC_SUBST(BUILD_SYSROOT_LDFLAGS)
390
391 ])
392
393 AC_DEFUN([FLAGS_SETUP_FLAGS],
394 [
395 FLAGS_SETUP_MACOSX_VERSION
396 FLAGS_SETUP_ABI_PROFILE
397
398 FLAGS_SETUP_SHARED_LIBS
399 FLAGS_SETUP_DEBUG_SYMBOLS
400 FLAGS_SETUP_WARNINGS
401 FLAGS_SETUP_QUALITY_CHECKS
402 FLAGS_SETUP_OPTIMIZATION
403
404 FLAGS_SETUP_CFLAGS
405 FLAGS_SETUP_LDFLAGS
406
407 FLAGS_SETUP_ARFLAGS
408 FLAGS_SETUP_STRIPFLAGS
409 FLAGS_SETUP_RCFLAGS
410
411 FLAGS_SETUP_ASFLAGS
412 FLAGS_SETUP_ASFLAGS_CPU_DEP([TARGET])
413 FLAGS_SETUP_ASFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_])
414 ])
415
416 # FLAGS_C_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
417 # IF_FALSE: [RUN-IF-FALSE])
418 # ------------------------------------------------------------
419 # Check that the C compiler supports an argument
420 BASIC_DEFUN_NAMED([FLAGS_C_COMPILER_CHECK_ARGUMENTS],
421 [*ARGUMENT IF_TRUE IF_FALSE PREFIX], [$@],
422 [
423 AC_MSG_CHECKING([if ARG_PREFIX[CC] supports "ARG_ARGUMENT"])
424 supports=yes
425
426 saved_cflags="$CFLAGS"
427 saved_cc="$CC"
428 CFLAGS="$CFLAGS ARG_ARGUMENT"
429 CC="$ARG_PREFIX[CC]"
430 AC_LANG_PUSH([C])
431 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
432 [supports=no])
433 AC_LANG_POP([C])
434 CC="$saved_cc"
435 CFLAGS="$saved_cflags"
436
437 AC_MSG_RESULT([$supports])
438 if test "x$supports" = "xyes" ; then
439 :
440 ARG_IF_TRUE
441 else
442 :
443 ARG_IF_FALSE
444 fi
445 ])
446
447 # FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
448 # IF_FALSE: [RUN-IF-FALSE])
449 # ------------------------------------------------------------
450 # Check that the C++ compiler supports an argument
451 BASIC_DEFUN_NAMED([FLAGS_CXX_COMPILER_CHECK_ARGUMENTS],
452 [*ARGUMENT IF_TRUE IF_FALSE PREFIX], [$@],
453 [
454 AC_MSG_CHECKING([if ARG_PREFIX[CXX] supports "ARG_ARGUMENT"])
455 supports=yes
456
457 saved_cxxflags="$CXXFLAGS"
458 saved_cxx="$CXX"
459 CXXFLAGS="$CXXFLAG ARG_ARGUMENT"
460 CXX="$ARG_PREFIX[CXX]"
461 AC_LANG_PUSH([C++])
462 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
463 [supports=no])
464 AC_LANG_POP([C++])
465 CXX="$saved_cxx"
466 CXXFLAGS="$saved_cxxflags"
467
468 AC_MSG_RESULT([$supports])
469 if test "x$supports" = "xyes" ; then
470 :
471 ARG_IF_TRUE
472 else
473 :
474 ARG_IF_FALSE
475 fi
476 ])
477
478 # FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
479 # IF_FALSE: [RUN-IF-FALSE])
480 # ------------------------------------------------------------
481 # Check that the C and C++ compilers support an argument
482 BASIC_DEFUN_NAMED([FLAGS_COMPILER_CHECK_ARGUMENTS],
483 [*ARGUMENT IF_TRUE IF_FALSE PREFIX], [$@],
484 [
485 FLAGS_C_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARG_ARGUMENT],
486 IF_TRUE: [C_COMP_SUPPORTS="yes"],
487 IF_FALSE: [C_COMP_SUPPORTS="no"],
488 PREFIX: [ARG_PREFIX])
489 FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [ARG_ARGUMENT],
490 IF_TRUE: [CXX_COMP_SUPPORTS="yes"],
491 IF_FALSE: [CXX_COMP_SUPPORTS="no"],
492 PREFIX: [ARG_PREFIX])
493
494 AC_MSG_CHECKING([if both ARG_PREFIX[CC] and ARG_PREFIX[CXX] support "ARG_ARGUMENT"])
495 supports=no
496 if test "x$C_COMP_SUPPORTS" = "xyes" -a "x$CXX_COMP_SUPPORTS" = "xyes"; then
497 supports=yes;
498 fi
499
500 AC_MSG_RESULT([$supports])
501 if test "x$supports" = "xyes" ; then
502 :
503 ARG_IF_TRUE
504 else
505 :
506 ARG_IF_FALSE
507 fi
508 ])
509
510 # FLAGS_LINKER_CHECK_ARGUMENTS(ARGUMENT: [ARGUMENT], IF_TRUE: [RUN-IF-TRUE],
511 # IF_FALSE: [RUN-IF-FALSE])
512 # ------------------------------------------------------------
513 # Check that the linker support an argument
514 BASIC_DEFUN_NAMED([FLAGS_LINKER_CHECK_ARGUMENTS],
515 [*ARGUMENT IF_TRUE IF_FALSE], [$@],
516 [
517 AC_MSG_CHECKING([if linker supports "ARG_ARGUMENT"])
518 supports=yes
519
520 saved_ldflags="$LDFLAGS"
521 LDFLAGS="$LDFLAGS ARG_ARGUMENT"
522 AC_LANG_PUSH([C])
523 AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],[[]])],
524 [], [supports=no])
525 AC_LANG_POP([C])
526 LDFLAGS="$saved_ldflags"
527
528 AC_MSG_RESULT([$supports])
529 if test "x$supports" = "xyes" ; then
530 :
531 ARG_IF_TRUE
532 else
533 :
534 ARG_IF_FALSE
535 fi
536 ])