1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # All valid JVM features, regardless of platform
27 VALID_JVM_FEATURES="compiler1 compiler2 zero minimal dtrace jvmti jvmci \
28 graal vm-structs jni-check services management cmsgc epsilongc g1gc parallelgc serialgc zgc nmt cds \
29 static-build link-time-opt aot jfr"
30
31 # Deprecated JVM features (these are ignored, but with a warning)
32 DEPRECATED_JVM_FEATURES="trace"
33
34 # All valid JVM variants
35 VALID_JVM_VARIANTS="server client minimal core zero custom"
36
37 ###############################################################################
38 # Check if the specified JVM variant should be built. To be used in shell if
39 # constructs, like this:
40 # if HOTSPOT_CHECK_JVM_VARIANT(server); then
41 #
42 # Only valid to use after HOTSPOT_SETUP_JVM_VARIANTS has setup variants.
43
44 # Definition kept in one line to allow inlining in if statements.
45 # Additional [] needed to keep m4 from mangling shell constructs.
46 AC_DEFUN([HOTSPOT_CHECK_JVM_VARIANT],
47 [ [ [[ " $JVM_VARIANTS " =~ " $1 " ]] ] ])
48
49 ###############################################################################
50 # Check if the specified JVM features are explicitly enabled. To be used in
51 # shell if constructs, like this:
52 # if HOTSPOT_CHECK_JVM_FEATURE(jvmti); then
53 #
54 # Only valid to use after HOTSPOT_SETUP_JVM_FEATURES has setup features.
55
56 # Definition kept in one line to allow inlining in if statements.
57 # Additional [] needed to keep m4 from mangling shell constructs.
58 AC_DEFUN([HOTSPOT_CHECK_JVM_FEATURE],
59 [ [ [[ " $JVM_FEATURES " =~ " $1 " ]] ] ])
60
61 ###############################################################################
62 # Check which variants of the JVM that we want to build. Available variants are:
63 # server: normal interpreter, and a tiered C1/C2 compiler
64 # client: normal interpreter, and C1 (no C2 compiler)
65 # minimal: reduced form of client with optional features stripped out
66 # core: normal interpreter only, no compiler
67 # zero: C++ based interpreter only, no compiler
68 # custom: baseline JVM with no default features
69 #
70 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_VARIANTS],
71 [
72 AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
73 [JVM variants (separated by commas) to build (server,client,minimal,core,zero,custom) @<:@server@:>@])])
74
75 SETUP_HOTSPOT_TARGET_CPU_PORT
76
77 if test "x$with_jvm_variants" = x; then
78 with_jvm_variants="server"
79 fi
80 JVM_VARIANTS_OPT="$with_jvm_variants"
81
82 # Has the user listed more than one variant?
83 # Additional [] needed to keep m4 from mangling shell constructs.
84 if [ [[ "$JVM_VARIANTS_OPT" =~ "," ]] ]; then
85 BUILDING_MULTIPLE_JVM_VARIANTS=true
86 else
87 BUILDING_MULTIPLE_JVM_VARIANTS=false
88 fi
89 # Replace the commas with AND for use in the build directory name.
90 JVM_VARIANTS_WITH_AND=`$ECHO "$JVM_VARIANTS_OPT" | $SED -e 's/,/AND/g'`
91
92 AC_MSG_CHECKING([which variants of the JVM to build])
93 # JVM_VARIANTS is a space-separated list.
94 # Also use minimal, not minimal1 (which is kept for backwards compatibility).
95 JVM_VARIANTS=`$ECHO $JVM_VARIANTS_OPT | $SED -e 's/,/ /g' -e 's/minimal1/minimal/'`
96 AC_MSG_RESULT([$JVM_VARIANTS])
97
98 # Check that the selected variants are valid
99 BASIC_GET_NON_MATCHING_VALUES(INVALID_VARIANTS, $JVM_VARIANTS, $VALID_JVM_VARIANTS)
100 if test "x$INVALID_VARIANTS" != x; then
101 AC_MSG_NOTICE([Unknown variant(s) specified: "$INVALID_VARIANTS"])
102 AC_MSG_NOTICE([The available JVM variants are: "$VALID_JVM_VARIANTS"])
103 AC_MSG_ERROR([Cannot continue])
104 fi
105
106 # All "special" variants share the same output directory ("server")
107 VALID_MULTIPLE_JVM_VARIANTS="server client minimal"
108 BASIC_GET_NON_MATCHING_VALUES(INVALID_MULTIPLE_VARIANTS, $JVM_VARIANTS, $VALID_MULTIPLE_JVM_VARIANTS)
109 if test "x$INVALID_MULTIPLE_VARIANTS" != x && test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = xtrue; then
110 AC_MSG_ERROR([You cannot build multiple variants with anything else than $VALID_MULTIPLE_JVM_VARIANTS.])
111 fi
112
113 # The "main" variant is the one used by other libs to link against during the
114 # build.
115 if test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = "xtrue"; then
116 MAIN_VARIANT_PRIO_ORDER="server client minimal"
117 for variant in $MAIN_VARIANT_PRIO_ORDER; do
118 if HOTSPOT_CHECK_JVM_VARIANT($variant); then
119 JVM_VARIANT_MAIN="$variant"
120 break
121 fi
122 done
123 else
124 JVM_VARIANT_MAIN="$JVM_VARIANTS"
125 fi
126
127 AC_SUBST(JVM_VARIANTS)
128 AC_SUBST(VALID_JVM_VARIANTS)
129 AC_SUBST(JVM_VARIANT_MAIN)
130
131 if HOTSPOT_CHECK_JVM_VARIANT(zero); then
132 # zero behaves as a platform and rewrites these values. This is really weird. :(
133 # We are guaranteed that we do not build any other variants when building zero.
134 HOTSPOT_TARGET_CPU=zero
135 HOTSPOT_TARGET_CPU_ARCH=zero
136 fi
137 ])
138
139 ###############################################################################
140 # Check if dtrace should be enabled and has all prerequisites present.
141 #
142 AC_DEFUN_ONCE([HOTSPOT_SETUP_DTRACE],
143 [
144 # Test for dtrace dependencies
145 AC_ARG_ENABLE([dtrace], [AS_HELP_STRING([--enable-dtrace@<:@=yes/no/auto@:>@],
146 [enable dtrace. Default is auto, where dtrace is enabled if all dependencies
147 are present.])])
148
149 DTRACE_DEP_MISSING=false
150
151 AC_MSG_CHECKING([for dtrace tool])
152 if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
153 AC_MSG_RESULT([$DTRACE])
154 else
155 AC_MSG_RESULT([not found, cannot build dtrace])
156 DTRACE_DEP_MISSING=true
157 fi
158
159 AC_CHECK_HEADERS([sys/sdt.h], [DTRACE_HEADERS_OK=yes],[DTRACE_HEADERS_OK=no])
160 if test "x$DTRACE_HEADERS_OK" != "xyes"; then
161 DTRACE_DEP_MISSING=true
162 fi
163
164 AC_MSG_CHECKING([if dtrace should be built])
165 if test "x$enable_dtrace" = "xyes"; then
166 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
167 AC_MSG_RESULT([no, missing dependencies])
168 HELP_MSG_MISSING_DEPENDENCY([dtrace])
169 AC_MSG_ERROR([Cannot enable dtrace with missing dependencies. See above. $HELP_MSG])
170 else
171 INCLUDE_DTRACE=true
172 AC_MSG_RESULT([yes, forced])
173 fi
174 elif test "x$enable_dtrace" = "xno"; then
175 INCLUDE_DTRACE=false
176 AC_MSG_RESULT([no, forced])
177 elif test "x$enable_dtrace" = "xauto" || test "x$enable_dtrace" = "x"; then
178 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
179 INCLUDE_DTRACE=false
180 AC_MSG_RESULT([no, missing dependencies])
181 else
182 INCLUDE_DTRACE=true
183 AC_MSG_RESULT([yes, dependencies present])
184 fi
185 else
186 AC_MSG_ERROR([Invalid value for --enable-dtrace: $enable_dtrace])
187 fi
188 ])
189
190 ################################################################################
191 # Check if AOT should be enabled
192 #
193 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_AOT],
194 [
195 AC_ARG_ENABLE([aot], [AS_HELP_STRING([--enable-aot@<:@=yes/no/auto@:>@],
196 [enable ahead of time compilation feature. Default is auto, where aot is enabled if all dependencies are present.])])
197
198 if test "x$enable_aot" = "x" || test "x$enable_aot" = "xauto"; then
199 ENABLE_AOT="true"
200 elif test "x$enable_aot" = "xyes"; then
201 ENABLE_AOT="true"
202 elif test "x$enable_aot" = "xno"; then
203 ENABLE_AOT="false"
204 else
205 AC_MSG_ERROR([Invalid value for --enable-aot: $enable_aot])
206 fi
207
208 if test "x$ENABLE_AOT" = "xtrue"; then
209 # Only enable AOT on X64 platforms.
210 if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
211 if test -e "${TOPDIR}/src/jdk.aot"; then
212 if test -e "${TOPDIR}/src/jdk.internal.vm.compiler"; then
213 ENABLE_AOT="true"
214 else
215 ENABLE_AOT="false"
216 if test "x$enable_aot" = "xyes"; then
217 AC_MSG_ERROR([Cannot build AOT without src/jdk.internal.vm.compiler sources. Remove --enable-aot.])
218 fi
219 fi
220 else
221 ENABLE_AOT="false"
222 if test "x$enable_aot" = "xyes"; then
223 AC_MSG_ERROR([Cannot build AOT without src/jdk.aot sources. Remove --enable-aot.])
224 fi
225 fi
226 else
227 ENABLE_AOT="false"
228 if test "x$enable_aot" = "xyes"; then
229 AC_MSG_ERROR([AOT is currently only supported on x86_64 and aarch64. Remove --enable-aot.])
230 fi
231 fi
232 fi
233
234 AC_SUBST(ENABLE_AOT)
235 ])
236
237 ################################################################################
238 # Allow to disable CDS
239 #
240 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_CDS],
241 [
242 AC_ARG_ENABLE([cds], [AS_HELP_STRING([--enable-cds@<:@=yes/no/auto@:>@],
243 [enable class data sharing feature in non-minimal VM. Default is auto, where cds is enabled if supported on the platform.])])
244
245 if test "x$enable_cds" = "x" || test "x$enable_cds" = "xauto"; then
246 ENABLE_CDS="true"
247 elif test "x$enable_cds" = "xyes"; then
248 ENABLE_CDS="true"
249 elif test "x$enable_cds" = "xno"; then
250 ENABLE_CDS="false"
251 else
252 AC_MSG_ERROR([Invalid value for --enable-cds: $enable_cds])
253 fi
254
255 AC_SUBST(ENABLE_CDS)
256 ])
257
258 ###############################################################################
259 # Set up all JVM features for each JVM variant.
260 #
261 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_FEATURES],
262 [
263 # Prettify the VALID_JVM_FEATURES string
264 BASIC_SORT_LIST(VALID_JVM_FEATURES, $VALID_JVM_FEATURES)
265
266 # The user can in some cases supply additional jvm features. For the custom
267 # variant, this defines the entire variant.
268 AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
269 [JVM features to enable (foo) or disable (-foo), separated by comma. Use '--help' to show possible values @<:@none@:>@])])
270 if test "x$with_jvm_features" != x; then
271 AC_MSG_CHECKING([user specified JVM feature list])
272 USER_JVM_FEATURE_LIST=`$ECHO $with_jvm_features | $SED -e 's/,/ /g'`
273 AC_MSG_RESULT([$user_jvm_feature_list])
274 # These features will be added to all variant defaults
275 JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (!match($i, /^-.*/)) printf("%s ", $i) }'`
276 # These features will be removed from all variant defaults
277 DISABLED_JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (match($i, /^-.*/)) printf("%s ", substr($i, 2))}'`
278
279 # Verify that the user has provided valid features
280 BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES $DISABLED_JVM_FEATURES, $VALID_JVM_FEATURES $DEPRECATED_JVM_FEATURES)
281 if test "x$INVALID_FEATURES" != x; then
282 AC_MSG_NOTICE([Unknown JVM features specified: "$INVALID_FEATURES"])
283 AC_MSG_NOTICE([The available JVM features are: "$VALID_JVM_FEATURES"])
284 AC_MSG_ERROR([Cannot continue])
285 fi
286
287 # Check if the user has provided deprecated features
288 BASIC_GET_MATCHING_VALUES(DEPRECATED_FEATURES, $JVM_FEATURES $DISABLED_JVM_FEATURES, $DEPRECATED_JVM_FEATURES)
289 if test "x$DEPRECATED_FEATURES" != x; then
290 AC_MSG_WARN([Deprecated JVM features specified (will be ignored): "$DEPRECATED_FEATURES"])
291 # Filter out deprecated features
292 BASIC_GET_NON_MATCHING_VALUES(JVM_FEATURES, $JVM_FEATURES, $DEPRECATED_FEATURES)
293 BASIC_GET_NON_MATCHING_VALUES(DISABLED_JVM_FEATURES, $DISABLED_JVM_FEATURES, $DEPRECATED_FEATURES)
294 fi
295
296 fi
297
298 # Override hotspot cpu definitions for ARM platforms
299 if test "x$OPENJDK_TARGET_CPU" = xarm; then
300 HOTSPOT_TARGET_CPU=arm_32
301 HOTSPOT_TARGET_CPU_DEFINE="ARM32"
302 elif test "x$OPENJDK_TARGET_CPU" = xaarch64 && test "x$HOTSPOT_TARGET_CPU_PORT" = xarm64; then
303 HOTSPOT_TARGET_CPU=arm_64
304 HOTSPOT_TARGET_CPU_ARCH=arm
305 fi
306
307 # Verify that dependencies are met for explicitly set features.
308 if HOTSPOT_CHECK_JVM_FEATURE(jvmti) && ! HOTSPOT_CHECK_JVM_FEATURE(services); then
309 AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services'])
310 fi
311
312 if HOTSPOT_CHECK_JVM_FEATURE(management) && ! HOTSPOT_CHECK_JVM_FEATURE(nmt); then
313 AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt'])
314 fi
315
316 if HOTSPOT_CHECK_JVM_FEATURE(jvmci) && ! (HOTSPOT_CHECK_JVM_FEATURE(compiler1) || HOTSPOT_CHECK_JVM_FEATURE(compiler2)); then
317 AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2' or 'compiler1'])
318 fi
319
320 if HOTSPOT_CHECK_JVM_FEATURE(cmsgc) && ! HOTSPOT_CHECK_JVM_FEATURE(serialgc); then
321 AC_MSG_ERROR([Specified JVM feature 'cmsgc' requires feature 'serialgc'])
322 fi
323
324 # Enable JFR by default, except for Zero, linux-sparcv9 and on minimal.
325 if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
326 if test "x$OPENJDK_TARGET_OS" != xaix; then
327 if test "x$OPENJDK_TARGET_OS" != xlinux || test "x$OPENJDK_TARGET_CPU" != xsparcv9; then
328 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES jfr"
329 fi
330 fi
331 fi
332
333 # Only enable ZGC on Linux x86_64
334 AC_MSG_CHECKING([if zgc should be built])
335 if HOTSPOT_CHECK_JVM_FEATURE(zgc); then
336 if test "x$OPENJDK_TARGET_OS" = "xlinux" && test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
337 AC_MSG_RESULT([yes])
338 else
339 DISABLED_JVM_FEATURES="$DISABLED_JVM_FEATURES zgc"
340 AC_MSG_RESULT([no, platform not supported])
341 fi
342 else
343 AC_MSG_RESULT([no])
344 fi
345
346 # Disable unsupported GCs for Zero
347 if HOTSPOT_CHECK_JVM_VARIANT(zero); then
348 DISABLED_JVM_FEATURES="$DISABLED_JVM_FEATURES epsilongc g1gc zgc"
349 fi
350
351 # Turn on additional features based on other parts of configure
352 if test "x$INCLUDE_DTRACE" = "xtrue"; then
353 JVM_FEATURES="$JVM_FEATURES dtrace"
354 else
355 if HOTSPOT_CHECK_JVM_FEATURE(dtrace); then
356 AC_MSG_ERROR([To enable dtrace, you must use --enable-dtrace])
357 fi
358 fi
359
360 if test "x$STATIC_BUILD" = "xtrue"; then
361 JVM_FEATURES="$JVM_FEATURES static-build"
362 else
363 if HOTSPOT_CHECK_JVM_FEATURE(static-build); then
364 AC_MSG_ERROR([To enable static-build, you must use --enable-static-build])
365 fi
366 fi
367
368 if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
369 if HOTSPOT_CHECK_JVM_FEATURE(zero); then
370 AC_MSG_ERROR([To enable zero, you must use --with-jvm-variants=zero])
371 fi
372 fi
373
374 AC_MSG_CHECKING([if jvmci module jdk.internal.vm.ci should be built])
375 # Check if jvmci is diabled
376 DISABLE_JVMCI=`$ECHO $DISABLED_JVM_FEATURES | $GREP jvmci`
377 if test "x$DISABLE_JVMCI" = "xjvmci"; then
378 AC_MSG_RESULT([no, forced])
379 JVM_FEATURES_jvmci=""
380 INCLUDE_JVMCI="false"
381 else
382 # Only enable jvmci on x86_64, sparcv9 and aarch64
383 if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
384 test "x$OPENJDK_TARGET_CPU" = "xsparcv9" || \
385 test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
386 AC_MSG_RESULT([yes])
387 JVM_FEATURES_jvmci="jvmci"
388 INCLUDE_JVMCI="true"
389 else
390 AC_MSG_RESULT([no])
391 JVM_FEATURES_jvmci=""
392 INCLUDE_JVMCI="false"
393 if HOTSPOT_CHECK_JVM_FEATURE(jvmci); then
394 AC_MSG_ERROR([JVMCI is currently not supported on this platform.])
395 fi
396 fi
397 fi
398
399 AC_SUBST(INCLUDE_JVMCI)
400
401 AC_MSG_CHECKING([if graal module jdk.internal.vm.compiler should be built])
402 # Check if graal is diabled
403 DISABLE_GRAAL=`$ECHO $DISABLED_JVM_FEATURES | $GREP graal`
404 if test "x$DISABLE_GRAAL" = "xgraal"; then
405 AC_MSG_RESULT([no, forced])
406 JVM_FEATURES_graal=""
407 INCLUDE_GRAAL="false"
408 else
409 if HOTSPOT_CHECK_JVM_FEATURE(graal); then
410 AC_MSG_RESULT([yes, forced])
411 if test "x$JVM_FEATURES_jvmci" != "xjvmci" ; then
412 AC_MSG_ERROR([Specified JVM feature 'graal' requires feature 'jvmci'])
413 fi
414 JVM_FEATURES_graal="graal"
415 INCLUDE_GRAAL="true"
416 else
417 # By default enable graal build on x64 or where AOT is available.
418 # graal build requires jvmci.
419 if test "x$JVM_FEATURES_jvmci" = "xjvmci" && \
420 (test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
421 test "x$ENABLE_AOT" = "xtrue") ; then
422 AC_MSG_RESULT([yes])
423 JVM_FEATURES_graal="graal"
424 INCLUDE_GRAAL="true"
425 else
426 AC_MSG_RESULT([no])
427 JVM_FEATURES_graal=""
428 INCLUDE_GRAAL="false"
429 fi
430 fi
431 fi
432
433 AC_SUBST(INCLUDE_GRAAL)
434
435 # Disable aot with '--with-jvm-features=-aot'
436 DISABLE_AOT=`$ECHO $DISABLED_JVM_FEATURES | $GREP aot`
437 if test "x$DISABLE_AOT" = "xaot"; then
438 ENABLE_AOT="false"
439 fi
440
441 AC_MSG_CHECKING([if aot should be enabled])
442 if test "x$ENABLE_AOT" = "xtrue"; then
443 if test "x$JVM_FEATURES_graal" != "xgraal"; then
444 if test "x$enable_aot" = "xyes" || HOTSPOT_CHECK_JVM_FEATURE(aot); then
445 AC_MSG_RESULT([yes, forced])
446 AC_MSG_ERROR([Specified JVM feature 'aot' requires feature 'graal'])
447 else
448 AC_MSG_RESULT([no])
449 fi
450 JVM_FEATURES_aot=""
451 ENABLE_AOT="false"
452 else
453 if test "x$enable_aot" = "xyes" || HOTSPOT_CHECK_JVM_FEATURE(aot); then
454 AC_MSG_RESULT([yes, forced])
455 else
456 AC_MSG_RESULT([yes])
457 fi
458 JVM_FEATURES_aot="aot"
459 fi
460 else
461 if test "x$enable_aot" = "xno" || test "x$DISABLE_AOT" = "xaot"; then
462 AC_MSG_RESULT([no, forced])
463 else
464 AC_MSG_RESULT([no])
465 fi
466 JVM_FEATURES_aot=""
467 if HOTSPOT_CHECK_JVM_FEATURE(aot); then
468 AC_MSG_ERROR([To enable aot, you must use --enable-aot])
469 fi
470 fi
471
472 AC_SUBST(ENABLE_AOT)
473
474 if test "x$OPENJDK_TARGET_CPU" = xarm ; then
475 # Default to use link time optimizations on minimal on arm
476 JVM_FEATURES_link_time_opt="link-time-opt"
477 else
478 JVM_FEATURES_link_time_opt=""
479 fi
480
481 # All variants but minimal (and custom) get these features
482 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cmsgc g1gc parallelgc serialgc epsilongc jni-check jvmti management nmt services vm-structs"
483
484 # Disable CDS on AIX.
485 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
486 ENABLE_CDS="false"
487 if test "x$enable_cds" = "xyes"; then
488 AC_MSG_ERROR([CDS is currently not supported on AIX. Remove --enable-cds.])
489 fi
490 fi
491
492 # Disable CDS if user requested it with --with-jvm-features=-cds.
493 DISABLE_CDS=`$ECHO $DISABLED_JVM_FEATURES | $GREP cds`
494 if test "x$DISABLE_CDS" = "xcds"; then
495 ENABLE_CDS="false"
496 if test "x$enable_cds" = "xyes"; then
497 AC_MSG_ERROR([CDS was disabled by --with-jvm-features=-cds. Remove --enable-cds.])
498 fi
499 fi
500
501 # Disable CDS for zero, minimal, core..
502 if HOTSPOT_CHECK_JVM_VARIANT(zero) || HOTSPOT_CHECK_JVM_VARIANT(minimal) || HOTSPOT_CHECK_JVM_VARIANT(core); then
503 # ..except when the user explicitely requested it with --enable-jvm-features
504 if ! HOTSPOT_CHECK_JVM_FEATURE(cds); then
505 ENABLE_CDS="false"
506 if test "x$enable_cds" = "xyes"; then
507 AC_MSG_ERROR([CDS not implemented for variants zero, minimal, core. Remove --enable-cds.])
508 fi
509 fi
510 fi
511
512 AC_MSG_CHECKING([if cds should be enabled])
513 if test "x$ENABLE_CDS" = "xtrue"; then
514 if test "x$enable_cds" = "xyes"; then
515 AC_MSG_RESULT([yes, forced])
516 else
517 AC_MSG_RESULT([yes])
518 fi
519 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cds"
520 else
521 if test "x$enable_cds" = "xno"; then
522 AC_MSG_RESULT([no, forced])
523 else
524 AC_MSG_RESULT([no])
525 fi
526 fi
527
528 # Enable features depending on variant.
529 JVM_FEATURES_server="compiler1 compiler2 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci $JVM_FEATURES_aot $JVM_FEATURES_graal"
530 JVM_FEATURES_client="compiler1 $NON_MINIMAL_FEATURES $JVM_FEATURES"
531 JVM_FEATURES_core="$NON_MINIMAL_FEATURES $JVM_FEATURES"
532 JVM_FEATURES_minimal="compiler1 minimal serialgc $JVM_FEATURES $JVM_FEATURES_link_time_opt"
533 JVM_FEATURES_zero="zero $NON_MINIMAL_FEATURES $JVM_FEATURES"
534 JVM_FEATURES_custom="$JVM_FEATURES"
535
536 AC_SUBST(JVM_FEATURES_server)
537 AC_SUBST(JVM_FEATURES_client)
538 AC_SUBST(JVM_FEATURES_core)
539 AC_SUBST(JVM_FEATURES_minimal)
540 AC_SUBST(JVM_FEATURES_zero)
541 AC_SUBST(JVM_FEATURES_custom)
542
543 # Used for verification of Makefiles by check-jvm-feature
544 AC_SUBST(VALID_JVM_FEATURES)
545 ])
546
547 ###############################################################################
548 # Finalize JVM features once all setup is complete, including custom setup.
549 #
550 AC_DEFUN_ONCE([HOTSPOT_FINALIZE_JVM_FEATURES],
551 [
552 for variant in $JVM_VARIANTS; do
553 AC_MSG_CHECKING([JVM features for JVM variant '$variant'])
554 features_var_name=JVM_FEATURES_$variant
555 JVM_FEATURES_FOR_VARIANT=${!features_var_name}
556
557 # Filter out user-requested disabled features
558 BASIC_GET_NON_MATCHING_VALUES(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT, $DISABLED_JVM_FEATURES)
559
560 # Keep feature lists sorted and free of duplicates
561 BASIC_SORT_LIST(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT)
562
563 # Update real feature set variable
564 eval $features_var_name='"'$JVM_FEATURES_FOR_VARIANT'"'
565 AC_MSG_RESULT(["$JVM_FEATURES_FOR_VARIANT"])
566
567 # Verify that we have at least one gc selected
568 GC_FEATURES=`$ECHO $JVM_FEATURES_FOR_VARIANT | $GREP gc`
569 if test "x$GC_FEATURES" = x; then
570 AC_MSG_WARN([Invalid JVM features: No gc selected for variant $variant.])
571 fi
572
573 # Validate features (for configure script errors, not user errors)
574 BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES_FOR_VARIANT, $VALID_JVM_FEATURES)
575 if test "x$INVALID_FEATURES" != x; then
576 AC_MSG_ERROR([Internal configure script error. Invalid JVM feature(s): $INVALID_FEATURES])
577 fi
578 done
579 ])
580
581 ################################################################################
582 #
583 # Specify which sources will be used to build the 64-bit ARM port
584 #
585 # --with-cpu-port=arm64 will use hotspot/src/cpu/arm
586 # --with-cpu-port=aarch64 will use hotspot/src/cpu/aarch64
587 #
588 AC_DEFUN([SETUP_HOTSPOT_TARGET_CPU_PORT],
589 [
590 AC_ARG_WITH(cpu-port, [AS_HELP_STRING([--with-cpu-port],
591 [specify sources to use for Hotspot 64-bit ARM port (arm64,aarch64) @<:@aarch64@:>@ ])])
592
593 if test "x$with_cpu_port" != x; then
594 if test "x$OPENJDK_TARGET_CPU" != xaarch64; then
595 AC_MSG_ERROR([--with-cpu-port only available on aarch64])
596 fi
597 if test "x$with_cpu_port" != xarm64 && \
598 test "x$with_cpu_port" != xaarch64; then
599 AC_MSG_ERROR([--with-cpu-port must specify arm64 or aarch64])
600 fi
601 HOTSPOT_TARGET_CPU_PORT="$with_cpu_port"
602 fi
603 ])
604
605
606 ################################################################################
607 # Check if gtest should be built
608 #
609 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_GTEST],
610 [
611 AC_ARG_ENABLE([hotspot-gtest], [AS_HELP_STRING([--disable-hotspot-gtest],
612 [Disables building of the Hotspot unit tests @<:@enabled@:>@])])
613
614 if test -e "${TOPDIR}/test/hotspot/gtest"; then
615 GTEST_DIR_EXISTS="true"
616 else
617 GTEST_DIR_EXISTS="false"
618 fi
619
620 AC_MSG_CHECKING([if Hotspot gtest unit tests should be built])
621 if test "x$enable_hotspot_gtest" = "xyes"; then
622 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
623 AC_MSG_RESULT([yes, forced])
624 BUILD_GTEST="true"
625 else
626 AC_MSG_ERROR([Cannot build gtest without the test source])
627 fi
628 elif test "x$enable_hotspot_gtest" = "xno"; then
629 AC_MSG_RESULT([no, forced])
630 BUILD_GTEST="false"
631 elif test "x$enable_hotspot_gtest" = "x"; then
632 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
633 AC_MSG_RESULT([yes])
634 BUILD_GTEST="true"
635 else
636 AC_MSG_RESULT([no])
637 BUILD_GTEST="false"
638 fi
639 else
640 AC_MSG_ERROR([--enable-gtest must be either yes or no])
641 fi
642
643 AC_SUBST(BUILD_GTEST)
644 ])