1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # All valid JVM features, regardless of platform
27 VALID_JVM_FEATURES="compiler1 compiler2 zero minimal dtrace jvmti jvmci \
28 graal vm-structs jni-check services management cmsgc epsilongc g1gc parallelgc serialgc shenandoahgc zgc nmt cds \
29 static-build link-time-opt aot jfr"
30
31 # Deprecated JVM features (these are ignored, but with a warning)
32 DEPRECATED_JVM_FEATURES="trace"
33
34 # All valid JVM variants
35 VALID_JVM_VARIANTS="server client minimal core zero custom"
36
37 ###############################################################################
38 # Check if the specified JVM variant should be built. To be used in shell if
39 # constructs, like this:
40 # if HOTSPOT_CHECK_JVM_VARIANT(server); then
41 #
42 # Only valid to use after HOTSPOT_SETUP_JVM_VARIANTS has setup variants.
43
44 # Definition kept in one line to allow inlining in if statements.
45 # Additional [] needed to keep m4 from mangling shell constructs.
46 AC_DEFUN([HOTSPOT_CHECK_JVM_VARIANT],
47 [ [ [[ " $JVM_VARIANTS " =~ " $1 " ]] ] ])
48
49 ###############################################################################
50 # Check if the specified JVM feature is enabled. To be used in shell if
51 # constructs, like this:
52 # if HOTSPOT_CHECK_JVM_FEATURE(jvmti); then
53 #
54 # Only valid to use after HOTSPOT_SETUP_JVM_FEATURES has setup features.
55
56 # Definition kept in one line to allow inlining in if statements.
57 # Additional [] needed to keep m4 from mangling shell constructs.
58 AC_DEFUN([HOTSPOT_CHECK_JVM_FEATURE],
59 [ [ [[ " $JVM_FEATURES " =~ " $1 " ]] ] ])
60
61 ###############################################################################
62 # Check if the specified JVM feature is explicitly disabled. To be used in
63 # shell if constructs, like this:
64 # if HOTSPOT_IS_JVM_FEATURE_DISABLED(jvmci); then
65 #
66 # This function is internal to hotspot.m4, and is only used when constructing
67 # the valid set of enabled JVM features. Users outside of hotspot.m4 should just
68 # use HOTSPOT_CHECK_JVM_FEATURE to check if a feature is enabled or not.
69
70 # Definition kept in one line to allow inlining in if statements.
71 # Additional [] needed to keep m4 from mangling shell constructs.
72 AC_DEFUN([HOTSPOT_IS_JVM_FEATURE_DISABLED],
73 [ [ [[ " $DISABLED_JVM_FEATURES " =~ " $1 " ]] ] ])
74
75 ###############################################################################
76 # Check which variants of the JVM that we want to build. Available variants are:
77 # server: normal interpreter, and a tiered C1/C2 compiler
78 # client: normal interpreter, and C1 (no C2 compiler)
79 # minimal: reduced form of client with optional features stripped out
80 # core: normal interpreter only, no compiler
81 # zero: C++ based interpreter only, no compiler
82 # custom: baseline JVM with no default features
83 #
84 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_VARIANTS],
85 [
86 AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
87 [JVM variants (separated by commas) to build (server,client,minimal,core,zero,custom) @<:@server@:>@])])
88
89 if test "x$with_jvm_variants" = x; then
90 with_jvm_variants="server"
91 fi
92 JVM_VARIANTS_OPT="$with_jvm_variants"
93
94 # Has the user listed more than one variant?
95 # Additional [] needed to keep m4 from mangling shell constructs.
96 if [ [[ "$JVM_VARIANTS_OPT" =~ "," ]] ]; then
97 BUILDING_MULTIPLE_JVM_VARIANTS=true
98 else
99 BUILDING_MULTIPLE_JVM_VARIANTS=false
100 fi
101 # Replace the commas with AND for use in the build directory name.
102 JVM_VARIANTS_WITH_AND=`$ECHO "$JVM_VARIANTS_OPT" | $SED -e 's/,/AND/g'`
103
104 AC_MSG_CHECKING([which variants of the JVM to build])
105 # JVM_VARIANTS is a space-separated list.
106 # Also use minimal, not minimal1 (which is kept for backwards compatibility).
107 JVM_VARIANTS=`$ECHO $JVM_VARIANTS_OPT | $SED -e 's/,/ /g' -e 's/minimal1/minimal/'`
108 AC_MSG_RESULT([$JVM_VARIANTS])
109
110 # Check that the selected variants are valid
111 BASIC_GET_NON_MATCHING_VALUES(INVALID_VARIANTS, $JVM_VARIANTS, $VALID_JVM_VARIANTS)
112 if test "x$INVALID_VARIANTS" != x; then
113 AC_MSG_NOTICE([Unknown variant(s) specified: "$INVALID_VARIANTS"])
114 AC_MSG_NOTICE([The available JVM variants are: "$VALID_JVM_VARIANTS"])
115 AC_MSG_ERROR([Cannot continue])
116 fi
117
118 # All "special" variants share the same output directory ("server")
119 VALID_MULTIPLE_JVM_VARIANTS="server client minimal"
120 BASIC_GET_NON_MATCHING_VALUES(INVALID_MULTIPLE_VARIANTS, $JVM_VARIANTS, $VALID_MULTIPLE_JVM_VARIANTS)
121 if test "x$INVALID_MULTIPLE_VARIANTS" != x && test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = xtrue; then
122 AC_MSG_ERROR([You cannot build multiple variants with anything else than $VALID_MULTIPLE_JVM_VARIANTS.])
123 fi
124
125 # The "main" variant is the one used by other libs to link against during the
126 # build.
127 if test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = "xtrue"; then
128 MAIN_VARIANT_PRIO_ORDER="server client minimal"
129 for variant in $MAIN_VARIANT_PRIO_ORDER; do
130 if HOTSPOT_CHECK_JVM_VARIANT($variant); then
131 JVM_VARIANT_MAIN="$variant"
132 break
133 fi
134 done
135 else
136 JVM_VARIANT_MAIN="$JVM_VARIANTS"
137 fi
138
139 AC_SUBST(JVM_VARIANTS)
140 AC_SUBST(VALID_JVM_VARIANTS)
141 AC_SUBST(JVM_VARIANT_MAIN)
142
143 if HOTSPOT_CHECK_JVM_VARIANT(zero); then
144 # zero behaves as a platform and rewrites these values. This is really weird. :(
145 # We are guaranteed that we do not build any other variants when building zero.
146 HOTSPOT_TARGET_CPU=zero
147 HOTSPOT_TARGET_CPU_ARCH=zero
148 fi
149 ])
150
151 ###############################################################################
152 # Check if dtrace should be enabled and has all prerequisites present.
153 #
154 AC_DEFUN_ONCE([HOTSPOT_SETUP_DTRACE],
155 [
156 # Test for dtrace dependencies
157 AC_ARG_ENABLE([dtrace], [AS_HELP_STRING([--enable-dtrace@<:@=yes/no/auto@:>@],
158 [enable dtrace. Default is auto, where dtrace is enabled if all dependencies
159 are present.])])
160
161 DTRACE_DEP_MISSING=false
162
163 AC_MSG_CHECKING([for dtrace tool])
164 if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
165 AC_MSG_RESULT([$DTRACE])
166 else
167 AC_MSG_RESULT([not found, cannot build dtrace])
168 DTRACE_DEP_MISSING=true
169 fi
170
171 AC_CHECK_HEADERS([sys/sdt.h], [DTRACE_HEADERS_OK=yes],[DTRACE_HEADERS_OK=no])
172 if test "x$DTRACE_HEADERS_OK" != "xyes"; then
173 DTRACE_DEP_MISSING=true
174 fi
175
176 AC_MSG_CHECKING([if dtrace should be built])
177 if test "x$enable_dtrace" = "xyes"; then
178 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
179 AC_MSG_RESULT([no, missing dependencies])
180 HELP_MSG_MISSING_DEPENDENCY([dtrace])
181 AC_MSG_ERROR([Cannot enable dtrace with missing dependencies. See above. $HELP_MSG])
182 else
183 INCLUDE_DTRACE=true
184 AC_MSG_RESULT([yes, forced])
185 fi
186 elif test "x$enable_dtrace" = "xno"; then
187 INCLUDE_DTRACE=false
188 AC_MSG_RESULT([no, forced])
189 elif test "x$enable_dtrace" = "xauto" || test "x$enable_dtrace" = "x"; then
190 if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
191 INCLUDE_DTRACE=false
192 AC_MSG_RESULT([no, missing dependencies])
193 else
194 INCLUDE_DTRACE=true
195 AC_MSG_RESULT([yes, dependencies present])
196 fi
197 else
198 AC_MSG_ERROR([Invalid value for --enable-dtrace: $enable_dtrace])
199 fi
200 ])
201
202 ################################################################################
203 # Check if AOT should be enabled
204 #
205 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_AOT],
206 [
207 AC_ARG_ENABLE([aot], [AS_HELP_STRING([--enable-aot@<:@=yes/no/auto@:>@],
208 [enable ahead of time compilation feature. Default is auto, where aot is enabled if all dependencies are present.])])
209
210 if test "x$enable_aot" = "x" || test "x$enable_aot" = "xauto"; then
211 ENABLE_AOT="true"
212 elif test "x$enable_aot" = "xyes"; then
213 ENABLE_AOT="true"
214 elif test "x$enable_aot" = "xno"; then
215 ENABLE_AOT="false"
216 else
217 AC_MSG_ERROR([Invalid value for --enable-aot: $enable_aot])
218 fi
219
220 if test "x$ENABLE_AOT" = "xtrue"; then
221 # Only enable AOT on X64 platforms.
222 if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
223 if test -e "${TOPDIR}/src/jdk.aot"; then
224 if test -e "${TOPDIR}/src/jdk.internal.vm.compiler"; then
225 ENABLE_AOT="true"
226 else
227 ENABLE_AOT="false"
228 if test "x$enable_aot" = "xyes"; then
229 AC_MSG_ERROR([Cannot build AOT without src/jdk.internal.vm.compiler sources. Remove --enable-aot.])
230 fi
231 fi
232 else
233 ENABLE_AOT="false"
234 if test "x$enable_aot" = "xyes"; then
235 AC_MSG_ERROR([Cannot build AOT without src/jdk.aot sources. Remove --enable-aot.])
236 fi
237 fi
238 else
239 ENABLE_AOT="false"
240 if test "x$enable_aot" = "xyes"; then
241 AC_MSG_ERROR([AOT is currently only supported on x86_64 and aarch64. Remove --enable-aot.])
242 fi
243 fi
244 fi
245
246 AC_SUBST(ENABLE_AOT)
247 ])
248
249 ################################################################################
250 # Allow to disable CDS
251 #
252 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_CDS],
253 [
254 AC_ARG_ENABLE([cds], [AS_HELP_STRING([--enable-cds@<:@=yes/no/auto@:>@],
255 [enable class data sharing feature in non-minimal VM. Default is auto, where cds is enabled if supported on the platform.])])
256
257 if test "x$enable_cds" = "x" || test "x$enable_cds" = "xauto"; then
258 ENABLE_CDS="true"
259 elif test "x$enable_cds" = "xyes"; then
260 ENABLE_CDS="true"
261 elif test "x$enable_cds" = "xno"; then
262 ENABLE_CDS="false"
263 else
264 AC_MSG_ERROR([Invalid value for --enable-cds: $enable_cds])
265 fi
266
267 AC_SUBST(ENABLE_CDS)
268 ])
269
270 ###############################################################################
271 # Set up all JVM features for each JVM variant.
272 #
273 AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_FEATURES],
274 [
275 # Prettify the VALID_JVM_FEATURES string
276 BASIC_SORT_LIST(VALID_JVM_FEATURES, $VALID_JVM_FEATURES)
277
278 # The user can in some cases supply additional jvm features. For the custom
279 # variant, this defines the entire variant.
280 AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
281 [JVM features to enable (foo) or disable (-foo), separated by comma. Use '--help' to show possible values @<:@none@:>@])])
282 if test "x$with_jvm_features" != x; then
283 AC_MSG_CHECKING([user specified JVM feature list])
284 USER_JVM_FEATURE_LIST=`$ECHO $with_jvm_features | $SED -e 's/,/ /g'`
285 AC_MSG_RESULT([$user_jvm_feature_list])
286 # These features will be added to all variant defaults
287 JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (!match($i, /^-.*/)) printf("%s ", $i) }'`
288 # These features will be removed from all variant defaults
289 DISABLED_JVM_FEATURES=`$ECHO $USER_JVM_FEATURE_LIST | $AWK '{ for (i=1; i<=NF; i++) if (match($i, /^-.*/)) printf("%s ", substr($i, 2))}'`
290
291 # Verify that the user has provided valid features
292 BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES $DISABLED_JVM_FEATURES, $VALID_JVM_FEATURES $DEPRECATED_JVM_FEATURES)
293 if test "x$INVALID_FEATURES" != x; then
294 AC_MSG_NOTICE([Unknown JVM features specified: "$INVALID_FEATURES"])
295 AC_MSG_NOTICE([The available JVM features are: "$VALID_JVM_FEATURES"])
296 AC_MSG_ERROR([Cannot continue])
297 fi
298
299 # Check if the user has provided deprecated features
300 BASIC_GET_MATCHING_VALUES(DEPRECATED_FEATURES, $JVM_FEATURES $DISABLED_JVM_FEATURES, $DEPRECATED_JVM_FEATURES)
301 if test "x$DEPRECATED_FEATURES" != x; then
302 AC_MSG_WARN([Deprecated JVM features specified (will be ignored): "$DEPRECATED_FEATURES"])
303 # Filter out deprecated features
304 BASIC_GET_NON_MATCHING_VALUES(JVM_FEATURES, $JVM_FEATURES, $DEPRECATED_FEATURES)
305 BASIC_GET_NON_MATCHING_VALUES(DISABLED_JVM_FEATURES, $DISABLED_JVM_FEATURES, $DEPRECATED_FEATURES)
306 fi
307
308 fi
309
310 # Override hotspot cpu definitions for ARM platforms
311 if test "x$OPENJDK_TARGET_CPU" = xarm; then
312 HOTSPOT_TARGET_CPU=arm_32
313 HOTSPOT_TARGET_CPU_DEFINE="ARM32"
314 fi
315
316 # Verify that dependencies are met for explicitly set features.
317 if HOTSPOT_CHECK_JVM_FEATURE(jvmti) && ! HOTSPOT_CHECK_JVM_FEATURE(services); then
318 AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services'])
319 fi
320
321 if HOTSPOT_CHECK_JVM_FEATURE(management) && ! HOTSPOT_CHECK_JVM_FEATURE(nmt); then
322 AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt'])
323 fi
324
325 if HOTSPOT_CHECK_JVM_FEATURE(jvmci) && ! (HOTSPOT_CHECK_JVM_FEATURE(compiler1) || HOTSPOT_CHECK_JVM_FEATURE(compiler2)); then
326 AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2' or 'compiler1'])
327 fi
328
329 if HOTSPOT_CHECK_JVM_FEATURE(cmsgc) && ! HOTSPOT_CHECK_JVM_FEATURE(serialgc); then
330 AC_MSG_ERROR([Specified JVM feature 'cmsgc' requires feature 'serialgc'])
331 fi
332
333 # Enable JFR by default, except for Zero, linux-sparcv9 and on minimal.
334 if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
335 if test "x$OPENJDK_TARGET_OS" != xaix; then
336 if test "x$OPENJDK_TARGET_OS" != xlinux || test "x$OPENJDK_TARGET_CPU" != xsparcv9; then
337 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES jfr"
338 fi
339 fi
340 fi
341
342 # Only enable Shenandoah on supported arches
343 AC_MSG_CHECKING([if shenandoah can be built])
344 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86" || test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
345 AC_MSG_RESULT([yes])
346 else
347 DISABLED_JVM_FEATURES="$DISABLED_JVM_FEATURES shenandoahgc"
348 AC_MSG_RESULT([no, platform not supported])
349 fi
350
351 # Only enable ZGC on supported platforms
352 AC_MSG_CHECKING([if zgc can be built])
353 if (test "x$OPENJDK_TARGET_OS" = "xlinux" && test "x$OPENJDK_TARGET_CPU" = "xx86_64") || \
354 (test "x$OPENJDK_TARGET_OS" = "xwindows" && test "x$OPENJDK_TARGET_CPU" = "xx86_64") || \
355 (test "x$OPENJDK_TARGET_OS" = "xlinux" && test "x$OPENJDK_TARGET_CPU" = "xaarch64"); then
356 AC_MSG_RESULT([yes])
357 else
358 DISABLED_JVM_FEATURES="$DISABLED_JVM_FEATURES zgc"
359 AC_MSG_RESULT([no, platform not supported])
360 fi
361
362 # Disable unsupported GCs for Zero
363 if HOTSPOT_CHECK_JVM_VARIANT(zero); then
364 DISABLED_JVM_FEATURES="$DISABLED_JVM_FEATURES epsilongc g1gc zgc shenandoahgc"
365 fi
366
367 # Turn on additional features based on other parts of configure
368 if test "x$INCLUDE_DTRACE" = "xtrue"; then
369 JVM_FEATURES="$JVM_FEATURES dtrace"
370 else
371 if HOTSPOT_CHECK_JVM_FEATURE(dtrace); then
372 AC_MSG_ERROR([To enable dtrace, you must use --enable-dtrace])
373 fi
374 fi
375
376 if test "x$STATIC_BUILD" = "xtrue"; then
377 JVM_FEATURES="$JVM_FEATURES static-build"
378 else
379 if HOTSPOT_CHECK_JVM_FEATURE(static-build); then
380 AC_MSG_ERROR([To enable static-build, you must use --enable-static-build])
381 fi
382 fi
383
384 if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
385 if HOTSPOT_CHECK_JVM_FEATURE(zero); then
386 AC_MSG_ERROR([To enable zero, you must use --with-jvm-variants=zero])
387 fi
388 fi
389
390 AC_MSG_CHECKING([if jvmci module jdk.internal.vm.ci should be built])
391 # Check if jvmci is diabled
392 if HOTSPOT_IS_JVM_FEATURE_DISABLED(jvmci); then
393 AC_MSG_RESULT([no, forced])
394 JVM_FEATURES_jvmci=""
395 INCLUDE_JVMCI="false"
396 else
397 # Only enable jvmci on x86_64 and aarch64
398 if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
399 test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
400 AC_MSG_RESULT([yes])
401 JVM_FEATURES_jvmci="jvmci"
402 INCLUDE_JVMCI="true"
403 else
404 AC_MSG_RESULT([no])
405 JVM_FEATURES_jvmci=""
406 INCLUDE_JVMCI="false"
407 if HOTSPOT_CHECK_JVM_FEATURE(jvmci); then
408 AC_MSG_ERROR([JVMCI is currently not supported on this platform.])
409 fi
410 fi
411 fi
412
413 AC_SUBST(INCLUDE_JVMCI)
414
415 AC_MSG_CHECKING([if graal module jdk.internal.vm.compiler should be built])
416 # Check if graal is diabled
417 if HOTSPOT_IS_JVM_FEATURE_DISABLED(graal); then
418 AC_MSG_RESULT([no, forced])
419 JVM_FEATURES_graal=""
420 INCLUDE_GRAAL="false"
421 else
422 if HOTSPOT_CHECK_JVM_FEATURE(graal); then
423 AC_MSG_RESULT([yes, forced])
424 if test "x$JVM_FEATURES_jvmci" != "xjvmci" ; then
425 AC_MSG_ERROR([Specified JVM feature 'graal' requires feature 'jvmci'])
426 fi
427 JVM_FEATURES_graal="graal"
428 INCLUDE_GRAAL="true"
429 else
430 # By default enable graal build on x64 or where AOT is available.
431 # graal build requires jvmci.
432 if test "x$JVM_FEATURES_jvmci" = "xjvmci" && \
433 (test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
434 test "x$ENABLE_AOT" = "xtrue") ; then
435 AC_MSG_RESULT([yes])
436 JVM_FEATURES_graal="graal"
437 INCLUDE_GRAAL="true"
438 else
439 AC_MSG_RESULT([no])
440 JVM_FEATURES_graal=""
441 INCLUDE_GRAAL="false"
442 fi
443 fi
444 fi
445
446 AC_SUBST(INCLUDE_GRAAL)
447
448 # Disable aot with '--with-jvm-features=-aot'
449 if HOTSPOT_IS_JVM_FEATURE_DISABLED(aot); then
450 ENABLE_AOT="false"
451 fi
452
453 AC_MSG_CHECKING([if aot should be enabled])
454 if test "x$ENABLE_AOT" = "xtrue"; then
455 if test "x$JVM_FEATURES_graal" != "xgraal"; then
456 if test "x$enable_aot" = "xyes" || HOTSPOT_CHECK_JVM_FEATURE(aot); then
457 AC_MSG_RESULT([yes, forced])
458 AC_MSG_ERROR([Specified JVM feature 'aot' requires feature 'graal'])
459 else
460 AC_MSG_RESULT([no])
461 fi
462 JVM_FEATURES_aot=""
463 ENABLE_AOT="false"
464 else
465 if test "x$enable_aot" = "xyes" || HOTSPOT_CHECK_JVM_FEATURE(aot); then
466 AC_MSG_RESULT([yes, forced])
467 else
468 AC_MSG_RESULT([yes])
469 fi
470 JVM_FEATURES_aot="aot"
471 fi
472 else
473 if test "x$enable_aot" = "xno" || HOTSPOT_IS_JVM_FEATURE_DISABLED(aot); then
474 AC_MSG_RESULT([no, forced])
475 else
476 AC_MSG_RESULT([no])
477 fi
478 JVM_FEATURES_aot=""
479 if HOTSPOT_CHECK_JVM_FEATURE(aot); then
480 AC_MSG_ERROR([To enable aot, you must use --enable-aot])
481 fi
482 fi
483
484 AC_SUBST(ENABLE_AOT)
485
486 if test "x$OPENJDK_TARGET_CPU" = xarm ; then
487 # Default to use link time optimizations on minimal on arm
488 JVM_FEATURES_link_time_opt="link-time-opt"
489 else
490 JVM_FEATURES_link_time_opt=""
491 fi
492
493 # All variants but minimal (and custom) get these features
494 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cmsgc g1gc parallelgc serialgc epsilongc shenandoahgc jni-check jvmti management nmt services vm-structs zgc"
495
496 # Disable CDS on AIX.
497 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
498 ENABLE_CDS="false"
499 if test "x$enable_cds" = "xyes"; then
500 AC_MSG_ERROR([CDS is currently not supported on AIX. Remove --enable-cds.])
501 fi
502 fi
503
504 # Disable CDS if user requested it with --with-jvm-features=-cds.
505 if HOTSPOT_IS_JVM_FEATURE_DISABLED(cds); then
506 ENABLE_CDS="false"
507 if test "x$enable_cds" = "xyes"; then
508 AC_MSG_ERROR([CDS was disabled by --with-jvm-features=-cds. Remove --enable-cds.])
509 fi
510 fi
511
512 # Disable CDS for zero, minimal, core..
513 if HOTSPOT_CHECK_JVM_VARIANT(zero) || HOTSPOT_CHECK_JVM_VARIANT(minimal) || HOTSPOT_CHECK_JVM_VARIANT(core); then
514 # ..except when the user explicitely requested it with --enable-jvm-features
515 if ! HOTSPOT_CHECK_JVM_FEATURE(cds); then
516 ENABLE_CDS="false"
517 if test "x$enable_cds" = "xyes"; then
518 AC_MSG_ERROR([CDS not implemented for variants zero, minimal, core. Remove --enable-cds.])
519 fi
520 fi
521 fi
522
523 AC_MSG_CHECKING([if cds should be enabled])
524 if test "x$ENABLE_CDS" = "xtrue"; then
525 if test "x$enable_cds" = "xyes"; then
526 AC_MSG_RESULT([yes, forced])
527 else
528 AC_MSG_RESULT([yes])
529 fi
530 NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES cds"
531 else
532 if test "x$enable_cds" = "xno"; then
533 AC_MSG_RESULT([no, forced])
534 else
535 AC_MSG_RESULT([no])
536 fi
537 fi
538
539 # Enable features depending on variant.
540 JVM_FEATURES_server="compiler1 compiler2 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci $JVM_FEATURES_aot $JVM_FEATURES_graal"
541 JVM_FEATURES_client="compiler1 $NON_MINIMAL_FEATURES $JVM_FEATURES"
542 JVM_FEATURES_core="$NON_MINIMAL_FEATURES $JVM_FEATURES"
543 JVM_FEATURES_minimal="compiler1 minimal serialgc $JVM_FEATURES $JVM_FEATURES_link_time_opt"
544 JVM_FEATURES_zero="zero $NON_MINIMAL_FEATURES $JVM_FEATURES"
545 JVM_FEATURES_custom="$JVM_FEATURES"
546
547 AC_SUBST(JVM_FEATURES_server)
548 AC_SUBST(JVM_FEATURES_client)
549 AC_SUBST(JVM_FEATURES_core)
550 AC_SUBST(JVM_FEATURES_minimal)
551 AC_SUBST(JVM_FEATURES_zero)
552 AC_SUBST(JVM_FEATURES_custom)
553
554 # Used for verification of Makefiles by check-jvm-feature
555 AC_SUBST(VALID_JVM_FEATURES)
556
557 # --with-cpu-port is no longer supported
558 BASIC_DEPRECATED_ARG_WITH(with-cpu-port)
559 ])
560
561 ###############################################################################
562 # Finalize JVM features once all setup is complete, including custom setup.
563 #
564 AC_DEFUN_ONCE([HOTSPOT_FINALIZE_JVM_FEATURES],
565 [
566 for variant in $JVM_VARIANTS; do
567 AC_MSG_CHECKING([JVM features for JVM variant '$variant'])
568 features_var_name=JVM_FEATURES_$variant
569 JVM_FEATURES_FOR_VARIANT=${!features_var_name}
570
571 # Filter out user-requested disabled features
572 BASIC_GET_NON_MATCHING_VALUES(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT, $DISABLED_JVM_FEATURES)
573
574 # Keep feature lists sorted and free of duplicates
575 BASIC_SORT_LIST(JVM_FEATURES_FOR_VARIANT, $JVM_FEATURES_FOR_VARIANT)
576
577 # Update real feature set variable
578 eval $features_var_name='"'$JVM_FEATURES_FOR_VARIANT'"'
579 AC_MSG_RESULT(["$JVM_FEATURES_FOR_VARIANT"])
580
581 # Verify that we have at least one gc selected
582 GC_FEATURES=`$ECHO $JVM_FEATURES_FOR_VARIANT | $GREP gc`
583 if test "x$GC_FEATURES" = x; then
584 AC_MSG_WARN([Invalid JVM features: No gc selected for variant $variant.])
585 fi
586
587 # Validate features (for configure script errors, not user errors)
588 BASIC_GET_NON_MATCHING_VALUES(INVALID_FEATURES, $JVM_FEATURES_FOR_VARIANT, $VALID_JVM_FEATURES)
589 if test "x$INVALID_FEATURES" != x; then
590 AC_MSG_ERROR([Internal configure script error. Invalid JVM feature(s): $INVALID_FEATURES])
591 fi
592 done
593 ])
594
595 ################################################################################
596 # Check if gtest should be built
597 #
598 AC_DEFUN_ONCE([HOTSPOT_ENABLE_DISABLE_GTEST],
599 [
600 AC_ARG_ENABLE([hotspot-gtest], [AS_HELP_STRING([--disable-hotspot-gtest],
601 [Disables building of the Hotspot unit tests @<:@enabled@:>@])])
602
603 if test -e "${TOPDIR}/test/hotspot/gtest"; then
604 GTEST_DIR_EXISTS="true"
605 else
606 GTEST_DIR_EXISTS="false"
607 fi
608
609 AC_MSG_CHECKING([if Hotspot gtest unit tests should be built])
610 if test "x$enable_hotspot_gtest" = "xyes"; then
611 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
612 AC_MSG_RESULT([yes, forced])
613 BUILD_GTEST="true"
614 else
615 AC_MSG_ERROR([Cannot build gtest without the test source])
616 fi
617 elif test "x$enable_hotspot_gtest" = "xno"; then
618 AC_MSG_RESULT([no, forced])
619 BUILD_GTEST="false"
620 elif test "x$enable_hotspot_gtest" = "x"; then
621 if test "x$GTEST_DIR_EXISTS" = "xtrue"; then
622 AC_MSG_RESULT([yes])
623 BUILD_GTEST="true"
624 else
625 AC_MSG_RESULT([no])
626 BUILD_GTEST="false"
627 fi
628 else
629 AC_MSG_ERROR([--enable-gtest must be either yes or no])
630 fi
631
632 AC_SUBST(BUILD_GTEST)
633 ])