1 #
   2 # Copyright (c) 2011, 2017, Oracle and/or its affiliates. All rights reserved.
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # This code is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License version 2 only, as
   7 # published by the Free Software Foundation.  Oracle designates this
   8 # particular file as subject to the "Classpath" exception as provided
   9 # by Oracle in the LICENSE file that accompanied this code.
  10 #
  11 # This code is distributed in the hope that it will be useful, but WITHOUT
  12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 # version 2 for more details (a copy is included in the LICENSE file that
  15 # accompanied this code).
  16 #
  17 # You should have received a copy of the GNU General Public License version
  18 # 2 along with this work; if not, write to the Free Software Foundation,
  19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
  20 #
  21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
  22 # or visit www.oracle.com if you need additional information or have any
  23 # questions.
  24 #
  25 
  26 # Create a function/macro that takes a series of named arguments. The call is
  27 # similar to AC_DEFUN, but the setup of the function looks like this:
  28 # BASIC_DEFUN_NAMED([MYFUNC], [FOO *BAR], [$@], [
  29 # ... do something
  30 #   AC_MSG_NOTICE([Value of BAR is ARG_BAR])
  31 # ])
  32 # A star (*) in front of a named argument means that it is required and it's
  33 # presence will be verified. To pass e.g. the first value as a normal indexed
  34 # argument, use [m4_shift($@)] as the third argument instead of [$@]. These
  35 # arguments are referenced in the function by their name prefixed by ARG_, e.g.
  36 # "ARG_FOO".
  37 #
  38 # The generated function can be called like this:
  39 # MYFUNC(FOO: [foo-val],
  40 #     BAR: [
  41 #         $ECHO hello world
  42 #     ])
  43 # Note that the argument value must start on the same line as the argument name.
  44 #
  45 # Argument 1: Name of the function to define
  46 # Argument 2: List of legal named arguments, with a * prefix for required arguments
  47 # Argument 3: Argument array to treat as named, typically $@
  48 # Argument 4: The main function body
  49 AC_DEFUN([BASIC_DEFUN_NAMED],
  50 [
  51   AC_DEFUN($1, [
  52     m4_foreach(arg, m4_split($2), [
  53       m4_if(m4_bregexp(arg, [^\*]), -1,
  54         [
  55           m4_set_add(legal_named_args, arg)
  56         ],
  57         [
  58           m4_set_add(legal_named_args, m4_substr(arg, 1))
  59           m4_set_add(required_named_args, m4_substr(arg, 1))
  60         ]
  61       )
  62     ])
  63 
  64     m4_foreach([arg], [$3], [
  65       m4_define(arg_name, m4_substr(arg, 0, m4_bregexp(arg, [: ])))
  66       m4_set_contains(legal_named_args, arg_name, [],[AC_MSG_ERROR([Internal error: arg_name is not a valid named argument to [$1]. Valid arguments are 'm4_set_contents(legal_named_args, [ ])'.])])
  67       m4_set_remove(required_named_args, arg_name)
  68       m4_set_remove(legal_named_args, arg_name)
  69       m4_pushdef([ARG_][]arg_name, m4_substr(arg, m4_incr(m4_incr(m4_bregexp(arg, [: ])))))
  70       m4_set_add(defined_args, arg_name)
  71       m4_undefine([arg_name])
  72     ])
  73     m4_set_empty(required_named_args, [], [
  74       AC_MSG_ERROR([Internal error: Required named arguments are missing for [$1]. Missing arguments: 'm4_set_contents(required_named_args, [ ])'])
  75     ])
  76     m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([legal_named_args])), [
  77       m4_pushdef([ARG_][]arg, [])
  78       m4_set_add(defined_args, arg)
  79     ])
  80     m4_set_delete(legal_named_args)
  81     m4_set_delete(required_named_args)
  82 
  83     # Execute function body
  84     $4
  85 
  86     m4_foreach([arg], m4_indir([m4_dquote]m4_set_listc([defined_args])), [
  87       m4_popdef([ARG_][]arg)
  88     ])
  89 
  90     m4_set_delete(defined_args)
  91   ])
  92 ])
  93 
  94 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
  95 # If so, then append $1 to $2 \
  96 # Also set JVM_ARG_OK to true/false depending on outcome.
  97 AC_DEFUN([ADD_JVM_ARG_IF_OK],
  98 [
  99   $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
 100   $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
 101   OUTPUT=`$3 $1 -version 2>&1`
 102   FOUND_WARN=`$ECHO "$OUTPUT" | $GREP -i warn`
 103   FOUND_VERSION=`$ECHO $OUTPUT | $GREP " version \""`
 104   if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
 105     $2="[$]$2 $1"
 106     JVM_ARG_OK=true
 107   else
 108     $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
 109     $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
 110     JVM_ARG_OK=false
 111   fi
 112 ])
 113 
 114 # Appends a string to a path variable, only adding the : when needed.
 115 AC_DEFUN([BASIC_APPEND_TO_PATH],
 116 [
 117   if test "x$2" != x; then
 118     if test "x[$]$1" = x; then
 119       $1="$2"
 120     else
 121       $1="[$]$1:$2"
 122     fi
 123   fi
 124 ])
 125 
 126 # Prepends a string to a path variable, only adding the : when needed.
 127 AC_DEFUN([BASIC_PREPEND_TO_PATH],
 128 [
 129   if test "x$2" != x; then
 130     if test "x[$]$1" = x; then
 131       $1="$2"
 132     else
 133       $1="$2:[$]$1"
 134     fi
 135   fi
 136 ])
 137 
 138 # This will make sure the given variable points to a full and proper
 139 # path. This means:
 140 # 1) There will be no spaces in the path. On unix platforms,
 141 #    spaces in the path will result in an error. On Windows,
 142 #    the path will be rewritten using short-style to be space-free.
 143 # 2) The path will be absolute, and it will be in unix-style (on
 144 #     cygwin).
 145 # $1: The name of the variable to fix
 146 AC_DEFUN([BASIC_FIXUP_PATH],
 147 [
 148   # Only process if variable expands to non-empty
 149 
 150   if test "x[$]$1" != x; then
 151     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 152       BASIC_FIXUP_PATH_CYGWIN($1)
 153     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 154       BASIC_FIXUP_PATH_MSYS($1)
 155     else
 156       # We're on a unix platform. Hooray! :)
 157       path="[$]$1"
 158       has_space=`$ECHO "$path" | $GREP " "`
 159       if test "x$has_space" != x; then
 160         AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
 161         AC_MSG_ERROR([Spaces are not allowed in this path.])
 162       fi
 163 
 164       # Use eval to expand a potential ~
 165       eval path="$path"
 166       if test ! -f "$path" && test ! -d "$path"; then
 167         AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
 168       fi
 169 
 170       if test -d "$path"; then
 171         $1="`cd "$path"; $THEPWDCMD -L`"
 172       else
 173         dir="`$DIRNAME "$path"`"
 174         base="`$BASENAME "$path"`"
 175         $1="`cd "$dir"; $THEPWDCMD -L`/$base"
 176       fi
 177     fi
 178   fi
 179 ])
 180 
 181 # This will make sure the given variable points to a executable
 182 # with a full and proper path. This means:
 183 # 1) There will be no spaces in the path. On unix platforms,
 184 #    spaces in the path will result in an error. On Windows,
 185 #    the path will be rewritten using short-style to be space-free.
 186 # 2) The path will be absolute, and it will be in unix-style (on
 187 #     cygwin).
 188 # Any arguments given to the executable is preserved.
 189 # If the input variable does not have a directory specification, then
 190 # it need to be in the PATH.
 191 # $1: The name of the variable to fix
 192 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
 193 [
 194   # Only process if variable expands to non-empty
 195 
 196   if test "x[$]$1" != x; then
 197     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 198       BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
 199     elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 200       BASIC_FIXUP_EXECUTABLE_MSYS($1)
 201     else
 202       # We're on a unix platform. Hooray! :)
 203       # First separate the path from the arguments. This will split at the first
 204       # space.
 205       complete="[$]$1"
 206       path="${complete%% *}"
 207       tmp="$complete EOL"
 208       arguments="${tmp#* }"
 209 
 210       # Cannot rely on the command "which" here since it doesn't always work.
 211       is_absolute_path=`$ECHO "$path" | $GREP ^/`
 212       if test -z "$is_absolute_path"; then
 213         # Path to executable is not absolute. Find it.
 214         IFS_save="$IFS"
 215         IFS=:
 216         for p in $PATH; do
 217           if test -f "$p/$path" && test -x "$p/$path"; then
 218             new_path="$p/$path"
 219             break
 220           fi
 221         done
 222         IFS="$IFS_save"
 223       else
 224         # This is an absolute path, we can use it without further modifications.
 225         new_path="$path"
 226       fi
 227 
 228       if test "x$new_path" = x; then
 229         AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
 230         has_space=`$ECHO "$complete" | $GREP " "`
 231         if test "x$has_space" != x; then
 232           AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
 233         fi
 234         AC_MSG_ERROR([Cannot locate the the path of $1])
 235       fi
 236     fi
 237 
 238     # Now join together the path and the arguments once again
 239     if test "x$arguments" != xEOL; then
 240       new_complete="$new_path ${arguments% *}"
 241     else
 242       new_complete="$new_path"
 243     fi
 244 
 245     if test "x$complete" != "x$new_complete"; then
 246       $1="$new_complete"
 247       AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
 248     fi
 249   fi
 250 ])
 251 
 252 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
 253 [
 254   if test "x$OPENJDK_BUILD_OS" != xwindows; then
 255     # Follow a chain of symbolic links. Use readlink
 256     # where it exists, else fall back to horribly
 257     # complicated shell code.
 258     if test "x$READLINK_TESTED" != yes; then
 259       # On MacOSX there is a readlink tool with a different
 260       # purpose than the GNU readlink tool. Check the found readlink.
 261       ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
 262       if test "x$ISGNU" = x; then
 263         # A readlink that we do not know how to use.
 264         # Are there other non-GNU readlinks out there?
 265         READLINK_TESTED=yes
 266         READLINK=
 267       fi
 268     fi
 269 
 270     if test "x$READLINK" != x; then
 271       $1=`$READLINK -f [$]$1`
 272     else
 273       # Save the current directory for restoring afterwards
 274       STARTDIR=$PWD
 275       COUNTER=0
 276       sym_link_dir=`$DIRNAME [$]$1`
 277       sym_link_file=`$BASENAME [$]$1`
 278       cd $sym_link_dir
 279       # Use -P flag to resolve symlinks in directories.
 280       cd `$THEPWDCMD -P`
 281       sym_link_dir=`$THEPWDCMD -P`
 282       # Resolve file symlinks
 283       while test $COUNTER -lt 20; do
 284         ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
 285         if test "x$ISLINK" == x; then
 286           # This is not a symbolic link! We are done!
 287           break
 288         fi
 289         # Again resolve directory symlinks since the target of the just found
 290         # link could be in a different directory
 291         cd `$DIRNAME $ISLINK`
 292         sym_link_dir=`$THEPWDCMD -P`
 293         sym_link_file=`$BASENAME $ISLINK`
 294         let COUNTER=COUNTER+1
 295       done
 296       cd $STARTDIR
 297       $1=$sym_link_dir/$sym_link_file
 298     fi
 299   fi
 300 ])
 301 
 302 # Register a --with argument but mark it as deprecated
 303 # $1: The name of the with argument to deprecate, not including --with-
 304 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
 305 [
 306   AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
 307       [Deprecated. Option is kept for backwards compatibility and is ignored])],
 308       [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
 309 ])
 310 
 311 # Register a --enable argument but mark it as deprecated
 312 # $1: The name of the with argument to deprecate, not including --enable-
 313 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
 314 # $3: Messages to user.
 315 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
 316 [
 317   AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
 318       [Deprecated. Option is kept for backwards compatibility and is ignored])])
 319   if test "x$enable_$2" != x; then
 320     AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
 321 
 322     if test "x$3" != x; then
 323       AC_MSG_WARN([$3])
 324     fi
 325 
 326   fi
 327 ])
 328 
 329 AC_DEFUN_ONCE([BASIC_INIT],
 330 [
 331   # Save the original command line. This is passed to us by the wrapper configure script.
 332   AC_SUBST(CONFIGURE_COMMAND_LINE)
 333   # Save the path variable before it gets changed
 334   ORIGINAL_PATH="$PATH"
 335   AC_SUBST(ORIGINAL_PATH)
 336   DATE_WHEN_CONFIGURED=`LANG=C date`
 337   AC_SUBST(DATE_WHEN_CONFIGURED)
 338   AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
 339   AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
 340 ])
 341 
 342 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
 343 # $1: variable to check
 344 AC_DEFUN([BASIC_CHECK_NONEMPTY],
 345 [
 346   if test "x[$]$1" = x; then
 347     AC_MSG_ERROR([Could not find required tool for $1])
 348   fi
 349 ])
 350 
 351 # Check that there are no unprocessed overridden variables left.
 352 # If so, they are an incorrect argument and we will exit with an error.
 353 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],
 354 [
 355   if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then
 356     # Replace the separating ! with spaces before presenting for end user.
 357     unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }
 358     AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])
 359   fi
 360 ])
 361 
 362 # Setup a tool for the given variable. If correctly specified by the user,
 363 # use that value, otherwise search for the tool using the supplied code snippet.
 364 # $1: variable to set
 365 # $2: code snippet to call to look for the tool
 366 # $3: code snippet to call if variable was used to find tool
 367 AC_DEFUN([BASIC_SETUP_TOOL],
 368 [
 369   # Publish this variable in the help.
 370   AC_ARG_VAR($1, [Override default value for $1])
 371 
 372   if [[ -z "${$1+x}" ]]; then
 373     # The variable is not set by user, try to locate tool using the code snippet
 374     $2
 375   else
 376     # The variable is set, but is it from the command line or the environment?
 377 
 378     # Try to remove the string !$1! from our list.
 379     try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}
 380     if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then
 381       # If it failed, the variable was not from the command line. Ignore it,
 382       # but warn the user (except for BASH, which is always set by the calling BASH).
 383       if test "x$1" != xBASH; then
 384         AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])
 385       fi
 386       # Try to locate tool using the code snippet
 387       $2
 388     else
 389       # If it succeeded, then it was overridden by the user. We will use it
 390       # for the tool.
 391 
 392       # First remove it from the list of overridden variables, so we can test
 393       # for unknown variables in the end.
 394       CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"
 395 
 396       # Check if we try to supply an empty value
 397       if test "x[$]$1" = x; then
 398         AC_MSG_NOTICE([Setting user supplied tool $1= (no value)])
 399         AC_MSG_CHECKING([for $1])
 400         AC_MSG_RESULT([disabled])
 401       else
 402         # Check if the provided tool contains a complete path.
 403         tool_specified="[$]$1"
 404         tool_basename="${tool_specified##*/}"
 405         if test "x$tool_basename" = "x$tool_specified"; then
 406           # A command without a complete path is provided, search $PATH.
 407           AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])
 408           AC_PATH_PROG($1, $tool_basename)
 409           if test "x[$]$1" = x; then
 410             AC_MSG_ERROR([User supplied tool $tool_basename could not be found])
 411           fi
 412         else
 413           # Otherwise we believe it is a complete path. Use it as it is.
 414           AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])
 415           AC_MSG_CHECKING([for $1])
 416           if test ! -x "$tool_specified"; then
 417             AC_MSG_RESULT([not found])
 418             AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])
 419           fi
 420           AC_MSG_RESULT([$tool_specified])
 421         fi
 422       fi
 423     fi
 424     $3
 425   fi
 426 ])
 427 
 428 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool
 429 # $1: variable to set
 430 # $2: executable name (or list of names) to look for
 431 # $3: [path]
 432 AC_DEFUN([BASIC_PATH_PROGS],
 433 [
 434   BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2, , $3)])
 435 ])
 436 
 437 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool
 438 # $1: variable to set
 439 # $2: executable name (or list of names) to look for
 440 AC_DEFUN([BASIC_CHECK_TOOLS],
 441 [
 442   BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])
 443 ])
 444 
 445 # Like BASIC_PATH_PROGS but fails if no tool was found.
 446 # $1: variable to set
 447 # $2: executable name (or list of names) to look for
 448 # $3: [path]
 449 AC_DEFUN([BASIC_REQUIRE_PROGS],
 450 [
 451   BASIC_PATH_PROGS($1, $2, , $3)
 452   BASIC_CHECK_NONEMPTY($1)
 453 ])
 454 
 455 # Like BASIC_SETUP_TOOL but fails if no tool was found.
 456 # $1: variable to set
 457 # $2: autoconf macro to call to look for the special tool
 458 AC_DEFUN([BASIC_REQUIRE_SPECIAL],
 459 [
 460   BASIC_SETUP_TOOL($1, [$2])
 461   BASIC_CHECK_NONEMPTY($1)
 462 ])
 463 
 464 # Setup the most fundamental tools that relies on not much else to set up,
 465 # but is used by much of the early bootstrap code.
 466 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
 467 [
 468   # Start with tools that do not need have cross compilation support
 469   # and can be expected to be found in the default PATH. These tools are
 470   # used by configure.
 471 
 472   # First are all the simple required tools.
 473   BASIC_REQUIRE_PROGS(BASENAME, basename)
 474   BASIC_REQUIRE_PROGS(BASH, bash)
 475   BASIC_REQUIRE_PROGS(CAT, cat)
 476   BASIC_REQUIRE_PROGS(CHMOD, chmod)
 477   BASIC_REQUIRE_PROGS(CMP, cmp)
 478   BASIC_REQUIRE_PROGS(COMM, comm)
 479   BASIC_REQUIRE_PROGS(CP, cp)
 480   BASIC_REQUIRE_PROGS(CUT, cut)
 481   BASIC_REQUIRE_PROGS(DATE, date)
 482   BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])
 483   BASIC_REQUIRE_PROGS(DIRNAME, dirname)
 484   BASIC_REQUIRE_PROGS(ECHO, echo)
 485   BASIC_REQUIRE_PROGS(EXPR, expr)
 486   BASIC_REQUIRE_PROGS(FILE, file)
 487   BASIC_REQUIRE_PROGS(FIND, find)
 488   BASIC_REQUIRE_PROGS(HEAD, head)
 489   BASIC_REQUIRE_PROGS(GUNZIP, gunzip)
 490   BASIC_REQUIRE_PROGS(GZIP, pigz gzip)
 491   BASIC_REQUIRE_PROGS(LN, ln)
 492   BASIC_REQUIRE_PROGS(LS, ls)
 493   BASIC_REQUIRE_PROGS(MKDIR, mkdir)
 494   BASIC_REQUIRE_PROGS(MKTEMP, mktemp)
 495   BASIC_REQUIRE_PROGS(MV, mv)
 496   BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])
 497   BASIC_REQUIRE_PROGS(PRINTF, printf)
 498   BASIC_REQUIRE_PROGS(RM, rm)
 499   BASIC_REQUIRE_PROGS(RMDIR, rmdir)
 500   BASIC_REQUIRE_PROGS(SH, sh)
 501   BASIC_REQUIRE_PROGS(SORT, sort)
 502   BASIC_REQUIRE_PROGS(TAIL, tail)
 503   BASIC_REQUIRE_PROGS(TAR, gtar tar)
 504   BASIC_REQUIRE_PROGS(TEE, tee)
 505   BASIC_REQUIRE_PROGS(TOUCH, touch)
 506   BASIC_REQUIRE_PROGS(TR, tr)
 507   BASIC_REQUIRE_PROGS(UNAME, uname)
 508   BASIC_REQUIRE_PROGS(UNIQ, uniq)
 509   BASIC_REQUIRE_PROGS(WC, wc)
 510   BASIC_REQUIRE_PROGS(WHICH, which)
 511   BASIC_REQUIRE_PROGS(XARGS, xargs)
 512 
 513   # Then required tools that require some special treatment.
 514   BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])
 515   BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])
 516   BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])
 517   BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])
 518   BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])
 519 
 520   # Always force rm.
 521   RM="$RM -f"
 522 
 523   # pwd behaves differently on various platforms and some don't support the -L flag.
 524   # Always use the bash builtin pwd to get uniform behavior.
 525   THEPWDCMD=pwd
 526 
 527   # These are not required on all platforms
 528   BASIC_PATH_PROGS(CYGPATH, cygpath)
 529   BASIC_PATH_PROGS(READLINK, [greadlink readlink])
 530   BASIC_PATH_PROGS(DF, df)
 531   BASIC_PATH_PROGS(CPIO, [cpio bsdcpio])
 532   BASIC_PATH_PROGS(NICE, nice)
 533   BASIC_PATH_PROGS(PANDOC, pandoc)
 534 ])
 535 
 536 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
 537 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
 538 [
 539   # Save the current directory this script was started from
 540   CURDIR="$PWD"
 541 
 542   # We might need to rewrite ORIGINAL_PATH, if it includes "#", to quote them
 543   # for make. We couldn't do this when we retrieved ORIGINAL_PATH, since SED
 544   # was not available at that time.
 545   REWRITTEN_PATH=`$ECHO "$ORIGINAL_PATH" | $SED -e 's/#/\\\\#/g'`
 546   if test "x$REWRITTEN_PATH" != "x$ORIGINAL_PATH"; then
 547     ORIGINAL_PATH="$REWRITTEN_PATH"
 548     AC_MSG_NOTICE([Rewriting ORIGINAL_PATH to $REWRITTEN_PATH])
 549   fi
 550 
 551   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
 552     PATH_SEP=";"
 553     BASIC_CHECK_PATHS_WINDOWS
 554   else
 555     PATH_SEP=":"
 556   fi
 557   AC_SUBST(PATH_SEP)
 558 
 559   # We get the top-level directory from the supporting wrappers.
 560   AC_MSG_CHECKING([for top-level directory])
 561   AC_MSG_RESULT([$TOPDIR])
 562   AC_SUBST(TOPDIR)
 563 
 564   # We can only call BASIC_FIXUP_PATH after BASIC_CHECK_PATHS_WINDOWS.
 565   BASIC_FIXUP_PATH(CURDIR)
 566   BASIC_FIXUP_PATH(TOPDIR)
 567 
 568   # Locate the directory of this script.
 569   AUTOCONF_DIR=$TOPDIR/make/autoconf
 570 
 571   # Setup username (for use in adhoc version strings etc)
 572   # Outer [ ] to quote m4.
 573   [ USERNAME=`$ECHO "$USER" | $TR -d -c '[a-z][A-Z][0-9]'` ]
 574   AC_SUBST(USERNAME)
 575 ])
 576 
 577 # Evaluates platform specific overrides for devkit variables.
 578 # $1: Name of variable
 579 AC_DEFUN([BASIC_EVAL_DEVKIT_VARIABLE],
 580 [
 581   if test "x[$]$1" = x; then
 582     eval $1="\${$1_${OPENJDK_TARGET_CPU}}"
 583   fi
 584 ])
 585 
 586 AC_DEFUN_ONCE([BASIC_SETUP_DEVKIT],
 587 [
 588   AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
 589       [use this devkit for compilers, tools and resources])],
 590       [
 591         BASIC_FIXUP_PATH([with_devkit])
 592         DEVKIT_ROOT="$with_devkit"
 593         # Check for a meta data info file in the root of the devkit
 594         if test -f "$DEVKIT_ROOT/devkit.info"; then
 595           . $DEVKIT_ROOT/devkit.info
 596           # This potentially sets the following:
 597           # A descriptive name of the devkit
 598           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_NAME])
 599           # Corresponds to --with-extra-path
 600           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_EXTRA_PATH])
 601           # Corresponds to --with-toolchain-path
 602           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_TOOLCHAIN_PATH])
 603           # Corresponds to --with-sysroot
 604           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_SYSROOT])
 605 
 606           # Identifies the Visual Studio version in the devkit
 607           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_VERSION])
 608           # The Visual Studio include environment variable
 609           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_INCLUDE])
 610           # The Visual Studio lib environment variable
 611           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_VS_LIB])
 612           # Corresponds to --with-msvcr-dll
 613           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCR_DLL])
 614           # Corresponds to --with-msvcp-dll
 615           BASIC_EVAL_DEVKIT_VARIABLE([DEVKIT_MSVCP_DLL])
 616         fi
 617 
 618         AC_MSG_CHECKING([for devkit])
 619         if test "x$DEVKIT_NAME" != x; then
 620           AC_MSG_RESULT([$DEVKIT_NAME in $DEVKIT_ROOT])
 621         else
 622           AC_MSG_RESULT([$DEVKIT_ROOT])
 623         fi
 624 
 625         BASIC_PREPEND_TO_PATH([EXTRA_PATH],$DEVKIT_EXTRA_PATH)
 626 
 627         # Fallback default of just /bin if DEVKIT_PATH is not defined
 628         if test "x$DEVKIT_TOOLCHAIN_PATH" = x; then
 629           DEVKIT_TOOLCHAIN_PATH="$DEVKIT_ROOT/bin"
 630         fi
 631         BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$DEVKIT_TOOLCHAIN_PATH)
 632 
 633         # If DEVKIT_SYSROOT is set, use that, otherwise try a couple of known
 634         # places for backwards compatiblity.
 635         if test "x$DEVKIT_SYSROOT" != x; then
 636           SYSROOT="$DEVKIT_SYSROOT"
 637         elif test -d "$DEVKIT_ROOT/$host_alias/libc"; then
 638           SYSROOT="$DEVKIT_ROOT/$host_alias/libc"
 639         elif test -d "$DEVKIT_ROOT/$host/sys-root"; then
 640           SYSROOT="$DEVKIT_ROOT/$host/sys-root"
 641         fi
 642 
 643         if test "x$DEVKIT_ROOT" != x; then
 644           DEVKIT_LIB_DIR="$DEVKIT_ROOT/lib"
 645           if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
 646             DEVKIT_LIB_DIR="$DEVKIT_ROOT/lib64"
 647           fi
 648           AC_SUBST(DEVKIT_LIB_DIR)
 649         fi
 650       ]
 651   )
 652 
 653   # You can force the sysroot if the sysroot encoded into the compiler tools
 654   # is not correct.
 655   AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
 656       [alias for --with-sysroot for backwards compatability])],
 657       [SYSROOT=$with_sys_root]
 658   )
 659 
 660   AC_ARG_WITH(sysroot, [AS_HELP_STRING([--with-sysroot],
 661       [use this directory as sysroot])],
 662       [SYSROOT=$with_sysroot]
 663   )
 664 
 665   AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
 666       [alias for --with-toolchain-path for backwards compatibility])],
 667       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_tools_dir)]
 668   )
 669 
 670   AC_ARG_WITH([toolchain-path], [AS_HELP_STRING([--with-toolchain-path],
 671       [prepend these directories when searching for toolchain binaries (compilers etc)])],
 672       [BASIC_PREPEND_TO_PATH([TOOLCHAIN_PATH],$with_toolchain_path)]
 673   )
 674 
 675   AC_ARG_WITH([extra-path], [AS_HELP_STRING([--with-extra-path],
 676       [prepend these directories to the default path])],
 677       [BASIC_PREPEND_TO_PATH([EXTRA_PATH],$with_extra_path)]
 678   )
 679 
 680   if test "x$OPENJDK_BUILD_OS" = "xmacosx"; then
 681     # If a devkit has been supplied, find xcodebuild in the toolchain_path.
 682     # If not, detect if Xcode is installed by running xcodebuild -version
 683     # if no Xcode installed, xcodebuild exits with 1
 684     # if Xcode is installed, even if xcode-select is misconfigured, then it exits with 0
 685     if test "x$DEVKIT_ROOT" != x || /usr/bin/xcodebuild -version >/dev/null 2>&1; then
 686       # We need to use xcodebuild in the toolchain dir provided by the user, this will
 687       # fall back on the stub binary in /usr/bin/xcodebuild
 688       AC_PATH_PROG([XCODEBUILD], [xcodebuild], [/usr/bin/xcodebuild], [$TOOLCHAIN_PATH])
 689     else
 690       # this should result in SYSROOT being empty, unless --with-sysroot is provided
 691       # when only the command line tools are installed there are no SDKs, so headers
 692       # are copied into the system frameworks
 693       XCODEBUILD=
 694       AC_SUBST(XCODEBUILD)
 695     fi
 696 
 697     AC_MSG_CHECKING([for sdk name])
 698     AC_ARG_WITH([sdk-name], [AS_HELP_STRING([--with-sdk-name],
 699         [use the platform SDK of the given name. @<:@macosx@:>@])],
 700         [SDKNAME=$with_sdk_name]
 701     )
 702     AC_MSG_RESULT([$SDKNAME])
 703 
 704     # if toolchain path is specified then don't rely on system headers, they may not compile
 705     HAVE_SYSTEM_FRAMEWORK_HEADERS=0
 706     test -z "$TOOLCHAIN_PATH" && \
 707       HAVE_SYSTEM_FRAMEWORK_HEADERS=`test ! -f /System/Library/Frameworks/Foundation.framework/Headers/Foundation.h; echo $?`
 708 
 709     if test -z "$SYSROOT"; then
 710       if test -n "$XCODEBUILD"; then
 711         # if we don't have system headers, use default SDK name (last resort)
 712         if test -z "$SDKNAME" -a $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
 713           SDKNAME=${SDKNAME:-macosx}
 714         fi
 715 
 716         if test -n "$SDKNAME"; then
 717           # Call xcodebuild to determine SYSROOT
 718           SYSROOT=`"$XCODEBUILD" -sdk $SDKNAME -version | $GREP '^Path: ' | $SED 's/Path: //'`
 719         fi
 720       else
 721         if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0; then
 722           AC_MSG_ERROR([No xcodebuild tool and no system framework headers found, use --with-sysroot or --with-sdk-name to provide a path to a valid SDK])
 723         fi
 724       fi
 725     else
 726       # warn user if --with-sdk-name was also set
 727       if test -n "$with_sdk_name"; then
 728         AC_MSG_WARN([Both SYSROOT and --with-sdk-name are set, only SYSROOT will be used])
 729       fi
 730     fi
 731 
 732     if test $HAVE_SYSTEM_FRAMEWORK_HEADERS -eq 0 -a -z "$SYSROOT"; then
 733       # If no system framework headers, then SYSROOT must be set, or we won't build
 734       AC_MSG_ERROR([Unable to determine SYSROOT and no headers found in /System/Library/Frameworks. Check Xcode configuration, --with-sysroot or --with-sdk-name arguments.])
 735     fi
 736 
 737     # Perform a basic sanity test
 738     if test ! -f "$SYSROOT/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then
 739       if test -z "$SYSROOT"; then
 740         AC_MSG_ERROR([Unable to find required framework headers, provide a path to an SDK via --with-sysroot or --with-sdk-name and be sure Xcode is installed properly])
 741       else
 742         AC_MSG_ERROR([Invalid SDK or SYSROOT path, dependent framework headers not found])
 743       fi
 744     fi
 745 
 746     # set SDKROOT too, Xcode tools will pick it up
 747     SDKROOT="$SYSROOT"
 748     AC_SUBST(SDKROOT)
 749   fi
 750 
 751   # Prepend the extra path to the global path
 752   BASIC_PREPEND_TO_PATH([PATH],$EXTRA_PATH)
 753 
 754   AC_MSG_CHECKING([for sysroot])
 755   AC_MSG_RESULT([$SYSROOT])
 756   AC_MSG_CHECKING([for toolchain path])
 757   AC_MSG_RESULT([$TOOLCHAIN_PATH])
 758   AC_MSG_CHECKING([for extra path])
 759   AC_MSG_RESULT([$EXTRA_PATH])
 760 ])
 761 
 762 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
 763 [
 764 
 765   AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
 766       [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
 767       [ CONF_NAME=${with_conf_name} ])
 768 
 769   # Test from where we are running configure, in or outside of src root.
 770   AC_MSG_CHECKING([where to store configuration])
 771   if test "x$CURDIR" = "x$TOPDIR" || test "x$CURDIR" = "x$CUSTOM_ROOT" \
 772       || test "x$CURDIR" = "x$TOPDIR/make/autoconf" \
 773       || test "x$CURDIR" = "x$TOPDIR/make" ; then
 774     # We are running configure from the src root.
 775     # Create a default ./build/target-variant-debuglevel output root.
 776     if test "x${CONF_NAME}" = x; then
 777       AC_MSG_RESULT([in default location])
 778       CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${JVM_VARIANTS_WITH_AND}-${DEBUG_LEVEL}"
 779     else
 780       AC_MSG_RESULT([in build directory with custom name])
 781     fi
 782 
 783     if test "x$CUSTOM_ROOT" != x; then
 784       OUTPUTDIR="${CUSTOM_ROOT}/build/${CONF_NAME}"
 785     else
 786       OUTPUTDIR="${TOPDIR}/build/${CONF_NAME}"
 787     fi
 788     $MKDIR -p "$OUTPUTDIR"
 789     if test ! -d "$OUTPUTDIR"; then
 790       AC_MSG_ERROR([Could not create build directory $OUTPUTDIR])
 791     fi
 792   else
 793     # We are running configure from outside of the src dir.
 794     # Then use the current directory as output dir!
 795     # If configuration is situated in normal build directory, just use the build
 796     # directory name as configuration name, otherwise use the complete path.
 797     if test "x${CONF_NAME}" = x; then
 798       CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${TOPDIR}/build/!!"`
 799     fi
 800     OUTPUTDIR="$CURDIR"
 801     AC_MSG_RESULT([in current directory])
 802 
 803     # WARNING: This might be a bad thing to do. You need to be sure you want to
 804     # have a configuration in this directory. Do some sanity checks!
 805 
 806     if test ! -e "$OUTPUTDIR/spec.gmk"; then
 807       # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
 808       # other files
 809       files_present=`$LS $OUTPUTDIR`
 810       # Configure has already touched config.log and confdefs.h in the current dir when this check
 811       # is performed.
 812       filtered_files=`$ECHO "$files_present" \
 813           | $SED -e 's/config.log//g' \
 814               -e 's/configure.log//g' \
 815               -e 's/confdefs.h//g' \
 816               -e 's/ //g' \
 817           | $TR -d '\n'`
 818       if test "x$filtered_files" != x; then
 819         AC_MSG_NOTICE([Current directory is $CURDIR.])
 820         AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
 821         AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
 822         AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
 823         AC_MSG_NOTICE([seriously mess up just about everything.])
 824         AC_MSG_NOTICE([Try 'cd $TOPDIR' and restart configure])
 825         AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
 826         AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
 827       fi
 828     fi
 829   fi
 830   AC_MSG_CHECKING([what configuration name to use])
 831   AC_MSG_RESULT([$CONF_NAME])
 832 
 833   BASIC_FIXUP_PATH(OUTPUTDIR)
 834 
 835   CONFIGURESUPPORT_OUTPUTDIR="$OUTPUTDIR/configure-support"
 836   $MKDIR -p "$CONFIGURESUPPORT_OUTPUTDIR"
 837 
 838   SPEC="$OUTPUTDIR/spec.gmk"
 839   AC_SUBST(SPEC)
 840   AC_SUBST(CONF_NAME)
 841   AC_SUBST(OUTPUTDIR)
 842   AC_SUBST(CONFIGURESUPPORT_OUTPUTDIR)
 843 
 844   # The spec.gmk file contains all variables for the make system.
 845   AC_CONFIG_FILES([$OUTPUTDIR/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
 846   # The bootcycle-spec.gmk file contains support for boot cycle builds.
 847   AC_CONFIG_FILES([$OUTPUTDIR/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
 848   # The buildjdk-spec.gmk file contains support for building a buildjdk when cross compiling.
 849   AC_CONFIG_FILES([$OUTPUTDIR/buildjdk-spec.gmk:$AUTOCONF_DIR/buildjdk-spec.gmk.in])
 850   # The compare.sh is used to compare the build output to other builds.
 851   AC_CONFIG_FILES([$OUTPUTDIR/compare.sh:$AUTOCONF_DIR/compare.sh.in])
 852   # The generated Makefile knows where the spec.gmk is and where the source is.
 853   # You can run make from the OUTPUTDIR, or from the top-level Makefile
 854   # which will look for generated configurations
 855   AC_CONFIG_FILES([$OUTPUTDIR/Makefile:$AUTOCONF_DIR/Makefile.in])
 856 ])
 857 
 858 #%%% Simple tools %%%
 859 
 860 # Check if we have found a usable version of make
 861 # $1: the path to a potential make binary (or empty)
 862 # $2: the description on how we found this
 863 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
 864 [
 865   MAKE_CANDIDATE="$1"
 866   DESCRIPTION="$2"
 867 
 868   # On Cygwin, we require a newer version of make than on other platforms
 869   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 870     MAKE_VERSION_EXPR="-e 4\."
 871     MAKE_REQUIRED_VERSION="4.0"
 872    else
 873     MAKE_VERSION_EXPR="-e 3\.8[[12]] -e 4\."
 874     MAKE_REQUIRED_VERSION="3.81"
 875   fi
 876 
 877   if test "x$MAKE_CANDIDATE" != x; then
 878     AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
 879     MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
 880     IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
 881     if test "x$IS_GNU_MAKE" = x; then
 882       AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
 883     else
 884       IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP $MAKE_VERSION_EXPR`
 885       if test "x$IS_MODERN_MAKE" = x; then
 886         AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version $MAKE_REQUIRED_VERSION or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
 887       else
 888         if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
 889           if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
 890             MAKE_EXPECTED_ENV='cygwin'
 891           elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
 892             MAKE_EXPECTED_ENV='msys'
 893           else
 894             AC_MSG_ERROR([Unknown Windows environment])
 895           fi
 896           MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
 897           IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
 898         else
 899           # Not relevant for non-Windows
 900           IS_MAKE_CORRECT_ENV=true
 901         fi
 902         if test "x$IS_MAKE_CORRECT_ENV" = x; then
 903           AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
 904         else
 905           FOUND_MAKE=$MAKE_CANDIDATE
 906           BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
 907         fi
 908       fi
 909     fi
 910   fi
 911 ])
 912 
 913 AC_DEFUN([BASIC_CHECK_MAKE_OUTPUT_SYNC],
 914 [
 915   # Check if make supports the output sync option and if so, setup using it.
 916   AC_MSG_CHECKING([if make --output-sync is supported])
 917   if $MAKE --version -O > /dev/null 2>&1; then
 918     OUTPUT_SYNC_SUPPORTED=true
 919     AC_MSG_RESULT([yes])
 920     AC_MSG_CHECKING([for output-sync value])
 921     AC_ARG_WITH([output-sync], [AS_HELP_STRING([--with-output-sync],
 922       [set make output sync type if supported by make. @<:@recurse@:>@])],
 923       [OUTPUT_SYNC=$with_output_sync])
 924     if test "x$OUTPUT_SYNC" = "x"; then
 925       OUTPUT_SYNC=none
 926     fi
 927     AC_MSG_RESULT([$OUTPUT_SYNC])
 928     if ! $MAKE --version -O$OUTPUT_SYNC > /dev/null 2>&1; then
 929       AC_MSG_ERROR([Make did not the support the value $OUTPUT_SYNC as output sync type.])
 930     fi
 931   else
 932     OUTPUT_SYNC_SUPPORTED=false
 933     AC_MSG_RESULT([no])
 934   fi
 935   AC_SUBST(OUTPUT_SYNC_SUPPORTED)
 936   AC_SUBST(OUTPUT_SYNC)
 937 ])
 938 
 939 # Goes looking for a usable version of GNU make.
 940 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
 941 [
 942   BASIC_SETUP_TOOL([MAKE],
 943   [
 944     # Try our hardest to locate a correct version of GNU make
 945     AC_PATH_PROGS(CHECK_GMAKE, gmake)
 946     BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
 947 
 948     if test "x$FOUND_MAKE" = x; then
 949       AC_PATH_PROGS(CHECK_MAKE, make)
 950       BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
 951     fi
 952 
 953     if test "x$FOUND_MAKE" = x; then
 954       if test "x$TOOLCHAIN_PATH" != x; then
 955         # We have a toolchain path, check that as well before giving up.
 956         OLD_PATH=$PATH
 957         PATH=$TOOLCHAIN_PATH:$PATH
 958         AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
 959         BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
 960         if test "x$FOUND_MAKE" = x; then
 961           AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
 962           BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
 963         fi
 964         PATH=$OLD_PATH
 965       fi
 966     fi
 967 
 968     if test "x$FOUND_MAKE" = x; then
 969       AC_MSG_ERROR([Cannot find GNU make $MAKE_REQUIRED_VERSION or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
 970     fi
 971   ],[
 972     # If MAKE was set by user, verify the version
 973     BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
 974     if test "x$FOUND_MAKE" = x; then
 975       AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make $MAKE_REQUIRED_VERSION or newer.])
 976     fi
 977   ])
 978 
 979   MAKE=$FOUND_MAKE
 980   AC_SUBST(MAKE)
 981   AC_MSG_NOTICE([Using GNU make at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
 982 
 983   BASIC_CHECK_MAKE_OUTPUT_SYNC
 984 ])
 985 
 986 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
 987 [
 988   # Test if find supports -delete
 989   AC_MSG_CHECKING([if find supports -delete])
 990   FIND_DELETE="-delete"
 991 
 992   DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
 993 
 994   echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
 995 
 996   TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
 997   if test -f $DELETEDIR/TestIfFindSupportsDelete; then
 998     # No, it does not.
 999     $RM $DELETEDIR/TestIfFindSupportsDelete
1000     if test "x$OPENJDK_TARGET_OS" = "xaix"; then
1001       # AIX 'find' is buggy if called with '-exec {} \+' and an empty file list
1002       FIND_DELETE="-print | $XARGS $RM"
1003     else
1004       FIND_DELETE="-exec $RM \{\} \+"
1005     fi
1006     AC_MSG_RESULT([no])
1007   else
1008     AC_MSG_RESULT([yes])
1009   fi
1010   $RMDIR $DELETEDIR
1011   AC_SUBST(FIND_DELETE)
1012 ])
1013 
1014 AC_DEFUN([BASIC_CHECK_TAR],
1015 [
1016   # Test which kind of tar was found
1017   if test "x$($TAR --version | $GREP "GNU tar")" != "x"; then
1018     TAR_TYPE="gnu"
1019   elif test "x$($TAR --version | $GREP "bsdtar")" != "x"; then
1020     TAR_TYPE="bsd"
1021   elif test "x$($TAR -v | $GREP "bsdtar")" != "x"; then
1022     TAR_TYPE="bsd"
1023   elif test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
1024     TAR_TYPE="solaris"
1025   fi
1026   AC_MSG_CHECKING([what type of tar was found])
1027   AC_MSG_RESULT([$TAR_TYPE])
1028 
1029   TAR_CREATE_FILE_PARAM=""
1030 
1031   if test "x$TAR_TYPE" = "xgnu"; then
1032     TAR_INCLUDE_PARAM="T"
1033     TAR_SUPPORTS_TRANSFORM="true"
1034     if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
1035       # When using gnu tar for Solaris targets, need to use compatibility mode
1036       TAR_CREATE_EXTRA_PARAM="--format=ustar"
1037     fi
1038   else
1039     TAR_INCLUDE_PARAM="I"
1040     TAR_SUPPORTS_TRANSFORM="false"
1041   fi
1042   AC_SUBST(TAR_TYPE)
1043   AC_SUBST(TAR_CREATE_EXTRA_PARAM)
1044   AC_SUBST(TAR_INCLUDE_PARAM)
1045   AC_SUBST(TAR_SUPPORTS_TRANSFORM)
1046 ])
1047 
1048 AC_DEFUN([BASIC_CHECK_GREP],
1049 [
1050   # Test that grep supports -Fx with a list of pattern which includes null pattern.
1051   # This is a problem for the grep resident on AIX.
1052   AC_MSG_CHECKING([that grep ($GREP) -Fx handles empty lines in the pattern list correctly])
1053   # Multiple subsequent spaces..
1054   STACK_SPACES='aaa   bbb   ccc'
1055   # ..converted to subsequent newlines, causes STACK_LIST to be a list with some empty
1056   # patterns in it.
1057   STACK_LIST=${STACK_SPACES// /$'\n'}
1058   NEEDLE_SPACES='ccc bbb aaa'
1059   NEEDLE_LIST=${NEEDLE_SPACES// /$'\n'}
1060   RESULT="$($GREP -Fvx "$STACK_LIST" <<< "$NEEDLE_LIST")"
1061   if test "x$RESULT" == "x"; then
1062     AC_MSG_RESULT([yes])
1063   else
1064     if test "x$OPENJDK_TARGET_OS" = "xaix"; then
1065       ADDINFO="Please make sure you use GNU grep, usually found at /opt/freeware/bin."
1066     fi
1067     AC_MSG_ERROR([grep does not handle -Fx correctly. ${ADDINFO}])
1068   fi
1069 ])
1070 
1071 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
1072 [
1073   BASIC_CHECK_GNU_MAKE
1074 
1075   BASIC_CHECK_FIND_DELETE
1076   BASIC_CHECK_TAR
1077   BASIC_CHECK_GREP
1078 
1079   # These tools might not be installed by default,
1080   # need hint on how to install them.
1081   BASIC_REQUIRE_PROGS(UNZIP, unzip)
1082   # Since zip uses "ZIP" as a environment variable for passing options, we need
1083   # to name our variable differently, hence ZIPEXE.
1084   BASIC_REQUIRE_PROGS(ZIPEXE, zip)
1085 
1086   # Non-required basic tools
1087 
1088   BASIC_PATH_PROGS(LDD, ldd)
1089   if test "x$LDD" = "x"; then
1090     # List shared lib dependencies is used for
1091     # debug output and checking for forbidden dependencies.
1092     # We can build without it.
1093     LDD="true"
1094   fi
1095   BASIC_PATH_PROGS(READELF, [greadelf readelf])
1096   BASIC_PATH_PROGS(DOT, dot)
1097   BASIC_PATH_PROGS(HG, hg)
1098   BASIC_PATH_PROGS(STAT, stat)
1099   BASIC_PATH_PROGS(TIME, time)
1100   BASIC_PATH_PROGS(FLOCK, flock)
1101   # Dtrace is usually found in /usr/sbin on Solaris, but that directory may not
1102   # be in the user path.
1103   BASIC_PATH_PROGS(DTRACE, dtrace, $PATH:/usr/sbin)
1104   BASIC_PATH_PROGS(PATCH, [gpatch patch])
1105   # Check if it's GNU time
1106   IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
1107   if test "x$IS_GNU_TIME" != x; then
1108     IS_GNU_TIME=yes
1109   else
1110     IS_GNU_TIME=no
1111   fi
1112   AC_SUBST(IS_GNU_TIME)
1113 
1114   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
1115     BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)
1116     BASIC_REQUIRE_PROGS(XATTR, xattr)
1117     BASIC_PATH_PROGS(CODESIGN, codesign)
1118     if test "x$CODESIGN" != "x"; then
1119       # Verify that the openjdk_codesign certificate is present
1120       AC_MSG_CHECKING([if openjdk_codesign certificate is present])
1121       $RM codesign-testfile
1122       $TOUCH codesign-testfile
1123       $CODESIGN -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
1124       $RM codesign-testfile
1125       if test "x$CODESIGN" = x; then
1126         AC_MSG_RESULT([no])
1127       else
1128         AC_MSG_RESULT([yes])
1129       fi
1130     fi
1131     BASIC_REQUIRE_PROGS(SETFILE, SetFile)
1132   fi
1133 ])
1134 
1135 # Check if build directory is on local disk. If not possible to determine,
1136 # we prefer to claim it's local.
1137 # Argument 1: directory to test
1138 # Argument 2: what to do if it is on local disk
1139 # Argument 3: what to do otherwise (remote disk or failure)
1140 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
1141 [
1142   # df -l lists only local disks; if the given directory is not found then
1143   # a non-zero exit code is given
1144   if test "x$DF" = x; then
1145     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
1146       # msys does not have df; use Windows "net use" instead.
1147       IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
1148       if test "x$IS_NETWORK_DISK" = x; then
1149         $2
1150       else
1151         $3
1152       fi
1153     else
1154       # No df here, say it's local
1155       $2
1156     fi
1157   else
1158     # JDK-8189619
1159     # df on AIX does not understand -l. On modern AIXes it understands "-T local" which
1160     # is the same. On older AIXes we just continue to live with a "not local build" warning.
1161     if test "x$OPENJDK_TARGET_OS" = xaix; then
1162       DF_LOCAL_ONLY_OPTION='-T local'
1163     else
1164       DF_LOCAL_ONLY_OPTION='-l'
1165     fi
1166     if $DF $DF_LOCAL_ONLY_OPTION $1 > /dev/null 2>&1; then
1167       $2
1168     else
1169       $3
1170     fi
1171   fi
1172 ])
1173 
1174 # Check that source files have basic read permissions set. This might
1175 # not be the case in cygwin in certain conditions.
1176 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
1177 [
1178   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
1179     file_to_test="$TOPDIR/LICENSE"
1180     if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
1181       AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
1182     fi
1183   fi
1184 ])
1185 
1186 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
1187 [
1188   # Did user specify any unknown variables?
1189   BASIC_CHECK_LEFTOVER_OVERRIDDEN
1190 
1191   AC_MSG_CHECKING([if build directory is on local disk])
1192   BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUTDIR,
1193       [OUTPUT_DIR_IS_LOCAL="yes"],
1194       [OUTPUT_DIR_IS_LOCAL="no"])
1195   AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
1196 
1197   BASIC_CHECK_SRC_PERMS
1198 
1199   # Check if the user has any old-style ALT_ variables set.
1200   FOUND_ALT_VARIABLES=`env | grep ^ALT_`
1201 
1202   # Before generating output files, test if they exist. If they do, this is a reconfigure.
1203   # Since we can't properly handle the dependencies for this, warn the user about the situation
1204   if test -e $OUTPUTDIR/spec.gmk; then
1205     IS_RECONFIGURE=yes
1206   else
1207     IS_RECONFIGURE=no
1208   fi
1209 ])
1210 
1211 # Check for support for specific options in bash
1212 AC_DEFUN_ONCE([BASIC_CHECK_BASH_OPTIONS],
1213 [
1214   # Check bash version
1215   # Extra [ ] to stop m4 mangling
1216   [ BASH_VER=`$BASH --version | $SED -n  -e 's/^.*bash.*ersion *\([0-9.]*\).*$/\1/ p'` ]
1217   AC_MSG_CHECKING([bash version])
1218   AC_MSG_RESULT([$BASH_VER])
1219 
1220   BASH_MAJOR=`$ECHO $BASH_VER | $CUT -d . -f 1`
1221   BASH_MINOR=`$ECHO $BASH_VER | $CUT -d . -f 2`
1222   if test $BASH_MAJOR -lt 3 || (test $BASH_MAJOR -eq 3 && test $BASH_MINOR -lt 2); then
1223     AC_MSG_ERROR([bash version 3.2 or better is required])
1224   fi
1225 
1226   # Test if bash supports pipefail.
1227   AC_MSG_CHECKING([if bash supports pipefail])
1228   if ${BASH} -c 'set -o pipefail'; then
1229     BASH_ARGS="$BASH_ARGS -o pipefail"
1230     AC_MSG_RESULT([yes])
1231   else
1232     AC_MSG_RESULT([no])
1233   fi
1234 
1235   AC_MSG_CHECKING([if bash supports errexit (-e)])
1236   if ${BASH} -e -c 'true'; then
1237     BASH_ARGS="$BASH_ARGS -e"
1238     AC_MSG_RESULT([yes])
1239   else
1240     AC_MSG_RESULT([no])
1241   fi
1242 
1243   AC_SUBST(BASH_ARGS)
1244 ])
1245 
1246 ################################################################################
1247 #
1248 # Default make target
1249 #
1250 AC_DEFUN_ONCE([BASIC_SETUP_DEFAULT_MAKE_TARGET],
1251 [
1252   AC_ARG_WITH(default-make-target, [AS_HELP_STRING([--with-default-make-target],
1253       [set the default make target @<:@exploded-image@:>@])])
1254   if test "x$with_default_make_target" = "x" \
1255       || test "x$with_default_make_target" = "xyes"; then
1256     DEFAULT_MAKE_TARGET="exploded-image"
1257   elif test "x$with_default_make_target" = "xno"; then
1258     AC_MSG_ERROR([--without-default-make-target is not a valid option])
1259   else
1260     DEFAULT_MAKE_TARGET="$with_default_make_target"
1261   fi
1262 
1263   AC_SUBST(DEFAULT_MAKE_TARGET)
1264 ])
1265 
1266 # Code to run after AC_OUTPUT
1267 AC_DEFUN_ONCE([BASIC_POST_CONFIG_OUTPUT],
1268 [
1269   # Try to move config.log (generated by autoconf) to the configure-support directory.
1270   if test -e ./config.log; then
1271     $MV -f ./config.log "$CONFIGURESUPPORT_OUTPUTDIR/config.log" 2> /dev/null
1272   fi
1273 
1274   # Rotate our log file (configure.log)
1275   if test -e "$OUTPUTDIR/configure.log.old"; then
1276     $RM -f "$OUTPUTDIR/configure.log.old"
1277   fi
1278   if test -e "$OUTPUTDIR/configure.log"; then
1279     $MV -f "$OUTPUTDIR/configure.log" "$OUTPUTDIR/configure.log.old" 2> /dev/null
1280   fi
1281 
1282   # Move configure.log from current directory to the build output root
1283   if test -e ./configure.log; then
1284     $MV -f ./configure.log "$OUTPUTDIR/configure.log" 2> /dev/null
1285   fi
1286 
1287   # Make the compare script executable
1288   $CHMOD +x $OUTPUTDIR/compare.sh
1289 ])