1 #
   2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 ########################################################################
  27 # This file is responsible for detecting, verifying and setting up the
  28 # toolchain, i.e. the compiler, linker and related utilities. It will setup
  29 # proper paths to the binaries, but it will not setup any flags.
  30 #
  31 # The binaries used is determined by the toolchain type, which is the family of
  32 # compilers and related tools that are used.
  33 ########################################################################
  34 
  35 
  36 # All valid toolchains, regardless of platform (used by help.m4)
  37 VALID_TOOLCHAINS_all="gcc clang solstudio xlc microsoft"
  38 
  39 # These toolchains are valid on different platforms
  40 VALID_TOOLCHAINS_linux="gcc clang"
  41 VALID_TOOLCHAINS_solaris="solstudio"
  42 VALID_TOOLCHAINS_macosx="gcc clang"
  43 VALID_TOOLCHAINS_aix="xlc"
  44 VALID_TOOLCHAINS_windows="microsoft"
  45 
  46 # Toolchain descriptions
  47 TOOLCHAIN_DESCRIPTION_clang="clang/LLVM"
  48 TOOLCHAIN_DESCRIPTION_gcc="GNU Compiler Collection"
  49 TOOLCHAIN_DESCRIPTION_microsoft="Microsoft Visual Studio"
  50 TOOLCHAIN_DESCRIPTION_solstudio="Oracle Solaris Studio"
  51 TOOLCHAIN_DESCRIPTION_xlc="IBM XL C/C++"
  52 
  53 # Minimum supported versions, empty means unspecified
  54 TOOLCHAIN_MINIMUM_VERSION_clang="3.2"
  55 TOOLCHAIN_MINIMUM_VERSION_gcc="4.8"
  56 TOOLCHAIN_MINIMUM_VERSION_microsoft="16.00.30319.01" # VS2010
  57 TOOLCHAIN_MINIMUM_VERSION_solstudio="5.13"
  58 TOOLCHAIN_MINIMUM_VERSION_xlc=""
  59 
  60 # Minimum supported linker versions, empty means unspecified
  61 TOOLCHAIN_MINIMUM_LD_VERSION_gcc="2.18"
  62 
  63 # Prepare the system so that TOOLCHAIN_CHECK_COMPILER_VERSION can be called.
  64 # Must have CC_VERSION_NUMBER and CXX_VERSION_NUMBER.
  65 # $1 - optional variable prefix for compiler and version variables (BUILD_)
  66 # $2 - optional variable prefix for comparable variable (OPENJDK_BUILD_)
  67 AC_DEFUN([TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS],
  68 [
  69   if test "x[$]$1CC_VERSION_NUMBER" != "x[$]$1CXX_VERSION_NUMBER"; then
  70     AC_MSG_WARN([C and C++ compiler have different version numbers, [$]$1CC_VERSION_NUMBER vs [$]$1CXX_VERSION_NUMBER.])
  71     AC_MSG_WARN([This typically indicates a broken setup, and is not supported])
  72   fi
  73 
  74   # We only check CC_VERSION_NUMBER since we assume CXX_VERSION_NUMBER is equal.
  75   if [ [[ "[$]$1CC_VERSION_NUMBER" =~ (.*\.){4} ]] ]; then
  76     AC_MSG_WARN([C compiler version number has more than four parts (W.X.Y.Z): [$]$1CC_VERSION_NUMBER. Comparisons might be wrong.])
  77   fi
  78 
  79   if [ [[  "[$]$1CC_VERSION_NUMBER" =~ [0-9]{6} ]] ]; then
  80     AC_MSG_WARN([C compiler version number has a part larger than 99999: [$]$1CC_VERSION_NUMBER. Comparisons might be wrong.])
  81   fi
  82 
  83   $2COMPARABLE_ACTUAL_VERSION=`$AWK -F. '{ printf("%05d%05d%05d%05d\n", [$]1, [$]2, [$]3, [$]4) }' <<< "[$]$1CC_VERSION_NUMBER"`
  84 ])
  85 
  86 # Check if the configured compiler (C and C++) is of a specific version or
  87 # newer. TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS must have been called before.
  88 #
  89 # Arguments:
  90 #   VERSION:   The version string to check against the found version
  91 #   IF_AT_LEAST:   block to run if the compiler is at least this version (>=)
  92 #   IF_OLDER_THAN:   block to run if the compiler is older than this version (<)
  93 #   PREFIX:   Optional variable prefix for compiler to compare version for (OPENJDK_BUILD_)
  94 BASIC_DEFUN_NAMED([TOOLCHAIN_CHECK_COMPILER_VERSION],
  95     [*VERSION PREFIX IF_AT_LEAST IF_OLDER_THAN], [$@],
  96 [
  97   # Need to assign to a variable since m4 is blocked from modifying parts in [].
  98   REFERENCE_VERSION=ARG_VERSION
  99 
 100   if [ [[ "$REFERENCE_VERSION" =~ (.*\.){4} ]] ]; then
 101     AC_MSG_ERROR([Internal error: Cannot compare to ARG_VERSION, only four parts (W.X.Y.Z) is supported])
 102   fi
 103 
 104   if [ [[ "$REFERENCE_VERSION" =~ [0-9]{6} ]] ]; then
 105     AC_MSG_ERROR([Internal error: Cannot compare to ARG_VERSION, only parts < 99999 is supported])
 106   fi
 107 
 108   # Version comparison method inspired by http://stackoverflow.com/a/24067243
 109   COMPARABLE_REFERENCE_VERSION=`$AWK -F. '{ printf("%05d%05d%05d%05d\n", [$]1, [$]2, [$]3, [$]4) }' <<< "$REFERENCE_VERSION"`
 110 
 111   if test [$]ARG_PREFIX[COMPARABLE_ACTUAL_VERSION] -ge $COMPARABLE_REFERENCE_VERSION ; then
 112     :
 113     ARG_IF_AT_LEAST
 114   else
 115     :
 116     ARG_IF_OLDER_THAN
 117   fi
 118 ])
 119 
 120 # Prepare the system so that TOOLCHAIN_CHECK_COMPILER_VERSION can be called.
 121 # Must have LD_VERSION_NUMBER.
 122 # $1 - optional variable prefix for compiler and version variables (BUILD_)
 123 # $2 - optional variable prefix for comparable variable (OPENJDK_BUILD_)
 124 AC_DEFUN([TOOLCHAIN_PREPARE_FOR_LD_VERSION_COMPARISONS],
 125 [
 126   if [ [[ "[$]$1LD_VERSION_NUMBER" =~ (.*\.){4} ]] ]; then
 127     AC_MSG_WARN([Linker version number has more than four parts (W.X.Y.Z): [$]$1LD_VERSION_NUMBER. Comparisons might be wrong.])
 128   fi
 129 
 130   if [ [[  "[$]$1LD_VERSION_NUMBER" =~ [0-9]{6} ]] ]; then
 131     AC_MSG_WARN([Linker version number has a part larger than 99999: [$]$1LD_VERSION_NUMBER. Comparisons might be wrong.])
 132   fi
 133 
 134   $2COMPARABLE_ACTUAL_LD_VERSION=`$AWK -F. '{ printf("%05d%05d%05d%05d\n", [$]1, [$]2, [$]3, [$]4) }' <<< "[$]$1LD_VERSION_NUMBER"`
 135 ])
 136 
 137 # Check if the configured linker is of a specific version or
 138 # newer. TOOLCHAIN_PREPARE_FOR_LD_VERSION_COMPARISONS must have been called before.
 139 #
 140 # Arguments:
 141 #   VERSION:   The version string to check against the found version
 142 #   IF_AT_LEAST:   block to run if the compiler is at least this version (>=)
 143 #   IF_OLDER_THAN:   block to run if the compiler is older than this version (<)
 144 #   PREFIX:   Optional variable prefix for compiler to compare version for (OPENJDK_BUILD_)
 145 BASIC_DEFUN_NAMED([TOOLCHAIN_CHECK_LINKER_VERSION],
 146     [*VERSION PREFIX IF_AT_LEAST IF_OLDER_THAN], [$@],
 147 [
 148   # Need to assign to a variable since m4 is blocked from modifying parts in [].
 149   REFERENCE_VERSION=ARG_VERSION
 150 
 151   if [ [[ "$REFERENCE_VERSION" =~ (.*\.){4} ]] ]; then
 152     AC_MSG_ERROR([Internal error: Cannot compare to ARG_VERSION, only four parts (W.X.Y.Z) is supported])
 153   fi
 154 
 155   if [ [[ "$REFERENCE_VERSION" =~ [0-9]{6} ]] ]; then
 156     AC_MSG_ERROR([Internal error: Cannot compare to ARG_VERSION, only parts < 99999 is supported])
 157   fi
 158 
 159   # Version comparison method inspired by http://stackoverflow.com/a/24067243
 160   COMPARABLE_REFERENCE_VERSION=`$AWK -F. '{ printf("%05d%05d%05d%05d\n", [$]1, [$]2, [$]3, [$]4) }' <<< "$REFERENCE_VERSION"`
 161 
 162   if test [$]ARG_PREFIX[COMPARABLE_ACTUAL_LD_VERSION] -ge $COMPARABLE_REFERENCE_VERSION ; then
 163     :
 164     ARG_IF_AT_LEAST
 165   else
 166     :
 167     ARG_IF_OLDER_THAN
 168   fi
 169 ])
 170 
 171 # Setup a number of variables describing how native output files are
 172 # named on this platform/toolchain.
 173 AC_DEFUN([TOOLCHAIN_SETUP_FILENAME_PATTERNS],
 174 [
 175   # Define filename patterns
 176   if test "x$OPENJDK_TARGET_OS" = xwindows; then
 177     LIBRARY_PREFIX=
 178     SHARED_LIBRARY_SUFFIX='.dll'
 179     STATIC_LIBRARY_SUFFIX='.lib'
 180     SHARED_LIBRARY='[$]1.dll'
 181     STATIC_LIBRARY='[$]1.lib'
 182     OBJ_SUFFIX='.obj'
 183     EXE_SUFFIX='.exe'
 184   else
 185     LIBRARY_PREFIX=lib
 186     SHARED_LIBRARY_SUFFIX='.so'
 187     STATIC_LIBRARY_SUFFIX='.a'
 188     SHARED_LIBRARY='lib[$]1.so'
 189     STATIC_LIBRARY='lib[$]1.a'
 190     OBJ_SUFFIX='.o'
 191     EXE_SUFFIX=''
 192     if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 193       # For full static builds, we're overloading the SHARED_LIBRARY
 194       # variables in order to limit the amount of changes required.
 195       # It would be better to remove SHARED and just use LIBRARY and
 196       # LIBRARY_SUFFIX for libraries that can be built either
 197       # shared or static and use STATIC_* for libraries that are
 198       # always built statically.
 199       if test "x$STATIC_BUILD" = xtrue; then
 200         SHARED_LIBRARY='lib[$]1.a'
 201         SHARED_LIBRARY_SUFFIX='.a'
 202       else
 203         SHARED_LIBRARY='lib[$]1.dylib'
 204         SHARED_LIBRARY_SUFFIX='.dylib'
 205       fi
 206     fi
 207   fi
 208 
 209   AC_SUBST(LIBRARY_PREFIX)
 210   AC_SUBST(SHARED_LIBRARY_SUFFIX)
 211   AC_SUBST(STATIC_LIBRARY_SUFFIX)
 212   AC_SUBST(SHARED_LIBRARY)
 213   AC_SUBST(STATIC_LIBRARY)
 214   AC_SUBST(OBJ_SUFFIX)
 215   AC_SUBST(EXE_SUFFIX)
 216 ])
 217 
 218 # Determine which toolchain type to use, and make sure it is valid for this
 219 # platform. Setup various information about the selected toolchain.
 220 AC_DEFUN_ONCE([TOOLCHAIN_DETERMINE_TOOLCHAIN_TYPE],
 221 [
 222   AC_ARG_WITH(toolchain-type, [AS_HELP_STRING([--with-toolchain-type],
 223       [the toolchain type (or family) to use, use '--help' to show possible values @<:@platform dependent@:>@])])
 224 
 225   # Use indirect variable referencing
 226   toolchain_var_name=VALID_TOOLCHAINS_$OPENJDK_BUILD_OS
 227   VALID_TOOLCHAINS=${!toolchain_var_name}
 228 
 229   if test "x$OPENJDK_TARGET_OS" = xmacosx; then
 230     if test -n "$XCODEBUILD"; then
 231       # On Mac OS X, default toolchain to clang after Xcode 5
 232       XCODE_VERSION_OUTPUT=`"$XCODEBUILD" -version 2>&1 | $HEAD -n 1`
 233       $ECHO "$XCODE_VERSION_OUTPUT" | $GREP "Xcode " > /dev/null
 234       if test $? -ne 0; then
 235         AC_MSG_ERROR([Failed to determine Xcode version.])
 236       fi
 237       XCODE_MAJOR_VERSION=`$ECHO $XCODE_VERSION_OUTPUT | \
 238           $SED -e 's/^Xcode \(@<:@1-9@:>@@<:@0-9.@:>@*\)/\1/' | \
 239           $CUT -f 1 -d .`
 240       AC_MSG_NOTICE([Xcode major version: $XCODE_MAJOR_VERSION])
 241       if test $XCODE_MAJOR_VERSION -ge 5; then
 242           DEFAULT_TOOLCHAIN="clang"
 243       else
 244           DEFAULT_TOOLCHAIN="gcc"
 245       fi
 246     else
 247       # If Xcode is not installed, but the command line tools are
 248       # then we can't run xcodebuild. On these systems we should
 249       # default to clang
 250       DEFAULT_TOOLCHAIN="clang"
 251     fi
 252   else
 253     # First toolchain type in the list is the default
 254     DEFAULT_TOOLCHAIN=${VALID_TOOLCHAINS%% *}
 255   fi
 256 
 257   if test "x$with_toolchain_type" = xlist; then
 258     # List all toolchains
 259     AC_MSG_NOTICE([The following toolchains are valid on this platform:])
 260     for toolchain in $VALID_TOOLCHAINS; do
 261       toolchain_var_name=TOOLCHAIN_DESCRIPTION_$toolchain
 262       TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
 263       $PRINTF "  %-10s  %s\n" $toolchain "$TOOLCHAIN_DESCRIPTION"
 264     done
 265 
 266     exit 0
 267   elif test "x$with_toolchain_type" != x; then
 268     # User override; check that it is valid
 269     if test "x${VALID_TOOLCHAINS/$with_toolchain_type/}" = "x${VALID_TOOLCHAINS}"; then
 270       AC_MSG_NOTICE([Toolchain type $with_toolchain_type is not valid on this platform.])
 271       AC_MSG_NOTICE([Valid toolchains: $VALID_TOOLCHAINS.])
 272       AC_MSG_ERROR([Cannot continue.])
 273     fi
 274     TOOLCHAIN_TYPE=$with_toolchain_type
 275   else
 276     # No flag given, use default
 277     TOOLCHAIN_TYPE=$DEFAULT_TOOLCHAIN
 278   fi
 279   AC_SUBST(TOOLCHAIN_TYPE)
 280 
 281   TOOLCHAIN_CC_BINARY_clang="clang"
 282   TOOLCHAIN_CC_BINARY_gcc="gcc"
 283   TOOLCHAIN_CC_BINARY_microsoft="cl"
 284   TOOLCHAIN_CC_BINARY_solstudio="cc"
 285   TOOLCHAIN_CC_BINARY_xlc="xlc_r"
 286 
 287   TOOLCHAIN_CXX_BINARY_clang="clang++"
 288   TOOLCHAIN_CXX_BINARY_gcc="g++"
 289   TOOLCHAIN_CXX_BINARY_microsoft="cl"
 290   TOOLCHAIN_CXX_BINARY_solstudio="CC"
 291   TOOLCHAIN_CXX_BINARY_xlc="xlC_r"
 292 
 293   # Use indirect variable referencing
 294   toolchain_var_name=TOOLCHAIN_DESCRIPTION_$TOOLCHAIN_TYPE
 295   TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
 296   toolchain_var_name=TOOLCHAIN_MINIMUM_VERSION_$TOOLCHAIN_TYPE
 297   TOOLCHAIN_MINIMUM_VERSION=${!toolchain_var_name}
 298   toolchain_var_name=TOOLCHAIN_MINIMUM_LD_VERSION_$TOOLCHAIN_TYPE
 299   TOOLCHAIN_MINIMUM_LD_VERSION=${!toolchain_var_name}
 300   toolchain_var_name=TOOLCHAIN_CC_BINARY_$TOOLCHAIN_TYPE
 301   TOOLCHAIN_CC_BINARY=${!toolchain_var_name}
 302   toolchain_var_name=TOOLCHAIN_CXX_BINARY_$TOOLCHAIN_TYPE
 303   TOOLCHAIN_CXX_BINARY=${!toolchain_var_name}
 304 
 305   TOOLCHAIN_SETUP_FILENAME_PATTERNS
 306 
 307   if test "x$TOOLCHAIN_TYPE" = "x$DEFAULT_TOOLCHAIN"; then
 308     AC_MSG_NOTICE([Using default toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION)])
 309   else
 310     AC_MSG_NOTICE([Using user selected toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION). Default toolchain is $DEFAULT_TOOLCHAIN.])
 311   fi
 312 ])
 313 
 314 # Before we start detecting the toolchain executables, we might need some
 315 # special setup, e.g. additional paths etc.
 316 AC_DEFUN_ONCE([TOOLCHAIN_PRE_DETECTION],
 317 [
 318   # FIXME: Is this needed?
 319   AC_LANG(C++)
 320 
 321   # Store the CFLAGS etc passed to the configure script.
 322   ORG_CFLAGS="$CFLAGS"
 323   ORG_CXXFLAGS="$CXXFLAGS"
 324 
 325   # autoconf magic only relies on PATH, so update it if tools dir is specified
 326   OLD_PATH="$PATH"
 327 
 328   # On Windows, we need to detect the visual studio installation first.
 329   # This will change the PATH, but we need to keep that new PATH even
 330   # after toolchain detection is done, since the compiler (on x86) uses
 331   # it for DLL resolution in runtime.
 332   if test "x$OPENJDK_BUILD_OS" = "xwindows" \
 333       && test "x$TOOLCHAIN_TYPE" = "xmicrosoft"; then
 334     TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV
 335     # Reset path to VS_PATH. It will include everything that was on PATH at the time we
 336     # ran TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV.
 337     PATH="$VS_PATH"
 338     # The microsoft toolchain also requires INCLUDE and LIB to be set.
 339     export INCLUDE="$VS_INCLUDE"
 340     export LIB="$VS_LIB"
 341   else
 342     if test "x$XCODE_VERSION_OUTPUT" != x; then
 343       # For Xcode, we set the Xcode version as TOOLCHAIN_VERSION
 344       TOOLCHAIN_VERSION=`$ECHO $XCODE_VERSION_OUTPUT | $CUT -f 2 -d ' '`
 345       TOOLCHAIN_DESCRIPTION="$TOOLCHAIN_DESCRIPTION from Xcode $TOOLCHAIN_VERSION"
 346     else
 347       # Currently we do not define this for other toolchains. This might change as the need arise.
 348       TOOLCHAIN_VERSION=
 349     fi
 350   fi
 351   AC_SUBST(TOOLCHAIN_VERSION)
 352 
 353   # Finally add TOOLCHAIN_PATH at the beginning, to allow --with-tools-dir to
 354   # override all other locations.
 355   if test "x$TOOLCHAIN_PATH" != x; then
 356     PATH=$TOOLCHAIN_PATH:$PATH
 357   fi
 358 ])
 359 
 360 # Restore path, etc
 361 AC_DEFUN_ONCE([TOOLCHAIN_POST_DETECTION],
 362 [
 363   # Restore old path, except for the microsoft toolchain, which requires VS_PATH
 364   # to remain in place. Otherwise the compiler will not work in some siutations
 365   # in later configure checks.
 366   if test "x$TOOLCHAIN_TYPE" != "xmicrosoft"; then
 367     PATH="$OLD_PATH"
 368   fi
 369 
 370   # Restore the flags to the user specified values.
 371   # This is necessary since AC_PROG_CC defaults CFLAGS to "-g -O2"
 372   CFLAGS="$ORG_CFLAGS"
 373   CXXFLAGS="$ORG_CXXFLAGS"
 374 ])
 375 
 376 # Check if a compiler is of the toolchain type we expect, and save the version
 377 # information from it. If the compiler does not match the expected type,
 378 # this function will abort using AC_MSG_ERROR. If it matches, the version will
 379 # be stored in CC_VERSION_NUMBER/CXX_VERSION_NUMBER (as a dotted number), and
 380 # the full version string in CC_VERSION_STRING/CXX_VERSION_STRING.
 381 #
 382 # $1 = compiler to test (CC or CXX)
 383 # $2 = human readable name of compiler (C or C++)
 384 AC_DEFUN([TOOLCHAIN_EXTRACT_COMPILER_VERSION],
 385 [
 386   COMPILER=[$]$1
 387   COMPILER_NAME=$2
 388 
 389   if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 390     # cc -V output typically looks like
 391     #     cc: Sun C 5.12 Linux_i386 2011/11/16
 392     # or
 393     #     cc: Studio 12.5 Sun C 5.14 SunOS_sparc 2016/05/31
 394     COMPILER_VERSION_OUTPUT=`$COMPILER -V 2>&1`
 395     # Check that this is likely to be the Solaris Studio cc.
 396     $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "^.* Sun $COMPILER_NAME" > /dev/null
 397     if test $? -ne 0; then
 398       ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
 399       AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
 400       AC_MSG_NOTICE([The result from running with -V was: "$COMPILER_VERSION_OUTPUT"])
 401       AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
 402       AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
 403     fi
 404     # Remove usage instructions (if present), and
 405     # collapse compiler output into a single line
 406     COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
 407         $SED -e 's/ *@<:@Uu@:>@sage:.*//'`
 408     COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
 409         $SED -e "s/^.*@<:@ ,\t@:>@$COMPILER_NAME@<:@ ,\t@:>@\(@<:@1-9@:>@\.@<:@0-9@:>@@<:@0-9@:>@*\).*/\1/"`
 410   elif test  "x$TOOLCHAIN_TYPE" = xxlc; then
 411     # xlc -qversion output typically looks like
 412     #     IBM XL C/C++ for AIX, V11.1 (5724-X13)
 413     #     Version: 11.01.0000.0015
 414     COMPILER_VERSION_OUTPUT=`$COMPILER -qversion 2>&1`
 415     # Check that this is likely to be the IBM XL C compiler.
 416     $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "IBM XL C" > /dev/null
 417     if test $? -ne 0; then
 418       ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
 419       AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
 420       AC_MSG_NOTICE([The result from running with -qversion was: "$COMPILER_VERSION_OUTPUT"])
 421       AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
 422       AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
 423     fi
 424     # Collapse compiler output into a single line
 425     COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
 426     COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
 427         $SED -e 's/^.*, V\(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
 428   elif test  "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 429     # There is no specific version flag, but all output starts with a version string.
 430     # First line typically looks something like:
 431     # Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 16.00.40219.01 for 80x86
 432     # but the compiler name may vary depending on locale.
 433     COMPILER_VERSION_OUTPUT=`$COMPILER 2>&1 | $HEAD -n 1 | $TR -d '\r'`
 434     # Check that this is likely to be Microsoft CL.EXE.
 435     $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Microsoft" > /dev/null
 436     if test $? -ne 0; then
 437       AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
 438       AC_MSG_NOTICE([The result from running it was: "$COMPILER_VERSION_OUTPUT"])
 439       AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
 440     fi
 441     # Collapse compiler output into a single line
 442     COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
 443     COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
 444         $SED -e 's/^.*ersion.\(@<:@1-9@:>@@<:@0-9.@:>@*\) .*$/\1/'`
 445   elif test  "x$TOOLCHAIN_TYPE" = xgcc; then
 446     # gcc --version output typically looks like
 447     #     gcc (Ubuntu/Linaro 4.8.1-10ubuntu9) 4.8.1
 448     #     Copyright (C) 2013 Free Software Foundation, Inc.
 449     #     This is free software; see the source for copying conditions.  There is NO
 450     #     warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
 451     COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
 452     # Check that this is likely to be GCC.
 453     $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Free Software Foundation" > /dev/null
 454     if test $? -ne 0; then
 455       AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
 456       AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION"])
 457       AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
 458     fi
 459     # Remove Copyright and legalese from version string, and
 460     # collapse into a single line
 461     COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
 462         $SED -e 's/ *Copyright .*//'`
 463     COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
 464         $SED -e 's/^.* \(@<:@1-9@:>@<:@0-9@:>@*\.@<:@0-9.@:>@*\)@<:@^0-9.@:>@.*$/\1/'`
 465   elif test  "x$TOOLCHAIN_TYPE" = xclang; then
 466     # clang --version output typically looks like
 467     #    Apple LLVM version 5.0 (clang-500.2.79) (based on LLVM 3.3svn)
 468     #    clang version 3.3 (tags/RELEASE_33/final)
 469     # or
 470     #    Debian clang version 3.2-7ubuntu1 (tags/RELEASE_32/final) (based on LLVM 3.2)
 471     #    Target: x86_64-pc-linux-gnu
 472     #    Thread model: posix
 473     COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
 474     # Check that this is likely to be clang
 475     $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "clang" > /dev/null
 476     if test $? -ne 0; then
 477       AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
 478       AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION_OUTPUT"])
 479       AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
 480     fi
 481     # Collapse compiler output into a single line
 482     COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
 483     COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
 484         $SED -e 's/^.* version \(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
 485   else
 486       AC_MSG_ERROR([Unknown toolchain type $TOOLCHAIN_TYPE.])
 487   fi
 488   # This sets CC_VERSION_NUMBER or CXX_VERSION_NUMBER. (This comment is a grep marker)
 489   $1_VERSION_NUMBER="$COMPILER_VERSION_NUMBER"
 490   # This sets CC_VERSION_STRING or CXX_VERSION_STRING. (This comment is a grep marker)
 491   $1_VERSION_STRING="$COMPILER_VERSION_STRING"
 492 
 493   AC_MSG_NOTICE([Using $TOOLCHAIN_TYPE $COMPILER_NAME compiler version $COMPILER_VERSION_NUMBER @<:@$COMPILER_VERSION_STRING@:>@])
 494 ])
 495 
 496 # Try to locate the given C or C++ compiler in the path, or otherwise.
 497 #
 498 # $1 = compiler to test (CC or CXX)
 499 # $2 = human readable name of compiler (C or C++)
 500 # $3 = compiler name to search for
 501 AC_DEFUN([TOOLCHAIN_FIND_COMPILER],
 502 [
 503   COMPILER_NAME=$2
 504   SEARCH_LIST="$3"
 505 
 506   if test "x[$]$1" != x; then
 507     # User has supplied compiler name already, always let that override.
 508     AC_MSG_NOTICE([Will use user supplied compiler $1=[$]$1])
 509     if test "x`basename [$]$1`" = "x[$]$1"; then
 510       # A command without a complete path is provided, search $PATH.
 511 
 512       AC_PATH_PROGS(POTENTIAL_$1, [$]$1)
 513       if test "x$POTENTIAL_$1" != x; then
 514         $1=$POTENTIAL_$1
 515       else
 516         AC_MSG_ERROR([User supplied compiler $1=[$]$1 could not be found])
 517       fi
 518     else
 519       # Otherwise it might already be a complete path
 520       if test ! -x "[$]$1"; then
 521         AC_MSG_ERROR([User supplied compiler $1=[$]$1 does not exist])
 522       fi
 523     fi
 524   else
 525     # No user supplied value. Locate compiler ourselves.
 526 
 527     # If we are cross compiling, assume cross compilation tools follows the
 528     # cross compilation standard where they are prefixed with the autoconf
 529     # standard name for the target. For example the binary
 530     # i686-sun-solaris2.10-gcc will cross compile for i686-sun-solaris2.10.
 531     # If we are not cross compiling, then the default compiler name will be
 532     # used.
 533 
 534     $1=
 535     # If TOOLCHAIN_PATH is set, check for all compiler names in there first
 536     # before checking the rest of the PATH.
 537     # FIXME: Now that we prefix the TOOLS_DIR to the PATH in the PRE_DETECTION
 538     # step, this should not be necessary.
 539     if test -n "$TOOLCHAIN_PATH"; then
 540       PATH_save="$PATH"
 541       PATH="$TOOLCHAIN_PATH"
 542       AC_PATH_TOOL(TOOLCHAIN_PATH_$1, $SEARCH_LIST)
 543       $1=$TOOLCHAIN_PATH_$1
 544       PATH="$PATH_save"
 545     fi
 546 
 547     # AC_PATH_TOOL can't be run multiple times with the same variable,
 548     # so create a new name for this run.
 549     if test "x[$]$1" = x; then
 550       AC_PATH_TOOL(POTENTIAL_$1, $SEARCH_LIST)
 551       $1=$POTENTIAL_$1
 552     fi
 553 
 554     if test "x[$]$1" = x; then
 555       HELP_MSG_MISSING_DEPENDENCY([devkit])
 556       AC_MSG_ERROR([Could not find a $COMPILER_NAME compiler. $HELP_MSG])
 557     fi
 558   fi
 559 
 560   # Now we have a compiler binary in $1. Make sure it's okay.
 561   BASIC_FIXUP_EXECUTABLE($1)
 562   TEST_COMPILER="[$]$1"
 563 
 564   AC_MSG_CHECKING([resolved symbolic links for $1])
 565   SYMLINK_ORIGINAL="$TEST_COMPILER"
 566   BASIC_REMOVE_SYMBOLIC_LINKS(SYMLINK_ORIGINAL)
 567   if test "x$TEST_COMPILER" = "x$SYMLINK_ORIGINAL"; then
 568     AC_MSG_RESULT([no symlink])
 569   else
 570     AC_MSG_RESULT([$SYMLINK_ORIGINAL])
 571 
 572     # We can't handle ccache by gcc wrappers, since we need to know if we're
 573     # using ccache. Instead ccache usage must be controlled by a configure option.
 574     COMPILER_BASENAME=`$BASENAME "$SYMLINK_ORIGINAL"`
 575     if test "x$COMPILER_BASENAME" = "xccache"; then
 576       AC_MSG_NOTICE([Please use --enable-ccache instead of providing a wrapped compiler.])
 577       AC_MSG_ERROR([$TEST_COMPILER is a symbolic link to ccache. This is not supported.])
 578     fi
 579   fi
 580 
 581   TOOLCHAIN_EXTRACT_COMPILER_VERSION([$1], [$COMPILER_NAME])
 582 ])
 583 
 584 # Retrieve the linker version number and store it in LD_VERSION_NUMBER
 585 # (as a dotted number), and
 586 # the full version string in LD_VERSION_STRING.
 587 #
 588 # $1 = linker to test (LD or BUILD_LD)
 589 # $2 = human readable name of linker (Linker or BuildLinker)
 590 AC_DEFUN([TOOLCHAIN_EXTRACT_LD_VERSION],
 591 [
 592   LINKER=[$]$1
 593   LINKER_NAME="$2"
 594 
 595   if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
 596     # cc -Wl,-V output typically looks like
 597     #   ld: Software Generation Utilities - Solaris Link Editors: 5.11-1.2329
 598 
 599     # solstudio cc requires us to have an existing file to pass as argument,
 600     # but it need not be a syntactically correct C file, so just use
 601     # ourself. :) The intermediate 'cat' is needed to stop ld from leaving
 602     # a lingering a.out (!).
 603     LINKER_VERSION_STRING=`$LD -Wl,-V $TOPDIR/configure 2>&1 | $CAT | $HEAD -n 1 | $SED -e 's/ld: //'`
 604     # Extract version number
 605     [ LINKER_VERSION_NUMBER=`$ECHO $LINKER_VERSION_STRING | \
 606         $SED -e 's/.* \([0-9][0-9]*\.[0-9][0-9]*\)-\([0-9][0-9]*\.[0-9][0-9]*\)/\1.\2/'` ]
 607   elif test  "x$TOOLCHAIN_TYPE" = xxlc; then
 608     LINKER_VERSION_STRING="Unknown"
 609     LINKER_VERSION_NUMBER="0.0"
 610   elif test  "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 611     # There is no specific version flag, but all output starts with a version string.
 612     # First line typically looks something like:
 613     #   Microsoft (R) Incremental Linker Version 12.00.31101.0
 614     LINKER_VERSION_STRING=`$LD 2>&1 | $HEAD -n 1 | $TR -d '\r'`
 615     # Extract version number
 616     [ LINKER_VERSION_NUMBER=`$ECHO $LINKER_VERSION_STRING | \
 617         $SED -e 's/.* \([0-9][0-9]*\(\.[0-9][0-9]*\)*\).*/\1/'` ]
 618   elif test  "x$TOOLCHAIN_TYPE" = xgcc; then
 619     # gcc -Wl,-version output typically looks like
 620     #   GNU ld (GNU Binutils for Ubuntu) 2.26.1
 621     #   Copyright (C) 2015 Free Software Foundation, Inc.
 622     #   This program is free software; [...]
 623     LINKER_VERSION_STRING=`$LD -Wl,-version 2>&1 | $HEAD -n 1`
 624     # Extract version number
 625     [ LINKER_VERSION_NUMBER=`$ECHO $LINKER_VERSION_STRING | \
 626         $SED -e 's/.* \([0-9][0-9]*\(\.[0-9][0-9]*\)*\).*/\1/'` ]
 627   elif test  "x$TOOLCHAIN_TYPE" = xclang; then
 628     # clang -Wl,-v output typically looks like
 629     #   @(#)PROGRAM:ld  PROJECT:ld64-305
 630     #   configured to support archs: armv6 armv7 armv7s arm64 i386 x86_64 x86_64h armv6m armv7k armv7m armv7em (tvOS)
 631     #   Library search paths: [...]
 632     # or
 633     #   GNU ld (GNU Binutils for Ubuntu) 2.26.1
 634 
 635     LINKER_VERSION_STRING=`$LD -Wl,-v 2>&1 | $HEAD -n 1`
 636     # Check if we're using the GNU ld
 637     $ECHO "$LINKER_VERSION_STRING" | $GREP "GNU" > /dev/null
 638     if test $? -eq 0; then
 639       # Extract version number
 640       [ LINKER_VERSION_NUMBER=`$ECHO $LINKER_VERSION_STRING | \
 641           $SED -e 's/.* \([0-9][0-9]*\(\.[0-9][0-9]*\)*\).*/\1/'` ]
 642     else
 643       # Extract version number
 644       [ LINKER_VERSION_NUMBER=`$ECHO $LINKER_VERSION_STRING | \
 645           $SED -e 's/.*-\([0-9][0-9]*\)/\1/'` ]
 646     fi
 647   fi
 648 
 649   $1_VERSION_NUMBER="$LINKER_VERSION_NUMBER"
 650   $1_VERSION_STRING="$LINKER_VERSION_STRING"
 651 
 652   AC_MSG_NOTICE([Using $TOOLCHAIN_TYPE $LINKER_NAME version $LINKER_VERSION_NUMBER @<:@$LINKER_VERSION_STRING@:>@])
 653 ])
 654 
 655 # Detect the core components of the toolchain, i.e. the compilers (CC and CXX),
 656 # preprocessor (CPP and CXXCPP), the linker (LD), the assembler (AS) and the
 657 # archiver (AR). Verify that the compilers are correct according to the
 658 # toolchain type.
 659 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_CORE],
 660 [
 661   #
 662   # Setup the compilers (CC and CXX)
 663   #
 664   TOOLCHAIN_FIND_COMPILER([CC], [C], $TOOLCHAIN_CC_BINARY)
 665   # Now that we have resolved CC ourself, let autoconf have its go at it
 666   AC_PROG_CC([$CC])
 667 
 668   TOOLCHAIN_FIND_COMPILER([CXX], [C++], $TOOLCHAIN_CXX_BINARY)
 669   # Now that we have resolved CXX ourself, let autoconf have its go at it
 670   AC_PROG_CXX([$CXX])
 671 
 672   # This is the compiler version number on the form X.Y[.Z]
 673   AC_SUBST(CC_VERSION_NUMBER)
 674   AC_SUBST(CXX_VERSION_NUMBER)
 675 
 676   TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS
 677 
 678   if test "x$TOOLCHAIN_MINIMUM_VERSION" != x; then
 679     TOOLCHAIN_CHECK_COMPILER_VERSION(VERSION: $TOOLCHAIN_MINIMUM_VERSION,
 680         IF_OLDER_THAN: [
 681           AC_MSG_WARN([You are using $TOOLCHAIN_TYPE older than $TOOLCHAIN_MINIMUM_VERSION. This is not a supported configuration.])
 682         ]
 683     )
 684   fi
 685 
 686   #
 687   # Setup the preprocessor (CPP and CXXCPP)
 688   #
 689   AC_PROG_CPP
 690   BASIC_FIXUP_EXECUTABLE(CPP)
 691   AC_PROG_CXXCPP
 692   BASIC_FIXUP_EXECUTABLE(CXXCPP)
 693 
 694   #
 695   # Setup the linker (LD)
 696   #
 697   if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 698     # In the Microsoft toolchain we have a separate LD command "link".
 699     # Make sure we reject /usr/bin/link (as determined in CYGWIN_LINK), which is
 700     # a cygwin program for something completely different.
 701     AC_CHECK_PROG([LD], [link],[link],,, [$CYGWIN_LINK])
 702     BASIC_FIXUP_EXECUTABLE(LD)
 703     # Verify that we indeed succeeded with this trick.
 704     AC_MSG_CHECKING([if the found link.exe is actually the Visual Studio linker])
 705     "$LD" --version > /dev/null
 706     if test $? -eq 0 ; then
 707       AC_MSG_RESULT([no])
 708       AC_MSG_ERROR([This is the Cygwin link tool. Please check your PATH and rerun configure.])
 709     else
 710       AC_MSG_RESULT([yes])
 711     fi
 712     LDCXX="$LD"
 713     # jaotc being a windows program expects the linker to be supplied with exe suffix.
 714     LD_JAOTC="$LD$EXE_SUFFIX"
 715   else
 716     # All other toolchains use the compiler to link.
 717     LD="$CC"
 718     LDCXX="$CXX"
 719     # jaotc expects 'ld' as the linker rather than the compiler.
 720     BASIC_CHECK_TOOLS([LD_JAOTC], ld)
 721     BASIC_FIXUP_EXECUTABLE(LD_JAOTC)
 722   fi
 723   AC_SUBST(LD)
 724   AC_SUBST(LD_JAOTC)
 725   # FIXME: it should be CXXLD, according to standard (cf CXXCPP)
 726   AC_SUBST(LDCXX)
 727 
 728   TOOLCHAIN_EXTRACT_LD_VERSION([LD], [linker])
 729   TOOLCHAIN_PREPARE_FOR_LD_VERSION_COMPARISONS
 730 
 731   if test "x$TOOLCHAIN_MINIMUM_LD_VERSION" != x; then
 732     TOOLCHAIN_CHECK_LINKER_VERSION(VERSION: $TOOLCHAIN_MINIMUM_LD_VERSION,
 733         IF_OLDER_THAN: [
 734           AC_MSG_WARN([You are using a linker older than $TOOLCHAIN_MINIMUM_LD_VERSION. This is not a supported configuration.])
 735         ]
 736     )
 737   fi
 738 
 739   #
 740   # Setup the assembler (AS)
 741   #
 742   if test "x$OPENJDK_TARGET_OS" = xsolaris; then
 743     BASIC_PATH_PROGS(AS, as)
 744     BASIC_FIXUP_EXECUTABLE(AS)
 745     if test "x$AS" = x; then
 746       AC_MSG_ERROR([Solaris assembler (as) is required. Please install via "pkg install pkg:/developer/assembler".])
 747     fi
 748   else
 749     # FIXME: is this correct for microsoft?
 750     AS="$CC -c"
 751   fi
 752   AC_SUBST(AS)
 753 
 754   #
 755   # Setup the archiver (AR)
 756   #
 757   if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 758     # The corresponding ar tool is lib.exe (used to create static libraries)
 759     AC_CHECK_PROG([AR], [lib],[lib],,,)
 760   elif test "x$TOOLCHAIN_TYPE" = xgcc; then
 761     BASIC_CHECK_TOOLS(AR, ar gcc-ar)
 762   else
 763     BASIC_CHECK_TOOLS(AR, ar)
 764   fi
 765   BASIC_FIXUP_EXECUTABLE(AR)
 766 ])
 767 
 768 # Setup additional tools that is considered a part of the toolchain, but not the
 769 # core part. Many of these are highly platform-specific and do not exist,
 770 # and/or are not needed on all platforms.
 771 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_EXTRA],
 772 [
 773   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
 774     BASIC_PATH_PROGS(LIPO, lipo)
 775     BASIC_FIXUP_EXECUTABLE(LIPO)
 776     BASIC_REQUIRE_PROGS(OTOOL, otool)
 777     BASIC_FIXUP_EXECUTABLE(OTOOL)
 778     BASIC_REQUIRE_PROGS(INSTALL_NAME_TOOL, install_name_tool)
 779     BASIC_FIXUP_EXECUTABLE(INSTALL_NAME_TOOL)
 780   fi
 781 
 782   if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
 783     AC_CHECK_PROG([MT], [mt], [mt],,, [/usr/bin/mt])
 784     BASIC_FIXUP_EXECUTABLE(MT)
 785     # Setup the resource compiler (RC)
 786     AC_CHECK_PROG([RC], [rc], [rc],,, [/usr/bin/rc])
 787     BASIC_FIXUP_EXECUTABLE(RC)
 788     AC_CHECK_PROG([DUMPBIN], [dumpbin], [dumpbin],,,)
 789     BASIC_FIXUP_EXECUTABLE(DUMPBIN)
 790     # We need to check for 'msbuild.exe' because at the place where we expect to
 791     # find 'msbuild.exe' there's also a directory called 'msbuild' and configure
 792     # won't find the 'msbuild.exe' executable in that case (and the
 793     # 'ac_executable_extensions' is unusable due to performance reasons).
 794     # Notice that we intentionally don't fix up the path to MSBUILD because we
 795     # will call it in a DOS shell during freetype detection on Windows (see
 796     # 'LIB_SETUP_FREETYPE' in "libraries.m4"
 797     AC_CHECK_PROG([MSBUILD], [msbuild.exe], [msbuild.exe],,,)
 798   fi
 799 
 800   if test "x$OPENJDK_TARGET_OS" = xsolaris; then
 801     BASIC_PATH_PROGS(STRIP, strip)
 802     BASIC_FIXUP_EXECUTABLE(STRIP)
 803     BASIC_PATH_PROGS(NM, nm)
 804     BASIC_FIXUP_EXECUTABLE(NM)
 805     BASIC_PATH_PROGS(GNM, gnm)
 806     BASIC_FIXUP_EXECUTABLE(GNM)
 807   elif test "x$OPENJDK_TARGET_OS" != xwindows; then
 808     # FIXME: we should unify this with the solaris case above.
 809     BASIC_CHECK_TOOLS(STRIP, strip)
 810     BASIC_FIXUP_EXECUTABLE(STRIP)
 811     if test "x$TOOLCHAIN_TYPE" = xgcc; then
 812       BASIC_CHECK_TOOLS(NM, nm gcc-nm)
 813     else
 814       BASIC_CHECK_TOOLS(NM, nm)
 815     fi
 816     BASIC_FIXUP_EXECUTABLE(NM)
 817     GNM="$NM"
 818     AC_SUBST(GNM)
 819   fi
 820 
 821   # objcopy is used for moving debug symbols to separate files when
 822   # full debug symbols are enabled.
 823   if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
 824     BASIC_CHECK_TOOLS(OBJCOPY, [gobjcopy objcopy])
 825     # Only call fixup if objcopy was found.
 826     if test -n "$OBJCOPY"; then
 827       BASIC_FIXUP_EXECUTABLE(OBJCOPY)
 828       if test "x$OPENJDK_BUILD_OS" = xsolaris; then
 829         # objcopy prior to 2.21.1 on solaris is broken and is not usable.
 830         # Rewrite objcopy version output to VALID_VERSION or BAD_VERSION.
 831         # - version number is last blank separate word on first line
 832         # - version number formats that have been seen:
 833         #   - <major>.<minor>
 834         #   - <major>.<minor>.<micro>
 835         OBJCOPY_VERSION=`$OBJCOPY --version | $HEAD -n 1`
 836         # The outer [ ] is to prevent m4 from eating the [] in the sed expression.
 837         [ OBJCOPY_VERSION_CHECK=`$ECHO $OBJCOPY_VERSION | $SED -n \
 838               -e 's/.* //' \
 839               -e '/^[01]\./b bad' \
 840               -e '/^2\./{' \
 841               -e '  s/^2\.//' \
 842               -e '  /^[0-9]$/b bad' \
 843               -e '  /^[0-9]\./b bad' \
 844               -e '  /^1[0-9]$/b bad' \
 845               -e '  /^1[0-9]\./b bad' \
 846               -e '  /^20\./b bad' \
 847               -e '  /^21\.0$/b bad' \
 848               -e '  /^21\.0\./b bad' \
 849               -e '}' \
 850               -e ':good' \
 851               -e 's/.*/VALID_VERSION/p' \
 852               -e 'q' \
 853               -e ':bad' \
 854               -e 's/.*/BAD_VERSION/p' \
 855               -e 'q'` ]
 856         if test "x$OBJCOPY_VERSION_CHECK" = xBAD_VERSION; then
 857           OBJCOPY=
 858           AC_MSG_WARN([Ignoring found objcopy since it is broken (prior to 2.21.1). No debug symbols will be generated.])
 859           AC_MSG_NOTICE([objcopy reports version $OBJCOPY_VERSION])
 860           AC_MSG_NOTICE([Note: patch 149063-01 or newer contains the correct Solaris 10 SPARC version])
 861           AC_MSG_NOTICE([Note: patch 149064-01 or newer contains the correct Solaris 10 X86 version])
 862           AC_MSG_NOTICE([Note: Solaris 11 Update 1 contains the correct version])
 863         fi
 864       fi
 865     fi
 866   fi
 867 
 868   BASIC_CHECK_TOOLS(OBJDUMP, [gobjdump objdump])
 869   if test "x$OBJDUMP" != x; then
 870     # Only used for compare.sh; we can live without it. BASIC_FIXUP_EXECUTABLE
 871     # bails if argument is missing.
 872     BASIC_FIXUP_EXECUTABLE(OBJDUMP)
 873   fi
 874 
 875   case $TOOLCHAIN_TYPE in
 876     gcc|clang|solstudio)
 877       BASIC_CHECK_TOOLS(CXXFILT, [c++filt])
 878       BASIC_CHECK_NONEMPTY(CXXFILT)
 879       BASIC_FIXUP_EXECUTABLE(CXXFILT)
 880       ;;
 881   esac
 882 ])
 883 
 884 # Setup the build tools (i.e, the compiler and linker used to build programs
 885 # that should be run on the build platform, not the target platform, as a build
 886 # helper). Since the non-cross-compile case uses the normal, target compilers
 887 # for this, we can only do this after these have been setup.
 888 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_BUILD_COMPILERS],
 889 [
 890   if test "x$COMPILE_TYPE" = "xcross"; then
 891     # Now we need to find a C/C++ compiler that can build executables for the
 892     # build platform. We can't use the AC_PROG_CC macro, since it can only be
 893     # used once. Also, we need to do this without adding a tools dir to the
 894     # path, otherwise we might pick up cross-compilers which don't use standard
 895     # naming.
 896 
 897     OLDPATH="$PATH"
 898 
 899     AC_ARG_WITH(build-devkit, [AS_HELP_STRING([--with-build-devkit],
 900         [Devkit to use for the build platform toolchain])])
 901     if test "x$with_build_devkit" = "xyes"; then
 902       AC_MSG_ERROR([--with-build-devkit must have a value])
 903     elif test -n "$with_build_devkit"; then
 904       if test ! -d "$with_build_devkit"; then
 905         AC_MSG_ERROR([--with-build-devkit points to non existing dir: $with_build_devkit])
 906       else
 907         BASIC_FIXUP_PATH([with_build_devkit])
 908         BUILD_DEVKIT_ROOT="$with_build_devkit"
 909         # Check for a meta data info file in the root of the devkit
 910         if test -f "$BUILD_DEVKIT_ROOT/devkit.info"; then
 911           # Process devkit.info so that existing devkit variables are not
 912           # modified by this
 913           $SED -e "s/^DEVKIT_/BUILD_DEVKIT_/g" \
 914               -e "s/\$DEVKIT_ROOT/\$BUILD_DEVKIT_ROOT/g" \
 915               -e "s/\$host/\$build/g" \
 916               $BUILD_DEVKIT_ROOT/devkit.info \
 917               > $CONFIGURESUPPORT_OUTPUTDIR/build-devkit.info
 918           . $CONFIGURESUPPORT_OUTPUTDIR/build-devkit.info
 919           # This potentially sets the following:
 920           # A descriptive name of the devkit
 921           BASIC_EVAL_DEVKIT_VARIABLE([BUILD_DEVKIT_NAME])
 922           # Corresponds to --with-extra-path
 923           BASIC_EVAL_DEVKIT_VARIABLE([BUILD_DEVKIT_EXTRA_PATH])
 924           # Corresponds to --with-toolchain-path
 925           BASIC_EVAL_DEVKIT_VARIABLE([BUILD_DEVKIT_TOOLCHAIN_PATH])
 926           # Corresponds to --with-sysroot
 927           BASIC_EVAL_DEVKIT_VARIABLE([BUILD_DEVKIT_SYSROOT])
 928           # Skip the Window specific parts
 929         fi
 930 
 931         AC_MSG_CHECKING([for build platform devkit])
 932         if test "x$BUILD_DEVKIT_NAME" != x; then
 933           AC_MSG_RESULT([$BUILD_DEVKIT_NAME in $BUILD_DEVKIT_ROOT])
 934         else
 935           AC_MSG_RESULT([$BUILD_DEVKIT_ROOT])
 936         fi
 937 
 938         BUILD_SYSROOT="$BUILD_DEVKIT_SYSROOT"
 939 
 940          # Fallback default of just /bin if DEVKIT_PATH is not defined
 941         if test "x$BUILD_DEVKIT_TOOLCHAIN_PATH" = x; then
 942           BUILD_DEVKIT_TOOLCHAIN_PATH="$BUILD_DEVKIT_ROOT/bin"
 943         fi
 944         PATH="$BUILD_DEVKIT_TOOLCHAIN_PATH:$BUILD_DEVKIT_EXTRA_PATH"
 945       fi
 946     fi
 947 
 948     # FIXME: we should list the discovered compilers as an exclude pattern!
 949     # If we do that, we can do this detection before POST_DETECTION, and still
 950     # find the build compilers in the tools dir, if needed.
 951     if test "x$OPENJDK_BUILD_OS" = xmacosx; then
 952       BASIC_REQUIRE_PROGS(BUILD_CC, [clang cl cc gcc])
 953       BASIC_REQUIRE_PROGS(BUILD_CXX, [clang++ cl CC g++])
 954     else
 955       BASIC_REQUIRE_PROGS(BUILD_CC, [cl cc gcc])
 956       BASIC_REQUIRE_PROGS(BUILD_CXX, [cl CC g++])
 957     fi
 958     BASIC_FIXUP_EXECUTABLE(BUILD_CC)
 959     BASIC_FIXUP_EXECUTABLE(BUILD_CXX)
 960     BASIC_PATH_PROGS(BUILD_NM, nm gcc-nm)
 961     BASIC_FIXUP_EXECUTABLE(BUILD_NM)
 962     BASIC_PATH_PROGS(BUILD_AR, ar gcc-ar)
 963     BASIC_FIXUP_EXECUTABLE(BUILD_AR)
 964     BASIC_PATH_PROGS(BUILD_OBJCOPY, objcopy)
 965     BASIC_FIXUP_EXECUTABLE(BUILD_OBJCOPY)
 966     BASIC_PATH_PROGS(BUILD_STRIP, strip)
 967     BASIC_FIXUP_EXECUTABLE(BUILD_STRIP)
 968     # Assume the C compiler is the assembler
 969     BUILD_AS="$BUILD_CC -c"
 970     # Just like for the target compiler, use the compiler as linker
 971     BUILD_LD="$BUILD_CC"
 972     BUILD_LDCXX="$BUILD_CXX"
 973 
 974     PATH="$OLDPATH"
 975 
 976     TOOLCHAIN_EXTRACT_COMPILER_VERSION(BUILD_CC, [BuildC])
 977     TOOLCHAIN_EXTRACT_COMPILER_VERSION(BUILD_CXX, [BuildC++])
 978     TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS([BUILD_], [OPENJDK_BUILD_])
 979     TOOLCHAIN_EXTRACT_LD_VERSION(BUILD_LD, [build linker])
 980     TOOLCHAIN_PREPARE_FOR_LD_VERSION_COMPARISONS([BUILD_], [OPENJDK_BUILD_])
 981   else
 982     # If we are not cross compiling, use the normal target compilers for
 983     # building the build platform executables.
 984     BUILD_CC="$CC"
 985     BUILD_CXX="$CXX"
 986     BUILD_LD="$LD"
 987     BUILD_LDCXX="$LDCXX"
 988     BUILD_NM="$NM"
 989     BUILD_AS="$AS"
 990     BUILD_OBJCOPY="$OBJCOPY"
 991     BUILD_STRIP="$STRIP"
 992     BUILD_AR="$AR"
 993 
 994     TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS([], [OPENJDK_BUILD_])
 995     TOOLCHAIN_PREPARE_FOR_LD_VERSION_COMPARISONS([BUILD_], [OPENJDK_BUILD_])
 996   fi
 997 
 998   AC_SUBST(BUILD_CC)
 999   AC_SUBST(BUILD_CXX)
1000   AC_SUBST(BUILD_LD)
1001   AC_SUBST(BUILD_LDCXX)
1002   AC_SUBST(BUILD_NM)
1003   AC_SUBST(BUILD_AS)
1004   AC_SUBST(BUILD_AR)
1005 ])
1006 
1007 # Do some additional checks on the detected tools.
1008 AC_DEFUN_ONCE([TOOLCHAIN_MISC_CHECKS],
1009 [
1010   # The package path is used only on macosx?
1011   # FIXME: clean this up, and/or move it elsewhere.
1012   PACKAGE_PATH=/opt/local
1013   AC_SUBST(PACKAGE_PATH)
1014 
1015   # Check for extra potential brokenness.
1016   if test  "x$TOOLCHAIN_TYPE" = xmicrosoft; then
1017     # On Windows, double-check that we got the right compiler.
1018     CC_VERSION_OUTPUT=`$CC 2>&1 | $HEAD -n 1 | $TR -d '\r'`
1019     COMPILER_CPU_TEST=`$ECHO $CC_VERSION_OUTPUT | $SED -n "s/^.* \(.*\)$/\1/p"`
1020     if test "x$OPENJDK_TARGET_CPU" = "xx86"; then
1021       if test "x$COMPILER_CPU_TEST" != "x80x86" -a "x$COMPILER_CPU_TEST" != "xx86"; then
1022         AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "80x86" or "x86".])
1023       fi
1024     elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
1025       if test "x$COMPILER_CPU_TEST" != "xx64"; then
1026         AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "x64".])
1027       fi
1028     fi
1029   fi
1030 
1031   if test "x$TOOLCHAIN_TYPE" = xgcc; then
1032     # If this is a --hash-style=gnu system, use --hash-style=both, why?
1033     HAS_GNU_HASH=`$CC -dumpspecs 2>/dev/null | $GREP 'hash-style=gnu'`
1034     # This is later checked when setting flags.
1035   fi
1036 
1037   if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
1038     # Check if linker has -z noexecstack.
1039     HAS_NOEXECSTACK=`$CC -Wl,--help 2>/dev/null | $GREP 'z noexecstack'`
1040     # This is later checked when setting flags.
1041   fi
1042 
1043   # Setup hotspot lecagy names for toolchains
1044   HOTSPOT_TOOLCHAIN_TYPE=$TOOLCHAIN_TYPE
1045   if test "x$TOOLCHAIN_TYPE" = xclang; then
1046     HOTSPOT_TOOLCHAIN_TYPE=gcc
1047   elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
1048     HOTSPOT_TOOLCHAIN_TYPE=sparcWorks
1049   elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
1050     HOTSPOT_TOOLCHAIN_TYPE=visCPP
1051   fi
1052   AC_SUBST(HOTSPOT_TOOLCHAIN_TYPE)
1053 ])
1054 
1055 # Setup the JTReg Regression Test Harness.
1056 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JTREG],
1057 [
1058   AC_ARG_WITH(jtreg, [AS_HELP_STRING([--with-jtreg],
1059       [Regression Test Harness @<:@probed@:>@])])
1060 
1061   if test "x$with_jtreg" = xno; then
1062     # jtreg disabled
1063     AC_MSG_CHECKING([for jtreg test harness])
1064     AC_MSG_RESULT([no, disabled])
1065   elif test "x$with_jtreg" != xyes && test "x$with_jtreg" != x; then
1066     # An explicit path is specified, use it.
1067     JT_HOME="$with_jtreg"
1068     BASIC_FIXUP_PATH([JT_HOME])
1069     if test ! -d "$JT_HOME"; then
1070       AC_MSG_ERROR([jtreg home directory from --with-jtreg=$with_jtreg does not exist])
1071     fi
1072 
1073     if test ! -e "$JT_HOME/lib/jtreg.jar"; then
1074       AC_MSG_ERROR([jtreg home directory from --with-jtreg=$with_jtreg is not a valid jtreg home])
1075     fi
1076 
1077     JTREGEXE="$JT_HOME/bin/jtreg"
1078     if test ! -x "$JTREGEXE"; then
1079       AC_MSG_ERROR([jtreg home directory from --with-jtreg=$with_jtreg does not contain valid jtreg executable])
1080     fi
1081 
1082     AC_MSG_CHECKING([for jtreg test harness])
1083     AC_MSG_RESULT([$JT_HOME])
1084   else
1085     # Try to locate jtreg
1086     if test "x$JT_HOME" != x; then
1087       # JT_HOME set in environment, use it
1088       if test ! -d "$JT_HOME"; then
1089         AC_MSG_WARN([Ignoring JT_HOME pointing to invalid directory: $JT_HOME])
1090         JT_HOME=
1091       else
1092         if test ! -e "$JT_HOME/lib/jtreg.jar"; then
1093           AC_MSG_WARN([Ignoring JT_HOME which is not a valid jtreg home: $JT_HOME])
1094           JT_HOME=
1095         elif test ! -x "$JT_HOME/bin/jtreg"; then
1096           AC_MSG_WARN([Ignoring JT_HOME which does not contain valid jtreg executable: $JT_HOME])
1097           JT_HOME=
1098         else
1099           JTREGEXE="$JT_HOME/bin/jtreg"
1100           AC_MSG_NOTICE([Located jtreg using JT_HOME from environment])
1101         fi
1102       fi
1103     fi
1104 
1105     if test "x$JT_HOME" = x; then
1106       # JT_HOME is not set in environment, or was deemed invalid.
1107       # Try to find jtreg on path
1108       BASIC_PATH_PROGS(JTREGEXE, jtreg)
1109       if test "x$JTREGEXE" != x; then
1110         # That's good, now try to derive JT_HOME
1111         JT_HOME=`(cd $($DIRNAME $JTREGEXE)/.. && pwd)`
1112         if test ! -e "$JT_HOME/lib/jtreg.jar"; then
1113           AC_MSG_WARN([Ignoring jtreg from path since a valid jtreg home cannot be found])
1114           JT_HOME=
1115           JTREGEXE=
1116         else
1117           AC_MSG_NOTICE([Located jtreg using jtreg executable in path])
1118         fi
1119       fi
1120     fi
1121 
1122     AC_MSG_CHECKING([for jtreg test harness])
1123     if test "x$JT_HOME" != x; then
1124       AC_MSG_RESULT([$JT_HOME])
1125     else
1126       AC_MSG_RESULT([no, not found])
1127 
1128       if test "x$with_jtreg" = xyes; then
1129         AC_MSG_ERROR([--with-jtreg was specified, but no jtreg found.])
1130       fi
1131     fi
1132   fi
1133 
1134   BASIC_FIXUP_EXECUTABLE(JTREGEXE)
1135   BASIC_FIXUP_PATH(JT_HOME)
1136   AC_SUBST(JT_HOME)
1137   AC_SUBST(JTREGEXE)
1138 ])
1139 
1140 # Setup the JIB dependency resolver
1141 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JIB],
1142 [
1143   AC_ARG_WITH(jib, [AS_HELP_STRING([--with-jib],
1144       [Jib dependency management tool @<:@not used@:>@])])
1145 
1146   if test "x$with_jib" = xno || test "x$with_jib" = x; then
1147     # jib disabled
1148     AC_MSG_CHECKING([for jib])
1149     AC_MSG_RESULT(no)
1150   elif test "x$with_jib" = xyes; then
1151     AC_MSG_ERROR([Must supply a value to --with-jib])
1152   else
1153     JIB_HOME="${with_jib}"
1154     AC_MSG_CHECKING([for jib])
1155     AC_MSG_RESULT(${JIB_HOME})
1156     if test ! -d "${JIB_HOME}"; then
1157       AC_MSG_ERROR([--with-jib must be a directory])
1158     fi
1159     JIB_JAR=$(ls ${JIB_HOME}/lib/jib-*.jar)
1160     if test ! -f "${JIB_JAR}"; then
1161       AC_MSG_ERROR([Could not find jib jar file in ${JIB_HOME}])
1162     fi
1163   fi
1164 
1165   AC_SUBST(JIB_HOME)
1166 ])