1 #
2 # Copyright (c) 2011, 2015, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
27 # If so, then append $1 to $2 \
28 # Also set JVM_ARG_OK to true/false depending on outcome.
29 AC_DEFUN([ADD_JVM_ARG_IF_OK],
30 [
31 $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
32 $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
33 OUTPUT=`$3 $1 -version 2>&1`
34 FOUND_WARN=`$ECHO "$OUTPUT" | grep -i warn`
35 FOUND_VERSION=`$ECHO $OUTPUT | grep " version \""`
36 if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
37 $2="[$]$2 $1"
38 JVM_ARG_OK=true
39 else
40 $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
41 $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
42 JVM_ARG_OK=false
43 fi
44 ])
45
46 # Appends a string to a path variable, only adding the : when needed.
47 AC_DEFUN([BASIC_APPEND_TO_PATH],
48 [
49 if test "x$2" != x; then
50 if test "x[$]$1" = x; then
51 $1="$2"
52 else
53 $1="[$]$1:$2"
54 fi
55 fi
56 ])
57
58 # Prepends a string to a path variable, only adding the : when needed.
59 AC_DEFUN([BASIC_PREPEND_TO_PATH],
60 [
61 if test "x$2" != x; then
62 if test "x[$]$1" = x; then
63 $1="$2"
64 else
65 $1="$2:[$]$1"
66 fi
67 fi
68 ])
69
70 # This will make sure the given variable points to a full and proper
71 # path. This means:
72 # 1) There will be no spaces in the path. On unix platforms,
73 # spaces in the path will result in an error. On Windows,
74 # the path will be rewritten using short-style to be space-free.
75 # 2) The path will be absolute, and it will be in unix-style (on
76 # cygwin).
77 # $1: The name of the variable to fix
78 AC_DEFUN([BASIC_FIXUP_PATH],
79 [
80 # Only process if variable expands to non-empty
81
82 if test "x[$]$1" != x; then
83 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
84 BASIC_FIXUP_PATH_CYGWIN($1)
85 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
86 BASIC_FIXUP_PATH_MSYS($1)
87 else
88 # We're on a unix platform. Hooray! :)
89 path="[$]$1"
90 has_space=`$ECHO "$path" | $GREP " "`
91 if test "x$has_space" != x; then
92 AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
93 AC_MSG_ERROR([Spaces are not allowed in this path.])
94 fi
95
96 # Use eval to expand a potential ~
97 eval path="$path"
98 if test ! -f "$path" && test ! -d "$path"; then
99 AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
100 fi
101
102 $1="`cd "$path"; $THEPWDCMD -L`"
103 fi
104 fi
105 ])
106
107 # This will make sure the given variable points to a executable
108 # with a full and proper path. This means:
109 # 1) There will be no spaces in the path. On unix platforms,
110 # spaces in the path will result in an error. On Windows,
111 # the path will be rewritten using short-style to be space-free.
112 # 2) The path will be absolute, and it will be in unix-style (on
113 # cygwin).
114 # Any arguments given to the executable is preserved.
115 # If the input variable does not have a directory specification, then
116 # it need to be in the PATH.
117 # $1: The name of the variable to fix
118 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
119 [
120 # Only process if variable expands to non-empty
121
122 if test "x[$]$1" != x; then
123 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
124 BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
125 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
126 BASIC_FIXUP_EXECUTABLE_MSYS($1)
127 else
128 # We're on a unix platform. Hooray! :)
129 # First separate the path from the arguments. This will split at the first
130 # space.
131 complete="[$]$1"
132 path="${complete%% *}"
133 tmp="$complete EOL"
134 arguments="${tmp#* }"
135
136 # Cannot rely on the command "which" here since it doesn't always work.
137 is_absolute_path=`$ECHO "$path" | $GREP ^/`
138 if test -z "$is_absolute_path"; then
139 # Path to executable is not absolute. Find it.
140 IFS_save="$IFS"
141 IFS=:
142 for p in $PATH; do
143 if test -f "$p/$path" && test -x "$p/$path"; then
144 new_path="$p/$path"
145 break
146 fi
147 done
148 IFS="$IFS_save"
149 else
150 # This is an absolute path, we can use it without further modifications.
151 new_path="$path"
152 fi
153
154 if test "x$new_path" = x; then
155 AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
156 has_space=`$ECHO "$complete" | $GREP " "`
157 if test "x$has_space" != x; then
158 AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
159 fi
160 AC_MSG_ERROR([Cannot locate the the path of $1])
161 fi
162 fi
163
164 # Now join together the path and the arguments once again
165 if test "x$arguments" != xEOL; then
166 new_complete="$new_path ${arguments% *}"
167 else
168 new_complete="$new_path"
169 fi
170
171 if test "x$complete" != "x$new_complete"; then
172 $1="$new_complete"
173 AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
174 fi
175 fi
176 ])
177
178 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
179 [
180 if test "x$OPENJDK_BUILD_OS" != xwindows; then
181 # Follow a chain of symbolic links. Use readlink
182 # where it exists, else fall back to horribly
183 # complicated shell code.
184 if test "x$READLINK_TESTED" != yes; then
185 # On MacOSX there is a readlink tool with a different
186 # purpose than the GNU readlink tool. Check the found readlink.
187 ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
188 if test "x$ISGNU" = x; then
189 # A readlink that we do not know how to use.
190 # Are there other non-GNU readlinks out there?
191 READLINK_TESTED=yes
192 READLINK=
193 fi
194 fi
195
196 if test "x$READLINK" != x; then
197 $1=`$READLINK -f [$]$1`
198 else
199 # Save the current directory for restoring afterwards
200 STARTDIR=$PWD
201 COUNTER=0
202 sym_link_dir=`$DIRNAME [$]$1`
203 sym_link_file=`$BASENAME [$]$1`
204 cd $sym_link_dir
205 # Use -P flag to resolve symlinks in directories.
206 cd `$THEPWDCMD -P`
207 sym_link_dir=`$THEPWDCMD -P`
208 # Resolve file symlinks
209 while test $COUNTER -lt 20; do
210 ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
211 if test "x$ISLINK" == x; then
212 # This is not a symbolic link! We are done!
213 break
214 fi
215 # Again resolve directory symlinks since the target of the just found
216 # link could be in a different directory
217 cd `$DIRNAME $ISLINK`
218 sym_link_dir=`$THEPWDCMD -P`
219 sym_link_file=`$BASENAME $ISLINK`
220 let COUNTER=COUNTER+1
221 done
222 cd $STARTDIR
223 $1=$sym_link_dir/$sym_link_file
224 fi
225 fi
226 ])
227
228 # Register a --with argument but mark it as deprecated
229 # $1: The name of the with argument to deprecate, not including --with-
230 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
231 [
232 AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
233 [Deprecated. Option is kept for backwards compatibility and is ignored])],
234 [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
235 ])
236
237 # Register a --enable argument but mark it as deprecated
238 # $1: The name of the with argument to deprecate, not including --enable-
239 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
240 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
241 [
242 AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
243 [Deprecated. Option is kept for backwards compatibility and is ignored])])
244 if test "x$enable_$2" != x; then
245 AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
246 fi
247 ])
248
249 AC_DEFUN_ONCE([BASIC_INIT],
250 [
251 # Save the original command line. This is passed to us by the wrapper configure script.
252 AC_SUBST(CONFIGURE_COMMAND_LINE)
253 # Save the path variable before it gets changed
254 ORIGINAL_PATH="$PATH"
255 AC_SUBST(ORIGINAL_PATH)
256 DATE_WHEN_CONFIGURED=`LANG=C date`
257 AC_SUBST(DATE_WHEN_CONFIGURED)
258 AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
259 AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
260 ])
261
262 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
263 # $1: variable to check
264 AC_DEFUN([BASIC_CHECK_NONEMPTY],
265 [
266 if test "x[$]$1" = x; then
267 AC_MSG_ERROR([Could not find required tool for $1])
268 fi
269 ])
270
271 # Check that there are no unprocessed overridden variables left.
272 # If so, they are an incorrect argument and we will exit with an error.
273 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],
274 [
275 if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then
276 # Replace the separating ! with spaces before presenting for end user.
277 unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }
278 AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])
279 fi
280 ])
281
282 # Setup a tool for the given variable. If correctly specified by the user,
283 # use that value, otherwise search for the tool using the supplied code snippet.
284 # $1: variable to set
285 # $2: code snippet to call to look for the tool
286 # $3: code snippet to call if variable was used to find tool
287 AC_DEFUN([BASIC_SETUP_TOOL],
288 [
289 # Publish this variable in the help.
290 AC_ARG_VAR($1, [Override default value for $1])
291
292 if [[ -z "${$1+x}" ]]; then
293 # The variable is not set by user, try to locate tool using the code snippet
294 $2
295 else
296 # The variable is set, but is it from the command line or the environment?
297
298 # Try to remove the string !$1! from our list.
299 try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}
300 if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then
301 # If it failed, the variable was not from the command line. Ignore it,
302 # but warn the user (except for BASH, which is always set by the calling BASH).
303 if test "x$1" != xBASH; then
304 AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])
305 fi
306 # Try to locate tool using the code snippet
307 $2
308 else
309 # If it succeeded, then it was overridden by the user. We will use it
310 # for the tool.
311
312 # First remove it from the list of overridden variables, so we can test
313 # for unknown variables in the end.
314 CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"
315
316 # Check if we try to supply an empty value
317 if test "x[$]$1" = x; then
318 AC_MSG_NOTICE([Setting user supplied tool $1= (no value)])
319 AC_MSG_CHECKING([for $1])
320 AC_MSG_RESULT([disabled])
321 else
322 # Check if the provided tool contains a complete path.
323 tool_specified="[$]$1"
324 tool_basename="${tool_specified##*/}"
325 if test "x$tool_basename" = "x$tool_specified"; then
326 # A command without a complete path is provided, search $PATH.
327 AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])
328 AC_PATH_PROG($1, $tool_basename)
329 if test "x[$]$1" = x; then
330 AC_MSG_ERROR([User supplied tool $tool_basename could not be found])
331 fi
332 else
333 # Otherwise we believe it is a complete path. Use it as it is.
334 AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])
335 AC_MSG_CHECKING([for $1])
336 if test ! -x "$tool_specified"; then
337 AC_MSG_RESULT([not found])
338 AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])
339 fi
340 AC_MSG_RESULT([$tool_specified])
341 fi
342 fi
343 fi
344 $3
345 fi
346 ])
347
348 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool
349 # $1: variable to set
350 # $2: executable name (or list of names) to look for
351 AC_DEFUN([BASIC_PATH_PROGS],
352 [
353 BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2)])
354 ])
355
356 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool
357 # $1: variable to set
358 # $2: executable name (or list of names) to look for
359 AC_DEFUN([BASIC_CHECK_TOOLS],
360 [
361 BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])
362 ])
363
364 # Like BASIC_PATH_PROGS but fails if no tool was found.
365 # $1: variable to set
366 # $2: executable name (or list of names) to look for
367 AC_DEFUN([BASIC_REQUIRE_PROGS],
368 [
369 BASIC_PATH_PROGS($1, $2)
370 BASIC_CHECK_NONEMPTY($1)
371 ])
372
373 # Like BASIC_SETUP_TOOL but fails if no tool was found.
374 # $1: variable to set
375 # $2: autoconf macro to call to look for the special tool
376 AC_DEFUN([BASIC_REQUIRE_SPECIAL],
377 [
378 BASIC_SETUP_TOOL($1, [$2])
379 BASIC_CHECK_NONEMPTY($1)
380 ])
381
382 # Setup the most fundamental tools that relies on not much else to set up,
383 # but is used by much of the early bootstrap code.
384 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
385 [
386 # Start with tools that do not need have cross compilation support
387 # and can be expected to be found in the default PATH. These tools are
388 # used by configure.
389
390 # First are all the simple required tools.
391 BASIC_REQUIRE_PROGS(BASENAME, basename)
392 BASIC_REQUIRE_PROGS(BASH, bash)
393 BASIC_REQUIRE_PROGS(CAT, cat)
394 BASIC_REQUIRE_PROGS(CHMOD, chmod)
395 BASIC_REQUIRE_PROGS(CMP, cmp)
396 BASIC_REQUIRE_PROGS(COMM, comm)
397 BASIC_REQUIRE_PROGS(CP, cp)
398 BASIC_REQUIRE_PROGS(CUT, cut)
399 BASIC_REQUIRE_PROGS(DATE, date)
400 BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])
401 BASIC_REQUIRE_PROGS(DIRNAME, dirname)
402 BASIC_REQUIRE_PROGS(ECHO, echo)
403 BASIC_REQUIRE_PROGS(EXPR, expr)
404 BASIC_REQUIRE_PROGS(FILE, file)
405 BASIC_REQUIRE_PROGS(FIND, find)
406 BASIC_REQUIRE_PROGS(HEAD, head)
407 BASIC_REQUIRE_PROGS(LN, ln)
408 BASIC_REQUIRE_PROGS(LS, ls)
409 BASIC_REQUIRE_PROGS(MKDIR, mkdir)
410 BASIC_REQUIRE_PROGS(MKTEMP, mktemp)
411 BASIC_REQUIRE_PROGS(MV, mv)
412 BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])
413 BASIC_REQUIRE_PROGS(PRINTF, printf)
414 BASIC_REQUIRE_PROGS(RM, rm)
415 BASIC_REQUIRE_PROGS(RMDIR, rmdir)
416 BASIC_REQUIRE_PROGS(SH, sh)
417 BASIC_REQUIRE_PROGS(SORT, sort)
418 BASIC_REQUIRE_PROGS(TAIL, tail)
419 BASIC_REQUIRE_PROGS(TAR, tar)
420 BASIC_REQUIRE_PROGS(TEE, tee)
421 BASIC_REQUIRE_PROGS(TOUCH, touch)
422 BASIC_REQUIRE_PROGS(TR, tr)
423 BASIC_REQUIRE_PROGS(UNAME, uname)
424 BASIC_REQUIRE_PROGS(UNIQ, uniq)
425 BASIC_REQUIRE_PROGS(WC, wc)
426 BASIC_REQUIRE_PROGS(WHICH, which)
427 BASIC_REQUIRE_PROGS(XARGS, xargs)
428
429 # Then required tools that require some special treatment.
430 BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])
431 BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])
432 BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])
433 BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])
434 BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])
435
436 # Always force rm.
437 RM="$RM -f"
438
439 # pwd behaves differently on various platforms and some don't support the -L flag.
440 # Always use the bash builtin pwd to get uniform behavior.
441 THEPWDCMD=pwd
442
443 # These are not required on all platforms
444 BASIC_PATH_PROGS(CYGPATH, cygpath)
445 BASIC_PATH_PROGS(READLINK, [greadlink readlink])
446 BASIC_PATH_PROGS(DF, df)
447 BASIC_PATH_PROGS(CPIO, [cpio bsdcpio])
448 BASIC_PATH_PROGS(NICE, nice)
449 ])
450
451 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
452 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
453 [
454 # Save the current directory this script was started from
455 CURDIR="$PWD"
456
457 # We might need to rewrite ORIGINAL_PATH, if it includes "#", to quote them
458 # for make. We couldn't do this when we retrieved ORIGINAL_PATH, since SED
459 # was not available at that time.
460 REWRITTEN_PATH=`$ECHO "$ORIGINAL_PATH" | $SED -e 's/#/\\\\#/g'`
461 if test "x$REWRITTEN_PATH" != "x$ORIGINAL_PATH"; then
462 ORIGINAL_PATH="$REWRITTEN_PATH"
463 AC_MSG_NOTICE([Rewriting ORIGINAL_PATH to $REWRITTEN_PATH])
464 fi
465
466 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
467 PATH_SEP=";"
468 BASIC_CHECK_PATHS_WINDOWS
469 else
470 PATH_SEP=":"
471 fi
472 AC_SUBST(PATH_SEP)
473
474 # We get the top-level directory from the supporting wrappers.
475 AC_MSG_CHECKING([for top-level directory])
476 AC_MSG_RESULT([$TOPDIR])
477 AC_SUBST(TOPDIR)
478
479 # Save the original version of TOPDIR for string comparisons
480 ORIGINAL_TOPDIR="$TOPDIR"
481 AC_SUBST(ORIGINAL_TOPDIR)
482
483 # We can only call BASIC_FIXUP_PATH after BASIC_CHECK_PATHS_WINDOWS.
484 BASIC_FIXUP_PATH(CURDIR)
485 BASIC_FIXUP_PATH(TOPDIR)
486 # SRC_ROOT is a traditional alias for TOPDIR.
487 SRC_ROOT=$TOPDIR
488
489 # Calculate a canonical version of TOPDIR for string comparisons
490 CANONICAL_TOPDIR=$TOPDIR
491 BASIC_REMOVE_SYMBOLIC_LINKS([CANONICAL_TOPDIR])
492 AC_SUBST(CANONICAL_TOPDIR)
493
494 # Locate the directory of this script.
495 AUTOCONF_DIR=$TOPDIR/common/autoconf
496 ])
497
498 # Evaluates platform specific overrides for devkit variables.
499 # $1: Name of variable
500 AC_DEFUN([BASIC_EVAL_DEVKIT_VARIABLE],
501 [
502 if test "x[$]$1" = x; then
503 eval $1="\${$1_${OPENJDK_TARGET_CPU}}"
504 fi
505 ])
506
507 AC_DEFUN_ONCE([BASIC_SETUP_DEVKIT],
508 [
509 AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
510 [use this devkit for compilers, tools and resources])],
511 [
512 BASIC_FIXUP_PATH([with_devkit])
513 DEVKIT_ROOT="$with_devkit"
514 # Check for a meta data info file in the root of the devkit
515 if test -f "$DEVKIT_ROOT/devkit.info"; then
516 . $DEVKIT_ROOT/devkit.info
517 # This potentially sets the following:
518 # A descriptive name of the devkit
519 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_NAME])
520 # Corresponds to --with-extra-path
521 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_EXTRA_PATH])
522 # Corresponds to --with-toolchain-path
523 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_TOOLCHAIN_PATH])
524 # Corresponds to --with-sysroot
525 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_SYSROOT])
526
527 # Identifies the Visual Studio version in the devkit
528 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_VERSION])
529 # The Visual Studio include environment variable
530 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_INCLUDE])
531 # The Visual Studio lib environment variable
532 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_LIB])
533 # Corresponds to --with-msvcr-dll
534 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCR_DLL])
535 # Corresponds to --with-msvcp-dll
536 BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCP_DLL])
537 fi
538
539 AC_MSG_CHECKING([for devkit])
540 if test "x$DEVKIT_NAME" != x; then
541 AC_MSG_RESULT([$DEVKIT_NAME in $DEVKIT_ROOT])
542 else
543 AC_MSG_RESULT([$DEVKIT_ROOT])
544 fi
545
546 BASIC_PREPEND_TO_PATH([EXTRA_PATH],$DEVKIT_EXTRA_PATH)
547
548 # Fallback default of just /bin if DEVKIT_PATH is not defined
549 if test "x$DEVKIT_TOOLCHAIN_PATH" = x; then
550 DEVKIT_TOOLCHAIN_PATH="$DEVKIT_ROOT/bin"
551 fi
552 BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$DEVKIT_TOOLCHAIN_PATH)
553
554 # If DEVKIT_SYSROOT is set, use that, otherwise try a couple of known
555 # places for backwards compatiblity.
556 if test "x$DEVKIT_SYSROOT" != x; then
557 SYSROOT="$DEVKIT_SYSROOT"
558 elif test -d "$DEVKIT_ROOT/$host_alias/libc"; then
559 SYSROOT="$DEVKIT_ROOT/$host_alias/libc"
560 elif test -d "$DEVKIT_ROOT/$host/sys-root"; then
561 SYSROOT="$DEVKIT_ROOT/$host/sys-root"
562 fi
563 ]
564 )
565
566 # You can force the sysroot if the sysroot encoded into the compiler tools
567 # is not correct.
568 AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
569 [alias for --with-sysroot for backwards compatability])],
570 [SYSROOT=$with_sys_root]
571 )
572
573 AC_ARG_WITH(sysroot, [AS_HELP_STRING([--with-sysroot],
574 [use this directory as sysroot])],
575 [SYSROOT=$with_sysroot]
576 )
577
578 AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
579 [alias for --with-toolchain-path for backwards compatibility])],
580 [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_tools_dir)]
581 )
582
583 AC_ARG_WITH([toolchain-path], [AS_HELP_STRING([--with-toolchain-path],
584 [prepend these directories when searching for toolchain binaries (compilers etc)])],
585 [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_toolchain_path)]
586 )
587
588 AC_ARG_WITH([extra-path], [AS_HELP_STRING([--with-extra-path],
589 [prepend these directories to the default path])],
590 [BASIC_PREPEND_TO_PATH([EXTRA_PATH],$with_extra_path)]
591 )
592
593 if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then
594 # If a devkit has been supplied, find xcodebuild in the toolchain_path.
595 # If not, detect if Xcode is installed by running xcodebuild -version
596 # if no Xcode installed, xcodebuild exits with 1
597 # if Xcode is installed, even if xcode-select is misconfigured, then it exits with 0
598 if test "x$DEVKIT_ROOT" != x || /usr/bin/xcodebuild -version >/dev/null 2>&1; then
599 # We need to use xcodebuild in the toolchain dir provided by the user, this will
600 # fall back on the stub binary in /usr/bin/xcodebuild
601 AC_PATH_PROG([XCODEBUILD], [xcodebuild], [/usr/bin/xcodebuild], [$TOOLCHAIN_PATH])
602 else
603 # this should result in SYSROOT being empty, unless --with-sysroot is provided
604 # when only the command line tools are installed there are no SDKs, so headers
605 # are copied into the system frameworks
606 XCODEBUILD=
607 AC_SUBST(XCODEBUILD)
608 fi
609
610 AC_MSG_CHECKING([for sdk name])
611 AC_ARG_WITH([sdk-name], [AS_HELP_STRING([--with-sdk-name],
612 [use the platform SDK of the given name. @<:@macosx@:>@])],
613 [SDKNAME=$with_sdk_name]
614 )
615 AC_MSG_RESULT([$SDKNAME])
616
617 # if toolchain path is specified then don't rely on system headers, they may not compile
618 HAVE_SYSTEM_FRAMEWORK_HEADERS=0
619 test -z "$TOOLCHAIN_PATH" && \
620 HAVE_SYSTEM_FRAMEWORK_HEADERS=`test ! -f /System/Library/Frameworks/Foundation.framework/Headers/Foundation.h; echo $?`
621
622 if test -z "$SYSROOT"; then
623 if test -n "$XCODEBUILD"; then
624 # if we don't have system headers, use default SDK name (last resort)
625 if test -z "$SDKNAME" -a $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
626 SDKNAME=${SDKNAME:-macosx}
627 fi
628
629 if test -n "$SDKNAME"; then
630 # Call xcodebuild to determine SYSROOT
631 SYSROOT=`"$XCODEBUILD" -sdk $SDKNAME -version | grep '^Path: ' | sed 's/Path: //'`
632 fi
633 else
634 if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
635 AC_MSG_ERROR([No xcodebuild tool and no system framework headers found, use --with-sysroot or --with-sdk-name to provide a path to a valid SDK])
636 fi
637 fi
638 else
639 # warn user if --with-sdk-name was also set
640 if test -n "$with_sdk_name"; then
641 AC_MSG_WARN([Both SYSROOT and --with-sdk-name are set, only SYSROOT will be used])
642 fi
643 fi
644
645 if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0 -a -z "$SYSROOT"; then
646 # If no system framework headers, then SYSROOT must be set, or we won't build
647 AC_MSG_ERROR([Unable to determine SYSROOT and no headers found in /System/Library/Frameworks. Check Xcode configuration, --with-sysroot or --with-sdk-name arguments.])
648 fi
649
650 # Perform a basic sanity test
651 if test ! -f "$SYSROOT/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then
652 if test -z "$SYSROOT"; then
653 AC_MSG_ERROR([Unable to find required framework headers, provide a path to an SDK via --with-sysroot or --with-sdk-name and be sure Xcode is installed properly])
654 else
655 AC_MSG_ERROR([Invalid SDK or SYSROOT path, dependent framework headers not found])
656 fi
657 fi
658
659 # set SDKROOT too, Xcode tools will pick it up
660 AC_SUBST(SDKROOT,$SYSROOT)
661 fi
662
663 # Prepend the extra path to the global path
664 BASIC_PREPEND_TO_PATH([PATH],$EXTRA_PATH)
665
666 if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
667 # Add extra search paths on solaris for utilities like ar and as etc...
668 PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
669 fi
670
671 AC_MSG_CHECKING([for sysroot])
672 AC_MSG_RESULT([$SYSROOT])
673 AC_MSG_CHECKING([for toolchain path])
674 AC_MSG_RESULT([$TOOLCHAIN_PATH])
675 AC_MSG_CHECKING([for extra path])
676 AC_MSG_RESULT([$EXTRA_PATH])
677 ])
678
679 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
680 [
681
682 AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
683 [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
684 [ CONF_NAME=${with_conf_name} ])
685
686 # Test from where we are running configure, in or outside of src root.
687 AC_MSG_CHECKING([where to store configuration])
688 if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \
689 || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \
690 || test "x$CURDIR" = "x$SRC_ROOT/make" ; then
691 # We are running configure from the src root.
692 # Create a default ./build/target-variant-debuglevel output root.
693 if test "x${CONF_NAME}" = x; then
694 AC_MSG_RESULT([in default location])
695 CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
696 else
697 AC_MSG_RESULT([in build directory with custom name])
698 fi
699 OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
700 $MKDIR -p "$OUTPUT_ROOT"
701 if test ! -d "$OUTPUT_ROOT"; then
702 AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
703 fi
704 else
705 # We are running configure from outside of the src dir.
706 # Then use the current directory as output dir!
707 # If configuration is situated in normal build directory, just use the build
708 # directory name as configuration name, otherwise use the complete path.
709 if test "x${CONF_NAME}" = x; then
710 CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
711 fi
712 OUTPUT_ROOT="$CURDIR"
713 AC_MSG_RESULT([in current directory])
714
715 # WARNING: This might be a bad thing to do. You need to be sure you want to
716 # have a configuration in this directory. Do some sanity checks!
717
718 if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
719 # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
720 # other files
721 files_present=`$LS $OUTPUT_ROOT`
722 # Configure has already touched config.log and confdefs.h in the current dir when this check
723 # is performed.
724 filtered_files=`$ECHO "$files_present" \
725 | $SED -e 's/config.log//g' \
726 -e 's/configure.log//g' \
727 -e 's/confdefs.h//g' \
728 -e 's/ //g' \
729 | $TR -d '\n'`
730 if test "x$filtered_files" != x; then
731 AC_MSG_NOTICE([Current directory is $CURDIR.])
732 AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
733 AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
734 AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
735 AC_MSG_NOTICE([seriously mess up just about everything.])
736 AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
737 AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
738 AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
739 fi
740 fi
741 fi
742 AC_MSG_CHECKING([what configuration name to use])
743 AC_MSG_RESULT([$CONF_NAME])
744
745 BASIC_FIXUP_PATH(OUTPUT_ROOT)
746
747 CONFIGURESUPPORT_OUTPUTDIR="$OUTPUT_ROOT/configure-support"
748 $MKDIR -p "$CONFIGURESUPPORT_OUTPUTDIR"
749
750 AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
751 AC_SUBST(CONF_NAME, $CONF_NAME)
752 AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
753 AC_SUBST(CONFIGURESUPPORT_OUTPUTDIR)
754
755 # The spec.gmk file contains all variables for the make system.
756 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
757 # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
758 AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
759 # The bootcycle-spec.gmk file contains support for boot cycle builds.
760 AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
761 # The compare.sh is used to compare the build output to other builds.
762 AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
763 # The generated Makefile knows where the spec.gmk is and where the source is.
764 # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
765 # which will look for generated configurations
766 AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
767 ])
768
769 #%%% Simple tools %%%
770
771 # Check if we have found a usable version of make
772 # $1: the path to a potential make binary (or empty)
773 # $2: the description on how we found this
774 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
775 [
776 MAKE_CANDIDATE="$1"
777 DESCRIPTION="$2"
778
779 # On Cygwin, we require a newer version of make than on other platforms
780 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
781 MAKE_VERSION_EXPR="-e 4\."
782 MAKE_REQUIRED_VERSION="4.0"
783 else
784 MAKE_VERSION_EXPR="-e 3\.8[[12]] -e 4\."
785 MAKE_REQUIRED_VERSION="3.81"
786 fi
787
788 if test "x$MAKE_CANDIDATE" != x; then
789 AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
790 MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
791 IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
792 if test "x$IS_GNU_MAKE" = x; then
793 AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
794 else
795 IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP $MAKE_VERSION_EXPR`
796 if test "x$IS_MODERN_MAKE" = x; then
797 AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version $MAKE_REQUIRED_VERSION or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
798 else
799 if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
800 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
801 MAKE_EXPECTED_ENV='cygwin'
802 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
803 MAKE_EXPECTED_ENV='msys'
804 else
805 AC_MSG_ERROR([Unknown Windows environment])
806 fi
807 MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
808 IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
809 else
810 # Not relevant for non-Windows
811 IS_MAKE_CORRECT_ENV=true
812 fi
813 if test "x$IS_MAKE_CORRECT_ENV" = x; then
814 AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
815 else
816 FOUND_MAKE=$MAKE_CANDIDATE
817 BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
818 fi
819 fi
820 fi
821 fi
822 ])
823
824 AC_DEFUN([BASIC_CHECK_MAKE_OUTPUT_SYNC],
825 [
826 # Check if make supports the output sync option and if so, setup using it.
827 AC_MSG_CHECKING([if make --output-sync is supported])
828 if $MAKE --version -O > /dev/null 2>&1; then
829 OUTPUT_SYNC_SUPPORTED=true
830 AC_MSG_RESULT([yes])
831 AC_MSG_CHECKING([for output-sync value])
832 AC_ARG_WITH([output-sync], [AS_HELP_STRING([--with-output-sync],
833 [set make output sync type if supported by make. @<:@recurse@:>@])],
834 [OUTPUT_SYNC=$with_output_sync])
835 if test "x$OUTPUT_SYNC" = "x"; then
836 OUTPUT_SYNC=none
837 fi
838 AC_MSG_RESULT([$OUTPUT_SYNC])
839 if ! $MAKE --version -O$OUTPUT_SYNC > /dev/null 2>&1; then
840 AC_MSG_ERROR([Make did not the support the value $OUTPUT_SYNC as output sync type.])
841 fi
842 else
843 OUTPUT_SYNC_SUPPORTED=false
844 AC_MSG_RESULT([no])
845 fi
846 AC_SUBST(OUTPUT_SYNC_SUPPORTED)
847 AC_SUBST(OUTPUT_SYNC)
848 ])
849
850 # Goes looking for a usable version of GNU make.
851 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
852 [
853 BASIC_SETUP_TOOL([MAKE],
854 [
855 # Try our hardest to locate a correct version of GNU make
856 AC_PATH_PROGS(CHECK_GMAKE, gmake)
857 BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
858
859 if test "x$FOUND_MAKE" = x; then
860 AC_PATH_PROGS(CHECK_MAKE, make)
861 BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
862 fi
863
864 if test "x$FOUND_MAKE" = x; then
865 if test "x$TOOLCHAIN_PATH" != x; then
866 # We have a toolchain path, check that as well before giving up.
867 OLD_PATH=$PATH
868 PATH=$TOOLCHAIN_PATH:$PATH
869 AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
870 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
871 if test "x$FOUND_MAKE" = x; then
872 AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
873 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
874 fi
875 PATH=$OLD_PATH
876 fi
877 fi
878
879 if test "x$FOUND_MAKE" = x; then
880 AC_MSG_ERROR([Cannot find GNU make $MAKE_REQUIRED_VERSION or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
881 fi
882 ],[
883 # If MAKE was set by user, verify the version
884 BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
885 if test "x$FOUND_MAKE" = x; then
886 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make $MAKE_REQUIRED_VERSION or newer.])
887 fi
888 ])
889
890 MAKE=$FOUND_MAKE
891 AC_SUBST(MAKE)
892 AC_MSG_NOTICE([Using GNU make at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
893
894 BASIC_CHECK_MAKE_OUTPUT_SYNC
895 ])
896
897 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
898 [
899 # Test if find supports -delete
900 AC_MSG_CHECKING([if find supports -delete])
901 FIND_DELETE="-delete"
902
903 DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
904
905 echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
906
907 TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
908 if test -f $DELETEDIR/TestIfFindSupportsDelete; then
909 # No, it does not.
910 rm $DELETEDIR/TestIfFindSupportsDelete
911 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
912 # AIX 'find' is buggy if called with '-exec {} \+' and an empty file list
913 FIND_DELETE="-print | xargs rm"
914 else
915 FIND_DELETE="-exec rm \{\} \+"
916 fi
917 AC_MSG_RESULT([no])
918 else
919 AC_MSG_RESULT([yes])
920 fi
921 rmdir $DELETEDIR
922 AC_SUBST(FIND_DELETE)
923 ])
924
925 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
926 [
927 BASIC_CHECK_GNU_MAKE
928
929 BASIC_CHECK_FIND_DELETE
930
931 # These tools might not be installed by default,
932 # need hint on how to install them.
933 BASIC_REQUIRE_PROGS(UNZIP, unzip)
934 BASIC_REQUIRE_PROGS(ZIP, zip)
935
936 # Non-required basic tools
937
938 BASIC_PATH_PROGS(LDD, ldd)
939 if test "x$LDD" = "x"; then
940 # List shared lib dependencies is used for
941 # debug output and checking for forbidden dependencies.
942 # We can build without it.
943 LDD="true"
944 fi
945 BASIC_PATH_PROGS(OTOOL, otool)
946 if test "x$OTOOL" = "x"; then
947 OTOOL="true"
948 fi
949 BASIC_PATH_PROGS(READELF, [greadelf readelf])
950 BASIC_PATH_PROGS(HG, hg)
951 BASIC_PATH_PROGS(STAT, stat)
952 BASIC_PATH_PROGS(TIME, time)
953 BASIC_PATH_PROGS(PATCH, [gpatch patch])
954 # Check if it's GNU time
955 IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
956 if test "x$IS_GNU_TIME" != x; then
957 IS_GNU_TIME=yes
958 else
959 IS_GNU_TIME=no
960 fi
961 AC_SUBST(IS_GNU_TIME)
962
963 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
964 BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)
965 BASIC_REQUIRE_PROGS(XATTR, xattr)
966 BASIC_PATH_PROGS(CODESIGN, codesign)
967 if test "x$CODESIGN" != "x"; then
968 # Verify that the openjdk_codesign certificate is present
969 AC_MSG_CHECKING([if openjdk_codesign certificate is present])
970 rm -f codesign-testfile
971 touch codesign-testfile
972 codesign -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
973 rm -f codesign-testfile
974 if test "x$CODESIGN" = x; then
975 AC_MSG_RESULT([no])
976 else
977 AC_MSG_RESULT([yes])
978 fi
979 fi
980 BASIC_REQUIRE_PROGS(SETFILE, SetFile)
981 fi
982 ])
983
984 # Check if build directory is on local disk. If not possible to determine,
985 # we prefer to claim it's local.
986 # Argument 1: directory to test
987 # Argument 2: what to do if it is on local disk
988 # Argument 3: what to do otherwise (remote disk or failure)
989 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
990 [
991 # df -l lists only local disks; if the given directory is not found then
992 # a non-zero exit code is given
993 if test "x$DF" = x; then
994 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
995 # msys does not have df; use Windows "net use" instead.
996 IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
997 if test "x$IS_NETWORK_DISK" = x; then
998 $2
999 else
1000 $3
1001 fi
1002 else
1003 # No df here, say it's local
1004 $2
1005 fi
1006 else
1007 if $DF -l $1 > /dev/null 2>&1; then
1008 $2
1009 else
1010 $3
1011 fi
1012 fi
1013 ])
1014
1015 # Check that source files have basic read permissions set. This might
1016 # not be the case in cygwin in certain conditions.
1017 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
1018 [
1019 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
1020 file_to_test="$SRC_ROOT/LICENSE"
1021 if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
1022 AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
1023 fi
1024 fi
1025 ])
1026
1027 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
1028 [
1029 # Did user specify any unknown variables?
1030 BASIC_CHECK_LEFTOVER_OVERRIDDEN
1031
1032 AC_MSG_CHECKING([if build directory is on local disk])
1033 BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
1034 [OUTPUT_DIR_IS_LOCAL="yes"],
1035 [OUTPUT_DIR_IS_LOCAL="no"])
1036 AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
1037
1038 BASIC_CHECK_SRC_PERMS
1039
1040 # Check if the user has any old-style ALT_ variables set.
1041 FOUND_ALT_VARIABLES=`env | grep ^ALT_`
1042
1043 # Before generating output files, test if they exist. If they do, this is a reconfigure.
1044 # Since we can't properly handle the dependencies for this, warn the user about the situation
1045 if test -e $OUTPUT_ROOT/spec.gmk; then
1046 IS_RECONFIGURE=yes
1047 else
1048 IS_RECONFIGURE=no
1049 fi
1050 ])
1051
1052 # Check for support for specific options in bash
1053 AC_DEFUN_ONCE([BASIC_CHECK_BASH_OPTIONS],
1054 [
1055 # Test if bash supports pipefail.
1056 AC_MSG_CHECKING([if bash supports pipefail])
1057 if ${BASH} -c 'set -o pipefail'; then
1058 BASH_ARGS="$BASH_ARGS -o pipefail"
1059 AC_MSG_RESULT([yes])
1060 else
1061 AC_MSG_RESULT([no])
1062 fi
1063
1064 AC_MSG_CHECKING([if bash supports errexit (-e)])
1065 if ${BASH} -e -c 'true'; then
1066 BASH_ARGS="$BASH_ARGS -e"
1067 AC_MSG_RESULT([yes])
1068 else
1069 AC_MSG_RESULT([no])
1070 fi
1071
1072 AC_SUBST(BASH_ARGS)
1073 ])
1074
1075 # Code to run after AC_OUTPUT
1076 AC_DEFUN_ONCE([BASIC_POST_CONFIG_OUTPUT],
1077 [
1078 # Try to move config.log (generated by autoconf) to the configure-support directory.
1079 if test -e ./config.log; then
1080 $MV -f ./config.log "$CONFIGURESUPPORT_OUTPUTDIR/config.log" 2> /dev/null
1081 fi
1082
1083 # Rotate our log file (configure.log)
1084 if test -e "$OUTPUT_ROOT/configure.log.old"; then
1085 $RM -f "$OUTPUT_ROOT/configure.log.old"
1086 fi
1087 if test -e "$OUTPUT_ROOT/configure.log"; then
1088 $MV -f "$OUTPUT_ROOT/configure.log" "$OUTPUT_ROOT/configure.log.old" 2> /dev/null
1089 fi
1090
1091 # Move configure.log from current directory to the build output root
1092 if test -e ./configure.log; then
1093 echo found it
1094 $MV -f ./configure.log "$OUTPUT_ROOT/configure.log" 2> /dev/null
1095 fi
1096
1097 # Make the compare script executable
1098 $CHMOD +x $OUTPUT_ROOT/compare.sh
1099 ])