1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 ################################################################################
27 #
28 # Setup flags for C/C++ compiler
29 #
30
31 ###############################################################################
32 #
33 # How to compile shared libraries.
34 #
35 AC_DEFUN([FLAGS_SETUP_SHARED_LIBS],
36 [
37 if test "x$TOOLCHAIN_TYPE" = xgcc; then
38 C_FLAG_REORDER=''
39
40 # Default works for linux, might work on other platforms as well.
41 SHARED_LIBRARY_FLAGS='-shared'
42 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
43 SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
44 SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
45 SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
46
47 elif test "x$TOOLCHAIN_TYPE" = xclang; then
48 C_FLAG_REORDER=''
49
50 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
51 # Linking is different on MacOSX
52 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0"
53 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,@loader_path$(or [$]1,/.)'
54 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
55 SET_SHARED_LIBRARY_NAME='-Wl,-install_name,@rpath/[$]1'
56 SET_SHARED_LIBRARY_MAPFILE='-Wl,-exported_symbols_list,[$]1'
57
58 else
59 # Default works for linux, might work on other platforms as well.
60 SHARED_LIBRARY_FLAGS='-shared'
61 SET_EXECUTABLE_ORIGIN='-Wl,-rpath,\$$ORIGIN[$]1'
62 SET_SHARED_LIBRARY_NAME='-Wl,-soname=[$]1'
63 SET_SHARED_LIBRARY_MAPFILE='-Wl,-version-script=[$]1'
64
65 # arm specific settings
66 if test "x$OPENJDK_TARGET_CPU" = "xarm"; then
67 # '-Wl,-z,origin' isn't used on arm.
68 SET_SHARED_LIBRARY_ORIGIN='-Wl,-rpath,\$$$$ORIGIN[$]1'
69 else
70 SET_SHARED_LIBRARY_ORIGIN="-Wl,-z,origin $SET_EXECUTABLE_ORIGIN"
71 fi
72 fi
73
74 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
75 C_FLAG_REORDER='-xF'
76 SHARED_LIBRARY_FLAGS="-G"
77 SET_EXECUTABLE_ORIGIN='-R\$$ORIGIN[$]1'
78 SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
79 SET_SHARED_LIBRARY_NAME='-h [$]1'
80 SET_SHARED_LIBRARY_MAPFILE='-M[$]1'
81
82 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
83 C_FLAG_REORDER=''
84 SHARED_LIBRARY_FLAGS="-qmkshrobj -bM:SRE -bnoentry"
85 SET_EXECUTABLE_ORIGIN=""
86 SET_SHARED_LIBRARY_ORIGIN=''
87 SET_SHARED_LIBRARY_NAME=''
88 SET_SHARED_LIBRARY_MAPFILE=''
89
90 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
91 C_FLAG_REORDER=''
92 SHARED_LIBRARY_FLAGS="-dll"
93 SET_EXECUTABLE_ORIGIN=''
94 SET_SHARED_LIBRARY_ORIGIN=''
95 SET_SHARED_LIBRARY_NAME=''
96 SET_SHARED_LIBRARY_MAPFILE='-def:[$]1'
97 fi
98
99 AC_SUBST(C_FLAG_REORDER)
100 AC_SUBST(SET_EXECUTABLE_ORIGIN)
101 AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
102 AC_SUBST(SET_SHARED_LIBRARY_NAME)
103 AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
104 AC_SUBST(SHARED_LIBRARY_FLAGS)
105 ])
106
107 AC_DEFUN([FLAGS_SETUP_DEBUG_SYMBOLS],
108 [
109 # Debug symbols
110 if test "x$TOOLCHAIN_TYPE" = xgcc; then
111 CFLAGS_DEBUG_SYMBOLS="-g"
112 elif test "x$TOOLCHAIN_TYPE" = xclang; then
113 CFLAGS_DEBUG_SYMBOLS="-g"
114 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
115 # -g0 enables debug symbols without disabling inlining.
116 CFLAGS_DEBUG_SYMBOLS="-g0 -xs"
117 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
118 CFLAGS_DEBUG_SYMBOLS="-g"
119 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
120 CFLAGS_DEBUG_SYMBOLS="-Z7 -d2Zi+"
121 fi
122
123 AC_SUBST(CFLAGS_DEBUG_SYMBOLS)
124 ])
125
126 AC_DEFUN([FLAGS_SETUP_WARNINGS],
127 [
128 AC_ARG_ENABLE([warnings-as-errors], [AS_HELP_STRING([--disable-warnings-as-errors],
129 [do not consider native warnings to be an error @<:@enabled@:>@])])
130
131 # Set default value.
132 if test "x$TOOLCHAIN_TYPE" = xxlc; then
133 WARNINGS_AS_ERRORS=false
134 else
135 WARNINGS_AS_ERRORS=true
136 fi
137
138 AC_MSG_CHECKING([if native warnings are errors])
139 if test "x$enable_warnings_as_errors" = "xyes"; then
140 AC_MSG_RESULT([yes (explicitly set)])
141 WARNINGS_AS_ERRORS=true
142 elif test "x$enable_warnings_as_errors" = "xno"; then
143 AC_MSG_RESULT([no (explicitly set)])
144 WARNINGS_AS_ERRORS=false
145 elif test "x$enable_warnings_as_errors" = "x"; then
146 AC_MSG_RESULT([${WARNINGS_AS_ERRORS} (default)])
147 # Do not change default value.
148 else
149 AC_MSG_ERROR([--enable-warnings-as-errors accepts no argument])
150 fi
151
152 AC_SUBST(WARNINGS_AS_ERRORS)
153
154 case "${TOOLCHAIN_TYPE}" in
155 microsoft)
156 DISABLE_WARNING_PREFIX="-wd"
157 CFLAGS_WARNINGS_ARE_ERRORS="-WX"
158 ;;
159 solstudio)
160 DISABLE_WARNING_PREFIX="-erroff="
161 CFLAGS_WARNINGS_ARE_ERRORS="-errtags -errwarn=%all"
162 ;;
163 gcc)
164 DISABLE_WARNING_PREFIX="-Wno-"
165 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
166 # Repeate the check for the BUILD_CC and BUILD_CXX. Need to also reset
167 # CFLAGS since any target specific flags will likely not work with the
168 # build compiler
169 CC_OLD="$CC"
170 CXX_OLD="$CXX"
171 CC="$BUILD_CC"
172 CXX="$BUILD_CXX"
173 CFLAGS_OLD="$CFLAGS"
174 CFLAGS=""
175 BUILD_CC_DISABLE_WARNING_PREFIX="-Wno-"
176 CC="$CC_OLD"
177 CXX="$CXX_OLD"
178 CFLAGS="$CFLAGS_OLD"
179 ;;
180 clang)
181 DISABLE_WARNING_PREFIX="-Wno-"
182 CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
183 ;;
184 xlc)
185 DISABLE_WARNING_PREFIX="-qsuppress="
186 CFLAGS_WARNINGS_ARE_ERRORS="-qhalt=w"
187 ;;
188 esac
189 AC_SUBST(DISABLE_WARNING_PREFIX)
190 AC_SUBST(BUILD_CC_DISABLE_WARNING_PREFIX)
191 AC_SUBST(CFLAGS_WARNINGS_ARE_ERRORS)
192 ])
193
194 AC_DEFUN([FLAGS_SETUP_QUALITY_CHECKS],
195 [
196 # bounds, memory and behavior checking options
197 if test "x$TOOLCHAIN_TYPE" = xgcc; then
198 case $DEBUG_LEVEL in
199 release )
200 # no adjustment
201 ;;
202 fastdebug )
203 # no adjustment
204 ;;
205 slowdebug )
206 # FIXME: By adding this to C(XX)FLAGS_DEBUG_OPTIONS/JVM_CFLAGS_SYMBOLS it
207 # get's added conditionally on whether we produce debug symbols or not.
208 # This is most likely not really correct.
209
210 # Add runtime stack smashing and undefined behavior checks.
211 CFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
212 CXXFLAGS_DEBUG_OPTIONS="-fstack-protector-all --param ssp-buffer-size=1"
213
214 JVM_CFLAGS_SYMBOLS="$JVM_CFLAGS_SYMBOLS -fstack-protector-all --param ssp-buffer-size=1"
215 ;;
216 esac
217 fi
218 ])
219
220 AC_DEFUN([FLAGS_SETUP_OPTIMIZATION],
221 [
222 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
223 CC_HIGHEST="-fns -fsimple -fsingle -xbuiltin=%all -xdepend -xrestrict -xlibmil"
224
225 C_O_FLAG_HIGHEST_JVM="-xO4"
226 C_O_FLAG_DEBUG_JVM=""
227 C_O_FLAG_SIZE=""
228 C_O_FLAG_DEBUG=""
229 C_O_FLAG_NONE=""
230 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
231 C_O_FLAG_HIGHEST="-xO4 -Wu,-O4~yz $CC_HIGHEST"
232 C_O_FLAG_HI="-xO4 -Wu,-O4~yz"
233 C_O_FLAG_NORM="-xO2 -Wu,-O2~yz"
234 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
235 C_O_FLAG_HIGHEST="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0 \
236 -xprefetch=auto,explicit -xchip=ultra $CC_HIGHEST"
237 C_O_FLAG_HI="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0"
238 C_O_FLAG_NORM="-xO2 -Wc,-Qrm-s -Wc,-Qiselect-T0"
239 fi
240 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
241 C_O_FLAG_HIGHEST_JVM="-O3"
242 C_O_FLAG_HIGHEST="-O3"
243 C_O_FLAG_HI="-O3"
244 C_O_FLAG_NORM="-O2"
245 C_O_FLAG_SIZE="-Os"
246 C_O_FLAG_DEBUG="-O0"
247 C_O_FLAG_DEBUG_JVM="-O0"
248 C_O_FLAG_NONE="-O0"
249 elif test "x$TOOLCHAIN_TYPE" = xclang; then
250 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
251 # On MacOSX we optimize for size, something
252 # we should do for all platforms?
253 C_O_FLAG_HIGHEST_JVM="-Os"
254 C_O_FLAG_HIGHEST="-Os"
255 C_O_FLAG_HI="-Os"
256 C_O_FLAG_NORM="-Os"
257 C_O_FLAG_DEBUG_JVM=""
258 else
259 C_O_FLAG_HIGHEST_JVM="-O3"
260 C_O_FLAG_HIGHEST="-O3"
261 C_O_FLAG_HI="-O3"
262 C_O_FLAG_NORM="-O2"
263 C_O_FLAG_DEBUG_JVM="-O0"
264 fi
265 C_O_FLAG_SIZE="-Os"
266 C_O_FLAG_DEBUG="-O0"
267 C_O_FLAG_NONE="-O0"
268 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
269 C_O_FLAG_HIGHEST_JVM="-O3 -qhot=level=1 -qinline -qinlglue"
270 C_O_FLAG_HIGHEST="-O3 -qhot=level=1 -qinline -qinlglue"
271 C_O_FLAG_HI="-O3 -qinline -qinlglue"
272 C_O_FLAG_NORM="-O2"
273 C_O_FLAG_DEBUG="-qnoopt"
274 # FIXME: Value below not verified.
275 C_O_FLAG_DEBUG_JVM=""
276 C_O_FLAG_NONE="-qnoopt"
277 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
278 C_O_FLAG_HIGHEST_JVM="-O2 -Oy-"
279 C_O_FLAG_HIGHEST="-O2"
280 C_O_FLAG_HI="-O1"
281 C_O_FLAG_NORM="-O1"
282 C_O_FLAG_DEBUG="-Od"
283 C_O_FLAG_DEBUG_JVM=""
284 C_O_FLAG_NONE="-Od"
285 C_O_FLAG_SIZE="-Os"
286 fi
287
288 # Now copy to C++ flags
289 CXX_O_FLAG_HIGHEST_JVM="$C_O_FLAG_HIGHEST_JVM"
290 CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
291 CXX_O_FLAG_HI="$C_O_FLAG_HI"
292 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
293 CXX_O_FLAG_DEBUG="$C_O_FLAG_DEBUG"
294 CXX_O_FLAG_DEBUG_JVM="$C_O_FLAG_DEBUG_JVM"
295 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
296 CXX_O_FLAG_SIZE="$C_O_FLAG_SIZE"
297
298 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
299 # In solstudio, also add this to C (but not C++) flags...
300 C_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST -xalias_level=basic"
301 fi
302
303 # Adjust optimization flags according to debug level.
304 case $DEBUG_LEVEL in
305 release )
306 # no adjustment
307 ;;
308 fastdebug )
309 # Not quite so much optimization
310 C_O_FLAG_HI="$C_O_FLAG_NORM"
311 CXX_O_FLAG_HI="$CXX_O_FLAG_NORM"
312 ;;
313 slowdebug )
314 # Disable optimization
315 C_O_FLAG_HIGHEST_JVM="$C_O_FLAG_DEBUG_JVM"
316 C_O_FLAG_HIGHEST="$C_O_FLAG_DEBUG"
317 C_O_FLAG_HI="$C_O_FLAG_DEBUG"
318 C_O_FLAG_NORM="$C_O_FLAG_DEBUG"
319 C_O_FLAG_SIZE="$C_O_FLAG_DEBUG"
320 CXX_O_FLAG_HIGHEST_JVM="$CXX_O_FLAG_DEBUG_JVM"
321 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_DEBUG"
322 CXX_O_FLAG_HI="$CXX_O_FLAG_DEBUG"
323 CXX_O_FLAG_NORM="$CXX_O_FLAG_DEBUG"
324 CXX_O_FLAG_SIZE="$CXX_O_FLAG_DEBUG"
325 ;;
326 esac
327
328 AC_SUBST(C_O_FLAG_HIGHEST_JVM)
329 AC_SUBST(C_O_FLAG_HIGHEST)
330 AC_SUBST(C_O_FLAG_HI)
331 AC_SUBST(C_O_FLAG_NORM)
332 AC_SUBST(C_O_FLAG_NONE)
333 AC_SUBST(C_O_FLAG_SIZE)
334 AC_SUBST(CXX_O_FLAG_HIGHEST_JVM)
335 AC_SUBST(CXX_O_FLAG_HIGHEST)
336 AC_SUBST(CXX_O_FLAG_HI)
337 AC_SUBST(CXX_O_FLAG_NORM)
338 AC_SUBST(CXX_O_FLAG_NONE)
339 AC_SUBST(CXX_O_FLAG_SIZE)
340 ])
341
342 AC_DEFUN([FLAGS_SETUP_CFLAGS],
343 [
344 ### CFLAGS
345
346 FLAGS_SETUP_CFLAGS_HELPER
347
348 FLAGS_OS=$OPENJDK_TARGET_OS
349 FLAGS_OS_TYPE=$OPENJDK_TARGET_OS_TYPE
350 FLAGS_CPU=$OPENJDK_TARGET_CPU
351 FLAGS_CPU_ARCH=$OPENJDK_TARGET_CPU_ARCH
352 FLAGS_CPU_BITS=$OPENJDK_TARGET_CPU_BITS
353 FLAGS_CPU_ENDIAN=$OPENJDK_TARGET_CPU_ENDIAN
354 FLAGS_CPU_LEGACY=$OPENJDK_TARGET_CPU_LEGACY
355 FLAGS_CPU_LEGACY_LIB=$OPENJDK_TARGET_CPU_LEGACY_LIB
356
357 FLAGS_SETUP_CFLAGS_CPU_DEP([TARGET])
358
359 FLAGS_OS=$OPENJDK_BUILD_OS
360 FLAGS_OS_TYPE=$OPENJDK_BUILD_OS_TYPE
361 FLAGS_CPU=$OPENJDK_BUILD_CPU
362 FLAGS_CPU_ARCH=$OPENJDK_BUILD_CPU_ARCH
363 FLAGS_CPU_BITS=$OPENJDK_BUILD_CPU_BITS
364 FLAGS_CPU_ENDIAN=$OPENJDK_BUILD_CPU_ENDIAN
365 FLAGS_CPU_LEGACY=$OPENJDK_BUILD_CPU_LEGACY
366 FLAGS_CPU_LEGACY_LIB=$OPENJDK_BUILD_CPU_LEGACY_LIB
367
368 FLAGS_SETUP_CFLAGS_CPU_DEP([BUILD], [OPENJDK_BUILD_])
369
370 # Tests are only ever compiled for TARGET
371 CFLAGS_TESTLIB="$CFLAGS_JDKLIB"
372 CXXFLAGS_TESTLIB="$CXXFLAGS_JDKLIB"
373 CFLAGS_TESTEXE="$CFLAGS_JDKEXE"
374 CXXFLAGS_TESTEXE="$CXXFLAGS_JDKEXE"
375
376 AC_SUBST(CFLAGS_TESTLIB)
377 AC_SUBST(CFLAGS_TESTEXE)
378 AC_SUBST(CXXFLAGS_TESTLIB)
379 AC_SUBST(CXXFLAGS_TESTEXE)
380 ])
381
382 ################################################################################
383 # platform independent
384 AC_DEFUN([FLAGS_SETUP_CFLAGS_HELPER],
385 [
386 #### OS DEFINES, these should be independent on toolchain
387 if test "x$OPENJDK_TARGET_OS" = xlinux; then
388 CFLAGS_OS_DEF_JVM="-DLINUX"
389 CFLAGS_OS_DEF_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
390 elif test "x$OPENJDK_TARGET_OS" = xsolaris; then
391 CFLAGS_OS_DEF_JVM="-DSOLARIS"
392 CFLAGS_OS_DEF_JDK="-D__solaris__"
393 elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
394 CFLAGS_OS_DEF_JVM="-D_ALLBSD_SOURCE -D_DARWIN_C_SOURCE -D_XOPEN_SOURCE"
395 CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE -D_DARWIN_UNLIMITED_SELECT"
396 elif test "x$OPENJDK_TARGET_OS" = xaix; then
397 CFLAGS_OS_DEF_JVM="-DAIX"
398 elif test "x$OPENJDK_TARGET_OS" = xbsd; then
399 CFLAGS_OS_DEF_JDK="-D_ALLBSD_SOURCE"
400 elif test "x$OPENJDK_TARGET_OS" = xwindows; then
401 CFLAGS_OS_DEF_JVM="-D_WINDOWS -DWIN32 -D_JNI_IMPLEMENTATION_"
402 fi
403
404 CFLAGS_OS_DEF_JDK="$CFLAGS_OS_DEF_JDK -D$OPENJDK_TARGET_OS_UPPERCASE"
405
406 #### GLOBAL DEFINES
407 # Set some common defines. These works for all compilers, but assume
408 # -D is universally accepted.
409
410 # Always enable optional macros for VM.
411 ALWAYS_CFLAGS_JVM="-D__STDC_FORMAT_MACROS -D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
412
413 # Setup some hard coded includes
414 ALWAYS_CFLAGS_JDK=" \
415 -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base \
416 -I\$(SUPPORT_OUTPUTDIR)/modules_include/java.base/\$(OPENJDK_TARGET_OS_INCLUDE_SUBDIR) \
417 -I${TOPDIR}/src/java.base/share/native/libjava \
418 -I${TOPDIR}/src/java.base/$OPENJDK_TARGET_OS_TYPE/native/libjava \
419 -I${TOPDIR}/src/hotspot/share/include \
420 -I${TOPDIR}/src/hotspot/os/${HOTSPOT_TARGET_OS_TYPE}/include"
421
422 ###############################################################################
423
424 # Adjust flags according to debug level.
425 # Setup debug/release defines
426 if test "x$DEBUG_LEVEL" = xrelease; then
427 DEBUG_CFLAGS_JDK="-DNDEBUG"
428 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
429 DEBUG_CFLAGS_JDK="$DEBUG_CFLAGS_JDK -DTRIMMED"
430 fi
431 else
432 DEBUG_CFLAGS_JDK="-DDEBUG"
433
434 if test "x$TOOLCHAIN_TYPE" = xxlc; then
435 # We need '-qminimaltoc' or '-qpic=large -bbigtoc' if the TOC overflows.
436 # Hotspot now overflows its 64K TOC (currently only for debug),
437 # so for debug we build with '-qpic=large -bbigtoc'.
438 DEBUG_CFLAGS_JVM="-qpic=large"
439 fi
440 fi
441
442 if test "x$DEBUG_LEVEL" != xrelease; then
443 DEBUG_OPTIONS_FLAGS_JDK="$CFLAGS_DEBUG_OPTIONS"
444 DEBUG_SYMBOLS_CFLAGS_JDK="$CFLAGS_DEBUG_SYMBOLS"
445 fi
446
447 #### TOOLCHAIN DEFINES
448
449 if test "x$TOOLCHAIN_TYPE" = xgcc; then
450 ALWAYS_DEFINES_JVM="-D_GNU_SOURCE -D_REENTRANT"
451 elif test "x$TOOLCHAIN_TYPE" = xclang; then
452 ALWAYS_DEFINES_JVM="-D_GNU_SOURCE"
453 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
454 ALWAYS_DEFINES_JVM="-DSPARC_WORKS -D_Crun_inline_placement"
455 ALWAYS_DEFINES_JDK="-DTRACING -DMACRO_MEMSYS_OPS -DBREAKPTS"
456 ALWAYS_DEFINES_JDK_CXXONLY="-DCC_NOEX"
457 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
458 ALWAYS_DEFINES_JVM="-D_REENTRANT"
459 ALWAYS_DEFINES_JDK="-D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
460 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
461 ALWAYS_DEFINES_JDK="-DWIN32_LEAN_AND_MEAN -D_CRT_SECURE_NO_DEPRECATE \
462 -D_CRT_NONSTDC_NO_DEPRECATE -DWIN32 -DIAL"
463 ALWAYS_DEFINES_JVM="-DNOMINMAX -DWIN32_LEAN_AND_MEAN"
464 fi
465
466 ###############################################################################
467 #
468 #
469 # CFLAGS BASIC
470 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
471 # COMMON to gcc and clang
472 TOOLCHAIN_CFLAGS_JVM="-pipe -fno-rtti -fno-exceptions \
473 -fvisibility=hidden -fno-strict-aliasing -fno-omit-frame-pointer"
474 fi
475
476 if test "x$TOOLCHAIN_TYPE" = xgcc; then
477 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -fcheck-new"
478 TOOLCHAIN_CFLAGS_JDK="-pipe"
479 TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing" # technically NOT for CXX (but since this gives *worse* performance, use no-strict-aliasing everywhere!)
480
481 CXXSTD_CXXFLAG="-std=gnu++98"
482 FLAGS_CXX_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$CXXSTD_CXXFLAG -Werror],
483 IF_FALSE: [CXXSTD_CXXFLAG=""])
484 TOOLCHAIN_CFLAGS_JDK_CXXONLY="$CXXSTD_CXXFLAG"
485 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM $CXXSTD_CXXFLAG"
486 ADLC_CXXFLAG="$CXXSTD_CXXFLAG"
487
488
489 elif test "x$TOOLCHAIN_TYPE" = xclang; then
490 # Restrict the debug information created by Clang to avoid
491 # too big object files and speed the build up a little bit
492 # (see http://llvm.org/bugs/show_bug.cgi?id=7554)
493 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM -flimit-debug-info"
494
495 if test "x$OPENJDK_TARGET_OS" = xlinux; then
496 TOOLCHAIN_CFLAGS_JDK="-pipe"
497 TOOLCHAIN_CFLAGS_JDK_CONLY="-fno-strict-aliasing" # technically NOT for CXX
498 fi
499 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
500 TOOLCHAIN_CFLAGS_JDK="-mt"
501 TOOLCHAIN_CFLAGS_JDK_CONLY="-xc99=%none -xCC -Xa -v -W0,-noglobal" # C only
502 TOOLCHAIN_CFLAGS_JDK_CXXONLY="-features=no%except -norunpath -xnolib" # CXX only
503 TOOLCHAIN_CFLAGS_JVM="-template=no%extdef -features=no%split_init \
504 -library=stlport4 -mt -features=no%except"
505 if test "x$DEBUG_LEVEL" = xslowdebug; then
506 # Previously -g was used instead of -g0 for slowdebug; this is equivalent
507 # to setting +d.
508 TOOLCHAIN_CFLAGS_JVM="$TOOLCHAIN_CFLAGS_JVM +d"
509 fi
510
511 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
512 TOOLCHAIN_CFLAGS_JDK="-qchars=signed -qfullpath -qsaveopt" # add on both CFLAGS
513 TOOLCHAIN_CFLAGS_JVM="-qtune=balanced \
514 -qalias=noansi -qstrict -qtls=default -qlanglvl=c99vla \
515 -qlanglvl=noredefmac -qnortti -qnoeh -qignerrno"
516 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
517 TOOLCHAIN_CFLAGS_JVM="-nologo -MD -MP"
518 TOOLCHAIN_CFLAGS_JDK="-nologo -MD -Zc:wchar_t-"
519 fi
520
521 # CFLAGS WARNINGS STUFF
522 # Set JVM_CFLAGS warning handling
523 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
524 # COMMON to gcc and clang
525 WARNING_CFLAGS_JVM="-Wpointer-arith -Wsign-compare -Wunused-function"
526 if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
527 # Non-zero builds have stricter warnings
528 WARNING_CFLAGS_JVM="$WARNING_CFLAGS_JVM -Wundef -Wformat=2"
529 fi
530
531 fi
532 if test "x$TOOLCHAIN_TYPE" = xgcc; then
533 WARNING_CFLAGS_JDK="-Wall -Wextra -Wno-unused -Wno-unused-parameter -Wformat=2"
534 WARNING_CFLAGS_JVM="$WARNING_CFLAGS_JVM -Wunused-value -Woverloaded-virtual"
535
536 if ! HOTSPOT_CHECK_JVM_VARIANT(zero); then
537 # Non-zero builds have stricter warnings
538 WARNING_CFLAGS_JVM="$WARNING_CFLAGS_JVM -Wreturn-type"
539 fi
540 elif test "x$TOOLCHAIN_TYPE" = xclang; then
541 WARNING_CFLAGS_JVM="$WARNING_CFLAGS_JVM -Wno-deprecated"
542 if test "x$OPENJDK_TARGET_OS" = xlinux; then
543 WARNING_CFLAGS_JVM="$WARNING_CFLAGS_JVM -Wno-sometimes-uninitialized"
544 WARNING_CFLAGS_JDK="-Wall -Wextra -Wno-unused -Wno-unused-parameter -Wformat=2"
545 fi
546 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
547 WARNING_CFLAGS_JDK_CONLY="-errshort=tags"
548 WARNING_CFLAGS_JDK_CXXONLY="+w"
549 WARNING_CFLAGS_JDK="-errtags=yes -errfmt"
550 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
551 WARNING_CFLAGS="-W3"
552 WARNING_CFLAGS_JDK="-wd4800"
553 fi
554
555 # Set some additional per-OS defines.
556
557 # Additional macosx handling
558 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
559 OS_CFLAGS="-DMAC_OS_X_VERSION_MIN_REQUIRED=$MACOSX_VERSION_MIN_NODOTS \
560 -mmacosx-version-min=$MACOSX_VERSION_MIN"
561
562 if test -n "$MACOSX_VERSION_MAX"; then
563 OS_CFLAGS="$OS_CFLAGS \
564 -DMAC_OS_X_VERSION_MAX_ALLOWED=$MACOSX_VERSION_MAX_NODOTS"
565 fi
566 fi
567
568 # Where does this really belong??
569 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
570 PICFLAG="-fPIC"
571 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
572 PICFLAG="-KPIC"
573 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
574 # '-qpic' defaults to 'qpic=small'. This means that the compiler generates only
575 # one instruction for accessing the TOC. If the TOC grows larger than 64K, the linker
576 # will have to patch this single instruction with a call to some out-of-order code which
577 # does the load from the TOC. This is of course slow. But in that case we also would have
578 # to use '-bbigtoc' for linking anyway so we could also change the PICFLAG to 'qpic=large'.
579 # With 'qpic=large' the compiler will by default generate a two-instruction sequence which
580 # can be patched directly by the linker and does not require a jump to out-of-order code.
581 # Another alternative instead of using 'qpic=large -bbigtoc' may be to use '-qminimaltoc'
582 # instead. This creates a distinct TOC for every compilation unit (and thus requires two
583 # loads for accessing a global variable). But there are rumors that this may be seen as a
584 # 'performance feature' because of improved code locality of the symbols used in a
585 # compilation unit.
586 PICFLAG="-qpic"
587 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
588 PICFLAG=""
589 fi
590
591 JVM_PICFLAG="$PICFLAG"
592 JDK_PICFLAG="$PICFLAG"
593
594 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
595 # Linking is different on MacOSX
596 JDK_PICFLAG=''
597 if test "x$STATIC_BUILD" = xtrue; then
598 JVM_PICFLAG=""
599 fi
600 fi
601
602 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
603 OS_CFLAGS_JVM="$OS_CFLAGS_JVM -mno-omit-leaf-frame-pointer -mstack-alignment=16"
604 fi
605
606 # Optional POSIX functionality needed by the JVM
607 #
608 # Check if clock_gettime is available and in which library. This indicates
609 # availability of CLOCK_MONOTONIC for hotspot. But we don't need to link, so
610 # don't let it update LIBS.
611 save_LIBS="$LIBS"
612 AC_SEARCH_LIBS(clock_gettime, rt, [HAS_CLOCK_GETTIME=true], [])
613 if test "x$LIBS" = "x-lrt "; then
614 CLOCK_GETTIME_IN_LIBRT=true
615 fi
616 LIBS="$save_LIBS"
617
618 if test "x$HAS_CLOCK_GETTIME" = "xtrue"; then
619 OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DSUPPORTS_CLOCK_MONOTONIC"
620 if test "x$CLOCK_GETTIME_IN_LIBRT" = "xtrue"; then
621 OS_CFLAGS_JVM="$OS_CFLAGS_JVM -DNEEDS_LIBRT"
622 fi
623 fi
624
625 # EXPORT
626 AC_SUBST(ADLC_CXXFLAG)
627 ])
628
629 ################################################################################
630 # $1 - Either BUILD or TARGET to pick the correct OS/CPU variables to check
631 # conditionals against.
632 # $2 - Optional prefix for each variable defined.
633 AC_DEFUN([FLAGS_SETUP_CFLAGS_CPU_DEP],
634 [
635 #### CPU DEFINES, these should (in theory) be independent on toolchain
636
637 # Setup target CPU
638 # Setup endianness
639 if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
640 $1_DEFINES_CPU_JVM="-DVM_LITTLE_ENDIAN"
641 fi
642 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
643 # The macro _LITTLE_ENDIAN needs to be defined the same to avoid the
644 # Sun C compiler warning message: warning: macro redefined: _LITTLE_ENDIAN
645 if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
646 $1_DEFINES_CPU_JDK="-D_LITTLE_ENDIAN="
647 else
648 $1_DEFINES_CPU_JDK="-D_BIG_ENDIAN="
649 fi
650 else
651 if test "x$FLAGS_CPU_ENDIAN" = xlittle; then
652 $1_DEFINES_CPU_JDK="-D_LITTLE_ENDIAN"
653 else
654 $1_DEFINES_CPU_JDK="-D_BIG_ENDIAN"
655 fi
656 fi
657
658 # setup CPU bit size
659 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -DARCH='\"$FLAGS_CPU_LEGACY\"' \
660 -D$FLAGS_CPU_LEGACY"
661
662 if test "x$FLAGS_CPU_BITS" = x64; then
663 # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
664 # unpack200.exe.
665 if test "x$FLAGS_OS" = xlinux || test "x$FLAGS_OS" = xmacosx; then
666 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_LP64=1"
667 fi
668 if test "x$FLAGS_OS" != xsolaris && test "x$FLAGS_OS" != xaix; then
669 # Solaris does not have _LP64=1 in the old build.
670 # xlc on AIX defines _LP64=1 by default and issues a warning if we redefine it.
671 $1_DEFINES_CPU_JVM="${$1_DEFINES_CPU_JVM} -D_LP64=1"
672 fi
673 fi
674
675 # toolchain dependend, per-cpu
676 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
677 if test "x$FLAGS_CPU_ARCH" = xx86; then
678 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -DcpuIntel -Di586 -D$FLAGS_CPU_LEGACY_LIB"
679 fi
680 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
681 if test "x$FLAGS_CPU" = xx86_64; then
682 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_AMD64_ -Damd64"
683 else
684 $1_DEFINES_CPU_JDK="${$1_DEFINES_CPU_JDK} -D_X86_ -Dx86"
685 fi
686 fi
687
688 # CFLAGS PER CPU
689 if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
690 # COMMON to gcc and clang
691 if test "x$FLAGS_CPU" = xx86; then
692 # Force compatibility with i586 on 32 bit intel platforms.
693 $1_CFLAGS_CPU="-march=i586"
694 fi
695 fi
696
697 if test "x$TOOLCHAIN_TYPE" = xgcc; then
698 if test "x$FLAGS_CPU" = xarm; then
699 # -Wno-psabi to get rid of annoying "note: the mangling of 'va_list' has changed in GCC 4.4"
700 $1_CFLAGS_CPU="-fsigned-char -Wno-psabi $ARM_ARCH_TYPE_FLAGS $ARM_FLOAT_TYPE_FLAGS -DJDK_ARCH_ABI_PROP_NAME='\"\$(JDK_ARCH_ABI_PROP_NAME)\"'"
701 $1_CFLAGS_CPU_JVM="-DARM"
702 elif test "x$FLAGS_CPU" = xaarch64; then
703 if test "x$HOTSPOT_TARGET_CPU_PORT" = xarm64; then
704 $1_CFLAGS_CPU_JVM="-fsigned-char -DARM"
705 fi
706 elif test "x$FLAGS_CPU_ARCH" = xppc; then
707 $1_CFLAGS_CPU_JVM="-minsert-sched-nops=regroup_exact -mno-multiple -mno-string"
708 if test "x$FLAGS_CPU" = xppc64; then
709 # -mminimal-toc fixes `relocation truncated to fit' error for gcc 4.1.
710 # Use ppc64 instructions, but schedule for power5
711 $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -mminimal-toc -mcpu=powerpc64 -mtune=power5"
712 elif test "x$FLAGS_CPU" = xppc64le; then
713 # Little endian machine uses ELFv2 ABI.
714 # Use Power8, this is the first CPU to support PPC64 LE with ELFv2 ABI.
715 $1_CFLAGS_CPU_JVM="${$1_CFLAGS_CPU_JVM} -DABI_ELFv2 -mcpu=power8 -mtune=power8"
716 fi
717 elif test "x$FLAGS_CPU" = xs390x; then
718 $1_CFLAGS_CPU="-mbackchain -march=z10"
719 fi
720
721 if test "x$FLAGS_CPU_ARCH" != xarm && test "x$FLAGS_CPU_ARCH" != xppc; then
722 # for all archs except arm and ppc, prevent gcc to omit frame pointer
723 $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
724 fi
725
726 elif test "x$TOOLCHAIN_TYPE" = xclang; then
727 if test "x$FLAGS_OS" = xlinux; then
728 # ppc test not really needed for clang
729 if test "x$FLAGS_CPU_ARCH" != xarm && test "x$FLAGS_CPU_ARCH" != xppc; then
730 # for all archs except arm and ppc, prevent gcc to omit frame pointer
731 $1_CFLAGS_CPU_JDK="${$1_CFLAGS_CPU_JDK} -fno-omit-frame-pointer"
732 fi
733 fi
734
735 elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
736 if test "x$FLAGS_CPU" = xx86_64; then
737 # NOTE: -xregs=no%frameptr is supposed to be default on x64
738 $1_CFLAGS_CPU_JDK="-xregs=no%frameptr"
739 elif test "x$FLAGS_CPU" = xsparcv9; then
740 $1_CFLAGS_CPU_JVM="-xarch=sparc"
741 $1_CFLAGS_CPU_JDK_LIBONLY="-xregs=no%appl"
742 fi
743
744 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
745 if test "x$FLAGS_CPU" = xppc64; then
746 $1_CFLAGS_CPU_JVM="-qarch=ppc64"
747 fi
748
749 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
750 if test "x$FLAGS_CPU" = xx86; then
751 $1_CFLAGS_CPU_JVM="-arch:IA32"
752 elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then
753 if test "x$DEBUG_LEVEL" != xrelease; then
754 # NOTE: This is probably redundant; -homeparams is default on
755 # non-release builds.
756 $1_CFLAGS_CPU_JVM="-homeparams"
757 fi
758 fi
759 fi
760
761 if test "x$TOOLCHAIN_TYPE" = xgcc; then
762 TOOLCHAIN_CHECK_COMPILER_VERSION(VERSION: 6, PREFIX: $2, IF_AT_LEAST: FLAGS_SETUP_GCC6_COMPILER_FLAGS($1))
763 $1_TOOLCHAIN_CFLAGS="${$1_GCC6_CFLAGS}"
764
765 $1_WARNING_CFLAGS_JVM="-Wno-format-zero-length -Wtype-limits -Wuninitialized"
766 fi
767
768 # EXPORT to API
769 CFLAGS_JVM_COMMON="$ALWAYS_CFLAGS_JVM $ALWAYS_DEFINES_JVM $TOOLCHAIN_CFLAGS_JVM \
770 $OS_CFLAGS $OS_CFLAGS_JVM $CFLAGS_OS_DEF_JVM $DEBUG_CFLAGS_JVM \
771 $WARNING_CFLAGS $WARNING_CFLAGS_JVM $JVM_PICFLAG"
772
773 CFLAGS_JDK_COMMON="$ALWAYS_CFLAGS_JDK $ALWAYS_DEFINES_JDK $TOOLCHAIN_CFLAGS_JDK \
774 $OS_CFLAGS $CFLAGS_OS_DEF_JDK $DEBUG_CFLAGS_JDK $DEBUG_OPTIONS_FLAGS_JDK \
775 $WARNING_CFLAGS $WARNING_CFLAGS_JDK $DEBUG_SYMBOLS_CFLAGS_JDK"
776
777 # Use ${$2EXTRA_CFLAGS} to block EXTRA_CFLAGS to be added to build flags.
778 # (Currently we don't have any OPENJDK_BUILD_EXTRA_CFLAGS, but that might
779 # change in the future.)
780
781 CFLAGS_JDK_COMMON_CONLY="$TOOLCHAIN_CFLAGS_JDK_CONLY \
782 $WARNING_CFLAGS_JDK_CONLY ${$2EXTRA_CFLAGS}"
783 CFLAGS_JDK_COMMON_CXXONLY="$ALWAYS_DEFINES_JDK_CXXONLY $TOOLCHAIN_CFLAGS_JDK_CXXONLY \
784 $WARNING_CFLAGS_JDK_CXXONLY ${$2EXTRA_CXXFLAGS}"
785
786 $1_CFLAGS_JVM="${$1_DEFINES_CPU_JVM} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JVM} ${$1_TOOLCHAIN_CFLAGS} ${$1_WARNING_CFLAGS_JVM}"
787 $1_CFLAGS_JDK="${$1_DEFINES_CPU_JDK} ${$1_CFLAGS_CPU} ${$1_CFLAGS_CPU_JDK} ${$1_TOOLCHAIN_CFLAGS}"
788
789 $2JVM_CFLAGS="$CFLAGS_JVM_COMMON ${$1_CFLAGS_JVM} ${$2EXTRA_CXXFLAGS}"
790
791 $2CFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CONLY ${$1_CFLAGS_JDK}"
792 $2CXXFLAGS_JDKEXE="$CFLAGS_JDK_COMMON $CFLAGS_JDK_COMMON_CXXONLY ${$1_CFLAGS_JDK}"
793 $2CFLAGS_JDKLIB="${$2CFLAGS_JDKEXE} $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
794 $2CXXFLAGS_JDKLIB="${$2CXXFLAGS_JDKEXE} $JDK_PICFLAG ${$1_CFLAGS_CPU_JDK_LIBONLY}"
795
796 AC_SUBST($2JVM_CFLAGS)
797 AC_SUBST($2CFLAGS_JDKLIB)
798 AC_SUBST($2CFLAGS_JDKEXE)
799 AC_SUBST($2CXXFLAGS_JDKLIB)
800 AC_SUBST($2CXXFLAGS_JDKEXE)
801 ])
802
803 # FLAGS_SETUP_GCC6_COMPILER_FLAGS([PREFIX])
804 # Arguments:
805 # $1 - Prefix for each variable defined.
806 AC_DEFUN([FLAGS_SETUP_GCC6_COMPILER_FLAGS],
807 [
808 # These flags are required for GCC 6 builds as undefined behaviour in OpenJDK code
809 # runs afoul of the more aggressive versions of these optimisations.
810 # Notably, value range propagation now assumes that the this pointer of C++
811 # member functions is non-null.
812 NO_DELETE_NULL_POINTER_CHECKS_CFLAG="-fno-delete-null-pointer-checks"
813 dnl Argument check is disabled until FLAGS_COMPILER_CHECK_ARGUMENTS handles cross-compilation
814 dnl FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_DELETE_NULL_POINTER_CHECKS_CFLAG -Werror],
815 dnl IF_FALSE: [NO_DELETE_NULL_POINTER_CHECKS_CFLAG=""])
816 NO_LIFETIME_DSE_CFLAG="-fno-lifetime-dse"
817 dnl Argument check is disabled until FLAGS_COMPILER_CHECK_ARGUMENTS handles cross-compilation
818 dnl FLAGS_COMPILER_CHECK_ARGUMENTS(ARGUMENT: [$NO_LIFETIME_DSE_CFLAG -Werror],
819 dnl IF_FALSE: [NO_LIFETIME_DSE_CFLAG=""])
820 AC_MSG_NOTICE([GCC >= 6 detected; adding ${NO_DELETE_NULL_POINTER_CHECKS_CFLAG} and ${NO_LIFETIME_DSE_CFLAG}])
821 $1_GCC6_CFLAGS="${NO_DELETE_NULL_POINTER_CHECKS_CFLAG} ${NO_LIFETIME_DSE_CFLAG}"
822 ])
823
824 # Documentation on common flags used for solstudio in HIGHEST.
825 #
826 # WARNING: Use of OPTIMIZATION_LEVEL=HIGHEST in your Makefile needs to be
827 # done with care, there are some assumptions below that need to
828 # be understood about the use of pointers, and IEEE behavior.
829 #
830 # -fns: Use non-standard floating point mode (not IEEE 754)
831 # -fsimple: Do some simplification of floating point arithmetic (not IEEE 754)
832 # -fsingle: Use single precision floating point with 'float'
833 # -xalias_level=basic: Assume memory references via basic pointer types do not alias
834 # (Source with excessing pointer casting and data access with mixed
835 # pointer types are not recommended)
836 # -xbuiltin=%all: Use intrinsic or inline versions for math/std functions
837 # (If you expect perfect errno behavior, do not use this)
838 # -xdepend: Loop data dependency optimizations (need -xO3 or higher)
839 # -xrestrict: Pointer parameters to functions do not overlap
840 # (Similar to -xalias_level=basic usage, but less obvious sometimes.
841 # If you pass in multiple pointers to the same data, do not use this)
842 # -xlibmil: Inline some library routines
843 # (If you expect perfect errno behavior, do not use this)
844 # -xlibmopt: Use optimized math routines (CURRENTLY DISABLED)
845 # (If you expect perfect errno behavior, do not use this)
846 # Can cause undefined external on Solaris 8 X86 on __sincos, removing for now