1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # All valid JVM features, regardless of platform
27 VALID_JVM_FEATURES="compiler1 compiler2 zero minimal dtrace jvmti jvmci \
28 graal vm-structs jni-check services management cmsgc epsilongc g1gc parallelgc serialgc shenandoahgc zgc nmt cds \
29 static-build link-time-opt aot jfr"
30
31 # Deprecated JVM features (these are ignored, but with a warning)
32 DEPRECATED_JVM_FEATURES="trace"
33
34 # All valid JVM variants
35 VALID_JVM_VARIANTS="server client minimal core zero custom"
36
37 ###############################################################################
38 # Check if the specified JVM variant should be built. To be used in shell if
39 # constructs, like this:
40 # if HOTSPOT_CHECK_JVM_VARIANT(server); then
41 #
42 # Only valid to use after HOTSPOT_SETUP_JVM_VARIANTS has setup variants.
43
44 # Definition kept in one line to allow inlining in if statements.
45 # Additional [] needed to keep m4 from mangling shell constructs.
46 AC_DEFUN([HOTSPOT_CHECK_JVM_VARIANT],
47 [ [ [[ " $JVM_VARIANTS " =~ " $1 " ]] ] ])
48
49 ###############################################################################
50 # Check if the specified JVM features are explicitly enabled. To be used in
51 # shell if constructs, like this:
52 # if HOTSPOT_CHECK_JVM_FEATURE(jvmti); then
53 #
54 # Only valid to use after HOTSPOT_SETUP_JVM_FEATURES has setup features.
55
56 # Definition kept in one line to allow inlining in if statements.
57 # Additional [] needed to keep m4 from mangling shell constructs.
58 AC_DEFUN([HOTSPOT_CHECK_JVM_FEATURE],
59 [ [ [[ " $JVM_FEATURES " =~ " $1 " ]] ] ])
60
61 ###############################################################################
62 # Check which variants of the JVM that we want to build. Available variants are:
63 # server: normal interpreter, and a tiered C1/C2 compiler
64 # client: normal interpreter, and C1 (no C2 compiler)
65 # minimal: reduced form of client with optional features stripped out
66 # core: normal interpreter only, no compiler
67 # zero: C++ based interpreter only, no compiler
68 # custom: baseline JVM with no default features
69 #
70 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_VARIANTS],
71 [
72 AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
73 [JVM variants (separated by commas) to build (server,client,minimal,core,zero,custom) @<:@server@:>@])])
74
75 SETUP_HOTSPOT_TARGET_CPU_PORT
76
77 if test "x$with_jvm_variants" = x; then
78 with_jvm_variants="server"
79 fi
80 JVM_VARIANTS_OPT="$with_jvm_variants"
81
82 # Has the user listed more than one variant?
83 # Additional [] needed to keep m4 from mangling shell constructs.
84 if [ [[ "$JVM_VARIANTS_OPT" =~ "," ]] ]; then
85 BUILDING_MULTIPLE_JVM_VARIANTS=true
86 else
87 BUILDING_MULTIPLE_JVM_VARIANTS=false
88 fi
89 # Replace the commas with AND for use in the build directory name.
90 JVM_VARIANTS_WITH_AND=`$ECHO "$JVM_VARIANTS_OPT" | $SED -e 's/,/AND/g'`
91
92 AC_MSG_CHECKING([which variants of the JVM to build])
93 # JVM_VARIANTS is a space-separated list.
94 # Also use minimal, not minimal1 (which is kept for backwards compatibility).
95 JVM_VARIANTS=`$ECHO $JVM_VARIANTS_OPT | $SED -e 's/,/ /g' -e 's/minimal1/minimal/'`
96 AC_MSG_RESULT([$JVM_VARIANTS])
97
98 # Check that the selected variants are valid
99 BASIC_GET_NON_MATCHING_VALUES(INVALID_VARIANTS, $JVM_VARIANTS, $VALID_JVM_VARIANTS)
100 if test "x$INVALID_VARIANTS" != x; then
101 AC_MSG_NOTICE([Unknown variant(s) specified: "$INVALID_VARIANTS"])
102 AC_MSG_NOTICE([The available JVM variants are: "$VALID_JVM_VARIANTS"])
103 AC_MSG_ERROR([Cannot continue])
104 fi
105
106 # All "special" variants share the same output directory ("server")
107 VALID_MULTIPLE_JVM_VARIANTS="server client minimal"
108 BASIC_GET_NON_MATCHING_VALUES(INVALID_MULTIPLE_VARIANTS, $JVM_VARIANTS, $VALID_MULTIPLE_JVM_VARIANTS)
109 if test "x$INVALID_MULTIPLE_VARIANTS" != x && test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = xtrue; then
110 AC_MSG_ERROR([You cannot build multiple variants with anything else than $VALID_MULTIPLE_JVM_VARIANTS.])
111 fi
112
113 # The "main" variant is the one used by other libs to link against during the
114 # build.
115 if test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = "xtrue"; then
116 MAIN_VARIANT_PRIO_ORDER="server client minimal"
117 for variant in $MAIN_VARIANT_PRIO_ORDER; do
118 if HOTSPOT_CHECK_JVM_VARIANT($variant); then
119 JVM_VARIANT_MAIN="$variant"
120 break
121 fi
122 done
123 else
124 JVM_VARIANT_MAIN="$JVM_VARIANTS"
125 fi
126
127 AC_SUBST(JVM_VARIANTS)
128 AC_SUBST(VALID_JVM_VARIANTS)
129 AC_SUBST(JVM_VARIANT_MAIN)
130
131 if HOTSPOT_CHECK_JVM_VARIANT(zero); then
132 # zero behaves as a platform and rewrites these values. This is really weird. :(
133 # We are guaranteed that we do not build any other variants when building zero.
134 HOTSPOT_TARGET_CPU=zero
135 HOTSPOT_TARGET_CPU_ARCH=zero
136 fi
137 ])
138
139 ###############################################################################
140 # Check if dtrace should be enabled and has all prerequisites present.
141 #
142 AC_DEFUN_ONCE([HOTSPOT_SETUP_DTRACE],
143 [
144 # Test for dtrace dependencies
145 AC_ARG_ENABLE([dtrace], [AS_HELP_STRING([--enable-dtrace@<:@=yes/no/auto@:>@],
146 [enable dtrace. Default is auto, where dtrace is enabled if all dependencies
147 are present.])])
148
149 DTRACE_DEP_MISSING=false
150
151 AC_MSG_CHECKING([for dtrace tool])
152 if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
153 AC_MSG_RESULT([$DTRACE])
154 else
155 AC_MSG_RESULT([not found, cannot build dtrace])
156 DTRACE_DEP_MISSING=true
157 fi
158
159 AC_CHECK_HEADERS([sys/sdt.h], [DTRACE_HEADERS_OK=yes],[DTRACE_HEADERS_OK=no])
160 if test "x$DTRACE_HEADERS_OK" != "xyes"; then
161 DTRACE_DEP_MISSING=true
162 fi
163
164 AC_MSG_CHECKING([if dtrace should be built])
165 if test "x$enable_dtrace" = "xyes"; then
166 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
167 AC_MSG_RESULT([no, missing dependencies])
168 HELP_MSG_MISSING_DEPENDENCY([dtrace])
169 AC_MSG_ERROR([Cannot enable dtrace with missing dependencies. See above. $HELP_MSG])
170 else
171 INCLUDE_DTRACE=true
172 AC_MSG_RESULT([yes, forced])
173 fi
174 elif test "x$enable_dtrace" = "xno"; then
175 INCLUDE_DTRACE=false
176 AC_MSG_RESULT([no, forced])
177 elif test "x$enable_dtrace" = "xauto" || test "x$enable_dtrace" = "x"; then
178 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
179 INCLUDE_DTRACE=false
180 AC_MSG_RESULT([no, missing dependencies])
181 else
182 INCLUDE_DTRACE=true
183 AC_MSG_RESULT([yes, dependencies present])
184 fi
185 else
186 AC_MSG_ERROR([Invalid value for --enable-dtrace: $enable_dtrace])
187 fi
188 ])
189
190 ################################################################################
191 # Check if AOT should be enabled
192 #
193 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_AOT],
194 [
195 AC_ARG_ENABLE([aot], [AS_HELP_STRING([--enable-aot@<:@=yes/no/auto@:>@],
196 [enable ahead of time compilation feature. Default is auto, where aot is enabled if all dependencies are present.])])
197
198 if test "x$enable_aot" = "x" || test "x$enable_aot" = "xauto"; then
199 ENABLE_AOT="true"
200 elif test "x$enable_aot" = "xyes"; then
201 ENABLE_AOT="true"
202 elif test "x$enable_aot" = "xno"; then
203 ENABLE_AOT="false"
204 else
205 AC_MSG_ERROR([Invalid value for --enable-aot: $enable_aot])
206 fi
207
208 if test "x$ENABLE_AOT" = "xtrue"; then
209 # Only enable AOT on X64 platforms.
210 if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
211 if test -e "${TOPDIR}/src/jdk.aot"; then
212 if test -e "${TOPDIR}/src/jdk.internal.vm.compiler"; then
213 ENABLE_AOT="true"
214 else
215 ENABLE_AOT="false"
216 if test "x$enable_aot" = "xyes"; then
217 AC_MSG_ERROR([Cannot build AOT without src/jdk.internal.vm.compiler sources. Remove --enable-aot.])
218 fi
219 fi
220 else
221 ENABLE_AOT="false"
222 if test "x$enable_aot" = "xyes"; then
223 AC_MSG_ERROR([Cannot build AOT without src/jdk.aot sources. Remove --enable-aot.])
224 fi
225 fi
226 else
227 ENABLE_AOT="false"
228 if test "x$enable_aot" = "xyes"; then
229 AC_MSG_ERROR([AOT is currently only supported on x86_64 and aarch64. Remove --enable-aot.])
230 fi
231 fi
232 fi
233
234 AC_SUBST(ENABLE_AOT)
235 ])
236
237 ################################################################################
238 # Allow to disable CDS
239 #
240 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_CDS],
241 [
242 AC_ARG_ENABLE([cds], [AS_HELP_STRING([--enable-cds@<:@=yes/no/auto@:>@],
243 [enable class data sharing feature in non-minimal VM. Default is auto, where cds is enabled if supported on the platform.])])
244
245 if test "x$enable_cds" = "x" || test "x$enable_cds" = "xauto"; then
246 ENABLE_CDS="true"
247 elif test "x$enable_cds" = "xyes"; then
248 ENABLE_CDS="true"
249 elif test "x$enable_cds" = "xno"; then
250 ENABLE_CDS="false"
251 else
252 AC_MSG_ERROR([Invalid value for --enable-cds: $enable_cds])
253 fi
254
255 # Disable CDS on AIX.
256 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
257 ENABLE_CDS="false"
258 if test "x$enable_cds" = "xyes"; then
259 AC_MSG_ERROR([CDS is currently not supported on AIX. Remove --enable-cds.])
260 fi
261 fi
262
263 AC_SUBST(ENABLE_CDS)
264 ])
265
266 ###############################################################################
267 # Set up all JVM features for each JVM variant.
268 #
269 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_FEATURES],
270 [
271 # Prettify the VALID_JVM_FEATURES string
272 BASIC_SORT_LIST(VALID_JVM_FEATURES, $VALID_JVM_FEATURES)
273
274 # The user can in some cases supply additional jvm features. For the custom
275 # variant, this defines the entire variant.
276 AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
277 [JVM features to enable (foo) or disable (-foo), separated by comma. Use '--help' to show possible values @<:@none@:>@])])
278 if test "x$with_jvm_features" != x; then
279 AC_MSG_CHECKING([user specified JVM feature list])
280 USER_JVM_FEATURE_LIST=`$ECHO $with_jvm_features | $SED -e 's/,/ /g'`
281 AC_MSG_RESULT([$user_jvm_feature_list])
282 # These features will be added to all variant defaults
283 JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (!match($i, /^-.*/)) printf("%s ", $i) }'`
284 # These features will be removed from all variant defaults
285 DISABLED_JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (match($i, /^-.*/)) printf("%s ", substr($i, 2))}'`
286
287 # Verify that the user has provided valid features
288 BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES $DISABLED_JVM_FEATURES, $VALID_JVM_FEATURES $DEPRECATED_JVM_FEATURES)
289 if test "x$INVALID_FEATURES" != x; then
290 AC_MSG_NOTICE([Unknown JVM features specified: "$INVALID_FEATURES"])
291 AC_MSG_NOTICE([The available JVM features are: "$VALID_JVM_FEATURES"])
292 AC_MSG_ERROR([Cannot continue])
293 fi
294
295 # Check if the user has provided deprecated features
296 BASIC_GET_MATCHING_VALUES(DEPRECATED_FEATURES, $JVM_FEATURES $DISABLED_JVM_FEATURES, $DEPRECATED_JVM_FEATURES)
297 if test "x$DEPRECATED_FEATURES" != x; then
298 AC_MSG_WARN([Deprecated JVM features specified (will be ignored): "$DEPRECATED_FEATURES"])
299 # Filter out deprecated features
300 BASIC_GET_NON_MATCHING_VALUES(JVM_FEATURES, $JVM_FEATURES, $DEPRECATED_FEATURES)
301 BASIC_GET_NON_MATCHING_VALUES(DISABLED_JVM_FEATURES, $DISABLED_JVM_FEATURES, $DEPRECATED_FEATURES)
302 fi
303
304 fi
305
306 # Override hotspot cpu definitions for ARM platforms
307 if test "x$OPENJDK_TARGET_CPU" = xarm; then
308 HOTSPOT_TARGET_CPU=arm_32
309 HOTSPOT_TARGET_CPU_DEFINE="ARM32"
310 elif test "x$OPENJDK_TARGET_CPU" = xaarch64 && test "x$HOTSPOT_TARGET_CPU_PORT" = xarm64; then
311 HOTSPOT_TARGET_CPU=arm_64
312 HOTSPOT_TARGET_CPU_ARCH=arm
313 fi
314
315 # Verify that dependencies are met for explicitly set features.
316 if HOTSPOT_CHECK_JVM_FEATURE(jvmti) && ! HOTSPOT_CHECK_JVM_FEATURE(services); then
317 AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services'])
318 fi
319
320 if HOTSPOT_CHECK_JVM_FEATURE(management) && ! HOTSPOT_CHECK_JVM_FEATURE(nmt); then
321 AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt'])
322 fi
323
324 if HOTSPOT_CHECK_JVM_FEATURE(jvmci) && ! (HOTSPOT_CHECK_JVM_FEATURE(compiler1) || HOTSPOT_CHECK_JVM_FEATURE(compiler2)); then
325 AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2' or 'compiler1'])
326 fi
327
328 if HOTSPOT_CHECK_JVM_FEATURE(cmsgc) && ! HOTSPOT_CHECK_JVM_FEATURE(serialgc); then
329 AC_MSG_ERROR([Specified JVM feature 'cmsgc' requires feature 'serialgc'])
330 fi
331
332 # Enable JFR by default, except for Zero, linux-sparcv9 and on minimal.
333 if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
334 if test "x$OPENJDK_TARGET_OS" != xaix; then
335 if test "x$OPENJDK_TARGET_OS" != xlinux || test "x$OPENJDK_TARGET_CPU" != xsparcv9; then
336 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES jfr"
337 fi
338 fi
339 fi
340
341 # Only enable Shenandoah on supported arches
342 AC_MSG_CHECKING([if shenandoah can be built])
343 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86" || test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
344 AC_MSG_RESULT([yes])
345 else
346 DISABLED_JVM_FEATURES="$DISABLED_JVM_FEATURES shenandoahgc"
347 AC_MSG_RESULT([no, platform not supported])
348 fi
349
350 # Only enable ZGC on supported platforms
351 AC_MSG_CHECKING([if zgc can be built])
352 if test "x$OPENJDK_TARGET_OS" = "xlinux" && test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
353 AC_MSG_RESULT([yes])
354 else
355 DISABLED_JVM_FEATURES="$DISABLED_JVM_FEATURES zgc"
356 AC_MSG_RESULT([no, platform not supported])
357 fi
358
359 # Disable unsupported GCs for Zero
360 if HOTSPOT_CHECK_JVM_VARIANT(zero); then
361 DISABLED_JVM_FEATURES="$DISABLED_JVM_FEATURES epsilongc g1gc shenandoahgc zgc"
362 fi
363
364 # Turn on additional features based on other parts of configure
365 if test "x$INCLUDE_DTRACE" = "xtrue"; then
366 JVM_FEATURES="$JVM_FEATURES dtrace"
367 else
368 if HOTSPOT_CHECK_JVM_FEATURE(dtrace); then
369 AC_MSG_ERROR([To enable dtrace, you must use --enable-dtrace])
370 fi
371 fi
372
373 if test "x$STATIC_BUILD" = "xtrue"; then
374 JVM_FEATURES="$JVM_FEATURES static-build"
375 else
376 if HOTSPOT_CHECK_JVM_FEATURE(static-build); then
377 AC_MSG_ERROR([To enable static-build, you must use --enable-static-build])
378 fi
379 fi
380
381 if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
382 if HOTSPOT_CHECK_JVM_FEATURE(zero); then
383 AC_MSG_ERROR([To enable zero, you must use --with-jvm-variants=zero])
384 fi
385 fi
386
387 AC_MSG_CHECKING([if jvmci module jdk.internal.vm.ci should be built])
388 # Check if jvmci is diabled
389 DISABLE_JVMCI=`$ECHO $DISABLED_JVM_FEATURES | $GREP jvmci`
390 if test "x$DISABLE_JVMCI" = "xjvmci"; then
391 AC_MSG_RESULT([no, forced])
392 JVM_FEATURES_jvmci=""
393 INCLUDE_JVMCI="false"
394 else
395 # Only enable jvmci on x86_64, sparcv9 and aarch64
396 if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
397 test "x$OPENJDK_TARGET_CPU" = "xsparcv9" || \
398 test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
399 AC_MSG_RESULT([yes])
400 JVM_FEATURES_jvmci="jvmci"
401 INCLUDE_JVMCI="true"
402 else
403 AC_MSG_RESULT([no])
404 JVM_FEATURES_jvmci=""
405 INCLUDE_JVMCI="false"
406 if HOTSPOT_CHECK_JVM_FEATURE(jvmci); then
407 AC_MSG_ERROR([JVMCI is currently not supported on this platform.])
408 fi
409 fi
410 fi
411
412 AC_SUBST(INCLUDE_JVMCI)
413
414 AC_MSG_CHECKING([if graal module jdk.internal.vm.compiler should be built])
415 # Check if graal is diabled
416 DISABLE_GRAAL=`$ECHO $DISABLED_JVM_FEATURES | $GREP graal`
417 if test "x$DISABLE_GRAAL" = "xgraal"; then
418 AC_MSG_RESULT([no, forced])
419 JVM_FEATURES_graal=""
420 INCLUDE_GRAAL="false"
421 else
422 if HOTSPOT_CHECK_JVM_FEATURE(graal); then
423 AC_MSG_RESULT([yes, forced])
424 if test "x$JVM_FEATURES_jvmci" != "xjvmci" ; then
425 AC_MSG_ERROR([Specified JVM feature 'graal' requires feature 'jvmci'])
426 fi
427 JVM_FEATURES_graal="graal"
428 INCLUDE_GRAAL="true"
429 else
430 # By default enable graal build on x64 or where AOT is available.
431 # graal build requires jvmci.
432 if test "x$JVM_FEATURES_jvmci" = "xjvmci" && \
433 (test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
434 test "x$ENABLE_AOT" = "xtrue") ; then
435 AC_MSG_RESULT([yes])
436 JVM_FEATURES_graal="graal"
437 INCLUDE_GRAAL="true"
438 else
439 AC_MSG_RESULT([no])
440 JVM_FEATURES_graal=""
441 INCLUDE_GRAAL="false"
442 fi
443 fi
444 fi
445
446 AC_SUBST(INCLUDE_GRAAL)
447
448 # Disable aot with '--with-jvm-features=-aot'
449 DISABLE_AOT=`$ECHO $DISABLED_JVM_FEATURES | $GREP aot`
450 if test "x$DISABLE_AOT" = "xaot"; then
451 ENABLE_AOT="false"
452 fi
453
454 AC_MSG_CHECKING([if aot should be enabled])
455 if test "x$ENABLE_AOT" = "xtrue"; then
456 if test "x$JVM_FEATURES_graal" != "xgraal"; then
457 if test "x$enable_aot" = "xyes" || HOTSPOT_CHECK_JVM_FEATURE(aot); then
458 AC_MSG_RESULT([yes, forced])
459 AC_MSG_ERROR([Specified JVM feature 'aot' requires feature 'graal'])
460 else
461 AC_MSG_RESULT([no])
462 fi
463 JVM_FEATURES_aot=""
464 ENABLE_AOT="false"
465 else
466 if test "x$enable_aot" = "xyes" || HOTSPOT_CHECK_JVM_FEATURE(aot); then
467 AC_MSG_RESULT([yes, forced])
468 else
469 AC_MSG_RESULT([yes])
470 fi
471 JVM_FEATURES_aot="aot"
472 fi
473 else
474 if test "x$enable_aot" = "xno" || test "x$DISABLE_AOT" = "xaot"; then
475 AC_MSG_RESULT([no, forced])
476 else
477 AC_MSG_RESULT([no])
478 fi
479 JVM_FEATURES_aot=""
480 if HOTSPOT_CHECK_JVM_FEATURE(aot); then
481 AC_MSG_ERROR([To enable aot, you must use --enable-aot])
482 fi
483 fi
484
485 AC_SUBST(ENABLE_AOT)
486
487 if test "x$OPENJDK_TARGET_CPU" = xarm ; then
488 # Default to use link time optimizations on minimal on arm
489 JVM_FEATURES_link_time_opt="link-time-opt"
490 else
491 JVM_FEATURES_link_time_opt=""
492 fi
493
494 # All variants but minimal (and custom) get these features
495 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cmsgc g1gc parallelgc serialgc epsilongc shenandoahgc jni-check jvmti management nmt services vm-structs zgc"
496
497 AC_MSG_CHECKING([if cds should be enabled])
498 if test "x$ENABLE_CDS" = "xtrue"; then
499 if test "x$enable_cds" = "xyes"; then
500 AC_MSG_RESULT([yes, forced])
501 else
502 AC_MSG_RESULT([yes])
503 fi
504 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cds"
505 else
506 if test "x$enable_cds" = "xno"; then
507 AC_MSG_RESULT([no, forced])
508 else
509 AC_MSG_RESULT([no])
510 fi
511 fi
512
513 # Enable features depending on variant.
514 JVM_FEATURES_server="compiler1 compiler2 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci $JVM_FEATURES_aot $JVM_FEATURES_graal"
515 JVM_FEATURES_client="compiler1 $NON_MINIMAL_FEATURES $JVM_FEATURES"
516 JVM_FEATURES_core="$NON_MINIMAL_FEATURES $JVM_FEATURES"
517 JVM_FEATURES_minimal="compiler1 minimal serialgc $JVM_FEATURES $JVM_FEATURES_link_time_opt"
518 JVM_FEATURES_zero="zero $NON_MINIMAL_FEATURES $JVM_FEATURES"
519 JVM_FEATURES_custom="$JVM_FEATURES"
520
521 AC_SUBST(JVM_FEATURES_server)
522 AC_SUBST(JVM_FEATURES_client)
523 AC_SUBST(JVM_FEATURES_core)
524 AC_SUBST(JVM_FEATURES_minimal)
525 AC_SUBST(JVM_FEATURES_zero)
526 AC_SUBST(JVM_FEATURES_custom)
527
528 # Used for verification of Makefiles by check-jvm-feature
529 AC_SUBST(VALID_JVM_FEATURES)
530
531 # We don't support --with-jvm-interpreter anymore, use zero instead.
532 BASIC_DEPRECATED_ARG_WITH(jvm-interpreter)
533 ])
534
535 ###############################################################################
536 # Finalize JVM features once all setup is complete, including custom setup.
537 #
538 AC_DEFUN_ONCE([HOTSPOT_FINALIZE_JVM_FEATURES],
539 [
540 for variant in $JVM_VARIANTS; do
541 AC_MSG_CHECKING([JVM features for JVM variant '$variant'])
542 features_var_name=JVM_FEATURES_$variant
543 JVM_FEATURES_FOR_VARIANT=${!features_var_name}
544
545 # Filter out user-requested disabled features
546 BASIC_GET_NON_MATCHING_VALUES(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT, $DISABLED_JVM_FEATURES)
547
548 # Keep feature lists sorted and free of duplicates
549 BASIC_SORT_LIST(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT)
550
551 # Update real feature set variable
552 eval $features_var_name='"'$JVM_FEATURES_FOR_VARIANT'"'
553 AC_MSG_RESULT(["$JVM_FEATURES_FOR_VARIANT"])
554
555 # Verify that we have at least one gc selected
556 GC_FEATURES=`$ECHO $JVM_FEATURES_FOR_VARIANT | $GREP gc`
557 if test "x$GC_FEATURES" = x; then
558 AC_MSG_WARN([Invalid JVM features: No gc selected for variant $variant.])
559 fi
560
561 # Validate features (for configure script errors, not user errors)
562 BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES_FOR_VARIANT, $VALID_JVM_FEATURES)
563 if test "x$INVALID_FEATURES" != x; then
564 AC_MSG_ERROR([Internal configure script error. Invalid JVM feature(s): $INVALID_FEATURES])
565 fi
566 done
567 ])
568
569 ################################################################################
570 #
571 # Specify which sources will be used to build the 64-bit ARM port
572 #
573 # --with-cpu-port=arm64 will use hotspot/src/cpu/arm
574 # --with-cpu-port=aarch64 will use hotspot/src/cpu/aarch64
575 #
576 AC_DEFUN([SETUP_HOTSPOT_TARGET_CPU_PORT],
577 [
578 AC_ARG_WITH(cpu-port, [AS_HELP_STRING([--with-cpu-port],
579 [specify sources to use for Hotspot 64-bit ARM port (arm64,aarch64) @<:@aarch64@:>@ ])])
580
581 if test "x$with_cpu_port" != x; then
582 if test "x$OPENJDK_TARGET_CPU" != xaarch64; then
583 AC_MSG_ERROR([--with-cpu-port only available on aarch64])
584 fi
585 if test "x$with_cpu_port" != xarm64 && \
586 test "x$with_cpu_port" != xaarch64; then
587 AC_MSG_ERROR([--with-cpu-port must specify arm64 or aarch64])
588 fi
589 HOTSPOT_TARGET_CPU_PORT="$with_cpu_port"
590 fi
591 ])
592
593
594 ################################################################################
595 # Check if gtest should be built
596 #
597 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_GTEST],
598 [
599 AC_ARG_ENABLE([hotspot-gtest], [AS_HELP_STRING([--disable-hotspot-gtest],
600 [Disables building of the Hotspot unit tests @<:@enabled@:>@])])
601
602 if test -e "${TOPDIR}/test/hotspot/gtest"; then
603 GTEST_DIR_EXISTS="true"
604 else
605 GTEST_DIR_EXISTS="false"
606 fi
607
608 AC_MSG_CHECKING([if Hotspot gtest unit tests should be built])
609 if test "x$enable_hotspot_gtest" = "xyes"; then
610 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
611 AC_MSG_RESULT([yes, forced])
612 BUILD_GTEST="true"
613 else
614 AC_MSG_ERROR([Cannot build gtest without the test source])
615 fi
616 elif test "x$enable_hotspot_gtest" = "xno"; then
617 AC_MSG_RESULT([no, forced])
618 BUILD_GTEST="false"
619 elif test "x$enable_hotspot_gtest" = "x"; then
620 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
621 AC_MSG_RESULT([yes])
622 BUILD_GTEST="true"
623 else
624 AC_MSG_RESULT([no])
625 BUILD_GTEST="false"
626 fi
627 else
628 AC_MSG_ERROR([--enable-gtest must be either yes or no])
629 fi
630
631 AC_SUBST(BUILD_GTEST)
632 ])