1 #
   2 # Copyright (c) 2011, 2015, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
  27 # If so, then append $1 to $2 \
  28 # Also set JVM_ARG_OK to true/false depending on outcome.
  29 AC_DEFUN([ADD_JVM_ARG_IF_OK],
  30 [
  31   $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
  32   $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
  33   OUTPUT=`$3 $1 -version 2>&1`
  34   FOUND_WARN=`$ECHO "$OUTPUT" | grep -i warn`
  35   FOUND_VERSION=`$ECHO $OUTPUT | grep " version \""`
  36   if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
  37     $2="[$]$2 $1"
  38     JVM_ARG_OK=true
  39   else
  40     $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
  41     $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
  42     JVM_ARG_OK=false
  43   fi
  44 ])
  45 
  46 # Appends a string to a path variable, only adding the : when needed.
  47 AC_DEFUN([BASIC_APPEND_TO_PATH],
  48 [
  49   if test "x$2" != x; then
  50     if test "x[$]$1" = x; then
  51       $1="$2"
  52     else
  53       $1="[$]$1:$2"
  54     fi
  55   fi
  56 ])
  57 
  58 # Prepends a string to a path variable, only adding the : when needed.
  59 AC_DEFUN([BASIC_PREPEND_TO_PATH],
  60 [
  61   if test "x$2" != x; then
  62     if test "x[$]$1" = x; then
  63       $1="$2"
  64     else
  65       $1="$2:[$]$1"
  66     fi
  67   fi
  68 ])
  69 
  70 # This will make sure the given variable points to a full and proper
  71 # path. This means:
  72 # 1) There will be no spaces in the path. On unix platforms,
  73 #    spaces in the path will result in an error. On Windows,
  74 #    the path will be rewritten using short-style to be space-free.
  75 # 2) The path will be absolute, and it will be in unix-style (on
  76 #     cygwin).
  77 # $1: The name of the variable to fix
  78 AC_DEFUN([BASIC_FIXUP_PATH],
  79 [
  80   # Only process if variable expands to non-empty
  81 
  82   if test "x[$]$1" != x; then
  83     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
  84       BASIC_FIXUP_PATH_CYGWIN($1)
  85     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
  86       BASIC_FIXUP_PATH_MSYS($1)
  87     else
  88       # We're on a unix platform. Hooray! :)
  89       path="[$]$1"
  90       has_space=`$ECHO "$path" | $GREP " "`
  91       if test "x$has_space" != x; then
  92         AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
  93         AC_MSG_ERROR([Spaces are not allowed in this path.])
  94       fi
  95 
  96       # Use eval to expand a potential ~
  97       eval path="$path"
  98       if test ! -f "$path" && test ! -d "$path"; then
  99         AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
 100       fi
 101 
 102       $1="`cd "$path"; $THEPWDCMD -L`"
 103     fi
 104   fi
 105 ])
 106 
 107 # This will make sure the given variable points to a executable
 108 # with a full and proper path. This means:
 109 # 1) There will be no spaces in the path. On unix platforms,
 110 #    spaces in the path will result in an error. On Windows,
 111 #    the path will be rewritten using short-style to be space-free.
 112 # 2) The path will be absolute, and it will be in unix-style (on
 113 #     cygwin).
 114 # Any arguments given to the executable is preserved.
 115 # If the input variable does not have a directory specification, then
 116 # it need to be in the PATH.
 117 # $1: The name of the variable to fix
 118 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
 119 [
 120   # Only process if variable expands to non-empty
 121 
 122   if test "x[$]$1" != x; then
 123     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 124       BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
 125     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 126       BASIC_FIXUP_EXECUTABLE_MSYS($1)
 127     else
 128       # We're on a unix platform. Hooray! :)
 129       # First separate the path from the arguments. This will split at the first
 130       # space.
 131       complete="[$]$1"
 132       path="${complete%% *}"
 133       tmp="$complete EOL"
 134       arguments="${tmp#* }"
 135 
 136       # Cannot rely on the command "which" here since it doesn't always work.
 137       is_absolute_path=`$ECHO "$path" | $GREP ^/`
 138       if test -z "$is_absolute_path"; then
 139         # Path to executable is not absolute. Find it.
 140         IFS_save="$IFS"
 141         IFS=:
 142         for p in $PATH; do
 143           if test -f "$p/$path" && test -x "$p/$path"; then
 144             new_path="$p/$path"
 145             break
 146           fi
 147         done
 148         IFS="$IFS_save"
 149       else
 150         # This is an absolute path, we can use it without further modifications.
 151         new_path="$path"
 152       fi
 153 
 154       if test "x$new_path" = x; then
 155         AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
 156         has_space=`$ECHO "$complete" | $GREP " "`
 157         if test "x$has_space" != x; then
 158           AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
 159         fi
 160         AC_MSG_ERROR([Cannot locate the the path of $1])
 161       fi
 162     fi
 163 
 164     # Now join together the path and the arguments once again
 165     if test "x$arguments" != xEOL; then
 166       new_complete="$new_path ${arguments% *}"
 167     else
 168       new_complete="$new_path"
 169     fi
 170 
 171     if test "x$complete" != "x$new_complete"; then
 172       $1="$new_complete"
 173       AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
 174     fi
 175   fi
 176 ])
 177 
 178 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
 179 [
 180   if test "x$OPENJDK_BUILD_OS" != xwindows; then
 181     # Follow a chain of symbolic links. Use readlink
 182     # where it exists, else fall back to horribly
 183     # complicated shell code.
 184     if test "x$READLINK_TESTED" != yes; then
 185       # On MacOSX there is a readlink tool with a different
 186       # purpose than the GNU readlink tool. Check the found readlink.
 187       ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
 188       if test "x$ISGNU" = x; then
 189         # A readlink that we do not know how to use.
 190         # Are there other non-GNU readlinks out there?
 191         READLINK_TESTED=yes
 192         READLINK=
 193       fi
 194     fi
 195 
 196     if test "x$READLINK" != x; then
 197       $1=`$READLINK -f [$]$1`
 198     else
 199       # Save the current directory for restoring afterwards
 200       STARTDIR=$PWD
 201       COUNTER=0
 202       sym_link_dir=`$DIRNAME [$]$1`
 203       sym_link_file=`$BASENAME [$]$1`
 204       cd $sym_link_dir
 205       # Use -P flag to resolve symlinks in directories.
 206       cd `$THEPWDCMD -P`
 207       sym_link_dir=`$THEPWDCMD -P`
 208       # Resolve file symlinks
 209       while test $COUNTER -lt 20; do
 210         ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
 211         if test "x$ISLINK" == x; then
 212           # This is not a symbolic link! We are done!
 213           break
 214         fi
 215         # Again resolve directory symlinks since the target of the just found
 216         # link could be in a different directory
 217         cd `$DIRNAME $ISLINK`
 218         sym_link_dir=`$THEPWDCMD -P`
 219         sym_link_file=`$BASENAME $ISLINK`
 220         let COUNTER=COUNTER+1
 221       done
 222       cd $STARTDIR
 223       $1=$sym_link_dir/$sym_link_file
 224     fi
 225   fi
 226 ])
 227 
 228 # Register a --with argument but mark it as deprecated
 229 # $1: The name of the with argument to deprecate, not including --with-
 230 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
 231 [
 232   AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
 233       [Deprecated. Option is kept for backwards compatibility and is ignored])],
 234       [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
 235 ])
 236 
 237 # Register a --enable argument but mark it as deprecated
 238 # $1: The name of the with argument to deprecate, not including --enable-
 239 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
 240 # $3: Messages to user.
 241 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
 242 [
 243   AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
 244       [Deprecated. Option is kept for backwards compatibility and is ignored])])
 245   if test "x$enable_$2" != x; then
 246     AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
 247 
 248     if test "x$3" != x; then
 249       AC_MSG_WARN([$3])
 250     fi
 251 
 252   fi
 253 ])
 254 
 255 AC_DEFUN_ONCE([BASIC_INIT],
 256 [
 257   # Save the original command line. This is passed to us by the wrapper configure script.
 258   AC_SUBST(CONFIGURE_COMMAND_LINE)
 259   # Save the path variable before it gets changed
 260   ORIGINAL_PATH="$PATH"
 261   AC_SUBST(ORIGINAL_PATH)
 262   DATE_WHEN_CONFIGURED=`LANG=C date`
 263   AC_SUBST(DATE_WHEN_CONFIGURED)
 264   AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
 265   AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
 266 ])
 267 
 268 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
 269 # $1: variable to check
 270 AC_DEFUN([BASIC_CHECK_NONEMPTY],
 271 [
 272   if test "x[$]$1" = x; then
 273     AC_MSG_ERROR([Could not find required tool for $1])
 274   fi
 275 ])
 276 
 277 # Check that there are no unprocessed overridden variables left.
 278 # If so, they are an incorrect argument and we will exit with an error.
 279 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],
 280 [
 281   if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then
 282     # Replace the separating ! with spaces before presenting for end user.
 283     unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }
 284     AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])
 285   fi
 286 ])
 287 
 288 # Setup a tool for the given variable. If correctly specified by the user,
 289 # use that value, otherwise search for the tool using the supplied code snippet.
 290 # $1: variable to set
 291 # $2: code snippet to call to look for the tool
 292 # $3: code snippet to call if variable was used to find tool
 293 AC_DEFUN([BASIC_SETUP_TOOL],
 294 [
 295   # Publish this variable in the help.
 296   AC_ARG_VAR($1, [Override default value for $1])
 297 
 298   if [[ -z "${$1+x}" ]]; then
 299     # The variable is not set by user, try to locate tool using the code snippet
 300     $2
 301   else
 302     # The variable is set, but is it from the command line or the environment?
 303 
 304     # Try to remove the string !$1! from our list.
 305     try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}
 306     if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then
 307       # If it failed, the variable was not from the command line. Ignore it,
 308       # but warn the user (except for BASH, which is always set by the calling BASH).
 309       if test "x$1" != xBASH; then
 310         AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])
 311       fi
 312       # Try to locate tool using the code snippet
 313       $2
 314     else
 315       # If it succeeded, then it was overridden by the user. We will use it
 316       # for the tool.
 317 
 318       # First remove it from the list of overridden variables, so we can test
 319       # for unknown variables in the end.
 320       CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"
 321 
 322       # Check if we try to supply an empty value
 323       if test "x[$]$1" = x; then
 324         AC_MSG_NOTICE([Setting user supplied tool $1= (no value)])
 325         AC_MSG_CHECKING([for $1])
 326         AC_MSG_RESULT([disabled])
 327       else
 328         # Check if the provided tool contains a complete path.
 329         tool_specified="[$]$1"
 330         tool_basename="${tool_specified##*/}"
 331         if test "x$tool_basename" = "x$tool_specified"; then
 332           # A command without a complete path is provided, search $PATH.
 333           AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])
 334           AC_PATH_PROG($1, $tool_basename)
 335           if test "x[$]$1" = x; then
 336             AC_MSG_ERROR([User supplied tool $tool_basename could not be found])
 337           fi
 338         else
 339           # Otherwise we believe it is a complete path. Use it as it is.
 340           AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])
 341           AC_MSG_CHECKING([for $1])
 342           if test ! -x "$tool_specified"; then
 343             AC_MSG_RESULT([not found])
 344             AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])
 345           fi
 346           AC_MSG_RESULT([$tool_specified])
 347         fi
 348       fi
 349     fi
 350     $3
 351   fi
 352 ])
 353 
 354 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool
 355 # $1: variable to set
 356 # $2: executable name (or list of names) to look for
 357 AC_DEFUN([BASIC_PATH_PROGS],
 358 [
 359   BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2)])
 360 ])
 361 
 362 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool
 363 # $1: variable to set
 364 # $2: executable name (or list of names) to look for
 365 AC_DEFUN([BASIC_CHECK_TOOLS],
 366 [
 367   BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])
 368 ])
 369 
 370 # Like BASIC_PATH_PROGS but fails if no tool was found.
 371 # $1: variable to set
 372 # $2: executable name (or list of names) to look for
 373 AC_DEFUN([BASIC_REQUIRE_PROGS],
 374 [
 375   BASIC_PATH_PROGS($1, $2)
 376   BASIC_CHECK_NONEMPTY($1)
 377 ])
 378 
 379 # Like BASIC_SETUP_TOOL but fails if no tool was found.
 380 # $1: variable to set
 381 # $2: autoconf macro to call to look for the special tool
 382 AC_DEFUN([BASIC_REQUIRE_SPECIAL],
 383 [
 384   BASIC_SETUP_TOOL($1, [$2])
 385   BASIC_CHECK_NONEMPTY($1)
 386 ])
 387 
 388 # Setup the most fundamental tools that relies on not much else to set up,
 389 # but is used by much of the early bootstrap code.
 390 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
 391 [
 392   # Start with tools that do not need have cross compilation support
 393   # and can be expected to be found in the default PATH. These tools are
 394   # used by configure.
 395 
 396   # First are all the simple required tools.
 397   BASIC_REQUIRE_PROGS(BASENAME, basename)
 398   BASIC_REQUIRE_PROGS(BASH, bash)
 399   BASIC_REQUIRE_PROGS(CAT, cat)
 400   BASIC_REQUIRE_PROGS(CHMOD, chmod)
 401   BASIC_REQUIRE_PROGS(CMP, cmp)
 402   BASIC_REQUIRE_PROGS(COMM, comm)
 403   BASIC_REQUIRE_PROGS(CP, cp)
 404   BASIC_REQUIRE_PROGS(CUT, cut)
 405   BASIC_REQUIRE_PROGS(DATE, date)
 406   BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])
 407   BASIC_REQUIRE_PROGS(DIRNAME, dirname)
 408   BASIC_REQUIRE_PROGS(ECHO, echo)
 409   BASIC_REQUIRE_PROGS(EXPR, expr)
 410   BASIC_REQUIRE_PROGS(FILE, file)
 411   BASIC_REQUIRE_PROGS(FIND, find)
 412   BASIC_REQUIRE_PROGS(HEAD, head)
 413   BASIC_REQUIRE_PROGS(LN, ln)
 414   BASIC_REQUIRE_PROGS(LS, ls)
 415   BASIC_REQUIRE_PROGS(MKDIR, mkdir)
 416   BASIC_REQUIRE_PROGS(MKTEMP, mktemp)
 417   BASIC_REQUIRE_PROGS(MV, mv)
 418   BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])
 419   BASIC_REQUIRE_PROGS(PRINTF, printf)
 420   BASIC_REQUIRE_PROGS(RM, rm)
 421   BASIC_REQUIRE_PROGS(RMDIR, rmdir)
 422   BASIC_REQUIRE_PROGS(SH, sh)
 423   BASIC_REQUIRE_PROGS(SORT, sort)
 424   BASIC_REQUIRE_PROGS(TAIL, tail)
 425   BASIC_REQUIRE_PROGS(TAR, tar)
 426   BASIC_REQUIRE_PROGS(TEE, tee)
 427   BASIC_REQUIRE_PROGS(TOUCH, touch)
 428   BASIC_REQUIRE_PROGS(TR, tr)
 429   BASIC_REQUIRE_PROGS(UNAME, uname)
 430   BASIC_REQUIRE_PROGS(UNIQ, uniq)
 431   BASIC_REQUIRE_PROGS(WC, wc)
 432   BASIC_REQUIRE_PROGS(WHICH, which)
 433   BASIC_REQUIRE_PROGS(XARGS, xargs)
 434 
 435   # Then required tools that require some special treatment.
 436   BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])
 437   BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])
 438   BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])
 439   BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])
 440   BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])
 441 
 442   # Always force rm.
 443   RM="$RM -f"
 444 
 445   # pwd behaves differently on various platforms and some don't support the -L flag.
 446   # Always use the bash builtin pwd to get uniform behavior.
 447   THEPWDCMD=pwd
 448 
 449   # These are not required on all platforms
 450   BASIC_PATH_PROGS(CYGPATH, cygpath)
 451   BASIC_PATH_PROGS(READLINK, [greadlink readlink])
 452   BASIC_PATH_PROGS(DF, df)
 453   BASIC_PATH_PROGS(CPIO, [cpio bsdcpio])
 454   BASIC_PATH_PROGS(NICE, nice)
 455 ])
 456 
 457 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
 458 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
 459 [
 460   # Save the current directory this script was started from
 461   CURDIR="$PWD"
 462 
 463   # We might need to rewrite ORIGINAL_PATH, if it includes "#", to quote them
 464   # for make. We couldn't do this when we retrieved ORIGINAL_PATH, since SED
 465   # was not available at that time.
 466   REWRITTEN_PATH=`$ECHO "$ORIGINAL_PATH" | $SED -e 's/#/\\\\#/g'`
 467   if test "x$REWRITTEN_PATH" != "x$ORIGINAL_PATH"; then
 468     ORIGINAL_PATH="$REWRITTEN_PATH"
 469     AC_MSG_NOTICE([Rewriting ORIGINAL_PATH to $REWRITTEN_PATH])
 470   fi
 471 
 472   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 473     PATH_SEP=";"
 474     BASIC_CHECK_PATHS_WINDOWS
 475   else
 476     PATH_SEP=":"
 477   fi
 478   AC_SUBST(PATH_SEP)
 479 
 480   # We get the top-level directory from the supporting wrappers.
 481   AC_MSG_CHECKING([for top-level directory])
 482   AC_MSG_RESULT([$TOPDIR])
 483   AC_SUBST(TOPDIR)
 484 
 485   # Save the original version of TOPDIR for string comparisons
 486   ORIGINAL_TOPDIR="$TOPDIR"
 487   AC_SUBST(ORIGINAL_TOPDIR)
 488 
 489   # We can only call BASIC_FIXUP_PATH after BASIC_CHECK_PATHS_WINDOWS.
 490   BASIC_FIXUP_PATH(CURDIR)
 491   BASIC_FIXUP_PATH(TOPDIR)
 492   # SRC_ROOT is a traditional alias for TOPDIR.
 493   SRC_ROOT=$TOPDIR
 494 
 495   # Calculate a canonical version of TOPDIR for string comparisons
 496   CANONICAL_TOPDIR=$TOPDIR
 497   BASIC_REMOVE_SYMBOLIC_LINKS([CANONICAL_TOPDIR])
 498   AC_SUBST(CANONICAL_TOPDIR)
 499 
 500   # Locate the directory of this script.
 501   AUTOCONF_DIR=$TOPDIR/common/autoconf
 502 ])
 503 
 504 # Evaluates platform specific overrides for devkit variables.
 505 # $1: Name of variable
 506 AC_DEFUN([BASIC_EVAL_DEVKIT_VARIABLE],
 507 [
 508   if test "x[$]$1" = x; then
 509     eval $1="\${$1_${OPENJDK_TARGET_CPU}}"
 510   fi
 511 ])
 512 
 513 AC_DEFUN_ONCE([BASIC_SETUP_DEVKIT],
 514 [
 515   AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
 516       [use this devkit for compilers, tools and resources])],
 517       [
 518         BASIC_FIXUP_PATH([with_devkit])
 519         DEVKIT_ROOT="$with_devkit"
 520         # Check for a meta data info file in the root of the devkit
 521         if test -f "$DEVKIT_ROOT/devkit.info"; then
 522           . $DEVKIT_ROOT/devkit.info
 523           # This potentially sets the following:
 524           # A descriptive name of the devkit
 525           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_NAME])
 526           # Corresponds to --with-extra-path
 527           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_EXTRA_PATH])
 528           # Corresponds to --with-toolchain-path
 529           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_TOOLCHAIN_PATH])
 530           # Corresponds to --with-sysroot
 531           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_SYSROOT])
 532 
 533           # Identifies the Visual Studio version in the devkit
 534           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_VERSION])
 535           # The Visual Studio include environment variable
 536           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_INCLUDE])
 537           # The Visual Studio lib environment variable
 538           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_LIB])
 539           # Corresponds to --with-msvcr-dll
 540           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCR_DLL])
 541           # Corresponds to --with-msvcp-dll
 542           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCP_DLL])
 543         fi
 544 
 545         AC_MSG_CHECKING([for devkit])
 546         if test "x$DEVKIT_NAME" != x; then
 547           AC_MSG_RESULT([$DEVKIT_NAME in $DEVKIT_ROOT])
 548         else
 549           AC_MSG_RESULT([$DEVKIT_ROOT])
 550         fi
 551 
 552         BASIC_PREPEND_TO_PATH([EXTRA_PATH],$DEVKIT_EXTRA_PATH)
 553 
 554         # Fallback default of just /bin if DEVKIT_PATH is not defined
 555         if test "x$DEVKIT_TOOLCHAIN_PATH" = x; then
 556           DEVKIT_TOOLCHAIN_PATH="$DEVKIT_ROOT/bin"
 557         fi
 558         BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$DEVKIT_TOOLCHAIN_PATH)
 559 
 560         # If DEVKIT_SYSROOT is set, use that, otherwise try a couple of known
 561         # places for backwards compatiblity.
 562         if test "x$DEVKIT_SYSROOT" != x; then
 563           SYSROOT="$DEVKIT_SYSROOT"
 564         elif test -d "$DEVKIT_ROOT/$host_alias/libc"; then
 565           SYSROOT="$DEVKIT_ROOT/$host_alias/libc"
 566         elif test -d "$DEVKIT_ROOT/$host/sys-root"; then
 567           SYSROOT="$DEVKIT_ROOT/$host/sys-root"
 568         fi
 569       ]
 570   )
 571 
 572   # You can force the sysroot if the sysroot encoded into the compiler tools
 573   # is not correct.
 574   AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
 575       [alias for --with-sysroot for backwards compatability])],
 576       [SYSROOT=$with_sys_root]
 577   )
 578 
 579   AC_ARG_WITH(sysroot, [AS_HELP_STRING([--with-sysroot],
 580       [use this directory as sysroot])],
 581       [SYSROOT=$with_sysroot]
 582   )
 583 
 584   AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
 585       [alias for --with-toolchain-path for backwards compatibility])],
 586       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_tools_dir)]
 587   )
 588 
 589   AC_ARG_WITH([toolchain-path], [AS_HELP_STRING([--with-toolchain-path],
 590       [prepend these directories when searching for toolchain binaries (compilers etc)])],
 591       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_toolchain_path)]
 592   )
 593 
 594   AC_ARG_WITH([extra-path], [AS_HELP_STRING([--with-extra-path],
 595       [prepend these directories to the default path])],
 596       [BASIC_PREPEND_TO_PATH([EXTRA_PATH],$with_extra_path)]
 597   )
 598 
 599   if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then
 600     # If a devkit has been supplied, find xcodebuild in the toolchain_path.
 601     # If not, detect if Xcode is installed by running xcodebuild -version
 602     # if no Xcode installed, xcodebuild exits with 1
 603     # if Xcode is installed, even if xcode-select is misconfigured, then it exits with 0
 604     if test "x$DEVKIT_ROOT" != x || /usr/bin/xcodebuild -version >/dev/null 2>&1; then
 605       # We need to use xcodebuild in the toolchain dir provided by the user, this will
 606       # fall back on the stub binary in /usr/bin/xcodebuild
 607       AC_PATH_PROG([XCODEBUILD], [xcodebuild], [/usr/bin/xcodebuild], [$TOOLCHAIN_PATH])
 608     else
 609       # this should result in SYSROOT being empty, unless --with-sysroot is provided
 610       # when only the command line tools are installed there are no SDKs, so headers
 611       # are copied into the system frameworks
 612       XCODEBUILD=
 613       AC_SUBST(XCODEBUILD)
 614     fi
 615 
 616     AC_MSG_CHECKING([for sdk name])
 617     AC_ARG_WITH([sdk-name], [AS_HELP_STRING([--with-sdk-name],
 618         [use the platform SDK of the given name. @<:@macosx@:>@])],
 619         [SDKNAME=$with_sdk_name]
 620     )
 621     AC_MSG_RESULT([$SDKNAME])
 622 
 623     # if toolchain path is specified then don't rely on system headers, they may not compile
 624     HAVE_SYSTEM_FRAMEWORK_HEADERS=0
 625     test -z "$TOOLCHAIN_PATH" && \
 626       HAVE_SYSTEM_FRAMEWORK_HEADERS=`test ! -f /System/Library/Frameworks/Foundation.framework/Headers/Foundation.h; echo $?`
 627 
 628     if test -z "$SYSROOT"; then
 629       if test -n "$XCODEBUILD"; then
 630         # if we don't have system headers, use default SDK name (last resort)
 631         if test -z "$SDKNAME" -a $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
 632           SDKNAME=${SDKNAME:-macosx}
 633         fi
 634 
 635         if test -n "$SDKNAME"; then
 636           # Call xcodebuild to determine SYSROOT
 637           SYSROOT=`"$XCODEBUILD" -sdk $SDKNAME -version | grep '^Path: ' | sed 's/Path: //'`
 638         fi
 639       else
 640         if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
 641           AC_MSG_ERROR([No xcodebuild tool and no system framework headers found, use --with-sysroot or --with-sdk-name to provide a path to a valid SDK])
 642         fi
 643       fi
 644     else
 645       # warn user if --with-sdk-name was also set
 646       if test -n "$with_sdk_name"; then
 647         AC_MSG_WARN([Both SYSROOT and --with-sdk-name are set, only SYSROOT will be used])
 648       fi
 649     fi
 650 
 651     if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0 -a -z "$SYSROOT"; then
 652       # If no system framework headers, then SYSROOT must be set, or we won't build
 653       AC_MSG_ERROR([Unable to determine SYSROOT and no headers found in /System/Library/Frameworks. Check Xcode configuration, --with-sysroot or --with-sdk-name arguments.])
 654     fi
 655 
 656     # Perform a basic sanity test
 657     if test ! -f "$SYSROOT/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then
 658       if test -z "$SYSROOT"; then
 659         AC_MSG_ERROR([Unable to find required framework headers, provide a path to an SDK via --with-sysroot or --with-sdk-name and be sure Xcode is installed properly])
 660       else
 661         AC_MSG_ERROR([Invalid SDK or SYSROOT path, dependent framework headers not found])
 662       fi
 663     fi
 664 
 665     # set SDKROOT too, Xcode tools will pick it up
 666     AC_SUBST(SDKROOT,$SYSROOT)
 667   fi
 668 
 669   # Prepend the extra path to the global path
 670   BASIC_PREPEND_TO_PATH([PATH],$EXTRA_PATH)
 671 
 672   if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
 673     # Add extra search paths on solaris for utilities like ar and as etc...
 674     PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
 675   fi
 676 
 677   AC_MSG_CHECKING([for sysroot])
 678   AC_MSG_RESULT([$SYSROOT])
 679   AC_MSG_CHECKING([for toolchain path])
 680   AC_MSG_RESULT([$TOOLCHAIN_PATH])
 681   AC_MSG_CHECKING([for extra path])
 682   AC_MSG_RESULT([$EXTRA_PATH])
 683 ])
 684 
 685 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
 686 [
 687 
 688   AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
 689       [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
 690       [ CONF_NAME=${with_conf_name} ])
 691 
 692   # Test from where we are running configure, in or outside of src root.
 693   AC_MSG_CHECKING([where to store configuration])
 694   if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \
 695       || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \
 696       || test "x$CURDIR" = "x$SRC_ROOT/make" ; then
 697     # We are running configure from the src root.
 698     # Create a default ./build/target-variant-debuglevel output root.
 699     if test "x${CONF_NAME}" = x; then
 700       AC_MSG_RESULT([in default location])
 701       CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
 702     else
 703       AC_MSG_RESULT([in build directory with custom name])
 704     fi
 705     OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
 706     $MKDIR -p "$OUTPUT_ROOT"
 707     if test ! -d "$OUTPUT_ROOT"; then
 708       AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
 709     fi
 710   else
 711     # We are running configure from outside of the src dir.
 712     # Then use the current directory as output dir!
 713     # If configuration is situated in normal build directory, just use the build
 714     # directory name as configuration name, otherwise use the complete path.
 715     if test "x${CONF_NAME}" = x; then
 716       CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
 717     fi
 718     OUTPUT_ROOT="$CURDIR"
 719     AC_MSG_RESULT([in current directory])
 720 
 721     # WARNING: This might be a bad thing to do. You need to be sure you want to
 722     # have a configuration in this directory. Do some sanity checks!
 723 
 724     if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
 725       # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
 726       # other files
 727       files_present=`$LS $OUTPUT_ROOT`
 728       # Configure has already touched config.log and confdefs.h in the current dir when this check
 729       # is performed.
 730       filtered_files=`$ECHO "$files_present" \
 731           | $SED -e 's/config.log//g' \
 732               -e 's/configure.log//g' \
 733               -e 's/confdefs.h//g' \
 734               -e 's/ //g' \
 735           | $TR -d '\n'`
 736       if test "x$filtered_files" != x; then
 737         AC_MSG_NOTICE([Current directory is $CURDIR.])
 738         AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
 739         AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
 740         AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
 741         AC_MSG_NOTICE([seriously mess up just about everything.])
 742         AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
 743         AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
 744         AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
 745       fi
 746     fi
 747   fi
 748   AC_MSG_CHECKING([what configuration name to use])
 749   AC_MSG_RESULT([$CONF_NAME])
 750 
 751   BASIC_FIXUP_PATH(OUTPUT_ROOT)
 752 
 753   CONFIGURESUPPORT_OUTPUTDIR="$OUTPUT_ROOT/configure-support"
 754   $MKDIR -p "$CONFIGURESUPPORT_OUTPUTDIR"
 755 
 756   AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
 757   AC_SUBST(CONF_NAME, $CONF_NAME)
 758   AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
 759   AC_SUBST(CONFIGURESUPPORT_OUTPUTDIR)
 760 
 761   # The spec.gmk file contains all variables for the make system.
 762   AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
 763   # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
 764   AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
 765   # The bootcycle-spec.gmk file contains support for boot cycle builds.
 766   AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
 767   # The compare.sh is used to compare the build output to other builds.
 768   AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
 769   # The generated Makefile knows where the spec.gmk is and where the source is.
 770   # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
 771   # which will look for generated configurations
 772   AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
 773 ])
 774 
 775 #%%% Simple tools %%%
 776 
 777 # Check if we have found a usable version of make
 778 # $1: the path to a potential make binary (or empty)
 779 # $2: the description on how we found this
 780 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
 781 [
 782   MAKE_CANDIDATE="$1"
 783   DESCRIPTION="$2"
 784 
 785   # On Cygwin, we require a newer version of make than on other platforms
 786   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 787     MAKE_VERSION_EXPR="-e 4\."
 788     MAKE_REQUIRED_VERSION="4.0"
 789    else
 790     MAKE_VERSION_EXPR="-e 3\.8[[12]] -e 4\."
 791     MAKE_REQUIRED_VERSION="3.81"
 792   fi
 793 
 794   if test "x$MAKE_CANDIDATE" != x; then
 795     AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
 796     MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
 797     IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
 798     if test "x$IS_GNU_MAKE" = x; then
 799       AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
 800     else
 801       IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP $MAKE_VERSION_EXPR`
 802       if test "x$IS_MODERN_MAKE" = x; then
 803         AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version $MAKE_REQUIRED_VERSION or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
 804       else
 805         if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
 806           if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 807             MAKE_EXPECTED_ENV='cygwin'
 808           elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 809             MAKE_EXPECTED_ENV='msys'
 810           else
 811             AC_MSG_ERROR([Unknown Windows environment])
 812           fi
 813           MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
 814           IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
 815         else
 816           # Not relevant for non-Windows
 817           IS_MAKE_CORRECT_ENV=true
 818         fi
 819         if test "x$IS_MAKE_CORRECT_ENV" = x; then
 820           AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
 821         else
 822           FOUND_MAKE=$MAKE_CANDIDATE
 823           BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
 824         fi
 825       fi
 826     fi
 827   fi
 828 ])
 829 
 830 AC_DEFUN([BASIC_CHECK_MAKE_OUTPUT_SYNC],
 831 [
 832   # Check if make supports the output sync option and if so, setup using it.
 833   AC_MSG_CHECKING([if make --output-sync is supported])
 834   if $MAKE --version -O > /dev/null 2>&1; then
 835     OUTPUT_SYNC_SUPPORTED=true
 836     AC_MSG_RESULT([yes])
 837     AC_MSG_CHECKING([for output-sync value])
 838     AC_ARG_WITH([output-sync], [AS_HELP_STRING([--with-output-sync],
 839       [set make output sync type if supported by make. @<:@recurse@:>@])],
 840       [OUTPUT_SYNC=$with_output_sync])
 841     if test "x$OUTPUT_SYNC" = "x"; then
 842       OUTPUT_SYNC=none
 843     fi
 844     AC_MSG_RESULT([$OUTPUT_SYNC])
 845     if ! $MAKE --version -O$OUTPUT_SYNC > /dev/null 2>&1; then
 846       AC_MSG_ERROR([Make did not the support the value $OUTPUT_SYNC as output sync type.])
 847     fi
 848   else
 849     OUTPUT_SYNC_SUPPORTED=false
 850     AC_MSG_RESULT([no])
 851   fi
 852   AC_SUBST(OUTPUT_SYNC_SUPPORTED)
 853   AC_SUBST(OUTPUT_SYNC)
 854 ])
 855 
 856 # Goes looking for a usable version of GNU make.
 857 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
 858 [
 859   BASIC_SETUP_TOOL([MAKE],
 860   [
 861     # Try our hardest to locate a correct version of GNU make
 862     AC_PATH_PROGS(CHECK_GMAKE, gmake)
 863     BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
 864 
 865     if test "x$FOUND_MAKE" = x; then
 866       AC_PATH_PROGS(CHECK_MAKE, make)
 867       BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
 868     fi
 869 
 870     if test "x$FOUND_MAKE" = x; then
 871       if test "x$TOOLCHAIN_PATH" != x; then
 872         # We have a toolchain path, check that as well before giving up.
 873         OLD_PATH=$PATH
 874         PATH=$TOOLCHAIN_PATH:$PATH
 875         AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
 876         BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
 877         if test "x$FOUND_MAKE" = x; then
 878           AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
 879           BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
 880         fi
 881         PATH=$OLD_PATH
 882       fi
 883     fi
 884 
 885     if test "x$FOUND_MAKE" = x; then
 886       AC_MSG_ERROR([Cannot find GNU make $MAKE_REQUIRED_VERSION or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
 887     fi
 888   ],[
 889     # If MAKE was set by user, verify the version
 890     BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
 891     if test "x$FOUND_MAKE" = x; then
 892       AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make $MAKE_REQUIRED_VERSION or newer.])
 893     fi
 894   ])
 895 
 896   MAKE=$FOUND_MAKE
 897   AC_SUBST(MAKE)
 898   AC_MSG_NOTICE([Using GNU make at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
 899 
 900   BASIC_CHECK_MAKE_OUTPUT_SYNC
 901 ])
 902 
 903 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
 904 [
 905   # Test if find supports -delete
 906   AC_MSG_CHECKING([if find supports -delete])
 907   FIND_DELETE="-delete"
 908 
 909   DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
 910 
 911   echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
 912 
 913   TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
 914   if test -f $DELETEDIR/TestIfFindSupportsDelete; then
 915     # No, it does not.
 916     rm $DELETEDIR/TestIfFindSupportsDelete
 917     if test "x$OPENJDK_TARGET_OS" = "xaix"; then
 918       # AIX 'find' is buggy if called with '-exec {} \+' and an empty file list
 919       FIND_DELETE="-print | xargs rm"
 920     else
 921       FIND_DELETE="-exec rm \{\} \+"
 922     fi
 923     AC_MSG_RESULT([no])
 924   else
 925     AC_MSG_RESULT([yes])
 926   fi
 927   rmdir $DELETEDIR
 928   AC_SUBST(FIND_DELETE)
 929 ])
 930 
 931 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
 932 [
 933   BASIC_CHECK_GNU_MAKE
 934 
 935   BASIC_CHECK_FIND_DELETE
 936 
 937   # These tools might not be installed by default,
 938   # need hint on how to install them.
 939   BASIC_REQUIRE_PROGS(UNZIP, unzip)
 940   BASIC_REQUIRE_PROGS(ZIP, zip)
 941 
 942   # Non-required basic tools
 943 
 944   BASIC_PATH_PROGS(LDD, ldd)
 945   if test "x$LDD" = "x"; then
 946     # List shared lib dependencies is used for
 947     # debug output and checking for forbidden dependencies.
 948     # We can build without it.
 949     LDD="true"
 950   fi
 951   BASIC_PATH_PROGS(OTOOL, otool)
 952   if test "x$OTOOL" = "x"; then
 953     OTOOL="true"
 954   fi
 955   BASIC_PATH_PROGS(READELF, [greadelf readelf])
 956   BASIC_PATH_PROGS(HG, hg)
 957   BASIC_PATH_PROGS(STAT, stat)
 958   BASIC_PATH_PROGS(TIME, time)
 959   BASIC_PATH_PROGS(PATCH, [gpatch patch])
 960   # Check if it's GNU time
 961   IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
 962   if test "x$IS_GNU_TIME" != x; then
 963     IS_GNU_TIME=yes
 964   else
 965     IS_GNU_TIME=no
 966   fi
 967   AC_SUBST(IS_GNU_TIME)
 968 
 969   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
 970     BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)
 971     BASIC_REQUIRE_PROGS(XATTR, xattr)
 972     BASIC_PATH_PROGS(CODESIGN, codesign)
 973     if test "x$CODESIGN" != "x"; then
 974       # Verify that the openjdk_codesign certificate is present
 975       AC_MSG_CHECKING([if openjdk_codesign certificate is present])
 976       rm -f codesign-testfile
 977       touch codesign-testfile
 978       codesign -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
 979       rm -f codesign-testfile
 980       if test "x$CODESIGN" = x; then
 981         AC_MSG_RESULT([no])
 982       else
 983         AC_MSG_RESULT([yes])
 984       fi
 985     fi
 986     BASIC_REQUIRE_PROGS(SETFILE, SetFile)
 987   fi
 988 ])
 989 
 990 # Check if build directory is on local disk. If not possible to determine,
 991 # we prefer to claim it's local.
 992 # Argument 1: directory to test
 993 # Argument 2: what to do if it is on local disk
 994 # Argument 3: what to do otherwise (remote disk or failure)
 995 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
 996 [
 997   # df -l lists only local disks; if the given directory is not found then
 998   # a non-zero exit code is given
 999   if test "x$DF" = x; then
1000     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
1001       # msys does not have df; use Windows "net use" instead.
1002       IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
1003       if test "x$IS_NETWORK_DISK" = x; then
1004         $2
1005       else
1006         $3
1007       fi
1008     else
1009       # No df here, say it's local
1010       $2
1011     fi
1012   else
1013     if $DF -l $1 > /dev/null 2>&1; then
1014       $2
1015     else
1016       $3
1017     fi
1018   fi
1019 ])
1020 
1021 # Check that source files have basic read permissions set. This might
1022 # not be the case in cygwin in certain conditions.
1023 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
1024 [
1025   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
1026     file_to_test="$SRC_ROOT/LICENSE"
1027     if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
1028       AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
1029     fi
1030   fi
1031 ])
1032 
1033 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
1034 [
1035   # Did user specify any unknown variables?
1036   BASIC_CHECK_LEFTOVER_OVERRIDDEN
1037 
1038   AC_MSG_CHECKING([if build directory is on local disk])
1039   BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
1040       [OUTPUT_DIR_IS_LOCAL="yes"],
1041       [OUTPUT_DIR_IS_LOCAL="no"])
1042   AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
1043 
1044   BASIC_CHECK_SRC_PERMS
1045 
1046   # Check if the user has any old-style ALT_ variables set.
1047   FOUND_ALT_VARIABLES=`env | grep ^ALT_`
1048 
1049   # Before generating output files, test if they exist. If they do, this is a reconfigure.
1050   # Since we can't properly handle the dependencies for this, warn the user about the situation
1051   if test -e $OUTPUT_ROOT/spec.gmk; then
1052     IS_RECONFIGURE=yes
1053   else
1054     IS_RECONFIGURE=no
1055   fi
1056 ])
1057 
1058 # Check for support for specific options in bash
1059 AC_DEFUN_ONCE([BASIC_CHECK_BASH_OPTIONS],
1060 [
1061   # Test if bash supports pipefail.
1062   AC_MSG_CHECKING([if bash supports pipefail])
1063   if ${BASH} -c 'set -o pipefail'; then
1064     BASH_ARGS="$BASH_ARGS -o pipefail"
1065     AC_MSG_RESULT([yes])
1066   else
1067     AC_MSG_RESULT([no])
1068   fi
1069 
1070   AC_MSG_CHECKING([if bash supports errexit (-e)])
1071   if ${BASH} -e -c 'true'; then
1072     BASH_ARGS="$BASH_ARGS -e"
1073     AC_MSG_RESULT([yes])
1074   else
1075     AC_MSG_RESULT([no])
1076   fi
1077 
1078   AC_SUBST(BASH_ARGS)
1079 ])
1080 
1081 # Code to run after AC_OUTPUT
1082 AC_DEFUN_ONCE([BASIC_POST_CONFIG_OUTPUT],
1083 [
1084   # Try to move config.log (generated by autoconf) to the configure-support directory.
1085   if test -e ./config.log; then
1086     $MV -f ./config.log "$CONFIGURESUPPORT_OUTPUTDIR/config.log" 2> /dev/null
1087   fi
1088 
1089   # Rotate our log file (configure.log)
1090   if test -e "$OUTPUT_ROOT/configure.log.old"; then
1091     $RM -f "$OUTPUT_ROOT/configure.log.old"
1092   fi
1093   if test -e "$OUTPUT_ROOT/configure.log"; then
1094     $MV -f "$OUTPUT_ROOT/configure.log" "$OUTPUT_ROOT/configure.log.old" 2> /dev/null
1095   fi
1096 
1097   # Move configure.log from current directory to the build output root
1098   if test -e ./configure.log; then
1099     echo found it
1100     $MV -f ./configure.log "$OUTPUT_ROOT/configure.log" 2> /dev/null
1101   fi
1102 
1103   # Make the compare script executable
1104   $CHMOD +x $OUTPUT_ROOT/compare.sh
1105 ])
--- EOF ---