1 #
2 # Copyright (c) 2011, 2017, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
25
26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
27 # Converts autoconf style CPU name to OpenJDK style, into
28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
30 [
31 # First argument is the cpu name from the trip/quad
32 case "$1" in
33 x86_64)
34 VAR_CPU=x86_64
35 VAR_CPU_ARCH=x86
36 VAR_CPU_BITS=64
37 VAR_CPU_ENDIAN=little
38 ;;
39 i?86)
40 VAR_CPU=x86
41 VAR_CPU_ARCH=x86
42 VAR_CPU_BITS=32
43 VAR_CPU_ENDIAN=little
44 ;;
45 alpha*)
46 VAR_CPU=alpha
47 VAR_CPU_ARCH=alpha
48 VAR_CPU_BITS=64
49 VAR_CPU_ENDIAN=little
50 ;;
51 arm*)
52 VAR_CPU=arm
53 VAR_CPU_ARCH=arm
54 VAR_CPU_BITS=32
55 VAR_CPU_ENDIAN=little
56 ;;
57 aarch64)
58 VAR_CPU=aarch64
59 VAR_CPU_ARCH=aarch64
60 VAR_CPU_BITS=64
61 VAR_CPU_ENDIAN=little
62 ;;
63 m68k)
64 VAR_CPU=m68k
65 VAR_CPU_ARCH=m68k
66 VAR_CPU_BITS=32
67 VAR_CPU_ENDIAN=big
68 ;;
69 mips)
70 VAR_CPU=mips
71 VAR_CPU_ARCH=mips
72 VAR_CPU_BITS=32
73 VAR_CPU_ENDIAN=big
74 ;;
75 mipsel)
76 VAR_CPU=mipsel
77 VAR_CPU_ARCH=mipsel
78 VAR_CPU_BITS=32
79 VAR_CPU_ENDIAN=little
80 ;;
81 mips64)
82 VAR_CPU=mips64
83 VAR_CPU_ARCH=mips64
84 VAR_CPU_BITS=64
85 VAR_CPU_ENDIAN=big
86 ;;
87 mips64el)
88 VAR_CPU=mips64el
89 VAR_CPU_ARCH=mips64el
90 VAR_CPU_BITS=64
91 VAR_CPU_ENDIAN=little
92 ;;
93 powerpc)
94 VAR_CPU=ppc
95 VAR_CPU_ARCH=ppc
96 VAR_CPU_BITS=32
97 VAR_CPU_ENDIAN=big
98 ;;
99 powerpc64)
100 VAR_CPU=ppc64
101 VAR_CPU_ARCH=ppc
102 VAR_CPU_BITS=64
103 VAR_CPU_ENDIAN=big
104 ;;
105 powerpc64le)
106 VAR_CPU=ppc64le
107 VAR_CPU_ARCH=ppc
108 VAR_CPU_BITS=64
109 VAR_CPU_ENDIAN=little
110 ;;
111 s390)
112 VAR_CPU=s390
113 VAR_CPU_ARCH=s390
114 VAR_CPU_BITS=32
115 VAR_CPU_ENDIAN=big
116 ;;
117 s390x)
118 VAR_CPU=s390x
119 VAR_CPU_ARCH=s390
120 VAR_CPU_BITS=64
121 VAR_CPU_ENDIAN=big
122 ;;
123 sh*eb)
124 VAR_CPU=sh
125 VAR_CPU_ARCH=sh
126 VAR_CPU_BITS=32
127 VAR_CPU_ENDIAN=big
128 ;;
129 sh*)
130 VAR_CPU=sh
131 VAR_CPU_ARCH=sh
132 VAR_CPU_BITS=32
133 VAR_CPU_ENDIAN=little
134 ;;
135 sparc)
136 VAR_CPU=sparc
137 VAR_CPU_ARCH=sparc
138 VAR_CPU_BITS=32
139 VAR_CPU_ENDIAN=big
140 ;;
141 sparcv9|sparc64)
142 VAR_CPU=sparcv9
143 VAR_CPU_ARCH=sparc
144 VAR_CPU_BITS=64
145 VAR_CPU_ENDIAN=big
146 ;;
147 *)
148 AC_MSG_ERROR([unsupported cpu $1])
149 ;;
150 esac
151 ])
152
153 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
154 # Converts autoconf style OS name to OpenJDK style, into
155 # VAR_OS, VAR_OS_TYPE and VAR_OS_ENV.
156 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
157 [
158 case "$1" in
159 *linux*)
160 VAR_OS=linux
161 VAR_OS_TYPE=unix
162 ;;
163 *solaris*)
164 VAR_OS=solaris
165 VAR_OS_TYPE=unix
166 ;;
167 *darwin*)
168 VAR_OS=macosx
169 VAR_OS_TYPE=unix
170 ;;
171 *bsd*)
172 VAR_OS=bsd
173 VAR_OS_TYPE=unix
174 ;;
175 *cygwin*)
176 VAR_OS=windows
177 VAR_OS_ENV=windows.cygwin
178 ;;
179 *mingw*)
180 VAR_OS=windows
181 VAR_OS_ENV=windows.msys
182 ;;
183 *wsl*)
184 VAR_OS=windows
185 VAR_OS_ENV=windows.wsl
186 ;;
187 *aix*)
188 VAR_OS=aix
189 VAR_OS_TYPE=unix
190 ;;
191 *)
192 AC_MSG_ERROR([unsupported operating system $1])
193 ;;
194 esac
195 ])
196
197 # Expects $host_os $host_cpu $build_os and $build_cpu
198 # and $with_target_bits to have been setup!
199 #
200 # Translate the standard triplet(quadruplet) definition
201 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
202 # OPENJDK_BUILD_OS, etc.
203 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
204 [
205 # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
206 # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
207 # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
208 # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
209 OPENJDK_TARGET_AUTOCONF_NAME="$host"
210 OPENJDK_BUILD_AUTOCONF_NAME="$build"
211 AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
212 AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
213
214 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
215 PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
216 PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
217 # ..and setup our own variables. (Do this explicitly to facilitate searching)
218 OPENJDK_BUILD_OS="$VAR_OS"
219 if test "x$VAR_OS_TYPE" != x; then
220 OPENJDK_BUILD_OS_TYPE="$VAR_OS_TYPE"
221 else
222 OPENJDK_BUILD_OS_TYPE="$VAR_OS"
223 fi
224 if test "x$VAR_OS_ENV" != x; then
225 OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
226 else
227 OPENJDK_BUILD_OS_ENV="$VAR_OS"
228 fi
229 OPENJDK_BUILD_CPU="$VAR_CPU"
230 OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
231 OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
232 OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
233 AC_SUBST(OPENJDK_BUILD_OS)
234 AC_SUBST(OPENJDK_BUILD_OS_TYPE)
235 AC_SUBST(OPENJDK_BUILD_OS_ENV)
236 AC_SUBST(OPENJDK_BUILD_CPU)
237 AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
238 AC_SUBST(OPENJDK_BUILD_CPU_BITS)
239 AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
240
241 AC_MSG_CHECKING([openjdk-build os-cpu])
242 AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
243
244 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
245 PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
246 PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
247 # ... and setup our own variables. (Do this explicitly to facilitate searching)
248 OPENJDK_TARGET_OS="$VAR_OS"
249 if test "x$VAR_OS_TYPE" != x; then
250 OPENJDK_TARGET_OS_TYPE="$VAR_OS_TYPE"
251 else
252 OPENJDK_TARGET_OS_TYPE="$VAR_OS"
253 fi
254 if test "x$VAR_OS_ENV" != x; then
255 OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
256 else
257 OPENJDK_TARGET_OS_ENV="$VAR_OS"
258 fi
259 OPENJDK_TARGET_CPU="$VAR_CPU"
260 OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
261 OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
262 OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
263 AC_SUBST(OPENJDK_TARGET_OS)
264 AC_SUBST(OPENJDK_TARGET_OS_TYPE)
265 AC_SUBST(OPENJDK_TARGET_OS_ENV)
266 AC_SUBST(OPENJDK_TARGET_CPU)
267 AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
268 AC_SUBST(OPENJDK_TARGET_CPU_BITS)
269 AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
270
271 AC_MSG_CHECKING([openjdk-target os-cpu])
272 AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
273 ])
274
275 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
276 # accordingly. Must be done after setting up build and target system, but before
277 # doing anything else with these values.
278 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
279 [
280 AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
281 [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
282
283 # We have three types of compiles:
284 # native == normal compilation, target system == build system
285 # cross == traditional cross compilation, target system != build system; special toolchain needed
286 # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
287 #
288 if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
289 # We're doing a proper cross-compilation
290 COMPILE_TYPE="cross"
291 else
292 COMPILE_TYPE="native"
293 fi
294
295 if test "x$with_target_bits" != x; then
296 if test "x$COMPILE_TYPE" = "xcross"; then
297 AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
298 fi
299
300 if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
301 # A reduced build is requested
302 COMPILE_TYPE="reduced"
303 OPENJDK_TARGET_CPU_BITS=32
304 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
305 OPENJDK_TARGET_CPU=x86
306 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
307 OPENJDK_TARGET_CPU=sparc
308 else
309 AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
310 fi
311 elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
312 AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
313 elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
314 AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
315 else
316 AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
317 fi
318 fi
319 AC_SUBST(COMPILE_TYPE)
320
321 AC_MSG_CHECKING([compilation type])
322 AC_MSG_RESULT([$COMPILE_TYPE])
323 ])
324
325 # Setup the legacy variables, for controlling the old makefiles.
326 #
327 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
328 [
329 PLATFORM_SETUP_LEGACY_VARS_HELPER([TARGET])
330 PLATFORM_SETUP_LEGACY_VARS_HELPER([BUILD])
331 ])
332
333 # $1 - Either TARGET or BUILD to setup the variables for.
334 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS_HELPER],
335 [
336 # Also store the legacy naming of the cpu.
337 # Ie i586 and amd64 instead of x86 and x86_64
338 OPENJDK_$1_CPU_LEGACY="$OPENJDK_$1_CPU"
339 if test "x$OPENJDK_$1_CPU" = xx86; then
340 OPENJDK_$1_CPU_LEGACY="i586"
341 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
342 # On all platforms except MacOSX replace x86_64 with amd64.
343 OPENJDK_$1_CPU_LEGACY="amd64"
344 elif test "x$OPENJDK_$1_CPU" = xalpha; then
345 # Avoid name collisions with variables named alpha
346 OPENJDK_$1_CPU_LEGACY="_alpha_"
347 elif test "x$OPENJDK_$1_CPU" = xsh; then
348 # Avoid name collisions with variables named sh
349 OPENJDK_$1_CPU_LEGACY="_sh_"
350 fi
351 AC_SUBST(OPENJDK_$1_CPU_LEGACY)
352
353 # And the second legacy naming of the cpu.
354 # Ie i386 and amd64 instead of x86 and x86_64.
355 OPENJDK_$1_CPU_LEGACY_LIB="$OPENJDK_$1_CPU"
356 if test "x$OPENJDK_$1_CPU" = xx86; then
357 OPENJDK_$1_CPU_LEGACY_LIB="i386"
358 elif test "x$OPENJDK_$1_CPU" = xx86_64; then
359 OPENJDK_$1_CPU_LEGACY_LIB="amd64"
360 fi
361 AC_SUBST(OPENJDK_$1_CPU_LEGACY_LIB)
362
363 # OPENJDK_$1_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
364 # /amd64 or /sparcv9. This string is appended to some library paths, like this:
365 # /usr/lib${OPENJDK_$1_CPU_ISADIR}/libexample.so
366 OPENJDK_$1_CPU_ISADIR=""
367 if test "x$OPENJDK_$1_OS" = xsolaris; then
368 if test "x$OPENJDK_$1_CPU" = xx86_64; then
369 OPENJDK_$1_CPU_ISADIR="/amd64"
370 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
371 OPENJDK_$1_CPU_ISADIR="/sparcv9"
372 fi
373 fi
374 AC_SUBST(OPENJDK_$1_CPU_ISADIR)
375
376 # Setup OPENJDK_$1_CPU_OSARCH, which is used to set the os.arch Java system property
377 OPENJDK_$1_CPU_OSARCH="$OPENJDK_$1_CPU"
378 if test "x$OPENJDK_$1_OS" = xlinux && test "x$OPENJDK_$1_CPU" = xx86; then
379 # On linux only, we replace x86 with i386.
380 OPENJDK_$1_CPU_OSARCH="i386"
381 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
382 # On all platforms except macosx, we replace x86_64 with amd64.
383 OPENJDK_$1_CPU_OSARCH="amd64"
384 fi
385 AC_SUBST(OPENJDK_$1_CPU_OSARCH)
386
387 OPENJDK_$1_CPU_JLI="$OPENJDK_$1_CPU"
388 if test "x$OPENJDK_$1_CPU" = xx86; then
389 OPENJDK_$1_CPU_JLI="i386"
390 elif test "x$OPENJDK_$1_OS" != xmacosx && test "x$OPENJDK_$1_CPU" = xx86_64; then
391 # On all platforms except macosx, we replace x86_64 with amd64.
392 OPENJDK_$1_CPU_JLI="amd64"
393 fi
394
395 # The new version string in JDK 9 also defined new naming of OS and ARCH for bundles
396 # Macosx is osx and x86_64 is x64
397 if test "x$OPENJDK_$1_OS" = xmacosx; then
398 OPENJDK_$1_OS_BUNDLE="osx"
399 else
400 OPENJDK_$1_OS_BUNDLE="$OPENJDK_TARGET_OS"
401 fi
402 if test "x$OPENJDK_$1_CPU" = xx86_64; then
403 OPENJDK_$1_CPU_BUNDLE="x64"
404 else
405 OPENJDK_$1_CPU_BUNDLE="$OPENJDK_$1_CPU"
406 fi
407 OPENJDK_$1_BUNDLE_PLATFORM="${OPENJDK_$1_OS_BUNDLE}-${OPENJDK_$1_CPU_BUNDLE}"
408 AC_SUBST(OPENJDK_$1_BUNDLE_PLATFORM)
409
410 if test "x$OPENJDK_$1_CPU_BITS" = x64; then
411 # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
412 # unpack200.exe. This variable is used in
413 # FLAGS_SETUP_COMPILER_FLAGS_FOR_JDK_HELPER.
414 if test "x$OPENJDK_$1_OS" = xlinux || test "x$OPENJDK_$1_OS" = xmacosx; then
415 OPENJDK_$1_ADD_LP64="-D_LP64=1"
416 fi
417 fi
418
419 if test "x$COMPILE_TYPE" = "xcross"; then
420 # FIXME: ... or should this include reduced builds..?
421 DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_$1_CPU_LEGACY"
422 else
423 DEFINE_CROSS_COMPILE_ARCH=""
424 fi
425 AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
426
427 # Convert openjdk platform names to hotspot names
428
429 HOTSPOT_$1_OS=${OPENJDK_$1_OS}
430 if test "x$OPENJDK_$1_OS" = xmacosx; then
431 HOTSPOT_$1_OS=bsd
432 fi
433 AC_SUBST(HOTSPOT_$1_OS)
434
435 HOTSPOT_$1_OS_TYPE=${OPENJDK_$1_OS_TYPE}
436 if test "x$OPENJDK_$1_OS_TYPE" = xunix; then
437 HOTSPOT_$1_OS_TYPE=posix
438 fi
439 AC_SUBST(HOTSPOT_$1_OS_TYPE)
440
441 HOTSPOT_$1_CPU=${OPENJDK_$1_CPU}
442 if test "x$OPENJDK_$1_CPU" = xx86; then
443 HOTSPOT_$1_CPU=x86_32
444 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
445 HOTSPOT_$1_CPU=sparc
446 elif test "x$OPENJDK_$1_CPU" = xppc64; then
447 HOTSPOT_$1_CPU=ppc_64
448 elif test "x$OPENJDK_$1_CPU" = xppc64le; then
449 HOTSPOT_$1_CPU=ppc_64
450 fi
451 AC_SUBST(HOTSPOT_$1_CPU)
452
453 # This is identical with OPENJDK_*, but define anyway for consistency.
454 HOTSPOT_$1_CPU_ARCH=${OPENJDK_$1_CPU_ARCH}
455 AC_SUBST(HOTSPOT_$1_CPU_ARCH)
456
457 # Setup HOTSPOT_$1_CPU_DEFINE
458 if test "x$OPENJDK_$1_CPU" = xx86; then
459 HOTSPOT_$1_CPU_DEFINE=IA32
460 elif test "x$OPENJDK_$1_CPU" = xx86_64; then
461 HOTSPOT_$1_CPU_DEFINE=AMD64
462 elif test "x$OPENJDK_$1_CPU" = xsparcv9; then
463 HOTSPOT_$1_CPU_DEFINE=SPARC
464 elif test "x$OPENJDK_$1_CPU" = xaarch64; then
465 HOTSPOT_$1_CPU_DEFINE=AARCH64
466 elif test "x$OPENJDK_$1_CPU" = xppc64; then
467 HOTSPOT_$1_CPU_DEFINE=PPC64
468 elif test "x$OPENJDK_$1_CPU" = xppc64le; then
469 HOTSPOT_$1_CPU_DEFINE=PPC64
470
471 # The cpu defines below are for zero, we don't support them directly.
472 elif test "x$OPENJDK_$1_CPU" = xsparc; then
473 HOTSPOT_$1_CPU_DEFINE=SPARC
474 elif test "x$OPENJDK_$1_CPU" = xppc; then
475 HOTSPOT_$1_CPU_DEFINE=PPC32
476 elif test "x$OPENJDK_$1_CPU" = xs390; then
477 HOTSPOT_$1_CPU_DEFINE=S390
478 elif test "x$OPENJDK_$1_CPU" = xs390x; then
479 HOTSPOT_$1_CPU_DEFINE=S390
480 elif test "x$OPENJDK_$1_CPU" != x; then
481 HOTSPOT_$1_CPU_DEFINE=$(echo $OPENJDK_$1_CPU | tr a-z A-Z)
482 fi
483 AC_SUBST(HOTSPOT_$1_CPU_DEFINE)
484
485 # For historical reasons, the OS include directories have odd names.
486 OPENJDK_$1_OS_INCLUDE_SUBDIR="$OPENJDK_TARGET_OS"
487 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
488 OPENJDK_$1_OS_INCLUDE_SUBDIR="win32"
489 elif test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
490 OPENJDK_$1_OS_INCLUDE_SUBDIR="darwin"
491 fi
492 AC_SUBST(OPENJDK_$1_OS_INCLUDE_SUBDIR)
493 ])
494
495 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
496 [
497 if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
498 RELEASE_FILE_OS_NAME=SunOS
499 fi
500 if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
501 RELEASE_FILE_OS_NAME=Linux
502 fi
503 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
504 RELEASE_FILE_OS_NAME=Windows
505 fi
506 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
507 RELEASE_FILE_OS_NAME="Darwin"
508 fi
509 if test "x$OPENJDK_TARGET_OS" = "xaix"; then
510 RELEASE_FILE_OS_NAME="AIX"
511 fi
512 RELEASE_FILE_OS_ARCH=${OPENJDK_TARGET_CPU}
513
514 AC_SUBST(RELEASE_FILE_OS_NAME)
515 AC_SUBST(RELEASE_FILE_OS_ARCH)
516 ])
517
518 AC_DEFUN([PLATFORM_SET_MODULE_TARGET_OS_VALUES],
519 [
520 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
521 OPENJDK_MODULE_TARGET_OS_NAME="macos"
522 else
523 OPENJDK_MODULE_TARGET_OS_NAME="$OPENJDK_TARGET_OS"
524 fi
525
526 if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
527 OPENJDK_MODULE_TARGET_OS_ARCH="amd64"
528 else
529 OPENJDK_MODULE_TARGET_OS_ARCH="$OPENJDK_TARGET_CPU"
530 fi
531
532 OPENJDK_MODULE_TARGET_PLATFORM="${OPENJDK_MODULE_TARGET_OS_NAME}-${OPENJDK_MODULE_TARGET_OS_ARCH}"
533 AC_SUBST(OPENJDK_MODULE_TARGET_PLATFORM)
534 ])
535
536 #%%% Build and target systems %%%
537 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
538 [
539 # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
540 # is confusing; it assumes you are cross-compiling a cross-compiler (!) and "target" is thus the target of the
541 # product you're building. The target of this build is called "host". Since this is confusing to most people, we
542 # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
543 # to use the configure naming style.
544 AC_CANONICAL_BUILD
545 AC_CANONICAL_HOST
546 AC_CANONICAL_TARGET
547
548 PLATFORM_EXTRACT_TARGET_AND_BUILD
549 PLATFORM_SETUP_TARGET_CPU_BITS
550 PLATFORM_SET_MODULE_TARGET_OS_VALUES
551 PLATFORM_SET_RELEASE_FILE_OS_VALUES
552 PLATFORM_SETUP_LEGACY_VARS
553 ])
554
555 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
556 [
557 ###############################################################################
558
559 # Note that this is the build platform OS version!
560
561 OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
562 OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
563 OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
564 OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
565 AC_SUBST(OS_VERSION_MAJOR)
566 AC_SUBST(OS_VERSION_MINOR)
567 AC_SUBST(OS_VERSION_MICRO)
568 ])
569
570 # Support macro for PLATFORM_SETUP_OPENJDK_TARGET_BITS.
571 # Add -mX to various FLAGS variables.
572 AC_DEFUN([PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS],
573 [
574 # When we add flags to the "official" CFLAGS etc, we need to
575 # keep track of these additions in ADDED_CFLAGS etc. These
576 # will later be checked to make sure only controlled additions
577 # have been made to CFLAGS etc.
578 ADDED_CFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
579 ADDED_CXXFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
580 ADDED_LDFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
581
582 CFLAGS="${CFLAGS}${ADDED_CFLAGS}"
583 CXXFLAGS="${CXXFLAGS}${ADDED_CXXFLAGS}"
584 LDFLAGS="${LDFLAGS}${ADDED_LDFLAGS}"
585
586 CFLAGS_JDK="${CFLAGS_JDK}${ADDED_CFLAGS}"
587 CXXFLAGS_JDK="${CXXFLAGS_JDK}${ADDED_CXXFLAGS}"
588 LDFLAGS_JDK="${LDFLAGS_JDK}${ADDED_LDFLAGS}"
589
590 JVM_CFLAGS="$JVM_CFLAGS $ADDED_CFLAGS"
591 JVM_LDFLAGS="$JVM_LDFLAGS $ADDED_LDFLAGS"
592 JVM_ASFLAGS="$JVM_ASFLAGS $ADDED_CFLAGS"
593 ])
594
595 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
596 [
597 ###############################################################################
598 #
599 # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
600 # (The JVM can use 32 or 64 bit Java pointers but that decision
601 # is made at runtime.)
602 #
603
604 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xaix; then
605 # Always specify -m flag on Solaris
606 # And -q on AIX because otherwise the compiler produces 32-bit objects by default
607 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
608 elif test "x$COMPILE_TYPE" = xreduced; then
609 if test "x$OPENJDK_TARGET_OS_TYPE" = xunix; then
610 # Specify -m if running reduced on unix platforms
611 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
612 fi
613 fi
614 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
615 JVM_CFLAGS="$JVM_CFLAGS ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
616 JVM_LDFLAGS="$JVM_LDFLAGS ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
617 JVM_ASFLAGS="$JVM_ASFLAGS ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
618 fi
619
620 # Make compilation sanity check
621 AC_CHECK_HEADERS([stdio.h], , [
622 AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
623 if test "x$COMPILE_TYPE" = xreduced; then
624 HELP_MSG_MISSING_DEPENDENCY([reduced])
625 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
626 elif test "x$COMPILE_TYPE" = xcross; then
627 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
628 fi
629 AC_MSG_ERROR([Cannot continue.])
630 ])
631
632 AC_CHECK_SIZEOF([int *], [1111])
633
634 # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
635 if test "x$ac_cv_sizeof_int_p" = x; then
636 # The test failed, lets stick to the assumed value.
637 AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
638 else
639 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
640
641 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
642 # This situation may happen on 64-bit platforms where the compiler by default only generates 32-bit objects
643 # Let's try to implicitely set the compilers target architecture and retry the test
644 AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS).])
645 AC_MSG_NOTICE([Retrying with platforms compiler target bits flag to ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}])
646 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
647
648 # We have to unset 'ac_cv_sizeof_int_p' first, otherwise AC_CHECK_SIZEOF will use the previously cached value!
649 unset ac_cv_sizeof_int_p
650 # And we have to undef the definition of SIZEOF_INT_P in confdefs.h by the previous invocation of AC_CHECK_SIZEOF
651 cat >>confdefs.h <<_ACEOF
652 #undef SIZEOF_INT_P
653 _ACEOF
654
655 AC_CHECK_SIZEOF([int *], [1111])
656
657 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
658
659 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
660 AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
661 if test "x$COMPILE_TYPE" = xreduced; then
662 HELP_MSG_MISSING_DEPENDENCY([reduced])
663 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed. $HELP_MSG])
664 elif test "x$COMPILE_TYPE" = xcross; then
665 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
666 fi
667 AC_MSG_ERROR([Cannot continue.])
668 fi
669 fi
670 fi
671
672 AC_MSG_CHECKING([for target address size])
673 AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
674 ])
675
676 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
677 [
678 ###############################################################################
679 #
680 # Is the target little of big endian?
681 #
682 AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
683
684 if test "x$ENDIAN" = xuniversal_endianness; then
685 AC_MSG_ERROR([Building with both big and little endianness is not supported])
686 fi
687 if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
688 AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
689 fi
690 ])